Télécharger la plaquette Cast3M


fr en

Télécharger formation_pasapas_2_solution_bis.dgibi

Retour à la liste

Numérotation des lignes : 

  1. * fichier : formation_pasapas_2_initial.dgibi
  2. *
  3. *----------------------------------------------------------------------*
  4. *              FORMATION AVANCEE SUR LA PROCEDURE PASAPAS              *
  5. *                                                                      *
  6. * Rupture d'une plaque trouee en traction                              *
  7. * Comportement elastique lineaire                                      *
  8. *                                                                      *
  9. * Ce fichier constitue la mise donnee solution du probleme et realise  *
  10. * - le maillage                                                        *
  11. * - la definition du modele et des parametres materiaux                *
  12. * - la definition du chargement                                        *
  13. * - la resolution avec PASAPAS                                         *
  14. * - la suppression des blocages selon un critere de rupture            *
  15. *   base sur la 1ere contrainte principale (avec la procedure PERSO1)  *
  16. * - le post traitement (contraintes, courbe force/deplacement)         *
  17. *----------------------------------------------------------------------*
  18.  
  19.  
  20.  
  21.  
  22.  
  23. ** Options de trace / Plotting options
  24. itrac = FAUX ;
  25. ***OPTI 'TRAC' 'PSC' ;
  26. ipsc  = EGA (VALE 'TRAC') 'PSC' ;
  27.  
  28. ** Options generales / General options
  29. OPTI 'DIME' 2 'ELEM' 'QUA8' 'MODE' 'PLAN' 'DEFO' ;
  30.  
  31. ** Parametres geometriques / Geometrical parameters
  32. l1    = 1. ;
  33. r1    = 0.15 ;
  34.  
  35. ** Maillage / Mesh
  36. dens1 = R1 / 15. ;
  37. dens2 = l1 / 15. ;
  38. p0    = 0. 0. ;
  39. p1    = r1 0. ;
  40. p2    = 0. r1 ;
  41. p3    = l1 0. ;
  42. p4    = l1 l1 ;
  43. p5    = 0. l1 ;
  44. CER   = CERC 20 p1 p0 p2 ;
  45. lid   = DROI 10 p3 p4 ;
  46. lih   = DROI 10 p4 p5 ;
  47. s1    = REGL cer (lid ET lih) 'DINI' dens1 'DFIN' dens2 ;
  48. lig   = s1 COTE 2 ;
  49. lib   = s1 COTE 4 ;
  50. cs1   = CONT s1 ;
  51.  
  52. ** Modele et materiau / Model and material properties
  53. mo    = MODE s1 'MECANIQUE' 'ELASTIQUE' ;
  54. ma    = MATE mo 'YOUN' 200.E9 'NU' 0.3 ;
  55.  
  56. ** Blocages mecaniques
  57. bl1   = BLOQ 'UY' lib ;
  58. bl2   = BLOQ 'UX' lig ;
  59. bl3   = BLOQ 'UY' lih ;
  60. bl    = bl1 ET bl2 ET bl3 ;
  61.  
  62. ** Chargement en deplacement impose / Load with imposed displacement
  63. umax  = l1 / 20. ;
  64. f1    = DEPI bl3 umax ;
  65. ev1   = EVOL 'MANU' (PROG 0. 1.) (PROG 0. 1.) ;
  66. cha   = CHAR 'DIMP' f1 ev1 ;
  67. SI ipsc ;
  68. ***  OPTI 'FTRA' 'exo_2_chargement.ps' ;
  69. FINSI ;
  70. SI itrac ;
  71. ***  TRAC (VECT f1 ' ' 'FLX' 'VERT') ((RIGI mo ma) ET bl1 ET bl2) ;
  72. FINSI ;
  73.  
  74. ** Procedure PERSO1
  75. DEBP PERSO1 t1*'TABLE' ;
  76.   mo1   = t1 . 'WTABLE' . 'MODELE' ;
  77.   mail1 = EXTR mo1 'MAIL' ;
  78.   sg1   = t1 . 'ESTIMATION' . 'CONTRAINTES' ;
  79.   sgp1  = PRIN sg1 mo1 ;
  80.   sgi   = EXCO 'SI11' sgp1 ;
  81.   sg11  = CHAN 'GRAVITE' sgi mo1 ;
  82.   mail2 = sg11 ELEM 'INFERIEUR' 2.2E10 ;
  83.   mail3 = DIFF mail1 mail2 ;
  84.   SI ((NBEL mail3) > 0) ;
  85.     bl1 = t1 . 'WTABLE' . 'BLOCAGES_MECANIQUES' ;
  86.     mb1 = EXTR bl1 'MAIL' ;
  87.     mb2 = mb1 ELEM 'APPU' 'LARG' mail3 ;
  88.     mb3 = DIFF mb1 mb2 ;
  89.     bl2  = REDU bl1 mb3 ;
  90.     t1 . 'WTABLE' . 'BLOCAGES_MECANIQUES' = bl2 ;
  91.   FINSI ;
  92. FINP ;
  93.  
  94. ** Resolution
  95. tab1                         = TABL ;
  96. tab1 . 'MODELE'              = mo ;
  97. tab1 . 'CARACTERISTIQUES'    = ma ;
  98. tab1 . 'BLOCAGES_MECANIQUES' = bl ;
  99. tab1 . 'CHARGEMENT'          = cha ;
  100. tab1 . 'TEMPS_CALCULES' =
  101.   PROG 0.1 'PAS' 0.1 0.6 'PAS' 0.01 1. ;
  102. tab1 . 'PROCEDURE_PERSO1'    = VRAI ;
  103. tab1 . 'GRANDS_DEPLACEMENTS' = VRAI ;
  104. PASAPAS tab1 ;
  105.  
  106. ** Post-traitement
  107. liso  = PROG 0. 'PAS' 4.E9 4.E10 ;
  108. box   = (0. -0.3) ET (1. 1.4) ;
  109. nt1   = DIME (tab1 . 'TEMPS') ;
  110. SI ipsc ;
  111.   OPTI 'FTRA' 'exo_2_solu_bis_sigma.ps' ;
  112. FINSI ;
  113. REPE b1 nt1 ;
  114. * contraintes / stresses
  115.   sg1   = tab1 . 'CONTRAINTES' . (&b1 - 1) ;
  116.   sp1   = EXCO 'SI11' (PRIN sg1 mo) ;
  117. * deplacements / displacements
  118.   u1    = tab1 . 'DEPLACEMENTS' . (&b1 - 1) ;
  119. * reactions
  120.   r1    = tab1 . 'REACTIONS' . (&b1 - 1) ;
  121.   vec1  = VECT r1 5.E-10 'FORC' 'VIOL' ;
  122. * deformees / deformed shape
  123.   def1  = DEFO s1 u1 2. vec1 sp1 mo ;
  124. * traces / plot
  125.   SI itrac ;
  126.     TRAC def1 cs1 liso 'BOIT' box ;
  127.   FINSI ;
  128. FIN b1 ;
  129. * courbe force vs deplacement / force vs displacement curve
  130. evu   = EVOL 'TEMP' tab1 'DEPLACEMENTS' 'UY' p5 ;
  131. evf   = -1. * (@GLOBAL tab1 bl1 evu 'FY') ;
  132. evfu  = EVOL 'ROUG' 'MANU' 'Deplac. UY'  (EXTR evu 'ORDO')
  133.                            'Reaction FY' (EXTR evf 'ORDO') ;
  134. SI ipsc ;
  135.   OPTI 'FTRA' 'exo_2_solu_bis_evol.ps' ;
  136. FINSI ;
  137. SI itrac ;
  138.   DESS evfu ;
  139. FINSI ;
  140.  
  141.  
  142. FIN ;
  143.  
  144.  
  145.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales