Télécharger joi1_decol.dgibi

Retour à la liste

Numérotation des lignes :

  1. *----------------------------------------------------------------------*
  2. *
  3. * Objet :
  4. * controler le probleme (solution non physique) observé
  5. * lors de la re-ouverture du JOI1 dans la simulation avec
  6. * Cast3M 2019 de la compression du modele
  7. * simplife du ressort a lames SM_1_2 (stage 2020 )
  8. *
  9. * Test d'écrasement du système de maintien assemblage REP :
  10. * JOI1 Mohr-Coulomb avec glissements et décollements sur lame plastique
  11. *
  12. *----------------------------------------------------------------------*
  13.  
  14.  
  15. *=== OPTIONS ==========================================================*
  16.  
  17. 'OPTI' 'DIME' 3 ;
  18. 'OPTI' 'MODE' 'TRIDIM' ;
  19. 'OPTI' 'ELEM' 'CUB8' ;
  20. 'OPTI' 'DENS' 1.E-3 ;
  21. 'OPTI' 'DENS' 9.37500E-04 ;
  22. 'OPTI' 'TRAC' 'PSC' ;
  23.  
  24. LOGITRAC = FAUX; comm 'à reactiver si besoin visu'; ;
  25.  
  26. * - pas de temps = 1 s
  27. * 18.09.23 passage à 10sec OK pour analyse/cas test rapide
  28. PAS_C = 10.;
  29.  
  30. OEIL_Z = 0.90E+06 -0.11E+07 0.70E+06 ;
  31. O_1 = 0.90E+06 -3.30E+06 0.70E+06 ;
  32.  
  33. * Titres
  34. STR_Z3 = 'MOT' 'SYST.MAINT. - SM_1_2' ;
  35. NOM_ESS = 'MOT' 'Essai EDF' ;
  36.  
  37.  
  38. *=== PARAMETRES =======================================================*
  39.  
  40. *--- Ressort
  41. * Angle de la partie inclinee (degres)
  42. A_INCL = 41.3 ;
  43. * 1/2 largeur de la plaque de compression BB
  44. C6130 = 1.81920E-01 ;
  45. C6132 = 6.50000E-03 ;
  46. BB = (0.5 * C6130) + C6132 ;
  47. * Materiau A718
  48. YOUN1 = 2.000E+11 ;
  49. NU1 = 2.900E-01 ;
  50. ALPH1 = 1.390E-05 ;
  51. RHO1 = 8.210E+03 ;
  52. * PROGX = 'PROG'
  53. * 0.000E+00 4.850E-03 5.700E-03 6.100E-03 6.400E-03 6.800E-03
  54. * 7.400E-03 8.600E-03 1.000E-02 1.200E-02 1.500E-02 1.900E-02
  55. * 2.390E-02 2.870E-02 4.720E-02 8.520E-02 1.218E-01 1.528E-01
  56. * 1.761E-01 10.1761 ;
  57. * PROGY = 'PROG'
  58. * 0.000E+00 9.700E+08 1.090E+09 1.128E+09 1.146E+09 1.165E+09
  59. * 1.185E+09 1.212E+09 1.229E+09 1.246E+09 1.265E+09 1.285E+09
  60. * 1.306E+09 1.328E+09 1.383E+09 1.484E+09 1.564E+09 1.622E+09
  61. * 1.664E+09 1.968975E+10 ;
  62. PROGX = 'PROG'
  63. 0.000E+00 (5.700E-03-4.850E-03) (6.100E-03-4.850E-03)
  64. (6.400E-03-4.850E-03) (6.800E-03-4.850E-03)
  65. (7.400E-03-4.850E-03) (8.600E-03-4.850E-03)
  66. (1.000E-02-4.850E-03)
  67. (1.200E-02-4.850E-03) (1.500E-02-4.850E-03) (1.900E-02-4.850E-03)
  68. (2.390E-02-4.850E-03) (2.870E-02-4.850E-03)
  69. (4.720E-02-4.850E-03)
  70. (8.520E-02-4.850E-03) (1.218E-01-4.850E-03) (1.528E-01-4.850E-03)
  71. (1.761E-01-4.850E-03) (10.1761-4.850E-03) ;
  72. PROGY = 'PROG'
  73. 9.700E+08 1.090E+09 1.128E+09 1.146E+09 1.165E+09
  74. 1.185E+09 1.212E+09 1.229E+09 1.246E+09 1.265E+09 1.285E+09
  75. 1.306E+09 1.328E+09 1.383E+09 1.484E+09 1.564E+09 1.622E+09
  76. 1.664E+09 1.968975E+10 ;
  77. TRAC1 = 'EVOL' 'TURQ' 'MANU' 'EPS.TOT.R' PROGX 'SIG.R' PROGY ;
  78. * Section poutre
  79. SECT5 = (2.73000E-04 + 1.38320E-04) / 2. ;
  80. SECR5 = (5./6.) * SECT5 ;
  81. INRY5 = (3.19922E-10 + 4.16113E-11) / 2. ;
  82. INRZ5 = (7.53571E-09 + 3.81809E-09) / 2. ;
  83. TORS5 = (7.85563E-09 + 3.85970E-09) / 2. ;
  84. 'MESS' 'INRY moyen' ' ' INRY5 ;
  85. 'MESS' 'INRZ moyen' ' ' INRZ5 ;
  86. 'MESS' 'TORS moyen' ' ' TORS5 ;
  87. EP_M = (3.75E-3 + 1.9E-3) / 2. ;
  88. DY5 = EP_M / 2. * (3./4.) ;
  89. LA_T = 18.2E-3 * 4. ;
  90. DZ5 = LA_T / 2. * (3./4.) ;
  91.  
  92. *--- Plaque
  93. * Rotation RY de la plaque vers l'avant : AP_Y > 0
  94. AP_Y = 10. ;
  95. * Rotation RX de la plaque sur le cote : AP_X = 0
  96. AP_X = 0. ;
  97.  
  98. *--- Element de liaison JOI1
  99. DIR1 =
  100. ((COS AP_X)*(SIN AP_Y)) (-1.*(SIN AP_X)) ((COS AP_X)*(COS AP_Y)) ;
  101. DIR2 =
  102. (COS AP_Y) 0. (-1.*(SIN AP_Y)) ;
  103. COFRO1 = 0.44000 ;
  104. PHI1 = 'ATG' COFRO1 ;
  105.  
  106.  
  107. *=== MAILLAGE =========================================================*
  108.  
  109. *--- Ressort
  110. * Base
  111. RE_P1 = 0. 0. 0. ;
  112. RE_P2 = 2.66500E-02 0. 0. ;
  113. RE_L1 = 'DROI' RE_P1 RE_P2 ;
  114. * MESH_Z = RE_L1 'COUL' 'ROUG' ;
  115. * TITR_Z = 'CHAI' 'Base Ressort RE_L1' ;
  116. * 'TRAC' 'QUAL' 'TITRE' TITR_Z MESH_Z OEIL_Z ;
  117.  
  118. * Coude
  119. RE_O1 = 2.66500E-02 0. 1.25000E-02 ;
  120. RE_P3 = RE_P2 'TOUR' (-1.*A_INCL) RE_O1 (RE_O1 'PLUS' (0. 1. 0.)) ;
  121. RE_L2 = 'CERC' RE_P2 RE_O1 RE_P3 ;
  122. * MESH_Z = RE_L2 'COUL' 'ROUG' ;
  123. * TITR_Z = 'CHAI' 'Coude Ressort RE_L2' ;
  124. * 'TRAC' 'QUAL' 'TITRE' TITR_Z MESH_Z OEIL_Z ;
  125. * MESH_Z = RE_L1 'ET' (RE_L2 'COUL' 'ROUG') ;
  126. * 'TRAC' 'QUAL' 'TITRE' TITR_Z MESH_Z OEIL_Z ;
  127.  
  128. * Partie inclinee
  129. RE_P4 = 1.18000E-01 0. 7.42462E-02 ;
  130. RE_L3 = 'DROI' RE_P3 RE_P4 ;
  131. * MESH_Z = RE_L3 'COUL' 'ROUG' ;
  132. * TITR_Z = 'CHAI' 'Partie inclinee Ressort RE_L3' ;
  133. * 'TRAC' 'QUAL' 'TITRE' TITR_Z MESH_Z OEIL_Z ;
  134. * MESH_Z = RE_L1 'ET' RE_L2 'ET' (RE_L3 'COUL' 'ROUG') ;
  135. * 'TRAC' 'QUAL' 'TITRE' TITR_Z MESH_Z OEIL_Z ;
  136.  
  137. * Maillage Ressort
  138. RE_ME = RE_L1 'ET' RE_L2 'ET' RE_L3 ;
  139.  
  140. *--- Plaque
  141. * Bord de la plaque // X
  142. PL_Z = 'COOR' 3 RE_P4 ;
  143. PL_XP2 = 1.78760E-01 ;
  144. PL_P2 = PL_XP2 0. PL_Z ;
  145. PL_P1 = (PL_XP2 - (2.*BB)) 0. PL_Z ;
  146. PL_L1 = 'DROI' 1 PL_P1 PL_P2 ;
  147. * MESH_Z = PL_L1 'COUL' 'ROUG' ;
  148. * TITR_Z = 'CHAI' 'Bord // X Plaque PL_L1' ;
  149. * 'TRAC' 'QUAL' 'TITRE' TITR_Z MESH_Z OEIL_Z ;
  150. * MESH_Z = RE_ME 'ET' (PL_L1 'COUL' 'ROUG') ;
  151. * 'TRAC' 'QUAL' 'TITRE' TITR_Z MESH_Z OEIL_Z ;
  152.  
  153. * Rotation du bord de la plaque // X
  154. PL_O1 = PL_XP2 (-1. * BB) PL_Z ;
  155. PL_O2 = PL_XP2 BB PL_Z ;
  156. PL_L1 = PL_L1 'TOUR' AP_Y PL_O1 PL_O2 ;
  157. PL_P1 = PL_L1 'POIN' 'INITIAL' ;
  158. PL_P2 = PL_L1 'POIN' 'FINAL' ;
  159. * MESH_Z = PL_L1 'COUL' 'ROUG' ;
  160. * TITR_Z = 'CHAI' 'Bord Plaque PL_L1 apres rot. AP_Y' ' ' AP_Y ' deg' ;
  161. * 'TRAC' 'QUAL' 'TITRE' TITR_Z MESH_Z ;
  162. * MESH_Z = RE_ME 'ET' (PL_L1 'COUL' 'ROUG') ;
  163. * 'TRAC' 'QUAL' 'TITRE' TITR_Z MESH_Z ;
  164.  
  165. * Surface plaque
  166. V_EXTRU = 0. ( 2. * BB) 0. ;
  167. PL_S1 = PL_L1 'TRAN' 1 V_EXTRU ;
  168. * MESH_Z = PL_S1 'COUL' 'ROUG' ;
  169. * TITR_Z = 'CHAI' 'Plaque PL_S1 apres rot. AP_Y' ' ' AP_Y ' deg' ;
  170. * 'TRAC' 'QUAL' 'TITRE' TITR_Z MESH_Z OEIL_Z ;
  171. * MESH_Z = RE_ME 'ET' (PL_S1 'COUL' 'ROUG') ;
  172. * 'TRAC' 'QUAL' 'TITRE' TITR_Z MESH_Z OEIL_Z ;
  173.  
  174. * Maillage Plaque
  175. PL_ME = PL_S1 ;
  176.  
  177. *--- Element de liaison JOI1
  178. * Points d'accrochage du JOI1
  179. * - sur le ressort : RE_J1 = RE_P4
  180. * - sur la plaque : PL_J1 = proj. RE_P4 sur la plaque dans la dir. Uimp (Z)
  181. RE_J1 = RE_P4 ;
  182. PL_J1 = RE_P4 'PROJ' 'CYLI' (0. 0. 1.) 'PLAN'
  183. (PL_ME 'POIN' 'PROC' PL_P1)
  184. (PL_ME 'POIN' 'PROC' PL_P2)
  185. (PL_ME 'POIN' 'PROC' (PL_P1 'PLUS' V_EXTRU)) ;
  186. * Distance entre RE_J1 et PL_J1
  187. D_I = ( ((('COOR' 1 PL_J1) - ('COOR' 1 RE_J1))**2) +
  188. ((('COOR' 2 PL_J1) - ('COOR' 2 RE_J1))**2) +
  189. ((('COOR' 3 PL_J1) - ('COOR' 3 RE_J1))**2) )**0.5 ;
  190. * Maillage du JOI1
  191. JO_ME = 'DROI' 1 RE_J1 PL_J1 ;
  192. TITR_Z = 'CHAI' 'Jeu initial dans le JOI1' ' ' D_I ' m' ;
  193. MESH_Z = RE_ME 'ET' (PL_S1 'COUL' 'ROUG') 'ET' (JO_ME 'COUL' 'JAUN') ;
  194. * 'TRAC' 'QUAL' 'TITRE' TITR_Z MESH_Z OEIL_Z ;
  195.  
  196.  
  197. *=== MODELE ET MATERIAU ===============================================*
  198.  
  199. *--- Ressort
  200. RE_MO = 'MODE' RE_ME 'MECANIQUE' 'ELASTIQUE' 'PLASTIQUE' 'POUT'
  201. 'CONS' 'SM_1_2' ;
  202.  
  203. RE_MA = ('MATE' RE_MO 'YOUN' YOUN1 'NU' NU1 'ALPH' ALPH1
  204. 'RHO ' RHO1 'ECRO' TRAC1) 'ET'
  205. ('CARA' RE_MO 'SECT' SECT5 'SECY' SECR5 'SECZ' SECR5
  206. 'INRY' INRY5 'INRZ' INRZ5 'TORS' TORS5
  207. 'DX' 0. 'DY' DY5 'DZ' DZ5) ;
  208.  
  209. *--- Element de liaison JOI1
  210. JO_MO = 'MODE' JO_ME 'MECANIQUE' 'ELASTIQUE' 'ORTHOTROPE'
  211. 'PLASTIQUE' 'COULOMB'
  212. 'JOI1' 'CONS' 'JO_SM12' ;
  213.  
  214. JO_MA = 'MATE' JO_MO 'DIRECTION' DIR1 DIR2
  215. 'KN' 1.E8 'KS1' 1.E8 'KS2' 1.E8
  216. 'QN' 1.E-7 'QS1' 1.E-7 'QS2' 1.E-7
  217. 'FRIC' PHI1 'TYPE' 1
  218. 'FNE' 1.E20 'QT' 1.E7 'COHE' 0. ;
  219.  
  220. *--- Assemblage
  221. MODTOT = RE_MO 'ET' JO_MO ;
  222. MATTOT = RE_MA 'ET' JO_MA ;
  223. 'MESS' 'Modele total'; 'LIST' MODTOT ;
  224. 'MESS' 'Materiau total'; 'LIST' MATTOT ;
  225.  
  226.  
  227. *=== CONDITIONS AUX LIMITES ===========================================*
  228.  
  229. *--- Maillages supports des CL sur l'ensemble inferieur
  230.  
  231. * Base du ressort
  232. CL_ME1 = RE_L1 ;
  233.  
  234. * Point de pilotage des deplacements de la base du ressort
  235. * et qui recoit la raideur inferieure du bati (point de liaison entre la
  236. * plaque inferieure support de l'embout et la partie inferieure du bati)
  237. * DZ_INF = 20 cm : distance verticale entre CL_ME1 et CL_ME2
  238. DZ_INF = 20.E-2 ;
  239. CL_ME2 = 0. 0. (-1.*DZ_INF) ;
  240.  
  241. * Ensemble inferieur CL_ME1 et CL_ME2 soumis a un mouvement de corps rigide
  242. CL_ME3 = CL_ME1 'ET' CL_ME2 ;
  243.  
  244. *--- CL sur l'ensemble inferieur
  245.  
  246. * Blocage du deplacement axial du point de pilotage
  247. * la partie inferieure du bati est supposee totalement rigide
  248. * dans la direction de compression des ressorts : UZ(CL_ME2) = 0
  249. CL1 = 'BLOQ' 'UZ' CL_ME2 ;
  250.  
  251. * Relation de corps rigide sur CL_ME3
  252. CL2 = 'RELA' 'CORI' 'DEPL' 'ROTA' CL_ME3 ;
  253.  
  254. * Relation d'ensemble en UZ sur 'CL_ME3'
  255. * pour eviter le basculement de l'ensemble (embout + ressort)
  256. CL3 = 'RELA' 'ENSE' 'UZ' CL_ME3 ;
  257.  
  258. * Blocage de la rotation RZ du bati inferieur
  259. * place sur CL_ME2
  260. CL4 = 'BLOQ' 'RZ' CL_ME2 ;
  261.  
  262. * Blocage du deplacement UX du bati inferieur
  263. * placee sur CL_ME2
  264. CL5 = 'BLOQ' 'UX' CL_ME2 ;
  265.  
  266. * Raideur externe en deplacement UY du bati inferieur
  267. * placee sur CL_ME2
  268. KUI_BATI = 20.E4 ;
  269. RE6 = 'APPU' 'UY' KUI_BATI CL_ME2 ;
  270.  
  271. *--- Maillages supports des CL sur l'ensemble superieur
  272.  
  273. * Ensemble superieur regroupant la plaque de compression PL_ME
  274. * et le point d'accrochage du JOI1 a la plaque PL_J1
  275. * soumis a un mouvement de corps rigide
  276. CL_ME4 = PL_ME 'ET' PL_J1 ;
  277.  
  278. *--- CL sur l'ensemble superieur
  279.  
  280. * Relation de corps rigide sur CL_ME4
  281. CL7 = 'RELA' 'CORI' 'DEPL' 'ROTA' CL_ME4 ;
  282.  
  283. * Blocage de la plaque PL_ME sauf en UZ
  284. * et/ou UX et/ou UY selon l'inclinaison de l'axe de poussee
  285. * 1. Axe de poussee vertical (AU_X = 0. ; AU_Y = 0.)
  286. * => deplacement UZ seulement (UX et UY bloques)
  287. CL8 = 'BLOQ' 'UX' 'UY' 'RX' 'RY' 'RZ' PL_ME ;
  288.  
  289. *--- Assemblage
  290. * Rigidite CL
  291. CLTOT = CL1 'ET' CL2 'ET' CL3 'ET' CL4 'ET'
  292. CL5 'ET' CL7 'ET' CL8 ;
  293.  
  294. * Rigidite constante externe
  295. RCTOT = RE6 ;
  296.  
  297.  
  298. *=== CHARGEMENT =======================================================*
  299.  
  300. *--- Chargement en deplacement impose de l'essai de compression EDF
  301.  
  302. * Depl.vertical imp. maxi et mini des cycles
  303. TAB_UV = 'TABLE' ;
  304. TAB_UV.0 = 0. ;
  305. TAB_UV.1 = 40.E-3 ;
  306. TAB_UV.2 = 0. ;
  307. TAB_UV.3 = 35.E-3 ;
  308. TAB_UV.4 = 0. ;
  309.  
  310. * Vitesse de charge/decharge = 5.E-3 m/min
  311. VIMP = 5.E-3 / 60. ;
  312.  
  313. * Pas de temps : t(i) = t(i-1) + (|u(i)-u(i-1)|/Vit.)
  314. TAB_TE = 'TABLE' ;
  315. TAB_TE.0 = 0. ;
  316. 'REPE' B_TE (('DIME' TAB_UV) - 1) ;
  317. TAB_TE. &B_TE = TAB_TE. (&B_TE - 1) +
  318. (('ABS' (TAB_UV. &B_TE - TAB_UV. (&B_TE - 1))) / VIMP) ;
  319. 'FIN' B_TE ;
  320.  
  321. * Evolution temporelle du chargement en deplacement impose
  322. * avec axe de poussee vertical (AU_X = 0. ; AU_Y = 0.)
  323. * Le debut de la montee en charge a lieu a t = 1.E-1s
  324. * de facon a ce que, si le poids propre est pris en compte, il se mette en place
  325. * avant (entre t = 1.E-4s et t = 1E-2s). On neglige l'ecart de 0.1s
  326. * par rapport a la duree totale (90.s) de la montee a UV1 sur la vitesse
  327. * de montee qui est par consequent legerement plus rapide que 5mm/min
  328. L_TPS = 'PROG' 0. 1.E-1 ;
  329. L_COZ = 'PROG' 0. 0. ;
  330. 'REPE' B_TE (('DIME' TAB_UV) - 1) ;
  331. L_TPS = L_TPS 'ET' ('PROG' TAB_TE . &B_TE) ;
  332. L_COZ = L_COZ 'ET' ('PROG' TAB_UV . &B_TE) ;
  333. 'FIN' B_TE ;
  334. * Prise en compte du signe du deplacement : vers -Z
  335. L_COZ = -1. * L_COZ ;
  336. EUZIMP = 'EVOL' TURQ 'MANU' 'TEMPS' L_TPS 'COEF' L_COZ ;
  337. TITR_Z = 'CHAI' 'UZ impose en fn du temps' ;
  338. 'DESS' EUZIMP 'TITR' TITR_Z ;
  339.  
  340. * Chargement UZ impose a la plaque
  341. RIG_1 = 'BLOQ' 'UZ' PL_ME ;
  342. DEP_1 = 'DEPI' RIG_1 1. ;
  343. CHA_1 = 'CHAR' 'DIMP' DEP_1 EUZIMP ;
  344.  
  345. *--- Chargement de jeu initial dans le JOI1
  346.  
  347. * MCHML zero partout
  348. DEF_0 = 'ZERO' MODTOT 'DEFORMATIONS' ;
  349. * Evolution temporelle
  350. EDEFJO = 'EVOL' 'MANU' 'TEMPS' ('PROG' 0. 1.E-4 1.E4)
  351. 'COEF' ('PROG' 0. 1. 1. ) ;
  352. * MCHML de jeu dans le JOI1
  353. DEF_JO = 'MANU' 'CHML' JO_MO 'EXX' (-1. * D_I)
  354. 'TYPE' 'DEFORMATIONS' 'STRESSES' ;
  355.  
  356. * Chargement 'DEFI' de jeu dans le JOI1
  357. DEF_2 = DEF_0 + DEF_JO ;
  358. CHA_2 = 'CHAR' 'DEFI' DEF_2 EDEFJO ;
  359.  
  360. *--- Assemblage
  361. CLTOT = CLTOT 'ET' RIG_1 ;
  362. CHATOT = CHA_1 'ET' CHA_2 ;
  363.  
  364. *=== RESOLUTION =======================================================*
  365.  
  366. *--- Liste des instants calcules, des resultats sauves, sauvegardes
  367.  
  368. * Instants calcules
  369.  
  370.  
  371. * - liste des instants
  372. I = 1 ;
  373. 'REPE' B_INST (('DIME' L_TPS) - 1) ;
  374. I = I + 1 ;
  375. T_PREC = 'EXTR' L_TPS (I - 1) ;
  376. T_COUR = 'EXTR' L_TPS I ;
  377. 'SI' (I 'EGA' 2) ;
  378. INST_C = 'PROG' T_PREC T_COUR ;
  379. 'FINS' ;
  380. 'SI' (I 'EGA' 3) ;
  381. 'SI' (T_PREC '<' 1.) ;
  382. T_PREC = 1. ;
  383. 'FINS' ;
  384. LIST_Z = 'PROG' T_PREC PAS PAS_C T_COUR ;
  385. INST_C = INST_C 'ET' LIST_Z ;
  386. 'FINS' ;
  387. 'SI' (I '>' 3) ;
  388. LIST_Z = 'PROG' T_PREC PAS PAS_C T_COUR ;
  389. LIST_Z = 'ENLE' LIST_Z 1 ;
  390. INST_C = INST_C 'ET' LIST_Z ;
  391. 'FINS' ;
  392. 'FIN' B_INST ;
  393. 'MESS' 'Instants CALCULES'; 'LIST' INST_C ;
  394.  
  395. * Instants des resultats sauves
  396. * - pas de temps : 1 pas dont les resultats sont sauves tous les 1 pas de calcul
  397. PAS_R = 1 ;
  398. * - liste des instants
  399. 'REPE' B_INST ('DIME' INST_C) ;
  400. T_Z = 'EXTR' INST_C &B_INST ;
  401. 'SI' (T_Z '<' 1.) ;
  402. 'SI' (&B_INST 'EGA' 1) ;
  403. INST_R = 'PROG' ;
  404. 'SINO' ;
  405. INST_R = INST_R 'ET' ('PROG' T_Z) ;
  406. 'FINS' ;
  407. 'SINO' ;
  408. 'SI' (T_Z 'EGA' 1.) ;
  409. INST_R = INST_R 'ET' ('PROG' T_Z) ;
  410. I_Z = &B_INST + PAS_R ;
  411. 'SINO' ;
  412. 'SI' (&B_INST 'EGA' I_Z) ;
  413. INST_R = INST_R 'ET' ('PROG' T_Z) ;
  414. I_Z = &B_INST + PAS_R ;
  415. 'SI' (I_Z '>EG' ('DIME' INST_C)) ;
  416. INST_R = INST_R 'ET'
  417. ('PROG' ('EXTR' INST_C ('DIME' INST_C))) ;
  418. 'QUIT' B_INST ;
  419. 'FINS' ;
  420. 'FINS' ;
  421. * Pas de temps aux pics de chargement et aux six instants suivants
  422. * pour decrire l'hysteresis pendant la decharge
  423. 'SI' ((T_Z 'EGA' TAB_TE.1) 'OU' (T_Z 'EGA' TAB_TE.3)) ;
  424. 'REPE' B_1 6 ;
  425. INST_R = INST_R 'ET'
  426. ('PROG' ('EXTR' INST_C (&B_INST + &B_1 - 1))) ;
  427. 'FIN' B_1 ;
  428. 'FINS' ;
  429. * Pas de temps a chargement = 0
  430. 'SI' ((T_Z 'EGA' TAB_TE.2) 'OU' (T_Z 'EGA' TAB_TE.4)) ;
  431. INST_R = INST_R 'ET' ('PROG' T_Z) ;
  432. 'FINS' ;
  433. 'FINS' ;
  434. 'FINS' ;
  435. 'FIN' B_INST ;
  436. INST_R = 'ORDO' 'UNIQUE' INST_R ;
  437. 'MESS' 'Instants des resultats SAUVES'; 'LIST' INST_R ;
  438.  
  439. * Instants sauvegardes
  440. * - pas de temps : 1 pas dont les resultats sont sauvegardes tous les 10 pas de calcul
  441. PAS_S = 10 ;
  442. 'REPE' B_INST ('DIME' INST_C) ;
  443. T_Z = 'EXTR' INST_C &B_INST ;
  444. 'SI' (T_Z '<' 1.) ;
  445. 'SI' (&B_INST 'EGA' 1) ;
  446. INST_S = 'PROG' ;
  447. 'SINO' ;
  448. INST_S = INST_S 'ET' ('PROG' T_Z) ;
  449. 'FINS' ;
  450. 'SINO' ;
  451. 'SI' (T_Z 'EGA' 1.) ;
  452. INST_S = INST_S 'ET' ('PROG' T_Z) ;
  453. I_Z = &B_INST + PAS_S ;
  454. 'SINO' ;
  455. 'SI' (&B_INST 'EGA' I_Z) ;
  456. INST_S = INST_S 'ET' ('PROG' T_Z) ;
  457. I_Z = &B_INST + PAS_S ;
  458. 'SI' (I_Z '>EG' ('DIME' INST_C)) ;
  459. INST_S = INST_S 'ET'
  460. ('PROG' ('EXTR' INST_C ('DIME' INST_C))) ;
  461. 'QUIT' B_INST ;
  462. 'FINS' ;
  463. 'FINS' ;
  464. 'FINS' ;
  465. 'FINS' ;
  466. 'FIN' B_INST ;
  467. INST_S = 'ORDO' 'UNIQUE' INST_S ;
  468. 'MESS' 'Instants des resultats SAUVEGARDES'; 'LIST' INST_S ;
  469.  
  470. ** Debug
  471. * INST_C = 'PROG' 0. 0.1 1. 2. ;
  472. * INST_R = INST_C ;
  473. * INST_S = INST_C ;
  474. * 'MESS' 'Instants CALCULES'; 'LIST' INST_C ;
  475. * 'MESS' 'Instants des resultats SAUVES'; 'LIST' INST_R ;
  476. * 'MESS' 'Instants des resultats SAUVEGARDES'; 'LIST' INST_S ;
  477.  
  478. *--- Apel a PASAPAS
  479.  
  480. TAB1 = 'TABLE' ;
  481. TAB1 . 'MODELE' = MODTOT ;
  482. TAB1 . 'CARACTERISTIQUES' = MATTOT ;
  483. TAB1 . 'BLOCAGES_MECANIQUES' = CLTOT ;
  484. TAB1 . 'RIGIDITE_CONSTANTE' = RCTOT ;
  485. TAB1 . 'CHARGEMENT' = CHATOT ;
  486. TAB1 . 'GRANDS_DEPLACEMENTS' = VRAI ;
  487. TAB1 . 'LAGRANGIEN' = 'MOT' 'REACTUALISE' ;
  488. TAB1 . 'TEMPS_CALCULES' = INST_C ;
  489. TAB1 . 'TEMPS_SAUVES' = INST_R ;
  490. TAB1 . 'TEMPS_SAUVEGARDES' = INST_S ;
  491. * TAB1 . 'PREDICTEUR' = HPP ;
  492. TAB1 . 'INITIALISATION' = FAUX ;
  493. TAB1 . 'PROCESSEURS' = 'MOT' 'MONO_PROCESSEUR' ;
  494.  
  495. T_EPS_SUP = 'TABLE' ;
  496. TAB1 . 'MES_SAUVEGARDES' = T_EPS_SUP ;
  497. T_EPS_SUP . 'DEFTO' = VRAI ;
  498. T_EPS_SUP . 'DEFIN' = VRAI ;
  499.  
  500. PASAPAS TAB1 ;
  501.  
  502.  
  503. *=== POST-TRAITEMENT ==================================================*
  504.  
  505. *--- Visualisation de la deformee du ressort a lames sous le
  506. *--- depacement vertical de la plaque superieure consideree rigide
  507. *--- et des efforts de contact (appui + frottement)
  508. *--- de la plaque sur le ressort
  509.  
  510. * Nombre de pas de temps sauves
  511. NRESU = 'DIME' TAB1 . 'DEPLACEMENTS' ;
  512.  
  513. * Maillage ressort et plaque
  514. MAIL_TO = RE_ME 'ET' PL_ME ;
  515.  
  516. * Points de cadrage des images animees
  517. CADR_1 = -11.E-2 -11.E-2 -25.E-3 ;
  518. CADR_2 = 11.E-2 -11.E-2 -25.E-3 ;
  519. CADR_3 = 11.E-2 11.E-2 -25.E-3 ;
  520. CADR_4 = -11.E-2 11.E-2 -25.E-3 ;
  521.  
  522. * Maillage fixe (pour comparaison avec maillage deforme)
  523. MAIL_FI = PL_ME 'ET'
  524. ('COUL' (CADR_1 'ET' CADR_2 'ET' CADR_3 'ET' CADR_4) 'BLAN') ;
  525.  
  526. * Etat initial
  527. DEP0 = TAB1 . 'DEPLACEMENTS' . 0 ;
  528. DEF0 = 'DEFO' MAIL_FI DEP0 0. ;
  529.  
  530. * Boucle d'extraction des resultats sur les pas de temps sauves
  531. 'REPE' BRESU (NRESU - 1) ;
  532.  
  533. * Instant de calcul et champ de deplacement calcule
  534. TPS1 = 'EXTR' (TAB1 . 'TEMPS_SAUVES') &BRESU ;
  535. DEP1 = TAB1 . 'DEPLACEMENTS' . &BRESU ;
  536.  
  537. * controle signe de la réaction normale (pb vu au décollement)
  538. FOJ1 = 'REDU' (TAB1 . 'CONTRAINTES' . &BRESU) JO_MO ;
  539. FNOR = ('EXTR' FOJ1 'EFFX' 1 1 1) ;
  540. 'MESS' 'Resultat' ' ' &BRESU ' t =' TPS1
  541. 'MCHAML(EFFX) dans le JOI1, elem1, pt.Gauss1' ' ' FNOR ;
  542.  
  543. SI (FNOR > 1.E-8);
  544. ERRE 5 'signe reaction normale contact JOI1';
  545. FINSI;
  546.  
  547. * Changement des noms de composante du MCHAML d'apres les directions
  548. * locales du JOI1 :
  549. * - Ressort 1 : DIR1(EFFX) = 0. 0. 1. = Z
  550. * DIR2(EFFY) = 1. 0. 0. = X
  551. * DIR3(EFFZ) = 0. 1. 0. = Y
  552. FOJ2 = 'CHAN' 'COMP'
  553. ('MOTS' 'EFFX' 'EFFY' 'EFFZ' 'MOMX' 'MOMY' 'MOMZ')
  554. ('MOTS' 'FZ' 'FX' 'FY' 'MOMZ' 'MOMX' 'MOMY')
  555. FOJ1 ;
  556.  
  557. * Changement en CHPOIN et reduction au point de raccordement
  558. * avec la poutre ressort : RE_J1
  559. FOJ3 = 'REDU' ('CHAN' 'CHPO' JO_MO FOJ2) RE_J1 ;
  560.  
  561. * - Vecteur force
  562. VFOT3 = 'VECT' FOJ3 2.E-5 'FX' 'FY' 'FZ' VERT ;
  563.  
  564. * - Maillage deforme et vecteur force
  565. DEF2 = 'DEFO' MAIL_TO DEP1 1. VFOT3 ROUG ;
  566.  
  567. * Affichage
  568. STR_Z0 = 'CHAI' 'Coef.frot.' FRO1 ;
  569. STR_Z1 = 'CHAI' 'Force de contact sur maillage deforme' ' '
  570. 'FORMAT' '(F7.2)'TPS1' s' ;
  571. STR_Z2 = 'CHAI' NOM_ESS ' ' STR_Z3 ;
  572. TITR_Z = 'CHAI' STR_Z0 ' -' ' ' STR_Z1 ' -' ' ' STR_Z2 ;
  573. SI LOGITRAC;
  574. 'TRAC' 'TITR' TITR_Z (DEF0 'ET' DEF2) O_1 ;
  575. FINSI;
  576.  
  577.  
  578.  
  579.  
  580. 'FIN' BRESU;
  581.  
  582.  
  583.  
  584. * controle signe de la réaction normale
  585.  
  586.  
  587.  
  588.  
  589.  
  590.  
  591.  
  592. 'FIN' ;
  593.  
  594.  
  595.  
  596.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales