Télécharger la plaquette Cast3M


fr en

Télécharger adve_04.dgibi

Retour à la liste

Numérotation des lignes : 

  1. * fichier : adve_04.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4. * Cas-test de l'operateur ADVEction dans la formulation DIFFUSION      *
  5. *                                                                      *
  6. * Comparaison a une solution analytique.                               *
  7. *                                                                      *
  8. * On calcule la concentration d'un fluide qui s'ecoule dans un tuyau   *
  9. * chauffe sur toute sa longueur.                                       *
  10. * On verifie la concentration du fluide en sortie du tuyau.            *
  11. *                                                                      *
  12. * Le flux lineique est de         : 500 mol/m-3/m-1                    *
  13. * La concentration en entree est de : 20mol.m-3                        *
  14. * La vitesse d'ecoulement est de  : 25 cm/s                            *
  15. * La section du tuyau est de      : 5.e-5 m2, diametre ~ 8 mm          *
  16. * La longueur du tuyau est de     : 5 m                                *
  17. *                                                                      *
  18. * La concentration attendue en sortie est de : 70mol.m-3               *
  19. *                                                                      *
  20. * On utilise les elements lineaires et quadratiques (TUY2,TUY3)        *
  21. *                                                                      *
  22. *----------------------------------------------------------------------*
  23. 'OPTI' 'DIME' 3 'ELEM' 'SEG2' ;
  24. *                                                                      *
  25. * Commentez cette ligne pour voir les traces :                         *
  26. 'OPTI' 'TRAC' 'PSC' ;
  27. *                                                                      *
  28. O1       = 0 0 0 ;
  29. X1       = 1 0 0 ;
  30. P1       = 2.5 * X1 ;
  31. P2       = 5.0 * X1 ;
  32. Y1       = 0 1 0 ;
  33. Z1       = 0 0 1 ;
  34. *                                                                      *
  35. L1       = O1 'DROI' 5 P1 'COUL' 'VERT' ;
  36. L2       = P1 'DROI' 10 P2 ;
  37. L2       = 'CHAN' 'QUAD' L2 'COUL' 'BLEU' ;
  38. 'TITR' ' Maillage du tuyau, longueur = 5 m (Vert=SEG2,Bleu=SEG3) ' ;
  39. 'TRAC' 'QUAL' (L1 'ET' L2) ;
  40. *                                                                      *
  41. mo1      ='MODE' L1 diffusion advection 'TUY2' ;
  42. mo2      ='MODE' L2 diffusion advection 'TUY3' ;
  43. mo1      = mo1 'ET' mo2 ;
  44. *                                                                      *
  45. L0       = L1 'ET' L2 ;
  46. *
  47. * Le flux advectee dans un tuyau est J = Cdif.Sect.V :                 *
  48. ma1      = 'MATE' mo1 'CDIF' 4.e6 'VITE' 0.25 'SECT' 5.e-5 ;
  49. *                                                                      *
  50. sq1      = 'SOUR' mo1 ma1 L0 (5.e2 / 5.e-5) ;
  51. list (MAXI (resu sq1));
  52. 'TITR' ' Terme source le long du tuyau ' ;
  53. 'DESS' ('EVOL' 'VERT' 'CHPO' sq1 L0 'QCO') 'YBOR' 0. 300. ;
  54. *                                                                      *
  55. KA1      = 'ADVE' mo1 ma1 ;
  56. *                                                                      *
  57. cl1      = 'BLOQ' 'CO' O1 ;
  58. dcl1     = 'DEPI' cl1 20. ;
  59. *                                                                      *
  60. chC2     = 'RESO' (ka1 'ET' cl1) (sq1 'ET' dcl1);
  61. *                                                                      *
  62. 'TITR' ' Evolution de la concentration le long du tuyau ' ;
  63. 'DESS' ('EVOL' 'VERT' 'CHPO' chC2 L0 'CO') ;
  64. *                                                                      *
  65. * Test :
  66. cref1    = 70. ;
  67. Cp1      = 'EXTR' chC2 'CO' P2 ;
  68. err1     = 'ABS' (cREF1 - Cp1) / Cp1 ;
  69. *                                                                      *
  70. 'OPTI' 'ECHO' 0 ;
  71. 'MESS' ;
  72. mot1     = 'CHAI' ' > concentration calculee en  sortie = '
  73.   'FORMAT' '(F3.0)' Cp1 'mol.m-3 pour 70mol.m-3 attendu ' ;
  74. 'MESS' mot1 ;
  75. 'MESS' ' > Erreur relative = ' err1 ;
  76. 'MESS' ;
  77. 'OPTI' 'ECHO' 1 ;
  78. *                                                                      *
  79. 'SI' (err1 > 1.e-5) ;
  80.   'ERRE' 5 ;
  81. 'SINO' ;
  82.   'OPTI' 'ECHO' 0 ;
  83.   'MESS' ;
  84.   'MESS' ' > Test reussi ' ;
  85.   'MESS' ;
  86. 'FINS' ;
  87. *                                                                      *
  88. 'FIN' ;
  89.  
  90.  
  91.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales