Télécharger la plaquette Cast3M


fr en

Télécharger pasapas.procedur

Retour à la liste

Numérotation des lignes : 

  1. * PASAPAS   PROCEDUR  FD218221  26/02/13    21:15:27     12462          
  2.  
  3. 'DEBP' PASAPAS  PRECED*'TABLE';
  4. 'SAUT' 1 'LIGNE';
  6. '------------------ DEBUT DE LA PROCEDURE PASAPAS --------------------';
  7. ************************************************************************
  8. *                                                                      *
  9. *   PRECED      objet de type TABLE                                    *
  10. *               C'est une table donnant , les arguments d'entrees, les *
  11. *               options, puis les  resultats des pas precedents        *
  12. *                                                                      *
  13. * champs de materiaux :                                                *
  14. *     WTAB.'MAT_REF' materiau etat a la temperature de REFERENCE       *
  15. *     WTAB.'MAT0'    materiau etat debut de calcul                     *
  16. *     WTAB.'MAT1'    materiau fin du pas de temps                      *
  17. *                                                                      *
  18. ************************************************************************
  19.  
  20. ****************   I PARTIE   ******************************************
  21. * Verifications des infos transmises et valeurs par defaut
  22. PAS_DEFA PRECED ;
  23. * Creation des tables de sortie et initialisations
  24. PAS_INIT PRECED ;
  25.  
  26. WTAB  = PRECED.'WTABLE'      ;
  27. conti = PRECED.'CONTINUATION';
  28. estim = PRECED.'ESTIMATION'  ;
  29. *-----------------------------------------------------------------------
  30. *              Appel aux procedures utilisateurs
  31. *-----------------------------------------------------------------------
  32. 'SI' WTAB.'PROCEDURE_PERSO1';
  33.   PRECED.'PERSO1_APPEL' = 1 ;
  34.   PERSO1 PRECED ;
  35.   'SI' ('EXIS' PRECED 'ARRET') ;
  36.     WTAB.'ARRET' = PRECED.'ARRET' ;
  37.   'FINSI' ;
  38. 'FINSI';
  39. *
  40. 'SI' WTAB.'PROCEDURE_REEV_MEC' ;
  41.   REEV_MEC PRECED 0 ;
  42. 'FINSI' ;
  43. *
  44. 'SI' WTAB.'PROCEDURE_REEV_THE' ;
  45.   REEV_THE PRECED 0 ;
  46. 'FINSI' ;
  47. *-----------------------------------------------------------------------
  48. *              Initialisation ETAT et MATERIAUX
  49. *-----------------------------------------------------------------------
  50. TEMP0       = conti.'TEMPS';
  51. ETAT0       = PAS_ETAT PRECED TEMP0 ;
  52. WTAB.'MAT0' = PAS_MATE PRECED ETAT0 ;
  53. WTAB.'MAT1' = WTAB.'MAT0' ;
  54. *
  55. *---------   initialisation deformation thermique de reference
  56. 'SI' WTAB.'FOR_MECA' ;
  57.   'SI' WTAB.'ITHER' ;
  58.     'SI' ('EGA' WTAB.'ETREF' 'INCONNU');
  59.       WTAB.'ETAT_REF'= PAS_ETAT PRECED TEMP0 'REFERENCE';
  60.       WTAB.'MAT_REF' = PAS_MATE PRECED WTAB.'ETAT_REF'  ;
  61.       WTAB.'ETREF'   ='EPTH' WTAB.'MO_TOT' WTAB.'MAT_REF' (chan chpo WTAB.'MO_TOT' WTAB.'TEMPERATURE_REFERENCE') ;
  62.     'FINS' ;
  63. *
  64.     TET1 = WTAB.'TET1' ;
  65.     'SI' ('EGA' ('TYPE' TET1) 'CHPOINT');
  66.       TET1 ='CHAN' 'CHAM' TET1 WTAB.'MO_TOT' 'STRESSES' 'TEMPERATURES' ;
  67.     'FINS';
  68.     ETT0  = 'EPTH' WTAB.'MO_TOT' WTAB.'MAT0' TET1 ;
  69.     WTAB.'ETHER1' = ETT0 - WTAB.'ETREF' ;
  70. *
  71.     'SI' WTAB.'POR1';
  72.       WTAB.'MSRTHER1'= PAS_EPTH PRECED WTAB.'MO_TOT' WTAB.'MAT0' TET1 ;
  73.     'FINS' ;
  74.   'FINS' ;
  75. 'FINS' ;
  76.  
  77. **************************   II PARTIE  *************************
  78. ******************************************************************
  79. ******************* boucle sur les pas de temps  *****************
  80. ******************************************************************
  81. * ------------quelques initialisations de l'algorithme
  82. IPAS  = 0 ;
  83. IAUTO = 1 ;
  84. ISAUV = VRAI;
  85. DTV   = ('EXTR' WTAB.'TEMPS_CALCULES' 1) - TEMP0 ;
  86. 'SI' ( DTV '<' 1.e-15 );
  87.   'SI' WTAB.'FREQUENTIEL' ;
  88.     DTV = 1.e-14 ;
  89.   'SINON' ;
  90.     DTV =('EXTR' WTAB.'TEMPS_CALCULES' 2) - TEMP0 ;
  91.   'FINSI';
  92. 'FINSI';
  93. * Pour l'option PAS_AJUSTE
  94. DT_AVANT = DTV ;
  95. IREREDU  = VRAI;
  96. PASFINAL = 0 ;
  97. *-----------------------------------------------------------------------
  98. *              Debut de la boucle sur les pas de temps
  99. *-----------------------------------------------------------------------
  100. 'REPETER' BEXTERN  ;
  101. *
  102. * ----- Determiner le nouvel instant a calculer TI
  103. *
  104.   TEMP0 = conti.'TEMPS' ;
  105.   NPAS  = 'DIME' WTAB.'TEMPS_CALCULES';
  106.   ICHG  = WTAB.'ICHG'; ICHG = ICHG + 1; WTAB.'ICHG' = ICHG;
  107.   'SI' ( ICHG '>' NPAS) ; 'QUITTER' BEXTERN; 'FINSI';
  108.   TI = 'EXTRAIRE'  WTAB.'TEMPS_CALCULES' ICHG ;
  109.   ITERTPS = (TI '<' TEMP0 ) ;
  110.   'SI' ('NON' WTAB.'FREQUENTIEL') ;
  111.     ITERTPS = ITERTPS 'OU' (TI 'EGA' PRECED.'TEMPS'. 0) ;
  112.     'SI' ('NON' WTAB.'REEQUILIBRAGE') ;
  113.       ITERTPS = ITERTPS 'OU' ('EGA' TI TEMP0) ;
  114.     'FINSI';
  115.   'FINSI';
  116.   'SI' ITERTPS ;
  117.     'ITERER' BEXTERN ;
  118.   'FINSI';
  119. *
  120. * ----- Ajustement du pas en fonction du nb d iteration du pas precedent
  121. *
  122.   'SI' WTAB.'PAS_AJUSTE';
  123.     PASFINAL=PASFINAL+1;
  124.     TIV=TI;
  125.     DTV=DT_AVANT;
  126.     'SI' WTAB.'CONV';
  127.       'SI' (WTAB.'NOMBRE_ITERATIONS' > 20);
  128.         DTV=DTV'/' (2. ** 0.5);
  129.       'FINSI';
  130.       'SI' (WTAB.'NOMBRE_ITERATIONS' <  7);
  131.         'SI' IREREDU;
  132.           DTV=DTV '*' (2. ** 0.5);
  133.         'FINSI';
  134.       'FINSI';
  135.       DT_AVANT= DTV;
  136.       IREREDU=VRAI;
  137.     'SINON';
  138.       DTV=0.0000000001D0* DT_AVANT;
  139.       DT_AVANT= DT_AVANT /2.;
  140.       IREREDU=FAUX;
  141.     'FINSI';
  142.     TTI = DTV* 1.0000000001 + TEMP0;
  143.     'SI' ( TTI '&lt;EG' TIV );
  144.       TI=TTI;
  145.       PASFINAL=0;
  146.     'FINSI';
  147.     'SI' (PASFINAL '>EG' 1.5) ; 
  148.       DT_AVANT = TI-TEMP0; 
  149.     'FINSI';
  150.   'FINSI';
  151. *
  152.   estim.'TEMPS' = TI;
  153.   WTAB.'DT'     = TI '-' TEMP0 ;
  154.   'SI'((WTAB.'CONSOLIDATION' 'OU' WTAB.'DYNAMIQUE') 'ET' (WTAB.'DT' 'EGA' 0.));
  155.     WTAB.'DT' = WTAB.'DTPREC' ;
  156.     'ITERER' BEXTERN;
  157.   'FINSI';
  158. *
  159. * ----- Compteur IPAS des pas de temps calcules
  160.   IPAS = IPAS + 1;
  161.   WTAB.'PAS'=IPAS;
  162.  
  163. * ----- Mise a jour du modele si chargement de type MODE :
  164.   'SI' WTAB.'CHAR_MODE' ;
  165.     MOD1P     =  WTAB.'MODELE' ;
  166.     MODEVOL1  = 'TIRE' PRECED.'MODELE' 'MODE' TI ;
  167.     WTAB.'MODELE' = MODEVOL1 ;
  168.  
  169.     'SI' WTAB.'CHAR_MATE' ;
  170.       MATEVOL1  = 'TIRE' PRECED.'CARACTERISTIQUES' 'MATE' TI ;
  171.       WTAB.'CARACTERISTIQUES' = MATEVOL1 ;
  172.     'FINSI' ;
  173.  
  174.     PAS_MODL PRECED ;
  175.  
  176. *   MaJ table rayonnement :
  177.     'SI' WTAB.'RAYO' ;
  178.       WTAB.'RAYONNEMENT' = 'PRRA' WTAB.'MOD_RAY' ;
  179.     'FINSI' ;
  180.  
  181. *   On sauvegarde les modeles successifs pour analyse resultats :
  182.     ESTIM.'MODELES' = WTAB.'MODELE' ;
  183.  
  184. *   Initialisation TINI si thermique :
  185.     'SI' WTAB.'THE1' ;
  186.       MODX      = WTAB.'MOD_COND' ;
  187.       MODXP     = MOD1P 'EXTR' 'MATE' 'CONDUCTION' ;
  188.       GEO1      = MODX  'EXTR' 'MAIL' ;
  189.       GEO1P     = MODXP 'EXTR' 'MAIL' ;
  190.       DGEO1     = GEO1  'DIFF' GEO1P ;
  191.  
  192. *     Adapation du modele : transport de la solution
  193.       'SI' ((WTAB.'ADAP_MODE') 'ET' ('NON' (TI '<' (WTAB.'TPS1_ADAP')))) ;
  194.         mess '*****  Transport solution adaptation' ;
  195.         IADAP1    = (WTAB.'INDI_ADAP') + 1 ;
  196.         'SI' (IADAP1 '&lt;EG' ('DIME' (WTAB.'LTPS_ADAP'))) ;
  197.           WTAB.'TPS1_ADAP' = WTAB.'LTPS_ADAP' 'EXTR' IADAP1 ;
  198.           WTAB.'INDI_ADAP' = IADAP1 ;
  199.         'SINON' ;
  200.           WTAB.'TPS1_ADAP' = 'MAXI' WTAB.'TEMPS_CALCULES' + 1. ;
  201.         'FINSI' ;
  202.  
  203. *       Projection du champ de temperature sur la partie adaptee :
  204.         DGEO1P    = DGEO1 'INTE' GEO1P ;
  205.         DGEO2P    = (DGEO1 'INTE' GEO1) 'INCLU' DGEO1P 'VOLU' 'BARY'  ;
  206.         CHT1P     = CONTI.'TEMPERATURES' 'EXCO' 'T' 'T' ;
  207.         CHAMT1P   = 'CHAN' 'CHAM' DGEO1P CHT1P ;
  208.         CHT2P     = 'PROI' CHAMT1P  DGEO2P ;
  209.         CHT1P     = ('REDU' CHT1P (GEO1P 'DIFF' DGEO1P)) 'ET' CHT2P ;
  210.         CONTI.'TEMPERATURES' = CHT1P ;
  211.  
  212. *       Calcul de la capacite courante sur la partie adaptee :
  213.         DMODX     = 'REDU' MODX DGEO2P ;
  214.         DMATX     = 'REDU' (WTAB.'CARACTERISTIQUES') DMODX ;
  215.         DMATX     = 'VARI' 'NUAG' DMODX DMATX CHT2P ;
  216.         CAPAX     = 'CAPA' DMODX DMATX ;
  217.         CAPA1P    = ('REDU' (WTAB.'CAPA_COURANTE') (GEO1P 'DIFF' DGEO1P)) 'ET' CAPAX ;
  218.         WTAB.'CAPA_COURANTE' = CAPA1P ;
  219.  
  220.         DGEO1     = (DGEO1 'INTE' GEO1) 'DIFF' DGEO2P ;
  221.       'FINSI' ;
  222.  
  223. *     Calcul temperature dans partie apportee du modele :
  224.       'SI' ('NON' (('VIDE' DGEO1) 'OU' ('VIDE' (DGEO1 'INTE' GEO1)))) ;
  225. *       Quantite de chaleur sur geometrie GEO1P :
  226.         CHT1P     = CONTI.'TEMPERATURES' 'EXCO' 'T' 'T' ;
  227.         CAPA1P    = WTAB.'CAPA_COURANTE' lump ;
  228.         CHQ1P     = CAPA1P * CHT1P ;
  229. *       Quantite de chaleur dans apport :
  230.         DMODX     = 'REDU' MODX DGEO1 ;
  231.         DMATX     = 'REDU' (WTAB.'CARACTERISTIQUES') DMODX ;
  232.         CHTINIX   = DMATX 'EXCO' 'TINI' 'T' ;
  233.         CHTINIX   = 'CHAN' 'CHPO' CHTINIX DMODX 'MOYE' ;
  234.         DMATX     = 'VARI' 'NUAG' DMODX DMATX CHTINIX ;
  235.         CAPAX     = ('CAPA' DMODX DMATX) lump ;
  236.         CHQX      = CAPAX * CHTINIX ;
  237. *       Calcul T sur GEO1 :
  238.         CAPA1     = CAPA1P et CAPAX ;
  239.         CHTX1     = 'MANU' 'CHPO' GEO1 1 'T' 1. 'NATURE' 'DIFFUS' ;
  240.         CHQX1     = CAPA1 * CHTX1;
  241.         CHT1      = (CHQ1P + CHQX) * ('INVE' CHQX1) ('MOTS' 'Q') ('MOTS' 'Q') ('MOTS' 'T') ;
  242. *        CHT1      = reso CAPA1 (CHQ1P + CHQX) ; comm plus lent avec RESO ;
  243.         CONTI.'TEMPERATURES' = CHT1 ;
  244.       'FINSI' ;
  245.  
  246. *      Sauvegarde TEMPERATURES au debut du pas apres APPORT :
  247.        IND1     = ('DIME' PRECED.'TEMPERATURES_APPORT') - 1 ;
  248.        CHTAPP1  = CONTI.'TEMPERATURES' 'EXCO' 'T' 'TAPP' ;
  249.        PRECED.'TEMPERATURES_APPORT' . IND1 = CHTAPP1 ;
  250.        ESTIM .'TEMPERATURES_APPORT'        = CHTAPP1 ;
  251.  
  252. *   Finsi formulation thermiquue
  253.     'FINSI' ;
  254.  
  255. *   Initialisation PROPORTIONS_PHASES si metallurgie :
  256.     'SI' WTAB.'FOR_METALLU' ;
  257.       MODX      = WTAB.'MODELE' 'EXTR' 'FORM' 'METALLURGIE' ;
  258.       MODXP     = MOD1P         'EXTR' 'FORM' 'METALLURGIE' ;
  259.       GEO1      = MODX  'EXTR' 'MAIL' ;
  260.       GEO1P     = MODXP 'EXTR' 'MAIL' ;
  261.       DGEO1     = GEO1 'DIFF' GEO1P ;
  262.       'SI' ('NON' (('VIDE' DGEO1) 'OU' ('VIDE' (DGEO1 'INTE' GEO1)))) ;
  263.         CHMET0    = CONTI.'PROPORTIONS_PHASES' ;
  264.         DMODX     = 'REDU' MODX DGEO1 ;
  265.         CHMET1    = 'ZERO' DMODX 'VARINTER' ;
  266.         LISCO     = 'EXTR' DMODX 'VARI' ;
  267.         CMP1      = 'EXCO' CHMET1 ('EXTR' LISCO 1) ('EXTR' LISCO 1) ;
  268.         CHMET1    = CHMET1 + (CMP1 + 1.D0);
  269.         CHMET1    = CHMET0 'ET' CHMET1 ;
  270.         CONTI.'PROPORTIONS_PHASES' = CHMET1 'REDU' MODX ;
  271. *trac CHMET1 MODX ;
  272.       'FINSI' ;
  273.     'FINS' ;
  274.  
  275. *   Initialisation MECA si besoin :
  276.     'SI' WTAB.'FOR_MECA' ;
  277.       MODM1    = 'VIDE' 'MMODEL' ;
  278.       MODM1P   = 'VIDE' 'MMODEL' ;
  279.       'SI'  WTAB.'MEC1' ;
  280.         MODM1    = MODM1 'ET' WTAB.'MOD_MEC' ;
  281.         MODM1P   = MODM1P 'ET' ('EXTR' MOD1P 'FORM' 'MECANIQUE') ;
  282.       'FINSI' ;
  283.       'SI'  WTAB.'POR1' ;
  284.         MODM1    = MODM1 'ET' WTAB.'MOD_POR' ;
  285.         MODM1P   = MODM1P 'ET' ('EXTR' MOD1P 'FORM' 'POREUX') ;
  286.       'FINSI' ;
  287.       'SI' ('NON' ('VIDE' MODM1)) ;
  288.         GEOM1    = 'EXTR' MODM1  'MAIL' ;
  289.         GEOM1P   = 'EXTR' MODM1P 'MAIL' ;
  290.         DGEOM1   = GEOM1 'DIFF' GEOM1P ;
  291.         'SI' ('NON' (('VIDE' DGEOM1) 'OU' ('VIDE' (DGEOM1 'INTE' GEOM1)))) ;
  292.           DMODM1   = 'REDU' MODM1 DGEOM1 ;
  293.  
  294. *         Mise a jour ETREF :
  295.           WTAB.'ETAT_REF'= PAS_ETAT PRECED TEMP0 'REFERENCE' ;
  296.           WTAB.'MAT_REF' = PAS_MATE PRECED WTAB.'ETAT_REF'   ;
  297.           TREF1    = 'EXCO' WTAB.'MAT_REF' 'TREF' 'T' ;
  298.           WTAB.'TEMPERATURE_REFERENCE' = 'CHAN' 'TYPE' TREF1 'TEMPERATURES' ;
  299.           DETREF1  = 'EPTH' DMODM1 WTAB.'MAT_REF' WTAB.'TEMPERATURE_REFERENCE' ;
  300.           WTAB.'ETREF' = WTAB.'ETREF' 'ET' DETREF1 ;
  301.  
  302. *         Mise a jour ETHER1 :
  303.           ETAT1    = PAS_ETAT PRECED TI ;
  304.           MAT1     = PAS_MATE PRECED ETAT1 ;
  305.           'SI' ('NON' ('EXIS' PRECED.'CHARGEMENT' 'TAPP')) ;
  306.             'ERREUR' '***** Il manque la donnee du chargement TAPP !' ;
  307.           'FINSI' ;
  308.           TET1     = ('TIRE' PRECED.'CHARGEMENT' 'TAPP' TI) 'EXCO' 'TAPP' 'T' ;
  309.           DETHER1  = ('EPTH' DMODM1 MAT1 TET1) - DETREF1 ;
  310.           WTAB.'ETHER1' = WTAB.'ETHER1' 'ET' DETHER1 ;
  311.  
  312. *         Mise a jour deplacements et deformations :
  313.           DEPDGEO1 = ('EXCO' ETAT1 ('EXTR' DMODM1 'DEPL')) 'CHAN' 'CHPO' DMODM1 ;
  314.           DEPSL1   = ('EPSI' DMODM1 DEPDGEO1) - DETHER1 ;
  315. *erre 21 ;
  316.  
  317. *         Mise a jour table estimation :
  318.           estim.DEPLACEMENTS               = conti.DEPLACEMENTS 'ET' DEPDGEO1 ;
  319.           estim.CONTRAINTES                = conti.CONTRAINTES  'ET' ('ZERO' DMODM1 'CONTRAIN') ;
  320.           estim.VARIABLES_INTERNES         = conti.VARIABLES_INTERNES  'ET' ('ZERO' DMODM1 'VARINTER') ;
  321.           estim.DEFORMATIONS_INELASTIQUES  = conti.DEFORMATIONS_INELASTIQUES  'ET' ('ZERO' DMODM1 'DEFINELA') ;
  322.           estim.DEFORMATIONS               = conti.DEFORMATIONS 'ET' ('ZERO' DMODM1 'DEFORMAT') ;
  323.           estim.DEFORMATIONS_APPORT        = conti.DEFORMATIONS_APPORT 'ET' DEPSL1 ;
  324.  
  325. *         Correction deformation apport avec CHAR_DEFI :
  326.           CGDEFAP1 = 'CHAR' 'DEFI' (-1. * (estim.DEFORMATIONS_APPORT)) ;
  327.           WTAB . 'CHARGEMENT' = WTAB . 'CHARGEMENT_I' 'ET' CGDEFAP1 ;
  328.           'SI' ('NON' WTAB.CHAR_DEFI) ;
  329.             WTAB.CHAR_DEFI = VRAI ;
  330.             WTAB.DEFOR1    = 'ZERO' MODM1 'DEFORMAT' ;
  331.           'FINSI' ;
  332.         'FINSI' ;
  333.  
  334.       'SINON' ;
  335.           estim.DEFORMATIONS_APPORT      = conti.DEFORMATIONS_APPORT ;
  336.  
  337.       'FINSI' ;
  338.     'FINSI' ;
  339.  
  340. * Fin traitement CHAR_MODE
  341.   'FINSI' ;
  342. *
  343. * ++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
  344. * +++++++++++++++++ BOUCLE interne de bouclage mec_ther ++++++++++++++++
  345. * ++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
  346.   I_BOTH = 0 ;
  347.   'REPETER' BO_BOTH WTAB.'BOU_METH' ;
  348.     I_BOTH = I_BOTH + 1 ;
  349. *
  350. *   Re-initialisation de WTAB.'CHARGEMENT' en tete de boucle mec-ther
  351.     'SI' WTAB.'CONVERGENCE_MEC_THE' ;
  352.       WTAB.'CHARGEMENT' = WTAB.'CHARGEMENT_I' ;
  353.     'FINSI';
  354. *
  355. *   ####################################################################
  356. *   ########### RESOLUTION D'UN PAS SI THERMIQUE/DIFFUSION #############
  357. *   ####################################################################
  358.     'SI' (WTAB.'FOR_THER' 'OU' WTAB.'FOR_DIFF') ;
  359. *
  360. *     Se placer dans la configuration adequate
  361.       'SI' WTAB.'FOR_MECA' ;
  362.         'SI' (I_BOTH > 1) ;
  363.           'SI' WTAB.'GRANDS_DEPLACEMENTS' ;
  364.             WTAB.'RECARI'   = VRAI ;
  365.             WTAB.'REA_GEOM' = VRAI ;
  366.             'FORM' WTAB.'FOR' ;
  367.           'FINSI';
  368.         'SINON' ;
  369.           'FORM' WTAB.'GE0_DEB' ;
  370.         'FINSI' ;
  371.       'FINSI' ;
  372. *
  373.       'SI' (TI 'NEG' TEMP0);
  374.         WTAB.'TEM_CALC' = 'PROG' TI;
  375.         'SI' ('EXISTE' PRECED 'PAS_MAX');
  376.           'SI' ((TEMP0 + PRECED.'PAS_MAX') '<' TI);
  377.             WTAB.'TEM_CALC' = 'PROG' TEMP0 'PAS' PRECED.'PAS_MAX' TI ;
  378.             WTAB.'TEM_CALC' = 'ENLE' WTAB.'TEM_CALC' 1;
  379.           'FINSI';
  380.         'FINSI';
  381.  
  382. *       Mise a jour blocages passes dans chargement
  383. *       -> ISO AVANT MAIS A FAIRE A CHAQUE FOIS SI DEPEND DE LA MECA ??
  384.         'SI' ('EGA' I_BOTH 1) ;
  385. *         Cas BLOCAGES_THERMIQUES (BLOT) :
  386.           'SI' WTAB.'CHAR_BLOT' ;
  387.             BLOT1 = 'TIRE' PRECED.'BLOCAGES_THERMIQUES' 'BLOT' TI ;
  388.             WTAB.'BLOCAGES_THERMIQUES' = BLOT1 ;
  389.           'FINSI' ;
  390. *
  391. *         Cas BLOCAGES_DIFFUSIONS (BLOD) :
  392.           'SI' WTAB.'CHAR_BLOD' ;
  393.             BLOD1 = 'TIRE' PRECED.'BLOCAGES_DIFFUSIONS' 'BLOD' TI ;
  394.             WTAB.'BLOCAGES_DIFFUSIONS' = BLOD1 ;
  395.           'FINSI' ;
  396.         'FINSI' ;
  397. *
  398. * ----- Appel a la procedure thermique (lineaire ou nonlineaire) ----
  399. *
  400.         'SI' ('NON' WTAB.'COUPLAGE'); 'MENAGE'; 'FINSI';
  401.         'SI' ('EGA' WTAB.'PROCEDURE_THERMIQUE' 'NONLINEAIRE');
  402.           CHTER = TRANSNON PRECED;
  403.         'FINSI';
  404.         'SI' ('EGA' WTAB.'PROCEDURE_THERMIQUE' 'LINEAIRE');
  405.           CHTER = TRANSLIN PRECED;
  406.         'FINSI';
  407.         'SI' ('EGA' WTAB.'PROCEDURE_THERMIQUE' 'DUPONT');
  408.           WTAB.'NOUV_PAS' = ('EXTR' WTAB.'TEM_CALC' 1) - TEMP0;
  409.           CHTER = DUPONT2 PRECED;
  410.         'FINSI';
  411. *
  412. *       Verification d'une erreur en sortie
  413.         'SI' CHTER.'ERREUR';
  414.           'ERREUR' ' ';
  415.         'FINSI';
  416. *
  417. *       Se placer sur la configuration de reference (appel proc ut.)
  418.         'FORM' WTAB.'FOR0' ;
  419. *
  420. *        Reevaluation des donnees du calcul dependant de la temperature
  421.         'SI' WTAB.'PROCEDURE_REEV_THE' ;
  422.           REEV_THE PRECED  1 ;
  423.         'FINSI' ;
  424.       'FINS';
  425. *
  426.     'FINSI' ;
  427. *   ####################################################################
  428. *   ###### RESOLUTION D'UN PAS SI MECANIQUE/MECANIQUE DES FLUIDES ######
  429. *   ####################################################################
  430.     'SI' (WTAB.'FOR_MECA' 'OU' WTAB .'NVSTNL') ;
  431.       'SAUT' 1 'LIGN';
  432.       'MESSAGE' ' Numero du pas : ' IPAS '  Indice d evolution : ' ICHG ' -> temps :' TI;
  433. *
  434. *     Se placer sur la configuration de debut de pas
  435.       'FORM' WTAB.'GE0_DEB' ;
  436. *
  437.       'MENA' ;
  438.       IERRMEC = UNPAS PRECED;
  439. *
  440. *     Se placer sur la configuration de reference
  441.       'FORM' WTAB.'FOR0' ;
  442. *
  443. *     Test si on a converge
  444.       'SI' IERRMEC ;
  445.         'ERREUR' 997 ;
  446.       'FINSI';
  447. *
  448. *     Reevaluation des donnees du calcul dependant de la mecanique
  449.       'SI' WTAB.'PROCEDURE_REEV_MEC' ;
  450.         REEV_MEC PRECED 1;
  451.       'FINSI' ;
  452. *
  453.     'FINSI';
  454. *   ####################################################################
  455. *   ############ TEST DE LA CONVERGENCE MECANIQUE THERMIQUE ############
  456. *   ####################################################################
  457.     'SI' WTAB.'CONVERGENCE_MEC_THE' ;
  458. *      je cherche la convergence thermo-mecanique : je dois au moins
  459. *      calculer deux fois mon probleme
  460.       WTAB.'CONV_THMEC' = FAUX ;
  461.       'SI' (I_BOTH > 1) ;
  462. *       Test sur toutes les composantes (notamment, si DIFFUSION)
  463.         CHT1     = WTAB.'THER_COURANT' ;
  464.         DUABS2   = 'ABS' (WTAB.'THER_COURANTP' - CHT1) ;
  465.         CRICOH1  = 0. ;
  466.         NBINCO1  = 'DIME' WTAB.'PRIM_TOT' ;
  467.         'REPE' BINCO1 NBINCO1 ;
  468.           LINCOI1  = 'MOTS' ('EXTR' WTAB.'PRIM_TOT' &BINCO1) ;
  469.           MDUABSI1 = 'MAXI' DUABS2 'AVEC' LINCOI1 ;
  470.           NORMI1   = 'MAXI' 'ABS' CHT1 'AVEC' LINCOI1 ;
  471.           'SI' (NORMI1 '&lt;EG' (1.E-14 * MDUABSI1)) ;
  472.             NORMI1 = 1. ;
  473.           'FINS' ;
  474.           CRICOHI1 = MDUABSI1 / NORMI1 ;
  475.           'SI' (CRICOHI1 '>' CRICOH1) ;
  476.             CRICOH1  = CRICOHI1 ;
  477.          'FINS' ;
  478.         'FIN' BINCO1 ;
  479.  
  480.         WTAB.'CONV_THMEC' = CRICOH1 '<' (WTAB . 'CRITERE_COHERENCE') ;
  481. *       Fin de boucle Si ne converge Pas
  482.         'SI'('NON' WTAB.'CONV_THMEC') ;
  483.           'SI' (I_BOTH >EG WTAB.'BOU_METH');
  484.             'MESS' 'PAS DE COHERENCE TROUVEE MECANIQUE THERMIQUE' ;
  485.             'ERREUR' 999;
  486.           'FINSI' ;
  487.         'FINSI' ;
  488.       'FINSI' ;
  489. *     THER_COURANTPrecedent dans WTAB pour test CONVERGENCE_MEC_THE
  490.       WTAB.'THER_COURANTP' = WTAB.'THER_COURANT' ;
  491.     'FINSI' ;
  492. *
  493.     'SI' WTAB.'CONV_THMEC' ;
  494.       'QUITTER' BO_BOTH ;
  495.     'FINSI' ;
  496. *
  497.   'FIN' BO_BOTH ;
  498. * ++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
  499. * +++++++++++++++++ BOUCLE interne de bouclage mec_ther ++++++++++++++++
  500. * ++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
  501. *
  502. * ----------------------------------------------------------------------
  503. *       Mise a jour de quantites de WTAB a partir de celles a TI
  504. * ----------------------------------------------------------------------
  505. *
  506. * Formulation THERMIQUE
  507.   'SI' WTAB.'FOR_THER';
  508.     'SI' ('EGA' WTAB.'PROCEDURE_THERMIQUE' 'DUPONT');
  509.       WTAB.'TET0'              = estim.'TEMPERATURES' ;
  510.       WTAB.'VIEUXPAS'          = WTAB.'NOUV_PAS' ;
  511.       WTAB.'RELAXATION_DUPONT' = CHTER.'RELAXATION_DUPONT';
  512.     'FINSI';
  513.   'FINSI' ;
  514.  
  515. * Cas du modele THERMOHYDRIQUE BETON_THM (Sciume) : mise a jour des variables internes
  516.   ITHM1=WTAB.'THM1';
  517.   'SI' ITHM1;
  518.          'SI' ('EXIS' WTAB 'VAR_THM1') ;
  519.          WTAB . 'VAR_THM1' = WTAB . 'VAR_THM2' ; 
  520.          'FINS';
  521.   'FINS';  
  522.  
  523. *
  524. * Formulation MECANIQUE
  525.   'SI' WTAB.'FOR_MECA' ;
  526. *
  527.     'SI' WTAB.'ITHER' ;
  528.       WTAB.'TET1'   = WTAB.'TET2';
  529.       WTAB.'ETHER1' = WTAB.'ETHER2';
  530.       'SI' WTAB.'POR1';
  531.         WTAB.'MSRTHER1'= WTAB.'MSRTHER2';
  532.       'FINSI';
  533.     'FINSI' ;
  534. *       
  535. * Cas du modle VISCOPLASTIQUE BETON_THM (Sciume)
  536.     'SI' WTAB.'BETON_THM';
  537.        WTAB.'BETON_MCR1' =  WTAB.'BETON_MCR2';
  538.     'FINS' ; 
  539. *
  540.     'SI' WTAB.'CHAR_DEFI' ; 
  541.       WTAB.'DEFOR1' = WTAB.'DEFOR2';
  542.     'FINSI';
  543. *
  544.     'SI' WTAB.'DYNAMIQUE' ;
  545.       'SI' ('NON' WTAB.'LIAISON_PERSISTANTE') ;
  546.         WTAB.'FREA1' = WTAB.'FOPL' ;
  547.       'FINSI';
  548.       WTAB.'REAPREC' = estim.'REACTIONS';
  549.     'FINSI';
  550. *
  551. *   Actualiser la configuration de debut de pas
  552.     'SI' ( WTAB.'GRANDS_DEPLACEMENTS' 'OU'
  553.           (WTAB.'FEFP_FORMULATION' 'ET' WTAB.'UPDATE_LAGRANGIAN')) ;
  554.       WTAB.'GE0_DEB' = WTAB.'FOR' ;
  555.     'FINSI';
  556. *
  557.   'FINSI';
  558. *
  559. * Option AUTOMATIQUE : temps effectivement calcule
  560.   'SI' (WTAB.'AUTOMATIQUE' 'OU' ('NON' WTAB.'CONV'));
  561.     TEMP0 = (TI '-' TEMP0) '*' WTAB.'AUTOCOEF' '+' TEMP0;
  562.     estim.'TEMPS' = TEMP0 ;
  563.     MSGZ = 'CHAI' ' Temps effectivement calcule';
  564.     'SI' ('NON' WTAB.'CONV');
  565.       MSGZ = 'CHAI' MSGZ ' et non converge';
  566.     'FINSI';
  567.     'MESS' MSGZ ' : 'TEMP0;
  568.   'FINSI';
  569.  
  570. * Procedure utilisateur
  571.   'SI' WTAB.'FOR_MECA' ;
  572.     'SI' WTAB.'PROCEDURE_PERSO1' ;
  573.       PRECED.'PERSO1_APPEL' = 2 ;
  574.       PERSO1 PRECED;
  575.       'SI' ('EXIS' PRECED 'ARRET') ;
  576.         WTAB.'ARRET' = PRECED.'ARRET' ;
  577.       'FINSI' ;
  578.     'FINSI';
  579. *
  580. *   Redefinir WTAB.'CHARGEMENT_I'
  581.     'SI' WTAB.'CONVERGENCE_MEC_THE' ;
  582.       WTAB.'CHARGEMENT_I' = WTAB.'CHARGEMENT' ;
  583.     'FINSI';
  584.   'FINSI';
  585. *
  586. * pour ne pas sauvegarder la matrice de raideur si on doit la recalculer
  587.   'SI' ('EXIS' WTAB 'RRRR') ;
  588.     'SI' WTAB.'RECARI' ;
  589.       'OUBL' WTAB 'RRRR' ;
  590.     'FINSI';
  591.   'FINSI';
  592. *
  593. * ----------------------------------------------------------------------
  594. *        Remplir CONTINUATION et table de resultats + sauvegarde
  595. * ----------------------------------------------------------------------
  596.   ISAUV = PAS_RESU iauto PRECED ;
  597. *
  598. * Option AUTOMATIQUE
  599.   'SI' WTAB.'AUTOMATIQUE'; 
  600.     'SI' ((WTAB.'AUTOCOEF' 'EGA'  0.9999999D0) 'OU' (TEMP0 '>EG' TI)) ;
  601.       'MESS' ' Objectif atteint '; 'MESS' ' ';
  602.       WTAB.'AUTODEUX' = FAUX ;
  603.       WTAB.'AUTORED1' = 0 ;
  604.       WTAB.'AUTOREDU' = 1. ;
  605.       IAUTO = 1;
  606.     'SINON';
  607.       'MESS' ' Objectif non atteint: On recommence'; 'MESS' '  ';
  608.       IAUTO = IAUTO+1;
  609.       'SI' (IAUTO >EG WTAB.'AUTOPAS');
  610.         'ERREUR' 1000;
  611. *       'MESS' 'Pilotage non converge  apres ' IAUTO ' pas.';
  612.       'FINSI';
  613.       WTAB.'AUTODEUX'=VRAI;
  614.       ICHG=ICHG - 1; WTAB.'ICHG' = ICHG ;
  615.     'FINSI';
  616.   'FINSI';
  617. *
  618. * Option PAS_AJUSTE
  619.   'SI' WTAB.'PAS_AJUSTE';
  620.     'SI' ((TI < TIV) 'OU' ('NON' WTAB.'CONV')); 
  621.       ICHG=ICHG-1; WTAB.'ICHG' = ICHG ;
  622.     'FINSI';
  623.   'FINSI';
  624. *
  625.   'SI' WTAB.'ARRET';
  626.     'QUITTER' BEXTERN;
  627.   'FINSI';
  628. *
  629. 'FIN' BEXTERN;
  630. *-----------------------------------------------------------------------
  631. *              Fin de la boucle sur les pas de temps
  632. *-----------------------------------------------------------------------
  633. 'SI' ('NEG' WTAB.'AMORTISSEMENT' 'INCONNU');
  634.   WTAB.'AMORTISSEMENT' = TOTO ;
  635. 'FINSI';
  636. *
  637. 'SI' ('NEG' ('TYPE'  WTAB.'GE0_DEB') 'MOT') ;
  638.   'OUBL' WTAB 'GE0_DEB' ;
  639. 'FINSI' ;
  640. *
  641. * pour forcer le calcul de la rigidite si on  rappele  pasapas
  642. 'SI' ('EXIS' WTAB 'RRRR') ;
  643.   'OUBL' WTAB 'RRRR';
  644. 'FINSI';
  645. *
  646. * on tue WTAB.'MAT1' s'il existe car il peut etre tres gourmand en place
  647. WTAB.'MAT1' = 'MOT' 'INCONNU';
  648. *
  649. 'MESS' ' ';
  651. '------------------- FIN DE LA PROCEDURE PASAPAS ---------------------';
  652. 'SAUT' 1 'LIGNE';
  653. ************************************************************************
  654. 'FINPROC' PRECED ;
  655.  
  656.  
  657.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales