Télécharger waam4.dgibi

Retour à la liste

* fichier waam4.dgibi
 
* section : thermique conduction convection
*----------------------------------------------------------------------*
*                         W A A M 4 . D G I B I                        *
*----------------------------------------------------------------------*
* Objet :                                                              
* -------
*
*    Exemple de simulation thermique d'une fabrication additive en WAAM.
* L'exemple simule la realisation d'un piquage a 45 degres sur un tube
* (tube A). Le depot et le tube A sont en acier 316L.
*
*    On modelise la conduction, la convection et le rayonnement avec le
* milieu ambiant. La source de chaleur suit une distribution gaussienne.
*
*    L'apport de matiere est defini a l'aide d'un chargement de nom MODE
* qui decrit l'evolution du modele au cours du temps. Un chargement de
* nom MATE definit celle de ses caracteristiques.
*
*    La modelisation fait appel a la procedure SOUDAGE pour definir la 
* sequence de fabrication et indexer l'appartion des mailles au cours
* du temps le long de la trajectoire de l'outil (sequancage de l'apport
* de matiere).
*
*    Cet exemple sert notamment a verifier le bon fonctionnement de
* l'option MAIL de la procedure SOUDAGE utilisee pour le sequencage du
* maillage dans le cas d'une trajectoire circulaire fermee.
*
*    Un test de non regression est realise sur la temperature en un point
* et un instant donne du calcul.
*
* Description :
* -------------
*
* Type de calcul : Thermique Transitoire
* Mode de calcul : 3D
* Type d'element : CUB8, PRI6, TET4
* Chargement     : Source de chaleur, Convection, Rayonnement,
*                  Apport de matiere
*
*----------------------------------------------------------------------*
opti dime 3 elem cub8 ; 
 
opti trac psc ;
 
* Pour affichages, mettre IG1 a VRAI :
ig1      = faux ;
 
* Pour sortie PS sequencage apport de matiere, mettre ISEQMAIL a VRAI :
iseqmail = faux ;
 
* Pour sortie PS champ temperature au cours du temps, mettre ITANIM a VRAI :
iT_anim  = faux ;
 
* Pour calcul complet, mettre ICOMPLET a VRAI :
icomplet = faux ;
 
*----------------------------------------------------------------------*
*                         Parametres du modele                         *
*----------------------------------------------------------------------*
 
*------------------ Parametres geometrie et maillage ------------------*
 
* Rae1   : rayon exte. tube A (m)
* Rai1   : rayon inte. tube A (m)
* Rbe1   : rayon exte. tube B (m)
* Rbi1   : rayon inte. tube B (m)
* Rbm1   : rayon moyen tube B (m)
* Angl1  : angle axes tubes A et B (degres)
* Np1    : nombre de passe de fabrication
* epp1   : epaisseur d'une passe
* de1    : densite maillage passe (tube B)
* de2    : densite maillage tube A
* ne1    : nombre d'element sur la trajectoire circulaire d'une passe
* ne2    : nombre d'element sur le perimetre du tube fabrique
Rae1     = 150.e-3 ; 
Rai1     = 135.e-3 ; 
Rbe1     = 100.e-3 ; 
Epb1     =  10.e-3 ;
Rbi1     = Rbe1 - Epb1 ;
Rbm1     = 0.5 * (Rbe1 + Rbi1) ;
Angl1    = 45. ; 
Np1      = 5 ;
epp1     = 4.e-3 ;
de1      = 2.e-3 ;
de2      = 10. * de1 ;
ne1      = 40 ;
ne2      = enti (2. * pi * Rbm1 / de1 + 0.5) ;
ne2      = ne2  / 2 ;
ne2      = ne2 - (ne2 - (ne2 / 4 * 4)) ; comm ne2 doit etre un multiple de 4 ;
 
*----------------------- Parametres fabrication -----------------------*
 
* Us1/Us2 : tension 1ere/autres passes
* Is1/Is2 : intensite 1ere/autres passes
* eta1    : rendement 
* dtini1  : duree prechauffage 1ere passe (s)
* dtpasse1: temps de pause entre 2 passes (s)
* Dfil1   : diametre de fil (m)
* Vfil1   : vitesse de debit de fil (m/s)
* Vs1     : vitesse de soudage (m/s) 
* Rg1     : rayon source Gaussienne (m)
* Zg1     : profondeur source Gaussienne (m)
Us1      = 30. ;
Us2      = 25. ;
Is1      = 250. ;
Is2      = 250. ;
eta1     = 0.8 ;
dtini1   = 1.0 ;
dtpasse1 = 600.  ;
Dfil1    = 2.e-3 ;
Vfil1    = 3.5 / 60. ;
Vs1      = 300.e-3 / 60. ;
Rg1      = 5.e-3 ;
Zg1      = 3.e-3 ;
 
*----------------- Parametres modelisation thermique ------------------*
 
* T0      : temperature initiale et ambiante (degC)
* H1      : coefficient de convection (W/m2)
* Em1     : emissivite
ZeroC1   = 273.16 ;
T0       = 20. + ZeroC1 ;
H1       = 20. ;
Em1      = 0.5 ;
 
*----------------------------------------------------------------------*
*                               MAILLAGE                               *
*----------------------------------------------------------------------*
 
* Repere :
O1       = 0 0 0 ; 
X1       = 1 0 0 ; 
y1       = 0 1 0 ; 
z1       = 0 0 1 ; 
 
*------------------------- Maillage du depot --------------------------*
 
* Points et lignes de de construction :
PCA1     = 1 0 0 ; 
PCB1     = 1 0 0 ; 
PAE1     = PCA1 plus (Rae1 * Y1) ; 
PAI1     = PCA1 plus (Rai1 * Y1) ; 
PBE1     = PCB1 plus (Rbe1 * Y1) ; 
PBI1     = PCB1 plus (Rbi1 * Y1) ; 
RBM1     = (0.2 * Rbi1) + (0.8 * Rbe1) ;
PBM1     = PCB1 plus (Rbm1 * Y1) ; 
 
* Diametres ext., int. et moyen du tube B oriente suivant Ox ;
LCBM1    = cerc ne1 rota 360. PBM1 O1 PCB1 ;
LCBE1    = cerc ne2 rota 360. PBE1 O1 PCB1 elim ;
LCBI1    = cerc ne2 rota 360. PBI1 O1 PCB1 elim ;
LCBM1    = LCBM1 coul vert ;
LCBE1    = LCBE1 coul roug ;
LCBI1    = LCBI1 coul bleu ;
 
* Rotation lignes de contruction tube B a Angl1 de Ox :
LCBE1 LCBI1 LCBM1 PCB1 = LCBE1 LCBI1 LCBM1 PCB1 tour Angl1 Y1 O1 ;
 
* Projections surfaces sur tube A :
Sb1      = LCBE1 regl LCBI1 dini de1 dfin de1 ;
Sb2      = Sb1   proj dire (O1 moin PCB1) cyli O1 PCA1 PAE1 ;
LCBM2    = LCBM1 proj dire (O1 moin PCB1) cyli O1 PCA1 PAE1 ;
PCB2     = PCB1  proj dire (O1 moin PCB1) cyli O1 PCA1 PAE1 ;
*trac (LCBE1 et LCBI1 et LCBM1) (1000. * PCB1) titr mot1 ;;
 
* Construction maillage passe par passe &
* Construction de la trajectoire :
nep1     = enti (epp1/de1+0.5) ;
VTB0     = vide maillage ;
ltrj1    = LCBM2 coul roug ;
ttrj1    = table ;
Si1      = Sb2 ;
Pi1      = Si1 poin proc O1 ;
repe bpasse1 Np1 ;
  i1       = &bpasse1 ;
 
* Maillage passe :
  Vi1      = Si1 volu nep1 tran (epp1*PCB1) ;
  Vi1      = Vi1 coul i1 ;
  VTB0     = VTB0 et Vi1 ;
  Si1      = Vi1 face 2 ;
*trac (Si1 et (aret VTB0)) ;
 
* Maillage trajectoire :
  Pi2      = Si1 poin proc O1 ;
  ltrj1    = ltrj1 plus (Pi2 moin Pi1) ;
  ttrj1 . i1 = ltrj1 ;
  Pi1       = Pi2 ;
  ltrj1    = inve ltrj1 ;
*trac (ltrj1 et (aret VTB0)) ;
fin bpasse1 ;
 
*----------------------- Tests option PROJ CYLI -----------------------*
 
LCAE1    = cerc ne2 rota 360. PAE1 O1 PCA1 elim ;
LCAI1    = cerc ne2 rota 360. PAI1 O1 PCA1 elim ;
LCA0     = LCAE1 et LCAI1 ;
LCA0     = LCA0 plus ((((bary sb2) moin (bary LCA0)) psca X1) * X1) ;
OB1      = bary LCA0 ;
 
SB3      = SB2 proj cyli O1 PCA1 cyli OB1 PCA1 PAI1 ;
SBX      = (SB2 coul roug) et (SB3 coul vert) ;
si ig1 ;
  trac (SBX et LCA0) (10000*X1) titr 'Sur un cylindre : vue dans l''axe de projection cylindrique' ;
  trac (SBX et LCA0) (10000*Y1) titr 'Sur un cylindre : vue // a l''axe de projection cylindrique' ;
fins ;
 
SB3      = SB2 proj cyli O1 PCA1 plan (0 0 RAE1) (1 0 RAE1) (0 1 RAE1) ;
SBX      = (SB2 coul roug) et (SB3 coul vert) ;
si ig1 ;
  trac (SBX et LCA0) (10000*X1) titr 'Sur un plan : vue dans l''axe de projection cylindrique' ;
  trac (SBX et LCA0) (10000*Y1) titr 'Sur un plan : vue // a l''axe de projection cylindrique' ;
fins ;
 
SB3      = SB2 proj cyli O1 PCA1 sphe OB1 (0 0 RAI1) ;
SBX      = (SB2 coul roug) et (SB3 coul vert) ;
si ig1 ;
  trac (SBX et LCA0) (10000*X1) titr 'Sur une sphere : vue dans l''axe de projection cylindrique' ;
  trac (SBX et LCA0) (10000*Y1) titr 'Sur une sphere : vue // a l''axe de projection cylindrique' ;
fins ;
 
SB3      = SB2 proj cyli O1 PCA1 coni (OB1 plus (RAE1*Z1)) (OB1 plus Z1) (OB1 plus (2.*RAE1*X1)) ;
SBX      = (SB2 coul roug) et (SB3 coul vert) ;
si ig1 ;
  trac (SBX et LCA0) (10000*X1) titr 'Sur un cone : vue dans l''axe de projection cylindrique' ;
  trac (SBX et LCA0) (10000*Y1) titr 'Sur un cone : vue // a l''axe de projection cylindrique' ;
fins ;
 
SB3      = SB2 proj cyli O1 PCA1 tori (0 0 -10) (1 1 -10) OB1 (1.5*RAI1*Z1) ;
SBX      = (SB2 coul roug) et (SB3 coul vert) ;
si ig1 ;
  trac (SBX et LCA0) (10000*X1) titr 'Sur un tore : vue dans l''axe de projection cylindrique' ;
  trac (SBX et LCA0) (10000*Y1) titr 'Sur un tore : vue // a l''axe de projection cylindrique' ;
fins ;
 
*------------------------- Maillage du tube A -------------------------*
 
* Maillage tranche tube A sous surface base tube B :
Stai1    = Sb2 proj cyli O1 X1 cyli O1 X1 (Rai1 * Y1) ;
*Stai1    = Sb2 proj dire (O1 moin pcb1) cyli O1 X1 (Rai1 * Y1) ;
Vta1     = Sb2 volu Stai1 dini de1 dfin (5.*de1) ;
*opti trac x ; trac face (1000*X1) (VTA1 et vtb0) ; opti trac psc ;
 
* Surface exterieure :
dXA1     = Rbe1 / (cos 45.) + (Rae1 + Rbe1 * 0.2) ;
PTA1     = PCB2 moin (dXA1 * X1) moin ((PCB2 coor 3) * Z1) plus (Rae1 * Y1) ;
LTA1     = PTA1 cerc dini de2 dfin de2 rota O1 X1 180. ;
PTA2     = LTA1 poin (nbno LTA1) ;
LTA3     = LTA1 plus (2. * dXA1 * X1) ;
LTA3     = inve LTA3 ;
PTA3     = LTA3 poin 1 ;
PTA4     = LTA3 poin (nbno LTA3) ;
LTA2     = PTA2 droi PTA3 dini de2 dfin de2 ;
LTA4     = PTA4 droi PTA1 dini de2 dfin de2 ;
 
* Contour du tube B :
tsb2     = (cont sb2) part nesc conn ;
csbe2    = tsb2 . 1 ;
si ((mesu csbe2) < (mesu tsb2 . 2)) ;
  csbe2    = tsb2 . 2 ;
fins ;
 
* Contour global et maillage surface exte. tube A :
LTA0     = LTA1 et LTA2 et LTA3 et LTA4 et (inve csbe2) ;
STA1     = surf LTA0 cyli O1 X1 ;
 
* Surace interieure :
LTA5     = LTA1 proj coni ((PTA1 plus PTA2) * 0.5) cyli O1 X1 (Rai1 * Y1) ;
PTA5     = LTA5 poin 1 ;
PTA6     = LTA5 poin (nbno LTA5) ;
LTA7     = LTA5 plus (2. * dXA1 * X1) ;
PTA7     = LTA7 poin (nbno LTA7) ;
PTA8     = LTA7 poin 1 ;
LTA6     = PTA6 droi PTA7 dini de2 dfin de2 ;
LTA8     = PTA8 droi PTA5 dini de2 dfin de2 ;
 
* Contour exte. Stai1 :
tstai1   = (cont Stai1) part nesc conn ;
cstai1   = tstai1  . 1 ;
si ((mesu cstai1) < (mesu tstai1 . 2)) ;
  cstai1   = tstai1  . 2 ;
fins ;
 
* Contour global et maillage surface inte. tube A :
LTA02    = (LTA5 et LTA6 et LTA7 et LTA8) elem comp PTA5 PTA5 ;
LTA02    = LTA02 et (inve cstai1) ;
STA2     = surf LTA02 cyli O1 X1 ;
 
* Bords :
STA3     = LTA0 regl LTA02 2 ;
 
* Volume partie sup. tube A :
VTA2     = volu ((sta1 et sta2 et sta3) chan tri3) ;
 
* Extensions axiales :
ptx0     = (VTA2 coor 1) poin mini ;
ptx1     = (VTA2 coor 1) poin maxi ;
STAx0    = (enve VTA2) elem appu stri ptx0 ;
STAx1    = (enve VTA2) elem appu stri ptx1 ;
VTAx0    = STAx0 volu tran 1 (-2. * Rae1 * X1) ;
VTAx1    = STAx1 volu tran 1 (+2. * Rae1 * X1) ;
VTA3     = VTAx0 et VTAx1 ;
 
* Volume partie infe. (opposee au piquage) :
ptz0     = ((VTA2 et VTA3) coor 3) poin infe 1.e-6 ;
ptz0     = (ptz0 coor 2) poin supe 0. ;
STAz0    = ((VTA2 et VTA3) enve) elem appu stri ptz0 ;
VTA4     = STAz0 volu 10 rota -180. O1 X1 ;
 
* Maillage total tube A :
VTA0     = (VTA1 et VTA2 et VTA3 et VTA4) coul turq ;
elim VTA0 1.e-6 ;
 
*------------------------ Affichages Maillages ------------------------*
 
oeil1    = -100 100 80 ;
si ig1 ;
  trac oeil1 face (VTA0 et VTB0) titr 'Maillage tube (turquoise) et piquage par depot WAAM' ;
  trac (100*Y1) face (VTA0 et VTB0) boit (boite VTB0) titr 'Maillage tube et piquage : detail piquage vue cote' ;
fins ;
 
*----------------------------------------------------------------------*
*                        Sequence de fabrication                       *
*----------------------------------------------------------------------*
 
* Puissances de soudage :
Qs1      = eta1 * Us1 * Is1 ;
Qs2      = eta1 * Us2 * Is2 ;
 
* Vitesse de deplacement entre 2 passes pour un temps de pause donnee :
ldepl1   = ((ttrj1 . 1) poin 1) droi 1 ((ttrj1 . 2) poin 2) ;
vdepl1   = (mesu ldepl1) / dtpasse1 ;
 
* Donnees d'entree :
tfab1    = table ;
tfab1 . vitesse_de_soudage       = Vs1 ;
tfab1 . vitesse_de_deplacement   = vdepl1 ;
tfab1 . puissance_de_soudage     = Qs2 ;
tfab1 . debit_de_fil             = 0.25 * pi * Dfil1 * Dfil1 * Vfil1 ;
tfab1 . point_de_depart          = (ttrj1 . 1) poin 1 ;
tfab1 . temps_de_coupure         = 0.5 ;
 
* Sequence de fabrication :
soudage tfab1 point dtini1 puis Qs1 debi 0. ;
nfab1    = dime ttrj1 ;
repe bfab1 nfab1 ;
  si (&bfab1 ega 1) ;
    soudage tfab1 passe mail (ttrj1 . &bfab1) puis Qs1 ;
  sino ;
    soudage tfab1 passe mail (ttrj1 . &bfab1) ;
  fins ;
  si (&bfab1 ega nfab1) ; quit bfab1 ; fins ;
  soudage tfab1 depla droi ((ttrj1 . (&bfab1+1)) poin 1) abso vite vdepl1 ;
fin bfab1 ;
soudage tfab1 point dtpasse1 puis 0. debi 0. ;
 
* Affichages sequence de fabrication :
si ig1 ;
  opti oeil (PCB2 plus Z1) ;
  trac tfab1.trajectoire           titr 'trajectoire realisation piquage' ;
  dess tfab1.evolution_deplacement titr 'evolution deplacement' ;
  dess tfab1.evolution_puissance   titr 'evolution puissance thermique' ;
  dess tfab1.evolution_debit       titr 'evolution debit apport de matiere' ;
fins ;
 
*-------------------- Sequencage apport de matiere --------------------*
 
* Sequencage maillage le long de la trajectoire :
tseq1    = soudage tfab1 mail VTB0 pas 10.e-3 temp ;
ttps1    = tseq1 . evolution_maillage . temps ;
tmai1    = tseq1 . evolution_maillage . maillage ;
 
oeil2    = 100 50 150. ;
si iseqmail ;
  si (ega (vale trac) 'PSC') ; opti ftra 'waam4_sequ_mail.ps' ; fins ;
  mbox1    = boite VTB0 ;
  i1       = 0 ;
  repe b1 (dime tmai1) ;
    geoi1    = tmai1 . i1 ;
    trac oeil2 face (geoi1 et VTA0) titr 'Sequencage du maillage du depot' boit mbox1 ;
    i1       = i1 + 1 ;
  fin b1 ;
fins ;
 
*----------------------------------------------------------------------*
*                        Modelisation Thermique                        *
*----------------------------------------------------------------------*
 
* Donnees materiau :
t316L    = biblio '316L' ;
rho1     = ipol t316L.'RHO' (T0-Zeroc1) ;
evk1     = t316L.'K' + Zeroc1 absc ;
evc1     = t316L.'C' + Zeroc1 absc ;
 
* Modele de conduction :
VT0      = VTA0 et VTB0 ;
mod1     = mode VT0  thermique conduction ;
mat1     = mate mod1 'RHO' rho1 'C' evc1 'K' evk1 'TINI' T0 ;
 
* Modele source thermique :
* Evolution de la position de la source :
evqt1    = tfab1.evolution_puissance ;
evxs1    = tfab1.evolution_deplacement ;
chxs1    = tfab1.trajectoire coor curv ;
cgxs1    = char traj chxs1 evxs1 ;
 
* Evolution de la direction de la source :
* On donne la normale au tube en chaque point de la trajectoire.
* L'axe du tube est selon (O,x), la normale est donc selon la coord.
* (y,z) de chaque point.
ltraj1   = tfab1.trajectoire ;
ldir1    = enum ;
ltpx1    = prog ;
evtxs1   = evol manu (evxs1 extr ordo) (evxs1 extr absc) ;
nbdir1   = nbno ltraj1 ;
tps0     = -1. ;
ddir1    = vide maillage ;
repe bdir1 nbdir1 ;
  pi1      = ltraj1 poin &bdir1 ;
  xsi1     = extr chxs1 scal pi1 ;
  txi1     = ipol evtxs1 xsi1 ;
  si (txi1 > tps0) ;
    pni1     = 0. (pi1 coor 2) (pi1 coor 3) ;
    ldir1    = ldir1 et (enum pni1) ;
    ltpx1    = ltpx1 et txi1 ;
    ddir1    = ddir1 et (pi1 droi 1 (pi1 plus pni1)) ;
  fins ;
fin bdir1 ;
cgdir1   = char dire ltpx1 ldir1 ;
 
* Visualisation :
si ig1 ;
  mbox1    = boite VTB0 ;
  ddir1    = ddir1 coul oran ;
  trac (100 100 20) face (VTA0 et VTB0 et ddir1) boit mbox1 titr 'Directions d''orientation de la source de chaleur' ;
fins ;
 
* Definition du modele :
mod2     = mode VT0  thermique source gaussienne elliptique ;
mat2     = mate mod2 'QTOT' evqt1 'ORIG' cgxs1 'DIRE' cgdir1 'RGAU' Rg1 'ZGAU' Zg1 ;
 
* Sequencage modeles :
ltps1    = prog tabl ttps1 ;
nb1      = dime tmai1 ;
lgeo0    = enum nb1*vta0 ;
lgeo1    = enum 'TABL' tmai1 ;
 
* Vectorisation des operations sur les listes de maillages et de modeles
* en activant la parallelisation :
opti para vrai ;
lgeo1    = lgeo0 et lgeo1 ;
lgeo2    = enve lgeo1 ;
lmod1    = redu lgeo1 (mod1 et mod2) ;
lmat1    = redu lmod1 (mat1 et mat2) ;
lmod2    = mode lgeo2 thermique convection ;
lmat2    = mate lmod2 'H' h1 'TC' T0 ;
lmod3    = mode lgeo2 thermique rayonnement infini ;
lmat3    = mate lmod3 'EMIS' Em1 'T_IN' T0 ;
 
* Chargements MODE / MATE :
opti para faux ;
* Retour en sequentiel : chaque commande sert de point d'arret
cgmod1   = char mode ltps1 lmod1 ;
cgmod2   = char mode ltps1 lmod2 ;
cgmod3   = char mode ltps1 lmod3 ;
cgmod0   = cgmod1 et cgmod2 et cgmod3 ;
 
cgmat1   = char mate ltps1 lmat1 ;
cgmat2   = char mate ltps1 lmat2 ;
cgmat3   = char mate ltps1 lmat3 ;
cgmat0   = cgmat1 et cgmat2 et cgmat3 ;
 
*------------------------- Resolution PASAPAS -------------------------*
 
ltca0    = tseq1.temps_calcules ;
si icomplet ;
  ltca1    = ltca0 ;
sino ;
  ltca1    = ltca0 extr (lect 1 pas 1 11) ;
fins ;
list ltca1 ;
 
tpas1                     = table ;
tpas1.modele              = cgmod0 ;
tpas1.caracteristiques    = cgmat0 ;
tpas1.temps_calcules      = ltca1 ;
 
temp zero ;
 
pasapas tpas1 ;
 
* Affichage temps de calcul : 
duree1   = temp horl ;
duree1   = (duree1 / 1000) ;
dmin1    = (duree1  / 60) ;
dsec1    = duree1  - (60 * dmin1) ;
mot1     = chai '*****  DUREE DU CALCUL (s) :' dmin1 ' min' dsec1 ' s' ;
mess mot1 ;
 
si icomplet ;
  opti sauv 'waam4.sauv' ;
  sauv ;
fins ;
 
*------------------------ Petit post-traitement -----------------------*
 
si iT_anim ;
  si (ega (vale trac) 'PSC') ; opti ftra 'waam4_T_anim.ps' ; fins ;
 
* Sorties PS du champ de temperature :
* Image toutes les :
* - dtimag1 quand puiss. thermique non nulle
* - FFwd1*dtimag1 sinon.
  dtimag1  = 2. ;
  si (ega (vale trac) 'PSC') ; dtimag1  = 0.5 ; fins ;
  FFwd1    = 10. ;
  liso1    = prog 50. 100. PAS 150. 1450. ;
  mbox1    = boite VTB0 ;
  tpsf1    = tpas1.temps . ((dime tpas1.temps) - 1) ;
  ifin1    = faux ;
  tpsi1    = 0. ;
  repe b1 ;
    modi1    = peche tpas1 modeles tpsi1 ipol ;
    geoi1    = (extr modi1 mate conduction) extr mail ;
    chti1    = peche tpas1 temperatures tpsi1 ipol ;
    chti1    = chti1 - ZeroC1 ;
    ptrj1    = tire cgxs1 traj tpsi1 ;
    Ri1      = ((ptrj1 coor 2) ** 2) + ((ptrj1 coor 3) ** 2) ** 0.5 ;
    yi1      = ptrj1 coor 2 ;
    thetai1  = yi1 / Ri1 * 180. / pi ;
    depl geoi1 tour thetai1 O1 X1 ;
    mot1     = chai format '(F6.1)' 'Temperature (degC) au temps (s) :' tpsi1 ;
    trac (100 0 100) chti1 geoi1 liso1 titr mot1 boit mbox1 ;
    depl geoi1 tour thetai1 X1 O1 ;
    tpsi1    = tpsi1 + dtimag1 ;
    qti1     = ipol evqt1 tpsi1 ;
    si (qti1 < 1.) ; comm si puissance nulle, on accelere le film (xFFwd1) ;
      tpsi1    = (FFwd1 - 1.) * dtimag1 + tpsi1 ;
    fins ;
    si (tpsi1 > tpsf1) ;
      si ifin1 ;
        quit b1 ;
      sino ;
        tpsi1    = tpsf1 ;
        ifin1    = vrai  ;
      fins ;
    fins ;
  fin b1 ;
 
fins ;
 
*------------------------- Test non-regression ------------------------*
 
ttest1   = tpas1.temps.10 ;
temp1    = peche tpas1 temperatures ttest1 ipol ;
tmax1    = maxi abs temp1 ;
tmaxref1 = 4596.8 ;
si ((abs (tmax1 - tmaxref1)) > 1.) ;
  erre 5 ;
fins ;
 
*------------------   F I N   W A A M 4 . D G I B I   -----------------*
fin ;
 
 
 
 
 
 
 
 
 

© Cast3M 2003 - Tous droits réservés.
Mentions légales