Télécharger ricrag_2d.dgibi

Retour à la liste

Numérotation des lignes :

  1. *******************************************************
  2. ************************************************************************
  3. ************************************************************************
  4. * Cas test de l'implantation numérique du modele
  5. * RICRAG 2D LOCAL/NON LOCAL
  6. *******************************************************
  7. * Développé par :
  8. * Benjamin Richard
  9. * Contact :
  10. * Benjamin.Richard@lmt.ens-cachan.fr
  11. *******************************************************
  12. * Les cas de charges sont entrés :
  13. * - 1 : Traction monotone
  14. * - 2 : Compression monotone
  15. * - 3 : Traction cyclique
  16. * - 4 : Compression cyclique
  17. * - 5 : Traction/compression cyclique
  18. *******************************************************
  19. * Choix du cas de charge
  20. ncas = 1;
  21.  
  22. * Test du fichier compatible avec le non local
  23. * nloc0 = 0; Cas local
  24. * nloc0 = 1; Cas non local
  25. graph= mot 'N';
  26. nloc0 = 0;
  27. *******************************************************
  28.  
  29. *
  30. *-------------- Options de calcul ---------------------
  31. *
  32. OPTION DIME 2 ELEM QUA4 MODE PLAN CONT;
  33.  
  34. *
  35. *-------------- Definition de la geometrie ------------
  36. *
  37. P1 = 0. 0.;
  38. P2 = 1. 0.;
  39. P3 = 1. 1.;
  40. P4 = 0. 1.;
  41.  
  42. L1 = P1 DROIT 1 P2 ;
  43. L2 = P2 DROIT 1 P3 ;
  44. L3 = P3 DROIT 1 P4 ;
  45. L4 = P4 DROIT 1 P1 ;
  46.  
  47. LTOT = L1 ET L2 ET L3 ET L4 ;
  48.  
  49. S1 = SURF LTOT PLANE;
  50.  
  51. *
  52. *------- Définition des conditions aux limites --------
  53. *----------- et des déplacements imposés --------------
  54. *
  55. CL = BLOQ P1 UX UY;
  56. CLL = BLOQ P2 UY;
  57. CL1 = BLOQ L3 UY;
  58.  
  59. D1 = DEPI CL1 1;
  60.  
  61. *
  62. *----- Définition du modèle ---------------------------
  63. *
  64. SI ( EGA nloc0 1 ) ;
  65. MOD1 = MODE S1 MECANIQUE ELASTIQUE ISOTROPE
  66. ENDOMMAGEMENT RICRAG
  67. 'NON_LOCAL' 'MOYE' 'V_MOYENNE' (MOTS 'EPTI') ;
  68. SINON ;
  69. MOD1 = MODE S1 MECANIQUE ELASTIQUE ISOTROPE
  70. ENDOMMAGEMENT RICRAG ;
  71. FINSI ;
  72.  
  73.  
  74. *
  75. *----- Paramètres matériaux ---------------------------
  76. *
  77.  
  78. * Module d'Young
  79. youngn = 36000E+6;
  80.  
  81. * Coefficient de Poisson
  82. nun = 0.2;
  83.  
  84. * Résistance en traction
  85. ftn = 3.6e6;
  86.  
  87. * Fragilité en traction
  88. aldin = 1.0e-2;
  89.  
  90. * Fragilité en compression
  91. alinn = 5.0e-4;
  92.  
  93. * Module d'écrouissage 1
  94. gam1n = 7.0e9;
  95.  
  96. * Moduke d'écrouissage 2
  97. a1n = 7.0e-7;
  98.  
  99. mat1 =MATE mod1 YOUN youngn NU nun
  100. FT ftn ALIN alinn
  101. GAM1 gam1n A1 a1n
  102. ALDI aldin;
  103.  
  104. *
  105. *----- Définition des cas de charge -------------------
  106. *
  107.  
  108. SI (EGA ncas 1) ;
  109. LI1 = PROG 0. 1.;
  110. LI2 = PROG 0. 4.0e-4;
  111. LIS1 = PROG 0. PAS 0.02 1.;
  112. FINSI;
  113.  
  114. SI (EGA ncas 2) ;
  115. LI1 = PROG 0. 1.;
  116. LI2 = PROG 0. -8.0e-3;
  117. LIS1 = PROG 0. PAS 0.02 1.;
  118. FINSI;
  119.  
  120. SI (EGA ncas 3) ;
  121. LI1 = PROG 0. 1. 2. 3. 4. 5.;
  122. LI2 = PROG 0. 1.5e-4 9.5e-6 2.0E-4 3.0E-5 2.5E-4;
  123. LIS1 = PROG 0. PAS 0.02 5.;
  124. FINSI;
  125.  
  126. SI (EGA ncas 4) ;
  127. LI1 = PROG 0. 1. 2. 3. 4. 5.;
  128. LI2 = PROG 0. -3.0e-3 -1.5e-4 -5.0E-3 -3.5E-4 -8.0E-3;
  129. LIS1 = PROG 0. PAS 0.02 5.;
  130. FINSI;
  131.  
  132. SI (EGA ncas 5) ;
  133. LI1 = PROG 0. 1. 2. 3. 4. 5. 6.;
  134. LI2 = PROG 0. 1.3e-4 -3.0e-3 -1.5E-4 -5.0E-3 -3.5E-4 -8.0E-3;
  135. LIS1 = PROG 0. PAS 0.02 6;
  136. FINSI;
  137.  
  138. EV = EVOL MANU LI1 LI2 ;
  139. CHA1 = CHAR 'DIMP' D1 EV ;
  140.  
  141. *
  142. *----------- Calcul par l'operateur PASAPAS ------------
  143. *
  144. SI (EGA nloc0 1);
  145. LC = 0.000001;
  146. CO1 = CONNEC mod1 LC NORMAL;
  147. MAT1 = MAT1 ET ( MATE MOD1 'LCAR' LC) ;
  148. FINSI;
  149.  
  150. TAB1 = TABLE ;
  151. TAB1.'BLOCAGES_MECANIQUES' = CL ET CLL ET CL1;
  152. TAB1.'MODELE' = MOD1;
  153. TAB1.'MOVA' = 'D ';
  154. TAB1.'CHARGEMENT' = CHA1;
  155. TAB1.'CARACTERISTIQUES' = MAT1;
  156. TAB1.'TEMPS_CALCULES' = LIS1;
  157.  
  158. SI (EGA nloc0 1);
  159. TAB1.CONN = CO1;
  160. FINSI;
  161.  
  162. PASAPAS TAB1 ;
  163.  
  164. *
  165. *----------- Courbe effort-deplacement -----------------
  166. *
  167. ev2=@global tab1 CL1 EV fy;
  168. si ( ega graph 'O');
  169.  
  170. DESS EV2;
  171. finsi;
  172. ee = extr ev2 ordo 1;
  173. aa = extr ee ( dime ee);
  174. list aa;
  175. err = abs (aa - 2.37395E+06) /2.37395E+06 ;
  176. message ' erreur relative ' err;
  177. si (err > 1.e-3);
  178. erreur (5);
  179. finsi;
  180. fin;
  181.  
  182.  
  183.  
  184.  
  185.  
  186.  
  187.  
  188.  
  189.  
  190.  
  191.  
  192.  
  193.  
  194.  
  195.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales