Télécharger la plaquette Cast3M


fr en

Télécharger rendsour.procedur

Retour à la liste

Numérotation des lignes : 

  1. * RENDSOUR  PROCEDUR  SP204843  23/10/23    21:15:11     11770          
  2. debp RENDSOUR CGMOD1*CHARGEMENT CGMAT1*CHARGEMENT LREE1/LISTREEL MOT1/MOT ;
  3.  
  4. *-------------------------- ANALYSE ENTREES ---------------------------*
  5.  
  6. * Lecture des arguments optionnels :
  7. si (non (exis LREE1)) ;
  8.   LREE1    = extr CGMOD1 'LREE' ;
  9. fins ;
  10.  
  11. imoye1   = faux ;
  12. si (exis MOT1) ;
  13.   si (neg MOT1 'MOYE') ;
  14.     mess '*****  ERREUR : on attend le mot-clé ''MOYE'' ' ;
  15.     quit RENDSOUR ;
  16.   fins ;
  17.   imoye1   = vrai ;
  18. fins ;
  19.  
  20. *----------------------------- TRAITEMENT -----------------------------*
  21.  
  22. * Listobje :
  23. LMOD1    = extr CGMOD1 'LOBJ' ;
  24. LMAT1    = extr CGMAT1 'LOBJ' ;
  25.  
  26. * Tolerance sur intensite source :
  27. MAT1     = extr LMAT1 1 ;
  28. qmax1    = ((mat1 extr qtot 1 1 1) extr ordo) maxi abs ;
  29. tolq1    = 1.e-6 * qmax1 ;
  30.  
  31. * Initialisation des sorties :
  32. ltps1    = prog ;
  33. resu1    = prog ;
  34. lmoy1    = prog ;
  35.  
  36. * Boucles sur instants fournis :
  37. nb1      = dime lree1 ;
  38. repe bmes1 nb1 ;
  39.   floti1   = extr lree1 &bmes1 ;
  40.   modi1    = tire CGMOD1 mode floti1 ;
  41.   chvari1  = manu chml modi1 temp floti1 ;
  42.   mati1    = tire CGMAT1 mate floti1 ;
  43.   mati1    = vari nuag modi1 mati1 chvari1 ;
  44.   qtoti1   = (exco mati1 qtot) maxi ;
  45.   si imoye1 ;
  46.     si ((abs qtoti1) < tolq1) ;
  47.       resui1   = qtoti1 ;
  48.     sino ;
  49.       chqi1    = sour modi1 mati1 ;
  50.       resui1   = (resu chqi1) maxi ;
  51.       resui1   = resui1 / qtoti1 ;
  52.     fins ;
  53.     si (&bmes1 > 1) ;
  54.       moyei1   = 0.5 * (resui0 + resui1) ;
  55.       si (moyei1 >EG tolq1) ;
  56.         lmoy1    = lmoy1 et moyei1 ;
  57.       fins ;
  58.     fins ;
  59.     qtoti0   = qtoti1 ;
  60.     resui0   = resui1 ;
  61.   sino ;
  62.     si ((abs qtoti1) < tolq1) ; iter bmes1 ; fins ;
  63.     chqi1    = sour modi1 mati1 ;
  64.     resui1   = (resu chqi1) maxi ;
  65.     resui1   = resui1 / qtoti1 ;
  66.     resu1    = resu1 et resui1 ;
  67.     ltps1    = ltps1 et floti1 ;
  68.   fins ;
  69. fin bmes1 ;
  70.  
  71. * Mise en forme resultat :
  72. si imoye1 ;
  73.   resu1    = (somm lmoy1) / ((dime lmoy1) flot) ;
  74. sino ;
  75.   si (nb1 ega 1) ;
  76.     resu1  = resu1 extr 1 ;
  77.   sino ;
  78.     resu1  = evol manu 'TEMP' ltps1 resu1 ;
  79.   fins ;
  80. fins ;
  81.  
  82. *------------------------------- SORTIE -------------------------------*
  83.  
  84. finp RESU1 ;
  85.  
  86.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales