Télécharger waam.procedur

Retour à la liste

* WAAM      PROCEDUR  SP204843  25/05/07    21:15:02     12262          
DEBP WAAM TAB1*'TABLE' ;
 
*-------------------------- Initialisations ---------------------------*
 
* Lecture des options :
argu MOT1*'MOT' ;
 
* icas1 = 1 / 2 / 3 pour MAIL / VISU / MACRO
* Si 0 in fine : erreur.
icas1    = 0 ;
 
*----------------------------------------------------------------------*
*                             Option MAIL   
*----------------------------------------------------------------------*
 
si (ega mot1 'MAIL') ;
  icas1    = 1 ;
 
*----------------- Lecture des arguments de l'option ------------------*
 
  imot1    = faux ;
  imot2    = faux ;
  imot3    = faux ;
  imot4    = faux ;
  imot5    = faux ;
  repe b1 5 ;
    argu moti1/'MOT' ;
    si (non (exis moti1)) ; quit b1 ; fins ;
 
*   Arguments option MAIL :
    si (ega moti1 'PAS') ;
      imot1    = vrai ;
      argu  lpas1/'LISTREEL' ;
      si (exis lpas1) ;
        npas1    = dime lpas1 ;
        si (npas1 ega 0) ;
          erre '*****  ERREUR : le LISTREEL fourni est de dimension nulle.' ;
          quit waam ;
        fins ;
        pas1   = extr lpas1 1 ;
      sino ;
        argu  pas1*'FLOTTANT' ;
        lpas1    = prog pas1 ;
        npas1    = 1 ;
      fins ;
    fins ;
    si (ega moti1 'LARG') ;
      imot2    = vrai ;
      argu larg1*'FLOTTANT' ;
    fins ;
    si (ega moti1 'DENS') ;
      imot3    = vrai ;
      argu dens1*'FLOTTANT' ;
    fins ;
 
*   Arguments option TEMP :
    si (ega moti1 'TEMP') ;
      imot4    = vrai ;
      argu flot4/'FLOTTANT' ;
      si (non (exis flot4)) ;
        flot4    = 3. * Pi ;
      fins ;
    fins ;
    si (ega moti1 'MAXI') ;
      imot5    = vrai ;
      argu flot5*'FLOTTANT' ;
    fins ;
  fin b1 ;
  si (non imot1) ;
    erre '*****  ERREUR : il manque la donnee du PAS de discretisation du depot' ;
    quit waam ;
  fins ;
  si (non imot2) ;
    si (exis tab1 'LARGEUR_DE_PASSE') ;
      larg1    = tab1.largeur_de_passe ;
    sino ;
      erre '*****  ERREUR : il manque la donnee de la LARGeur du depot' ;
      quit waam ;
    fins ;
  fins ;
  si (non imot3) ;
    argu N1/'ENTIER' ;
    si (exis N1) ;
      N1       = maxi (lect N1 1) ;
    sino ;
      N1       = 1 ;
    fins ;
    dens1    = pas1 / (flot N1) ;
  fins ;
 
*------------------- MAILLAGE des passes de soudage -------------------*
 
  si (non (exis tab1 passes)) ;
    erre '*****  ERREUR : la table de SOUDAGE en entree n"a pas d"indice PASSES' ;
    quit waam ;
  fins ;
 
* Definition d'une tolerance geometrique :
  tol1     = 1.e-4 * dens1 ;
 
* Maillage d'une section de cordon :
  lsi1     = (0 0 0) droi (0 larg1 0) dini dens1 dfin dens1 ;
 
* Initialisattion sorties (MAIL) :
  tab2     = table ;
  ttps1    = table ;
  tmai1    = table ;
  indi1    = 0 ;
 
* On parcourt la trajectoire :
  mtraj1   = tab1.trajectoire ;
  mail2    = vide maillage ;
  idebui1  = vrai ;
  ibouci1  = faux ;
 
* Boucle sur elements de la trajectoire :
  nb1      = nbel mtraj1 ;
  repe b1 nb1 ;
 
*   Lecture ieme element de la trajectoire :
    eli1     = mtraj1 elem &b1 ;
    Pi1      = eli1 poin 1 ;
    Pi2      = eli1 poin 2 ;
    vai1     = Pi2 moin Pi1 ;
    vni1     = vai1 / (norm vai1) ;
    mcouli1  = (eli1 elem coul) extr 1 ;
    imaili1  = ega mcouli1 'ROUG' ;
    idepli1  = ega mcouli1 'VERT' ;
*
*   Segment VERT : deplacement
    si idepli1 ;
      idebui1  = vrai ;
      ibouci1  = faux ;
      iter b1 ;
    fins ;
*
*   Segment ROUGE : maillage
    si imaili1 ;
 
*     Si debut nouvelle passe :
      si idebui1 ;
 
*       Identification de la passe :
        npassi1  = 0 ;
        nbp1     = dime tab1.passes ;
        repe bp1 nbp1 ;
          mailpss1 = (tab1.passes.&bp1).maillage ;
          pps1 pps2 = (mailpss1 poin 1) (mailpss1 poin 2) ;
          si ((Pi1 ega pps1) et (Pi2 ega pps2)) ;
            tpassi1  = tab1.passes.&bp1 ;
            npassi1  = &bp1 ;
            mess '*****  WAAM : maillage de la passe :' npassi1 ;
            quit bp1 ;
          fins ;
        fin bp1 ;
        si (npassi1 ega 0) ;
          erre '*****  WAAM : passe non identifiee' ;
          quit waam ;
        fins ;
 
*       Hauteur de cordon :
        debi1    = tpassi1 . debit ;
        vite1    = tpassi1 . vitesse ;
        haut1    = debi1 / vite1 / larg1 ;
        mess (chai '*****  WAAM : hauteur de la passe :' npassi1 ' =' haut1) ;
 
*       Maillage :
*       si1       : maillage section courante :
*       vnsi1     : normale a la section 
        si1      = lsi1 tran (0 0 haut1) dini dens1 dfin dens1 ;
        vnsi1    = 1 0 0 ;
 
*       Positionnement extremite initiale (Pi1 au centre de l'arete superieure) :
        Pmsup1   = 0 (0.5*larg1) haut1 ;
        si1      = si1 plus (Pi1 moin Pmsup1) ;
 
*       Initialisation section extremite finale :
        si2      = si1 plus vai1 ;
        vnsi2    = vnsi1 ;
        angl2    = 0. ;
*
*       Orientation sections de maillage :
*       Par defaut, selon vni1 :
        vnsmai1  = vni1 ;
        vnsmai2  = vnsmai1 ;
 
*       Detection suite segments rouges et boucle :
        tpsi2    = tpassi1.instants extr 1 ;
        tpsi22   = tpassi1.instants extr 2 ;
        si (&b1 neg nb1) ;
          elip1    = mtraj1 elem (&b1 + 1) ;
          mcoulip1 = (elip1 elem coul) extr 1 ;
          isuiti1  = ega mcoulip1 'ROUG' ;
          isuiti2  = non (vide (elip1 inte mailpss1)) ;
          si (npassi1 neg nbp1) ;
            isuiti2  = isuiti2 ou (ega tpsi22 (tab1.passes.(npassi1+1).instants extr 1)) ;
          fins ;
          isuiti1  = isuiti1 et isuiti2 ;
          si isuiti1 ;
            vai2     = (elip1 poin 2) moin (elip1 poin 1) ;
            vni2     = vai2 / (norm vai2) ;
            vasmai2  = vni1 plus vni2 ;
            vnsmai2  = vasmai2 / (norm vasmai2) ;
            elfini1  = elip1 ;
            pfini1   = elip1 poin 2 ;
            nb2      = nb1 - (&b1 + 1) ;
            i2       = &b1 + 2 ;
*           Rq : si nb2 = 0, le bloc n'est pas execute
            repe b2 nb2 ;
              eli2     = mtraj1 elem i2 ;
              mcoul2   = (eli2 elem coul) extr 1 ;
              si (neg mcoul2 'ROUG') ; quit b2 ; fins ;
              pfini1   = eli2 poin 2 ;
              elfini1  = eli2 ;
              vafini1  = pfini1 moin (eli2 poin 1) ;
              vnfini1  = vafini1 / (norm vafini1) ;
              i2       = i2 + 1 ;
            fin b2 ;
            ibouci1  = (norm (pfini1 moin pi1)) < tol1 ;
            si ibouci1 ;
              mess '*****  WAAM : boucle fermee detectee' ;
*             On definit la normale a la section de maillage (SMA) :
              vasmai1  = vni1 plus vnfini1 ;
              vnsmai1  = vasmai1 / (norm vasmai1) ;
            fins ;
          fins ;
        fins ;
 
*       Orientation de si1 selon vnsmai1 :
*list vnsmai1 ; list vnsi1 ;
*trac (0 -0 3) (mtraj1 et mail2 et (si1 coul rose) et (si2 coul turq) et pi1 et pi2) ;
        vnnz1    = pvec vnsi1 vnsmai1 ;
        lvnnz1   = norm vnnz1 ;
*       Si sinus non nul a tol1 pres, on oriente la section :
        si (lvnnz1 neg 0. (tol1 / dens1)) ;
          si (lvnnz1 ega 1. (vale prec)) ; lvnnz1 = 1. ; fins ;
          angl1    = asin lvnnz1 ;
*list vnsi1 ; list vnsmai1 ; list angl1 ;
          si ((psca vnsmai1 vnsi1) < 0.) ;
            angl1    = 180. - angl1 ;
*mess ' on prend (180.-angl1)' ;
          fins ;
          si1      =  si1 tour angl1 pi1 (pi1 plus vnnz1) ;
          vnsi1     = vnsmai1 ;
          si2      = si1 plus vai1 ;
          vnsi2    = vnsi1 ;
          angl2    = 0. ;
        sino ;
          si ((psca vnsmai1 vnsi1) < 0.) ;
            vnsi1     = vnsmai1 ;
            si2      = si1 plus vai1 ;
            vnsi2    = vnsi1 ;
            angl2    = 0. ;
          fins ;
        fins ;
*list vnsi1 ; list angl1 ;
titr 'Debut de passe, apres orientation de si1' ;
*trac (0 0 100) (mtraj1 et mail2 et (si1 coul rose) et (si2 coul turq) et pi1 et pi2) ;
 
*       Si boucle, on garde la section de maillage du debut :
        si ibouci1 ;
          sfini1   = si1 ;
          vnfini1  = vnsmai1 ;
        fins ;
 
      sino ;
 
*       On a deja si1 correctement orientee.
*       On doit orienter si2.
*       Par defaut, orientation de si1 :
        si2      = si1 plus vai1 ;
        vnsi2    = vnsi1 ;
        angl2    = 0. ;
        vnsmai2  = vnsi2 ;
 
*       Si fin d'une boucle, orientation si2 connue :
        si (ibouci1 et (pi2 ega pfini1)) ;
          vnsmai2  = vnfini1 ;
        sino ;
          si (&b1 neg nb1) ;
            elip1    = mtraj1 elem (&b1 + 1) ;
            mcoulip1 = (elip1 elem coul) extr 1 ;
            isuiti1  = ega mcoulip1 'ROUG' ;
            si isuiti1 ;
              vai2     = (elip1 poin 2) moin (elip1 poin 1) ;
              vni2     = vai2 / (norm vai2) ;
              vasmai2  = vni1 plus vni2 ;
              vnsmai2  = vasmai2 / (norm vasmai2) ;
            fins ;
          fins ;
        fins ;
 
*     Fin "Si idebui1 / sinon" :
      fins ;
*
*     Orientation de si2 selon vnsmai2 :
*list vnsmai2 ; list vnsi2 ;
*trac (0 0 100) (mtraj1 et mail2 et (si1 coul rose) et (si2 coul turq) et pi1 et pi2 et (pi1 droi 1 (pi1 plus (0.01*vnsi1))) et (pi2 droi 1 (pi2 plus (0.01*vnsi2)))) titr 'Avant orientation si2' ;
      vnnz1    = pvec vnsi2 vnsmai2 ;
      lvnnz1   = norm vnnz1 ;
*     Si sinus non nul a tol1 pres, on oriente la section :
      si (lvnnz1 neg 0. (tol1 / dens1)) ;
        si (lvnnz1 ega 1. (vale prec)) ; lvnnz1 = 1. ; fins ;
        angl2    = asin lvnnz1 ;
        si ((psca vnsi2 vnsmai2) < 0.) ;
*mess ' on prend (180.-angl2)'  ; saut 1 lign ;
          angl2    = 180. - angl2 ;
        fins ;
        si2      =    si2 tour angl2     pi2 (pi2 plus vnnz1) ;
        vnsi2    =  vnsi2 tour angl2 (0 0 0)            vnnz1 ;
      sino ;
*       Pas sur que ça serve a quelque chose...
        si ((psca vnsi2 vnsmai2) < 0.) ;
          vnsi2     = vnsmai2 ;
          angl2    = 180. ;
        fins ;
      fins ;
titr 'En cours de passe, apres orientation de si2' ;
*trac (0 0 100) (mtraj1 et mail2 et (si1 coul rose) et (si2 coul turq) et pi1 et pi2 et (pi1 droi 1 (pi1 plus (0.01*vnsi1))) et (pi2 droi 1 (pi2 plus (0.01*vnsi2)))) ;
*si (ibouci1 et (pi2 ega pfini1)) ;
*trac (5 -2 3) (mtraj1 et mail2 et (si1 coul rose) et (si2 coul turq) et (si22 coul oran) et pi1 et pi2) ;
*fins ;
 
*---- Maillage du segment :
 
      llpas1   = somm (lpas1 enle npas1) ;
      leli1    = mesu eli1 ;
      si (leli1 &lt;EG llpas1) ;
        erre '*****  ERREUR : somme pas de discretisation > long. ' &b1 'e passe' ;
        quit waam ;
      fins ;
 
*     Boucle sur les pas de discretisation :
 
*     pasi1 : pas de discretisation courant
*     nei1  : nb maillages pour ce pas de discretisation du segment
*     pami1 : pas de maillage courant
*     nei2  : nbel crees par pas de maillage
 
      idebui1  = non isuiti1 ;
      repe bp1 npas1 ;
        pasi1    = extr lpas1 &bp1 ;
        si (&bp1 neg npas1) ;
          nei1     = 1 ;
          pami1    = pasi1 ;
        sino ;
          llmi1    = leli1 - llpas1 ;
          nei1     = llmi1 / pasi1 + 0.5 ;
          nei1     = maxi (lect (enti nei1) 1) ;
*mess 'nei1=' nei1 ;
          pami1    = llmi1 / (flot nei1) ;
        fins ;
 
        vtrani1  = pami1 * vni1 ;
        ltrani1  = norm vtrani1 ;
        nei2     = enti (ltrani1 / dens1 + 0.5) ;
        nei2     = maxi (lect (enti nei2) 1) ;
*mess 'nei2=' nei2 ;
        itouri1  = (abs angl2) > 0. ;
*list itouri1 ;
*list angl2 ;
        angli2   = angl2 / (flot nei1) ;
        vnsi22   = vnsi1 ;
        si22     = si1 ;
        dti2     = ltrani1 / vite1 ;
        repe b2 nei1 ;
          pi22     = pi1 plus vtrani1 ;
          si itouri1 ;
            vnsi22   = vnsi22 tour angli2 (0 0 0) vnnz1 ;
            pi33     = pi22 plus vnnz1 ;
            pi44     = pi22 plus (pvec vnsi22 vnnz1) ;
            si22     = si22 proj dire vtrani1 plan pi22 pi33 pi44 ;
          sino ;
            si22     = si1 plus vtrani1 ;
          fins ;
          maili2   = si1 volu si22 nei2 ;
          si1      = si22 ;
          pi1      = pi22 ;
          maili2   = maili2 coul (indi1+1) ;
          mail2    = mail2 et maili2 ;
          tmai1 . indi1 = mail2 ;
          ttps1 . indi1 = tpsi2 ;
          tpsi2    = tpsi2 + dti2 ;
          indi1    = indi1 + 1 ;
        fin b2 ;
 
      fin bp1 ;
 
*trac (5 -2 3) (mtraj1 et mail2 et (si1 coul rose) et (si2 coul turq) et (si22 coul oran) et pi1 et pi2) ;
 
      vnsi1    = vnsi2 ;
      vnsmai1  = vnsmai2 ;
 
*   Fin si imail1 (segment rouge) ;
    sino ;
      erre '*****  ERREUR : pb definition trajectoire, couleur segment inconnue' ;
      quit waam ;
    fins ;
 
* Fin boucle segments trajectoire
  fin b1 ;
*  elim mail2 tol1 ;
 
* Verification list des temps de tttps1 bien ordonnee :
  ltps1    = prog table ttps1 ;
  ltps2    = ordo ltps1 ;
  si (((ltps2 - ltps1) maxi abs) > (1.e-3*dti2)) ;
    erre '*****  la liste des TEMPS de l''evolution du maillage est mal ordonnee' ;
  fins ;
* Enregistrement des sorties :
  tab2.maillage                    = mail2 ;
  tab2.evolution_maillage          = table ;
  tab2.evolution_maillage.temps    = ttps1 ;
  tab2.evolution_maillage.maillage = tmai1 ;
 
*-------------------------- Sous-option TEMP --------------------------*
 
  si imot4 ;
 
*   Valeurs de dtca1 :
    nbp1     = dime tab1 . passes ;
    tpi1     = 0. ;
    ltp1     = prog ;
    ldtca1   = prog ;
    repe bp1 nbp1 ;
      vsi1     = tab1 . passes . &bp1 . vitesse ;
      dtcai1   = pas1 / vsi1 / flot4 ;
      si (&bp1 ega nbp1) ;
        tpi2     = (tab1 . passes . &bp1 . instants) extr 2 ;
      sino ;
        ip1      = &bp1 + 1 ;
        tpip1    = (tab1 . passes . ip1 . instants) extr 1 ;
        tpi2     = tpip1 - tab1 . temps_de_coupure ;
      fins ;
      ltp1     = ltp1 et tpi1 et tpi2 ;
      ldtca1   = ldtca1 et dtcai1 et dtcai1 ;
      tpi1     = tpip1 ;
    fin bp1 ;
    evdtca1  = evol manu ltp1 ldtca1 ;
*list evdtca1 ;
 
*   Redecoupage de la liste des temps de l'evolution de la puissance thermique :
    evqt1    = tab1.evolution_puissance ;
    ltqt1    = extr evqt1 absc ;
    lqqt1    = extr evqt1 ordo ;
    tol2     = 1.e-6 * (maxi lqqt1) ;
    tol3     = 0.001 * tab1.temps_de_coupure ;
 
*   Gestion des evenements :
    ieve1    = exis tab1 evenements ;
    Si ieve1 ;
      lteve1   = prog ;
      lieve1   = lect ;
      repe beve1 (dime tab1.evenements) ;
        ie1      = &beve1 ;
        lteve1   = lteve1 et tab1.evenements.ie1.temps ;
        lieve1   = lieve1 et (lect (dime (tab1.evenements.ie1.temps)) * ie1) ;
      fin beve1 ;
      lpeve1   = posi ltqt1 dans lteve1 tol3 ;
*list lteve1 ;
*list lieve1 ;
*list lpeve1 ;
    sino ;
      lpeve1   = lect (dime ltqt1) * 0 ;
    fins ;
 
*   Sous-decoupage de l'historique de puissance :
    nb1      = dime ltqt1 ;
    t0       = extr ltqt1 1 ;
    q0       = extr lqqt1 1 ;
 
*   Gestion evenements :
    peve0    = extr lpeve1 1 ;
    si (peve0 neg 0) ;
      neve0    = extr lieve1 peve0 ;
      si ((peve0 + 1) &lt;EG (dime lieve1)) ; 
        neve1    = extr lieve1 (peve0 + 1) ;
      sino ;
        neve1    = -1 ;
      fins ;
      idtev1   = neve0 ega neve1 ;
      si idtev1 ;
        tev1     = lteve1 extr (peve0 + 1) ;
        dtev1    = tev1 - t0 ;
*mess (chai 'Even. = ' neve0 ', dtev1 =' dtev1) ;
      fins ;
    sino ;
      idtev1   = faux ;
    fins ;
 
*   Boucle sur les piquets de temps :
    ltca1    = prog t0 ;
    repe b1 (nb1 - 1) ;
      ip1      = &b1 + 1 ;
      t1       = extr ltqt1 ip1 ;
      q1       = extr lqqt1 ip1 ;
      peve1    = extr lpeve1 ip1 ;
      dt1      = t1 - t0 ;
      dtca1    = ipol evdtca1 t0 ;
      si (&b1 ega 1) ; dt0 = dt1 ; fins ;
* Avec evements :
      si idtev1 ;
        si (dt1 &lt;EG dtca1) ;
          si (dtev1 &lt;EG dtca1) ;
            si (dt1 ega dtev1 tol3) ;
              ltca1    = ltca1 et (prog t1) ;
            sino ;
              si (dt1 < dtev1) ;
                ltca1    = ltca1 et (prog t1) et (prog tev1) ;
                t1       = tev1 ;
              sino ;
                ltca1    = ltca1 et (prog tev1) et (prog t1) ;
              fins ;
            fins ;
          sino ;
            ltca1    = ltca1 et (prog t1) ;
            si ((q0 > tol2) ou (q1 > tol2)) ;
              ltca1    = ltca1 et ((prog t1 pas dtca1 tev1) enle 1) ;
            sino ;
              ltca1    = ltca1 et ((prog t1 pas dt1 geom 2. tev1) enle 1) ;
            fins ;
            t1       = tev1 ;
          fins ;
        sino ;
          si (dt1 ega dtev1 tol3) ;
            si ((q0 > tol2) ou (q1 > tol2)) ;
              ltca1    = ltca1 et ((prog t0 pas dtca1 t1) enle 1) ;
            sino ;
              ltca1    = ltca1 et ((prog t0 pas dtev1 geom 2. t1) enle 1) ;
            fins ;
          sino ;
            si (dtev1 < dt1) ;
              si (dtev1 < dtca1) ;
                ltca1    = ltca1 et (prog tev1) ;
              sino ;
                si ((q0 > tol2) ou (q1 > tol2)) ;
*mess '############ Ici 1' ;
                  ltca1    = ltca1 et ((prog t0 pas dtca1 tev1) enle 1) ;
                  ltca1    = ltca1 et ((prog tev1 pas dtca1 t1) enle 1) ;
                sino ;
                  ltca1    = ltca1 et (prog tev1 pas dtev1 geom 2. t1) ;
                fins ;
              fins ;
            sino ;
              si ((q0 > tol2) ou (q1 > tol2)) ;
*mess '############ Ici 2' ;
                ltca1    = ltca1 et ((prog t0 pas dtca1 tev1) enle 1) ;
              sino ;
                ltca1    = ltca1 et ((prog t0 pas dt0 geom 2. tev1) enle 1) ;
              fins ;
              t1       = tev1 ;
            fins ;
          fins ;
        fins ;
* Pas d'evenement :
      sino ;
        si (dt1 &lt;EG dtca1) ;
          ltca1    = ltca1 et (prog t1) ;
        sino ;
          si ((q0 > tol2) ou (q1 > tol2)) ;
            ltca1    = ltca1 et ((prog t0 pas dtca1 t1) enle 1) ;
          sino ;
            ltca1    = ltca1 et ((prog t0 pas dt0 geom 2. t1) enle 1) ;
          fins ;
        fins ;
      fins ;
      t0       = t1 ;
      q0       = q1 ;
      ntca1    = dime ltca1 ;
      dt0      = (ltca1 extr ntca1) - (ltca1 extr (ntca1-1)) ;
*     Gestion evenement suivant :
      peve0    = peve1 ;
      si (peve0 neg 0) ;
        neve0    = extr lieve1 peve0 ;
        si ((peve0 + 1) &lt;EG (dime lieve1)) ; 
          neve1    = extr lieve1 (peve0 + 1) ;
        sino ;
          neve1    = -1 ;
        fins ;
        idtev1   = neve0 ega neve1 ;
        si idtev1 ;
          tev1     = lteve1 extr (peve0 + 1) ;
          dtev1    = tev1 - t0 ;
*mess (chai 'Even. = ' neve0 ', dtev1 =' dtev1) ;
        fins ;
      sino ;
        idtev1   = faux ;
      fins ;
    fin b1 ;
 
*   Raffinement si pas > flot5 (option TEMP MAXI) :
    si imot5 ;
      ltca1    = ltca1 raff flot5 ;
    fins ;
 
*   Verification si liste temps calcules bien ordonnee :
    ltca2    = ordo ltca1 ;
    si (((ltca2 - ltca1) maxi abs) > (1.e-3*dtca1)) ;
      erre '*****  La liste des TEMPS_CALCULES est mal ordonnee' ;
      quit waam ;
    fins ;
 
    tab2.temps_calcules = ltca1 ;
 
*   Sorties si evenements :
    si ieve1 ;
      tab2.temps_evenements = lteve1 ;
      tab2.index_evenements = lieve1 ;
    fins ;
 
* Fin sous-option TEMP :
  fins ;
 
  resp tab2 ;
  quit waam ;
* Fin option MAILLAGE :
fins ; 
 
*----------------------------------------------------------------------*
*                             Option VISU                              *
*----------------------------------------------------------------------*
 
si (ega mot1 'VISU') ;
  icas1    = 2 ;
*
* Lecture MOT CACH / FACE :
  argu mot1/'MOT' ;
  si (exis mot1) ;
    cle1    = text mot1 ;
  sino ;
    cle1    = text ' ' ;
  fins ;
 
* Lecture maillage complementaire a afficher :
  argu mail2/maillage ;
  si (non (exis mail2)) ;
    mail2    = vide maillage ;
  fins ;
 
  mail1    = tab1.maillage ;
  tmai1    = tab1.evolution_maillage.maillage ;
  dep0     = manu chpo (mail1 et mail2) 3 ux 0 uy 0 uz 0 ;
  def0     = vide deforme ;
  i1       = 0 ;
  repe b2 (dime tmai1) ;
    maili1    = tmai1.i1 ;
    maili1    = maili1 et mail2 ;
    defi1     = defo maili1 dep0 0. ;
    def0      = def0 et defi1 ;
    i1       = i1 + 1 ;
  fin b2 ;
  trac cle1 anim def0 ;
 
  quit waam ;
* Fin option VISU :
fins ; 
 
*----------------------------------------------------------------------*
*                             Option MACRO  
*----------------------------------------------------------------------*
 
si (ega mot1 'MACRO') ;
  icas1    = 3 ;
 
*----------------- Lecture des arguments de l'option ------------------*
 
  imot1    = faux ; comm mot-cle LONG ;
  imot2    = faux ; comm mot-cle LARG ;
  imot3    = faux ; comm mot-cle HAUT ;
  imot4    = faux ; comm mot-cle DENS ;
  imot5    = faux ; comm mot-cle TEMP ;
  imot6    = faux ; comm mot-cle MAXI ;
  repe b1 10 ; comm volontairement superieur au nombre de mot-cle ;
    argu moti1/'MOT' ;
    si (non (exis moti1)) ; quit b1 ; fins ;
 
*   Arguments option MACRO :
    si (ega moti1 'LONG' 4) ;
      imot1    = vrai ;
      argu long1*'FLOTTANT' ;
      long1    = prog long1 ;
      npas1    = 1 ;
    fins ;
    si (ega moti1 'LARG' 4) ;
      imot2    = vrai ;
      argu larg1*'FLOTTANT' ;
    fins ;
    si (ega moti1 'HAUT' 4) ;
      imot3    = vrai ;
      argu enti1*'ENTIER' ;
    fins ;
    si (ega moti1 'DENS' 4) ;
      imot4    = vrai ;
      argu dens1*'FLOTTANT' ;
    fins ;
 
*   Arguments sous-option TEMP :
    si (ega moti1 'TEMP' 4) ;
      imot5    = vrai ;
*      argu flot4/'FLOTTANT' ; 
*      si (non (exis flot4)) ;
*        flot4    = 0.1 ;
*      fins ;
*    fins ;
*    si (ega moti1 'MAXI' 4) ;
      argu mot6*'MOT' ;
      si (neg mot6 'MAXI') ;
        erre '  ***** On attend le mot-cle MAXI' ;
      fins ;
      imot6    = vrai ;
      argu flot5*'FLOTTANT' ;
    fins ;
  fin b1 ;
 
* Analyse arguments lus :
* iltot1   : indicateur maillage de toute la longeur de la passe :
  si (non imot2) ;
    si (non (exis tab1 'PASSES')) ;
      erre '*****  ERREUR : il manque la donnee de la LARGeur du depot' ;
    fins ;
  fins ;
  si (non imot3) ;
    enti1    = 1 ;
  fins ;
  si (non imot4) ;
    dens1    = tab1 . passes . 1 . largeur ; comm pour calcul tolerance geom. ;
  fins ;
  si (non imot5) ;
*    flot4    = 0.1 ;
    imot5    = vrai ;
  fins ;
 
*list long1 ; list larg1 ; list dens1 ; list enti1 ; list flot5 ;
 
*--------------------- MAILLAGE des macro-depots ----------------------*
 
  si (non (exis tab1 passes)) ;
    erre '*****  ERREUR : la table de SOUDAGE en entree n"a pas d''indice PASSES' ;
    quit waam ;
  fins ;
 
* Definition d'une tolerance geometrique :
  tol1     = 1.e-4 * dens1 ;
 
* Appareillement des passes superposees (couches) :
* mtraj1   = tab1.trajectoire ;  comm pour affichage et debugage ;
* tgroup1  : table contenant des groupes de passes superposees
  tgroup1  = table ;
  lsaut1   = lect ;      comm liste des passes identifiees dans un groupe ;
  nbp1     = dime tab1 . passes ;
  repe bp1 nbp1 ;
    ip1      = &bp1 ;
    si (dans (lect ip1) lsaut1) ; iter bp1 ; fins ;
 
*   Initialisation nouveau groupe de passes superposees :
    elpi1    = tab1 . passes . ip1 . maillage ;
    tgroup1 . ip1 = lect ip1 ;
    lsaut1   = lsaut1 et ip1 ;
*    lgroup1 = elpi1 ;       comm pour affichage et debugage ;
 
    si (enti1 ega 1) ; iter bp1 ; fins ;
    si (ip1 ega nbp1) ; quit bp1 ; fins ;
 
*   Recherche couche suivante :
    ip2      = ip1 ;
    nc1      = tab1 . passes . ip1 . couche ;
    nbc1     = mini (lect (enti1 - 1) (nbp1 - ip1)) ;
    repe bc1 nbc1 ;
      nc1      = nc1 + 1 ;
      pi1      = elpi1 poin 1 ;
      pi2      = elpi1 poin (nbno elpi1) ;
      nbp2     = nbp1 - ip2 ;
      si (nbp2 ega 0) ; quit bc1 ; fins ;
      repe bp2 nbp2 ;
        ip2      = ip2 + 1 ;
        nc2      = tab1 . passes . ip2 . couche ;
        si (nc2 ega nc1) ;
          elpi2    = tab1 . passes . ip2 . maillage ;
          pi3      = elpi2 poin proc pi1 ;
          pi4      = elpi2 poin proc pi2 ;
          vitei2   = tab1 . passes . ip2 . vitesse ;
          debii2   = tab1 . passes . ip2 . debit ;
          largi2   = tab1 . passes . ip2 . largeur ;
          epc2     = debii2 / vitei2 / largi2 ;
          dmaxi2   = maxi (prog (norm (pi3 moin pi1)) (norm (pi4 moin pi2))) ;
*mess 'epc2 =' epc2 ; list dmaxi2 ; trac (lgroup1 et (elpi2 coul or) et  (mtraj1 coul blan)) ;
          si ((abs (dmaxi2 - epc2)) &lt;EG (0.01 * epc2)) ;
            tgroup1 . ip1 = tgroup1 . ip1 et ip2 ;
            lsaut1   = lsaut1 et ip2 ;
*            lgroup1 = lgroup1 et elpi2 ;
            quit bp2 ;
          fins ;
        fins ;
      fin bp2 ;
      elpi1    = elpi2 ;
    fin bc1 ;
*trac (lgroup1 et (mtraj1 chan poi1)) ;
 
  fin bp1 ;
 
* Initialisattion sorties (MACRO) :
  tab2     = table ;
  ttps1    = table ;
  tmai1    = table ;
  indi1    = 0 ;
 
* Boucle sur elements de la trajectoire :
  mtraj1   = tab1.trajectoire ;
  mail2    = vide maillage ;
  idebui1  = vrai ;
  ibouci1  = faux ;
  lsaut1   = lect ;     comm liste des passes deja maillees ;
  nb1      = nbel mtraj1 ;
  repe b1 nb1 ;
 
*   Lecture ieme element de la trajectoire :
    eli1     = mtraj1 elem &b1 ;
    Pi1      = eli1 poin 1 ;
    Pi2      = eli1 poin 2 ;
    vai1     = Pi2 moin Pi1 ;
    vni1     = vai1 / (norm vai1) ;
    mcouli1  = (eli1 elem coul) extr 1 ;
    imaili1  = ega mcouli1 'ROUG' ;
    idepli1  = ega mcouli1 'VERT' ;
 
    si (non imot1) ;
      long1    = prog (mesu eli1) ;
      npas1    = 1 ;
    fins ;
*
*   Segment VERT : deplacement
    si idepli1 ;
      idebui1  = vrai ;
      ibouci1  = faux ;
      iter b1 ;
    fins ;
*
*   Segment ROUGE : maillage
    si imaili1 ;
 
*     Si debut nouvelle passe :
      si idebui1 ;
 
*       Identification de la passe :
        npassi1  = 0 ;
        nbp1     = dime tab1.passes ;
        repe bp1 nbp1 ;
          mailpss1 = (tab1.passes.&bp1).maillage ;
          si ((dans pi1 mailpss1) et (dans pi2 mailpss1)) ;
            tpassi1  = tab1.passes.&bp1 ;
            npassi1  = &bp1 ;
            quit bp1 ;
          fins ;
        fin bp1 ;
        si (dans (lect npassi1) lsaut1) ;
          iter b1 ;
        fins ;
 
*       Affichage : 
        si (npassi1 ega 0) ;
          erre '*****  WAAM : passe non identifiee' ;
        sino ;
          mess '*****  WAAM : maillage de la passe :' npassi1 ;
          lsaut1   = lsaut1 et tgroup1 . npassi1 ;
        fins ;
 
*       Hauteur de cordon :
        haut1    = 0. ;
        hautp1   = 0. ;
        lpassi1  = tgroup1 . npassi1 ;
        nbgrp1   = mini (lect enti1 (dime lpassi1)) ;
        repe bgrp1 nbgrp1 ;
          ipassi1  = extr lpassi1 &bgrp1 ;
          debii1   = tab1 . passes . ipassi1 . debit ;
          vitei1   = tab1 . passes . ipassi1 . vitesse ;
          largi1   = tab1 . passes . ipassi1 . largeur ;
          haut1    = debii1 / vitei1 / largi1 + haut1 ;
          si (&bgrp1 ega 1) ; hautp1   = haut1 ; fins ;
        fin bgrp1 ;
        mess (chai '*****  WAAM : hauteur du macro-depot :' npassi1 ' =' haut1) ;
 
*       Maillage :
*       si1       : maillage section courante :
*       vnsi1     : normale a la section 
        largi1   = tab1 . passes . npassi1 . largeur ;
        si (non imot4) ;
          dens1 = largi1 ;
        fins ;
        lsi1     = (0 0 0) droi (0 largi1 0) dini dens1 dfin dens1 ;
        si1      = lsi1 tran (0 0 haut1) dini dens1 dfin dens1 ;
        vnsi1    = 1 0 0 ;
 
*       Positionnement extremite initiale (Pi1 au centre de l'arete superieure) :
        Pmsup1   = 0 (0.5*largi1) haut1 ;
        Prefi1   = Pi1 moin (0 0 hautp1) plus (0 0 haut1) ;
        si1      = si1 plus (Prefi1 moin Pmsup1) ;
 
*si (&b1 neg 1) ; trac qual (si1 et mail2 et mtraj1) ; fins ;
 
*       Initialisation section extremite finale :
        si2      = si1 plus vai1 ;
        vnsi2    = vnsi1 ;
        angl2    = 0. ;
*
*       Orientation sections de maillage :
*       Par defaut, selon vni1 :
        vnsmai1  = vni1 ;
        vnsmai2  = vnsmai1 ;
 
*       Detection suite segments rouges et boucle :
        tpsi2    = tpassi1.instants extr 1 ;
        dtc1     = tab1 . temps_de_coupure ;
        si (indi1 neg 0) ;
          dtpassi1 = tpsi2 - (tab1.passes.(npassi1-1).instants extr 2) - (1. * dtc1) ;
          tpsi2    = (ttps1 . (indi1 - 1)) + dtpassi1 ;
*mess 'tpsi2 =' tpsi2 ;
        fins ;
        tpsi22   = tpassi1.instants extr 2 ;
        si (&b1 neg nb1) ;
          elip1    = mtraj1 elem (&b1 + 1) ;
          mcoulip1 = (elip1 elem coul) extr 1 ;
          isuiti1  = ega mcoulip1 'ROUG' ;
          isuiti2  = non (vide (elip1 inte mailpss1)) ;
          si (npassi1 neg nbp1) ;
            isuiti2  = isuiti2 ou (ega tpsi22 (tab1.passes.(npassi1+1).instants extr 1)) ;
          fins ;
          isuiti1  = isuiti1 et isuiti2 ;
          si isuiti1 ;
            vai2     = (elip1 poin 2) moin (elip1 poin 1) ;
            vni2     = vai2 / (norm vai2) ;
            vasmai2  = vni1 plus vni2 ;
            vnsmai2  = vasmai2 / (norm vasmai2) ;
            elfini1  = elip1 ;
            pfini1   = elip1 poin 2 ;
            nb2      = nb1 - (&b1 + 1) ;
            i2       = &b1 + 2 ;
*           Rq : si nb2 = 0, le bloc n'est pas execute
            repe b2 nb2 ;
              eli2     = mtraj1 elem i2 ;
              mcoul2   = (eli2 elem coul) extr 1 ;
              si (neg mcoul2 'ROUG') ; quit b2 ; fins ;
              pfini1   = eli2 poin 2 ;
              elfini1  = eli2 ;
              vafini1  = pfini1 moin (eli2 poin 1) ;
              vnfini1  = vafini1 / (norm vafini1) ;
              i2       = i2 + 1 ;
            fin b2 ;
            ibouci1  = (norm (pfini1 moin pi1)) < tol1 ;
            si ibouci1 ;
              mess '*****  WAAM : boucle fermee detectee' ;
*             On definit la normale a la section de maillage (SMA) :
              vasmai1  = vni1 plus vnfini1 ;
              vnsmai1  = vasmai1 / (norm vasmai1) ;
            fins ;
          fins ;
        fins ;
 
*       Orientation de si1 selon vnsmai1 :
*list vnsmai1 ; list vnsi1 ;
*trac (0 -0 3) (mtraj1 et mail2 et (si1 coul rose) et (si2 coul turq) et pi1 et pi2) ;
        vnnz1    = pvec vnsi1 vnsmai1 ;
        lvnnz1   = norm vnnz1 ;
*       Si sinus non nul a tol1 pres, on oriente la section :
        si (lvnnz1 neg 0. (tol1 / dens1)) ;
          si (lvnnz1 ega 1. (vale prec)) ; lvnnz1 = 1. ; fins ;
          angl1    = asin lvnnz1 ;
*list vnsi1 ; list vnsmai1 ; list angl1 ;
          si ((psca vnsmai1 vnsi1) < 0.) ;
            angl1    = 180. - angl1 ;
*mess ' on prend (180.-angl1)' ;
          fins ;
          si1      =  si1 tour angl1 pi1 (pi1 plus vnnz1) ;
          vnsi1     = vnsmai1 ;
          si2      = si1 plus vai1 ;
          vnsi2    = vnsi1 ;
          angl2    = 0. ;
        sino ;
          si ((psca vnsmai1 vnsi1) < 0.) ;
            vnsi1     = vnsmai1 ;
            si2      = si1 plus vai1 ;
            vnsi2    = vnsi1 ;
            angl2    = 0. ;
          fins ;
        fins ;
*list vnsi1 ; list angl1 ;
titr 'Debut de passe, apres orientation de si1' ;
*trac (0 0 100) (mtraj1 et mail2 et (si1 coul rose) et (si2 coul turq) et pi1 et pi2) ;
 
*       Si boucle, on garde la section de maillage du debut :
        si ibouci1 ;
          sfini1   = si1 ;
          vnfini1  = vnsmai1 ;
        fins ;
 
      sino ;
 
*       On a deja si1 correctement orientee.
*       On doit orienter si2.
*       Par defaut, orientation de si1 :
        si2      = si1 plus vai1 ;
        vnsi2    = vnsi1 ;
        angl2    = 0. ;
        vnsmai2  = vnsi2 ;
 
*       Identification et enregitrement de la passe :
        npassi1  = 0 ;
        nbp1     = dime tab1.passes ;
        repe bp1 nbp1 ;
          mailpss1 = (tab1.passes.&bp1).maillage ;
          si ((dans pi1 mailpss1) et (dans pi2 mailpss1)) ;
            npassi1  = &bp1 ;
            quit bp1 ;
          fins ;
        fin bp1 ;
        lsaut1   = lsaut1 et tgroup1 . npassi1 ;
 
*       Si fin d'une boucle, orientation si2 connue :
        si (ibouci1 et (pi2 ega pfini1)) ;
          vnsmai2  = vnfini1 ;
        sino ;
          si (&b1 neg nb1) ;
            elip1    = mtraj1 elem (&b1 + 1) ;
            mcoulip1 = (elip1 elem coul) extr 1 ;
            isuiti1  = ega mcoulip1 'ROUG' ;
            si isuiti1 ;
              vai2     = (elip1 poin 2) moin (elip1 poin 1) ;
              vni2     = vai2 / (norm vai2) ;
              vasmai2  = vni1 plus vni2 ;
              vnsmai2  = vasmai2 / (norm vasmai2) ;
            fins ;
          fins ;
        fins ;
 
*     Fin "Si idebui1 / sinon" :
      fins ;
*
*     Orientation de si2 selon vnsmai2 :
*list vnsmai2 ; list vnsi2 ;
*trac (0 0 100) (mtraj1 et mail2 et (si1 coul rose) et (si2 coul turq) et pi1 et pi2 et (pi1 droi 1 (pi1 plus (0.01*vnsi1))) et (pi2 droi 1 (pi2 plus (0.01*vnsi2)))) titr 'Avant orientation si2' ;
      vnnz1    = pvec vnsi2 vnsmai2 ;
      lvnnz1   = norm vnnz1 ;
*     Si sinus non nul a tol1 pres, on oriente la section :
      si (lvnnz1 neg 0. (tol1 / dens1)) ;
        si (lvnnz1 ega 1. (vale prec)) ; lvnnz1 = 1. ; fins ;
        angl2    = asin lvnnz1 ;
        si ((psca vnsi2 vnsmai2) < 0.) ;
*mess ' on prend (180.-angl2)'  ; saut 1 lign ;
          angl2    = 180. - angl2 ;
        fins ;
        si2      =    si2 tour angl2     pi2 (pi2 plus vnnz1) ;
        vnsi2    =  vnsi2 tour angl2 (0 0 0)            vnnz1 ;
      sino ;
*       Pas sur que ça serve a quelque chose...
        si ((psca vnsi2 vnsmai2) < 0.) ;
          vnsi2     = vnsmai2 ;
          angl2    = 180. ;
        fins ;
      fins ;
*titr 'En cours de passe, apres orientation de si2' ;
*trac (0 0 100) (mtraj1 et mail2 et (si1 coul rose) et (si2 coul turq) et pi1 et pi2 et (pi1 droi 1 (pi1 plus (0.01*vnsi1))) et (pi2 droi 1 (pi2 plus (0.01*vnsi2)))) ;
*si (ibouci1 et (pi2 ega pfini1)) ;
*trac (5 -2 3) (mtraj1 et mail2 et (si1 coul rose) et (si2 coul turq) et (si22 coul oran) et pi1 et pi2) ;
*fins ;
 
*---- Maillage du segment :
 
      llong1   = somm (long1 enle npas1) ;
      leli1    = mesu eli1 ;
      si (leli1 &lt;EG llong1) ;
        erre '*****  ERREUR : somme pas de discretisation > long. ' &b1 'e passe' ;
        quit waam ;
      fins ;
 
*     Boucle sur les pas de discretisation :
 
*     pasi1 : pas de discretisation courant
*     nei1  : nb maillages pour ce pas de discretisation du segment
*     pami1 : pas de maillage courant
*     nei2  : nbel crees par pas de maillage
 
      idebui1  = non isuiti1 ;
      pi11     = pi1 ;
      repe bp1 npas1 ;
        pasi1    = extr long1 &bp1 ;
        si (&bp1 neg npas1) ;
          nei1     = 1 ;
          pami1    = pasi1 ;
        sino ;
          llmi1    = leli1 - llong1 ;
          nei1     = llmi1 / pasi1 + 0.5 ;
          nei1     = maxi (lect (enti nei1) 1) ;
*mess 'nei1=' nei1 ;
          pami1    = llmi1 / (flot nei1) ;
        fins ;
 
        vtrani1  = pami1 * vni1 ;
        ltrani1  = norm vtrani1 ;
        nei2     = enti (ltrani1 / dens1 + 0.5) ;
        nei2     = maxi (lect (enti nei2) 1) ;
*mess 'nei2=' nei2 ;
        itouri1  = (abs angl2) > 0. ;
*list itouri1 ;
*list angl2 ;
        angli2   = angl2 / (flot nei1) ;
        vnsi22   = vnsi1 ;
        si22     = si1 ;
        dti2     = ltrani1 / vitei1 ; 
        repe b2 nei1 ;
          pi22     = pi11 plus vtrani1 ;
          si itouri1 ;
            vnsi22   = vnsi22 tour angli2 (0 0 0) vnnz1 ;
            pi33     = pi22 plus vnnz1 ;
            pi44     = pi22 plus (pvec vnsi22 vnnz1) ;
            si22     = si22 proj dire vtrani1 plan pi22 pi33 pi44 ;
          sino ;
            si22     = si1 plus vtrani1 ;
          fins ;
          maili2   = si1 volu si22 nei2 ;
          si1      = si22 ;
          pi11     = pi22 ;
          maili2   = maili2 coul (indi1+1) ;
          mail2    = mail2 et maili2 ;
          tmai1 . indi1 = mail2 ;
          ttps1 . indi1 = tpsi2 ;
          tpsi2    = tpsi2 + dti2 + dtc1 ;
          indi1    = indi1 + 1 ;
        fin b2 ;
 
      fin bp1 ;
 
*trac (5 -2 3) (mtraj1 et mail2 et (si1 coul rose) et (si2 coul turq) et (si22 coul oran) et pi1 et pi2) ;
 
      vnsi1    = vnsi2 ;
      vnsmai1  = vnsmai2 ;
 
*   Fin si imail1 (segment rouge) ;
    sino ;
      erre '*****  ERREUR : pb definition trajectoire, couleur segment inconnue' ;
      quit waam ;
    fins ;
 
* Fin boucle segments trajectoire
  fin b1 ;
  elim mail2 tol1 ;
 
* Verification list des temps de tttps1 bien ordonnee :
  ltps1    = prog table ttps1 ;
  ltps2    = ordo ltps1 ;
  si (((ltps2 - ltps1) maxi abs) > (1.e-3 * dti2)) ;
    erre '*****  la liste des TEMPS de l''evolution du maillage est mal ordonnee' ;
  fins ;
* Enregistrement des sorties :
  tab2.maillage                    = mail2 ;
  tab2.evolution_maillage          = table ;
  tab2.evolution_maillage.temps    = ttps1 ;
  tab2.evolution_maillage.maillage = tmai1 ;
 
*--------------------------- TEMPS_CALCULES ---------------------------*
 
  nbt1     = dime ttps1 ;
  ltca1    = prog ;
  repe bt1 nbt1 ;
    tps0     = ttps1 . (&bt1 - 1) ;
    si (&bt1 neg nbt1) ;
      tps1     = (ttps1 . &bt1) - dtc1 ;
    sino ;
      tps1     = (tab1 . evolution_puissance extr absc) maxi ;
    fins ;
    si (tps1 < tps0) ; 
*        mess 'tps0 =' tps0 ;
*        mess 'tps1 =' tps1 ;
      erre '  ***** Erreur dans le calcul de la liste des TEMPS_CALCULES' ; 
    fins ;
    ltcai1   = prog tps0 pas dtc1 geom 2 tps1 ;
    ltca1    = ltca1 et ltcai1 ;
  fin bt1 ;
 
* Raffinement si pas > flot5 (option TEMP MAXI) :
  si imot6 ;
    ltca1    = ltca1 raff flot5 ;
  fins ;
 
*   Verification si liste temps calcules bien ordonnee :
  ltca2    = ordo ltca1 ;
  si (((ltca2 - ltca1) maxi abs) > (1.e-3 * dtc1)) ;
    erre '*****  La liste des TEMPS_CALCULES est mal ordonnee' ;
    quit waam ;
  fins ;
  tab2.temps_calcules = ltca1 ;
 
  resp tab2 ;
  quit waam ;
* Fin option MACRO-DEPOT :
fins ; 
 
*----------------------------------------------------------------------*
*                                  FIN                                 * 
*----------------------------------------------------------------------*
*
* MOT1 n'est pas un des mots-cles des options de la procedure :
si (icas1 ega 0) ;
  erre '*****  ERREUR WAAM : MOT-cle option WAAM non reconnu.' ;
  quit waam ;
fins ;
 
FINP ;
 
 
 
 
 
 

© Cast3M 2003 - Tous droits réservés.
Mentions légales