Télécharger soret_2.dgibi

Retour à la liste

Numérotation des lignes :

  1. * fichier : soret_2.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4.  
  5. ************************************************************************
  6. * CAS TEST soret_2.dgibi *
  7. ************************************************************************
  8. * Test effet Soret
  9. * - 2D PLAN
  10. * - ELEMENTS FINIS TESTES : 'QUA8'
  11. * - Regime permanent
  12. * - C(X0) = C0
  13. * - C(X1) = C1
  14. * - GRAD(T) choisi constant (T=GT*X ==> GRAD(T)= A)
  15. * - CONDUCTION et SORET sont en concurrence
  16. ************************************************************************
  17.  
  18.  
  19. ************************************************************************
  20. * OPTIONS & REGLAGES
  21. ************************************************************************
  22. GRAPH = 'N' ;
  23. 'OPTI' 'DIME' 2 'ELEM' 'QUA8' ;
  24.  
  25. 'SI' ('NEG' GRAPH 'N');
  26. 'OPTI' 'TRAC' 'X';
  27. 'SINO';
  28. 'OPTI' 'TRAC' 'PSC';
  29. 'FINS';
  30.  
  31. NBE1 = 15 ;
  32. NBE2 = 15 ;
  33.  
  34. K = -7.D0;
  35. GT = 1.D0;
  36.  
  37. X0 = 1. ;
  38. X1 = 2. ;
  39.  
  40. C0 = 0. ;
  41. C1 = 2. ;
  42.  
  43. ************************************************************************
  44. * MAILLAGE
  45. ************************************************************************
  46. P1 = X0 0. ;
  47. P2 = X0 1. ;
  48. P3 = X1 1. ;
  49. P4 = X1 0. ;
  50.  
  51. L1 ='DROI' NBE1 P1 P2;
  52. L2 ='DROI' NBE1 P4 P3;
  53.  
  54. S1 ='REGL' NBE2 L1 L2;
  55. L3 ='COTE' 2 S1;
  56.  
  57. 'TRAC' 'QUAL' S1;
  58.  
  59. ************************************************************************
  60. * MODELE & MATERIAU
  61. ************************************************************************
  62. MOD1 ='MODE' S1 'DIFFUSION' 'FICK' 'INCO' 'HI ' 'QHI ';
  63. MAT1 ='MATE' MOD1 'KD ' 1.D0 ;
  64. MAT2 ='MANU' 'CHML' MOD1 'SCAL' K 'RIGIDITE' ;
  65.  
  66. ************************************************************************
  67. * Champ de temperature pour que le GRAD(T) soit constant
  68. ************************************************************************
  69. COO1 ='COOR' 1 S1 ;
  70. EVO1 ='EVOL' 'BLEU' 'CHPO' COO1 'SCAL' L3 ;
  71. TEMP1 ='CHAN' 'COMP' (COO1 * GT) 'T' ;
  72. 'TITR' 'Evolution de la TEMPERATURE avec UX';
  73. EVOT ='EVOL' 'BLEU' 'CHPO' TEMP1 'T' L3 ;
  74. 'DESS' EVOT ;
  75.  
  76. ************************************************************************
  77. * RIGIDITE
  78. ************************************************************************
  79. RIG1 ='COND' MOD1 MAT1;
  80. RIG2 ='SORE' MOD1 MAT1 MAT2 TEMP1;
  81.  
  82. ************************************************************************
  83. * CONDITIONS AUX LIMITES
  84. ************************************************************************
  85. CLIM1 ='BLOQ' 'HI' L1 ;
  86. CLIM2 ='BLOQ' 'HI' L2 ;
  87.  
  88.  
  89. CIMP1 ='DEPI' CLIM1 C0 ;
  90. CIMP2 ='DEPI' CLIM2 C1 ;
  91.  
  92. ************************************************************************
  93. * RESOLUTION
  94. ************************************************************************
  95. SOL1 ='RESO' (RIG1 ET RIG2 ET CLIM1 ET CLIM2) (CIMP1 ET CIMP2);
  96. 'TITR' 'Isovaleurs de concentration en HI';
  97. 'TRAC' SOL1 S1;
  98.  
  99. ************************************************************************
  100. * POST-TRAITEMENT
  101. ************************************************************************
  102. * Solution NUMERIQUE
  103. EVONUM ='EVOL' 'ROUG' 'CHPO' SOL1 'HI ' L3 ;
  104. LCNUM ='EXTR' EVONUM 'ORDO' 1 ;
  105.  
  106. * Solution ANALYTIQUE
  107. EVO2 ='EVOL' 'CHPO' TEMP1 'HI' L3 ;
  108. LRX ='EXTR' EVO1 'ORDO' 1;
  109. LCANA = ((('EXP' (-1*K*GT*X1 ))*C0) - (('EXP' (-1*K*GT*X0 ))*C1) +
  110. (('EXP' (-1*K*GT*LRX))*C1) - (('EXP' (-1*K*GT*LRX))*C0) ) /
  111. ( ('EXP' (-1*K*GT*X1)) - ('EXP' (-1*K*GT*X0)) ) ;
  112.  
  113. EVOANA ='EVOL' 'BLEU' 'MANU' 'X' LRX 'HICA' LCANA;
  114. 'DESS' (EVONUM ET EVOANA);
  115.  
  116. * Comparaison
  117. LCDIFF = LCNUM - LCANA ;
  118. 'TITR' 'Difference entre la Solutions NUMERIQUE et ANALYTIQUE';
  119. EVODIF ='EVOL' 'VERT' 'MANU' 'X' LRX 'HICA' LCDIFF;
  120. 'DESS' EVODIF;
  121.  
  122.  
  123. * Critere d'erreur
  124. 'OPTI' 'ECHO' 0;
  125. ERRABS ='MAXI' 'ABS' LCDIFF;
  126. ERRREL = ERRABS / ('ABS' (C1 - C0)) ;
  127. 'MESS' '*********************************************' ;
  128. 'MESS' '* Erreur MAXIMALE absolue :' ERRABS '*';
  129. 'MESS' '* Erreur MAXIMALE relative :' ERRREL '*';
  130. 'MESS' '*********************************************' ;
  131. 'SI' (ERRREL >EG 8.8D-5);
  132. 'ERRE' 5;
  133. 'FINS';
  134.  
  135. 'FIN';
  136.  
  137.  
  138.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales