Télécharger la plaquette Cast3M


fr en

Télécharger uo2s_cas2.dgibi

Retour à la liste

Numérotation des lignes : 

  1. * fichier :  uo2s_cas2.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4. *
  5. *     Test uo2s_cas2.dgibi: Jeux de donnees            
  6. *     -------------------------------------
  7. * 
  8. * repertoire des fichiers "divers"
  9. DIVERS = VENV 'CASTEM_DIVERS';
  10.  
  11. 'OPTI' 'DIME' 3 'MODE' 'TRID'        ;
  12. 'OPTI' 'ELEM' 'CUB8'                 ;
  13. 'OPTI' 'TRAC' 'PSC'                  ;
  14. 'TEMPS' 'ZERO'                       ;
  15. *                                                                               
  16. **********************************************************         
  17. *                TEST DE VALIDATION                      *
  18. *                ------------------                      *
  19. *                   MODELE UO2                           *
  20. *   (COUPLAGE DES MODELES GATT_MONERIE ET OTTOSEN)       *
  21. *   UO2 STANDARD COMPRESSIBLE AVEC COUPLAGE STATIQUE     *
  22. *               RESOLUTION SIMPLIFIEE                    *
  23. *                                                        *
  24. *  MAILLAGE:                                             *
  25. *     CUBE                                               *
  26. *                                                        *
  27. *  CHARGEMENT:                                           *
  28. *     DEPLACEMENT VERTICAL IMPOSE EN  TRACTION AVEC      *
  29. *     VITESSE POSITIVE CTE PAR MORCEAU (3 MORCEAUX)      *
  30. *     TEMPERATURE         LINEAIRE CROISSANTE            *
  31. *     DENSITE DE FISSIONS LINEAIRE CROISSANTE            *
  32. *     OTTOSEN ACTIVE (TRACTION ELASTIQUE -               *
  33. *     FISSURATION = FRACTURATION - OUVERTURE             *
  34. *     FERMETURE - COMPRESSION - REOUVERTURE              *
  35. *     GONFLEMENT ACTIVE                                  *
  36. *     PAS DE VISCOPLASTICITE (GATT_MONERIE)              *
  37. *     PAS DE DENSIFICATION                               *
  38. **********************************************************        
  39. *
  40. DESSI = FAUX ;
  41. *
  42. * -----------------------------*
  43. * MAILLAGE D UN CUBE DE COTE 1 *
  44. * -----------------------------*
  45.    HS2  = 2E-5                                                 ;
  46. *
  47.    OO   = 0.     0.         0.                                 ;
  48.    A1   = HS2    0.         0.                                 ;
  49.    A2   = HS2    0.         HS2                                ;
  50.    A3   = 0.     0.         HS2                                ;
  51. *
  52.    LB   = 'DROIT' 1  OO A1                                     ;
  53.    LD   = 'DROIT' 1  A1 A2                                     ;
  54.    LH   = 'DROIT' 1  A2 A3                                     ;
  55.    LG   = 'DROIT' 1  A3 OO                                     ;
  56. *
  57.    SUA  = 'DALL' LB  LD  LH  LG  'PLAN'                        ;
  58.    SU2  = SUA 'PLUS' (0. HS2 0.)                               ;
  59.    VOL1 = 'VOLU' 1 SUA SU2                                     ;
  60.    'ELIM' (HS2/1000.) VOL1                                     ;
  61. *
  62.    SUB = 'POIN' ('COOR' 3 VOL1) 'INFERIEUR' (HS2/1000.)        ;
  63.    SUH = 'POIN' ('COOR' 3 VOL1) 'SUPERIEUR' (HS2 - (HS2/1000.));
  64.    LG  = 'POIN' ('COOR' 1 VOL1) 'INFERIEUR' (HS2/1000.)        ;
  65. * -----------------------------------------------------*
  66. * Conditions aux limites + deplacement impose sur CLZH *
  67. * -----------------------------------------------------*
  68. CLZB = 'BLOQ' UZ SUB                      ;
  69. CLZH = 'BLOQ' UZ SUH                      ;
  70. CLXG = 'BLOQ' UX LG                       ;
  71. CLYG = 'BLOQ' UY SUA                      ;
  72. CLT  = CLZB 'ET' CLZH 'ET' CLXG 'ET' CLYG ;
  73. * -------*
  74. * Modele *
  75. * -------*
  76. MODL1= MODE VOL1 MECANIQUE ELASTIQUE VISCOPLASTIQUE UO2 ;
  77. *
  78. * Temperature moyenne
  79. * -------------------
  80.  
  81.   TE0 = 1320. + 273.  ;
  82.   TE1 = 1420. + 273.  ;
  83.  
  84. * -----------------------------------------------------------------*
  85. * Temperature de reference et temperature de reference pour 'ALPH' *
  86. * -----------------------------------------------------------------*
  87.  TREF   = TE0 ;
  88.  TALPHA = 0.  ;
  89. *
  90. * Porosite initiale (cte au cours du calcul)
  91. * ------------------------------------------
  92.   PO   = 4.52E-2      ;
  93.  
  94. TA = @GATTPAR ('CHAINE' DIVERS '/fichier_gatt');
  95. *
  96. PP = 'MANU' 'CHML' MODL1 'T' TE1 'PORO' PO RIGIDITE ;
  97. *
  98. *
  99. * --------------------------------------*
  100. * 'YOUN' constant ou fonction de T et f *
  101. * --------------------------------------*
  102.  MATREE = MATE MODL1 'YOUN' (TA.'YOUN')          ;
  103.  EE     = 'VARI' 'NUAG' MODL1 MATREE PP          ;
  104. * EE     = (TA.'YOUN')                            ;
  105.  MATREE = MATE MODL1 'YOUN' EE                   ;
  106. * ------------------------------------*
  107. * 'NU' constant ou fonction de T et f *
  108. * ------------------------------------*
  109.  MATRUU = MATE MODL1 'NU' (TA.'NU')              ;
  110.  UU     = 'VARI' 'NUAG' MODL1 MATRUU PP          ;
  111. * UU     = (TA.'NU')                              ;
  112. * --------------------------------------*
  113. * 'ALPH' constant                       *
  114. * --------------------------------------*
  115.  ALFA  = 1.319E-5 ;
  116. *
  117. * -----------------------------*
  118. * Materiau partie GATT_MONERIE *
  119. * -----------------------------*
  120. * fluage primaire
  121.   TA.'KPUO'   = 0.                ;
  122. * fluage secondaire (2 mecanismes)
  123.   TA.'K1'   = 0.                  ;
  124.   TA.'K2'   = 0.                  ;
  125. * fluage d"irradiation
  126.   TA.'A'    = 0.                  ;
  127. * densification/gonflement
  128.   TA.'BUMI' = 1E4 * (TA.'BUMI')   ;
  129. *
  130. MATR11 = 'MATE' MODL1 'YOUN' EE 'NU' UU 'RHO' (TA.'RHO')  'ALPH' ALFA 'TALP' TALPHA 'TREF' TREF ;
  131. *
  132. MATR12 = 'MATE' MODL1  'R'    (TA.'R')    'DG0' (TA.'DG0') 'DG'  (TA.'DG') 'K1'   (TA.'K1')   'M1'  (TA.'M1')  'Q1'  (TA.'Q1')  'N1'   (TA.'N1')  'K2'   (TA.'K2')   'M2'  (TA.'M2')  'Q2'  (TA.'Q2')  'N2'   (TA.'N2')  'OMEG' (TA.'OMEG') 'H'   (TA.'H')   'Q'   (TA.'Q')   'BETA' (TA.'BETA') 'K'    (TA.'K')    'A'   (TA.'A')   'Q3'  (TA.'Q3')  'N3'   (TA.'N3') 'CR'   (TA.'CR')   'CR1' (TA.'CR1') 'CR2' (TA.'CR2') 'CR3'  (TA.'CR3');
  133. *
  134. MATR13 = 'MATE' MODL1  'KP'   (TA.'KPUO')   'AP'  (TA.'AP') 'BP'   (TA.'BP')     'QP'   (TA.'QP') ;
  135. *
  136. MATR14 = 'MATE' MODL1  'ADEN' (TA.'ADEN')   'KGON' (TA.'KGON')  'POR0' (TA.'POR0')   'BUMI' (TA.'BUMI')  'EFIS' (TA.'EFIS')                                ;
  137. *
  138. * TYPE = 0. combustible UO2            sinon combustible AFA3GLAA
  139. * COMP = 0. combustible compressible   sinon incompressible
  140. * DYN  = 0. couplage statique          sinon dynamique
  141. *
  142. * -----------------------------*
  143. * Materiau partie OTTOSEN      *
  144. * -----------------------------*
  145.  MATR16 = 'TAIL' MODL1 ;
  146. *
  147. * Resistance au cisaillement 'GS  ' par defaut: 'YOUN'*1.8E-4
  148. * Ouverture a rupture 'WRUP' = 0 --> 'WRUP' = 2*'GFTR'/'LTR '
  149. * Relation bilineaire 'BILI' = 0 --> 'BILI' = 0 (ouverture)
  150. *
  151.  XGFTR = 3.0   ; XGFTR1=XGFTR ; XGFTR2=XGFTR ; XGFTR3=XGFTR ;
  152.  XLTR  = 136E6 ; XLTR1 =XLTR  ; XLTR2 =XLTR  ; XLTR3 =XLTR  ;
  153.  XBTR  = 0.    ;
  154. *
  155.  MATR17 = 'MATE' MODL1  'GFTR' XGFTR    'LTR ' XLTR     'BTR ' XBTR 'WRUP' 0.       'BILI' 0. 'GFT1' XGFTR1   'GFT2' XGFTR2   'GFT3' XGFTR3 'GS1 ' 0.       'GS2 ' 0.       'GS3 ' 0. 'LTR1' XLTR1    'LTR2' XLTR2    'LTR3' XLTR3 'WRU1' 0.       'WRU2' 0.       'WRU3' 0. 'BIL1' 0.       'BIL2' 0.       'BIL3' 0. 'SIMP' 1.                                     ;
  156. *
  157. MATR1 = MATR11 'ET' MATR12 'ET' MATR13 'ET' MATR14 'ET' MATR16 'ET' MATR17  ;
  158. *
  159. *
  160. *-------------------------------------------------------
  161. * module d'young 
  162. *-------------------------------------------------------
  163.                 E    = 'MAXI' EE                       ;
  164. *-------------------------------------------------------
  165. *
  166. *
  167. *----------------------------------------------------------------------
  168.  'DEBPROC' TRINOME XA*'FLOTTANT' XB*'FLOTTANT' XC*'FLOTTANT'          ;
  169.     DISCRI  = ( (XB**2.) - (4.*XA*XC) )**0.5                          ;
  170.     RACINE1 = ( (-1.*XB) + DISCRI ) / (2.*XA)                         ;
  171.     RACINE2 = ( (-1.*XB) - DISCRI ) / (2.*XA)                         ;
  172.     LRACINE = 'PROG' RACINE1 RACINE2                                  ;
  173.     PRACINE = RACINE1 * RACINE2                                       ;
  174.     SRACINE = RACINE1 + RACINE2                                       ;
  175.     'SI' (PRACINE '<' 0.)                                             ;
  176.         RACINE = 'MAXI' LRACINE                                       ;
  177.     'SINON'                                                           ;
  178.         RACINE = 'MINI' LRACINE                                       ;
  179.     'FINSI'                                                           ;
  180.  'FINPROC' RACINE                                                     ;
  181. *----------------------------------------------------------------------
  182. *
  183. *-------------------------------------------
  184. * facteurs de conversion
  185. *-------------------------------------------
  186.  CONVSIG = 1E6                              ;
  187.  CONVTO  = 24.*3600E3                       ;
  188. *-------------------------------------------
  189. *
  190. *-------------------------------
  191. * fin d"ouverture apres fracture
  192. *-------------------------------
  193.  t1 = 1.5E6                              ;
  194.  mess 't1 = ' t1 ' secondes'             ;
  195. *--------------------------------------------------
  196. * fin de diminution de la contrainte de compression
  197. *--------------------------------------------------
  198.  t2 = 3.8E6                              ;
  199.  mess 't2 = ' t2 ' secondes'             ;
  200. *------------
  201. * temps final
  202. *------------
  203.  t3 = 5.5E6                              ;
  204.  mess 't3 = ' t3 ' secondes'             ;
  205. *
  206. * -------------------------*
  207. * vitesses de deformation  *
  208. * -------------------------*
  209. * pour 0 < t < t1
  210. *----------------
  211.  EPS1 = 7E-9      ;
  212.  
  213. * pour t1 < t < t2
  214. *-----------------
  215.  EPS2 = 5E-9      ;
  216.  
  217. * pour t2 < t
  218. *------------
  219.  EPS3 = 16E-9     ;
  220.  
  221. * -------------*
  222. * deformation  *
  223. * -------------*
  224. eps_t1 = EPS1 * t1                      ;
  225. eps_t2 = ( EPS2 * (t2 - t1) ) + eps_t1  ;
  226. eps_t3 = ( EPS3 * (t3 - t2) ) + eps_t2  ;
  227. *
  228. progt   = 'PROG' 0     t1     t2     t3            ;
  229. progeps = 'PROG' 0 eps_t1 eps_t2 eps_t3            ;
  230. eveps   = 'EVOL' 'MANU' 't(s)' progt 'eps' progeps ;
  231. * --------------------*
  232. * deplacement impose  *
  233. * --------------------*
  234. progdep  = HS2 * progeps                               ;
  235. 'TITR' 'DEPLACEMENT IMPOSE SELON DIRECTION Z'          ;
  236. evdep    = 'EVOL' 'MANU' 't(s)' progt 'dep(m)' progdep ;
  237. si DESSI ; 'DESS' evdep ; 'FINSI'                      ;
  238. DEPZ     = 'DEPI' CLZH 1                               ;
  239. CHARMECA = 'CHAR' 'DIMP' DEPZ evdep                    ;
  240. * --------------------------------------*
  241. * Vitesse d"evolution de la temperature *
  242. * --------------------------------------*
  243.  TP1 = 1E-4      ;
  244. *
  245. * ------------------------------*
  246. * Vitesse de densite de fission *
  247. * ------------------------------*
  248.  PHIP1 = 3E14 ;
  249. *
  250. *-------------------------------
  251. * premier coefficient du trinome
  252. *-------------------------------
  253.  RHO0 = 1. - TA.'POR0'                  ;
  254.  TAU0 = TA.'EFIS'*270./238./10950./RHO0 ;
  255.  XA   = (TA.'KGON' / 6.) * TAU0 * PHIP1 ;
  256. *
  257. *--------------------------------
  258. * caracteristiques de fissuration
  259. *--------------------------------
  260.  LZ     = 'MAXI' ('EXCO' MATR16 'LZZ')                     ;
  261.  PENTZ  = -1. * ( (XLTR1**2) / (2.*XGFTR1) )               ;
  262.  JZ     = 1./(LZ*PENTZ)                                    ;
  263.  WRUPT  = (2.*XGFTR1) / XLTR1                              ;
  264.  ERUPT  = WRUPT / LZ                                       ;
  265. *
  266. * -------------------------------------------------------------- *
  267. * INSTANTS PRIVILEGIES - CONTRAINTE - DEFORMATION DE FISSURATION *
  268. * -------------------------------------------------------------- *
  269. *
  270. npas   = 20       ;
  271. *
  272. * ---------------------
  273. * fissuration = rupture
  274. * ---------------------
  275.  XB = (ALFA * TP1) - EPS1                       ;
  276.  XC = XLTR1 / E                                 ;
  277.  TFISS = TRINOME XA XB XC                       ;
  278.  mess 'TFISS = ' TFISS ' secondes'              ;
  279.  tpas    = TFISS / npas                         ;
  280.  prt_th  = 'PROG' 0 'PAS' tpas TFISS            ;
  281.  prt_th2 = prt_th ** 2                          ;
  282.  prs_th  = (-1. * XB * prt_th) - (XA * prt_th2) ;
  283.  prs_th  = E * prs_th                           ;
  284.  prf_th  = 'PROG' ('DIME' prt_th)*0.            ;
  285. * ---------
  286. * ouverture
  287. * ---------
  288.  tpas   = (t1 - TFISS) / npas                             ;
  289.  prt    = 'PROG' (TFISS + 1) (TFISS + tpas) 'PAS' tpas t1 ;
  290.  prt2   = prt ** 2                                        ;
  291.  prs    = 'PROG' ('DIME' prt)*0.                          ;
  292.    b    = -1. * XC                                        ;
  293.  prb    = 'PROG' ('DIME' prt) * b                         ;
  294.  prf    = (-1. * XB * prt) - (XA * prt2)                  ;
  295.  prf    = prf + prb                                       ;
  296.  prt_th = prt_th 'ET' prt                                 ;
  297.  prs_th = prs_th 'ET' prs                                 ;
  298.  prf_th = prf_th 'ET' prf                                 ;
  299. *----------
  300. * fermeture
  301. *----------
  302.  XB = (ALFA * TP1) - EPS2                          ;
  303.  XC = t1 * (EPS2 - EPS1) - b                       ;
  304.  TFERM = TRINOME XA XB XC                          ;
  305.  mess 'TFERM = ' TFERM ' secondes'                 ;
  306.  tpas   = (TFERM - t1) / npas                      ;
  307.  prt    = 'PROG' (t1 + tpas) 'PAS' tpas TFERM      ;
  308.  prt2   = prt ** 2                                 ;
  309.  prs    = 'PROG' ('DIME' prt)*0.                   ;
  310.  cte    = t1 * (EPS1 - EPS2) + b                   ;
  311.  prcte  = 'PROG' ('DIME' prt) * cte                ;
  312.  prf    = ((-1. * XB * prt) - (XA * prt2)) + prcte ;
  313.  prt_th = prt_th 'ET' prt                          ;
  314.  prs_th = prs_th 'ET' prs                          ;
  315.  prf_th = prf_th 'ET' prf                          ;
  316. *---------------------------------------
  317. * compression et contrainte decroissante
  318. *---------------------------------------
  319.  tpas  = (t2 - TFERM) / npas                      ;
  320.  prt   = 'PROG' (TFERM + tpas) 'PAS' tpas t2      ;
  321.  prt2  = prt ** 2                                 ;
  322.  prcte = 'PROG' ('DIME' prt) * cte                ;
  323.  prs   = ((-1. * XB * prt) - (XA * prt2)) + prcte ;
  324.  prs   = E * prs                                  ;
  325.  prf   = 'PROG' ('DIME' prt)*0.                   ;
  326.  prt_th = prt_th 'ET' prt                         ;
  327.  prs_th = prs_th 'ET' prs                         ;
  328.  prf_th = prf_th 'ET' prf                         ;
  329. *-------------------------------------
  330. * compression et contrainte croissante
  331. *-------------------------------------
  332.  XB = (ALFA * TP1) - EPS3                              ;
  333.  XC = (t1 * (EPS2 - EPS1)) + (t2 * (EPS3 - EPS2)) - b  ;
  334.  TREOUV = TRINOME XA XB XC                             ;
  335.  mess 'TREOUV = ' TREOUV ' secondes'                   ;
  336.  tpas  = (TREOUV - t2) / npas                          ;
  337.  prt   = 'PROG' (t2 + tpas) 'PAS' tpas TREOUV          ;
  338.  prt2  = prt ** 2                                      ;
  339.  cte   = cte + (t2 * (EPS2 - EPS3))                    ;
  340.  prcte = 'PROG' ('DIME' prt) * cte                     ;
  341.  prs   = ((-1. * XB * prt) - (XA * prt2)) + prcte      ;
  342.  prs   = E * prs                                       ;
  343.  prf   = 'PROG' ('DIME' prt)*0.                        ;
  344.  prt_th = prt_th 'ET' prt                              ;
  345.  prs_th = prs_th 'ET' prs                              ;
  346.  prf_th = prf_th 'ET' prf                              ;
  347. *------------
  348. * reouverture
  349. *------------
  350.  tpas  = (t3 - TREOUV) / npas                          ;
  351.  prt   = 'PROG' (TREOUV + tpas) 'PAS' tpas t3          ;
  352.  prt2  = prt ** 2                                      ;
  353.  prs   = 'PROG' ('DIME' prt)*0.                        ;
  354.  prcte = 'PROG' ('DIME' prt) * cte                     ;
  355.  prf   = ((-1. * XB * prt) - (XA * prt2)) + prcte      ;
  356.  prt_th = prt_th 'ET' prt                              ;
  357.  prs_th = prs_th 'ET' prs                              ;
  358.  prf_th = prf_th 'ET' prf                              ;
  359. *
  360.  prs_th = prs_th / CONVSIG ;
  361.  prw_th = LZ * prf_th      ;
  362. *
  363. 'TITR' 'CONTRAINTE DANS LA DIRECTION Z'                          ;
  364. evs = 'EVOL' 'ROUG' 'MANU' 'Temps (s)' prt_th 'SIGZ(MPa)' prs_th ;
  365. 'TITR' 'DEFORMATION DE FISSURATION DANS LA DIRECTION Z'          ;
  366. evf = 'EVOL' 'ROUG' 'MANU' 'Temps (s)' prt_th 'EPSFZ'     prf_th ;
  367. 'TITR' 'OUVERTURE DANS LA DIRECTION Z'                           ;
  368. evw = 'EVOL' 'ROUG' 'MANU' 'Temps (s)' prt_th 'WZ(m)'     prw_th ;
  369. 'TITR' 'RELATION CONTRAINTE/OUVERTURE DANS LA DIRECTION Z'       ;
  370. evsw = 'EVOL' 'ROUG' 'MANU' 'WZ(m)' prw_th 'SIGZ(MPa)'    prs_th ;
  371. *
  372. * --------------------------*
  373. * chargement en temperature *
  374. * --------------------------*
  375. progun    = 'PROG' ('DIME' progt)*1                     ;
  376. progtemp  = (TP1*progt) + (TE0*progun)                  ;
  377. 'TITR' 'TEMPERATURE IMPOSEE'                            ;
  378. EVT       = 'EVOL' 'MANU' 't(s)' progt  'T(K)' progtemp ;
  379. si DESSI ; 'DESS' EVT ; 'FINSI'                         ;
  380. CHTEMP    = 'MANU' 'CHPO' VOL1 1 'T' 1.                 ;
  381. CHARTEMP  = 'CHAR' 'T' CHTEMP EVT                       ;
  382. * ---------------------------------*
  383. * Chargement en densite de fission *
  384. * ---------------------------------*
  385. progfiss     = PHIP1 * progt                                     ;
  386. 'TITR' 'DENSITE DE FISSION'                                      ;
  387. EVFIS    = 'EVOL' 'MANU' 't(s)' progt  'fission/m3/s' progfiss   ;
  388. si DESSI ; 'DESS' EVFIS ; 'FINSI'                                ;
  389. CHFISS   = 'MANU' 'CHPO' VOL1 1 'DFIS' 1.                        ;
  390. CHARFISS = 'CHAR' 'DFIS' CHFISS EVFIS                            ;
  391. *
  392. *
  393. *-------------------*
  394. * Instants calcules *
  395. *-------------------*
  396. LIST1 = 'PROG' 1E4  'PAS' 1E4   2.0E5 'PAS' 1E5   2.0E6 'PAS' 1E5   t3 ;
  397. * ---------------------------------------*
  398. * Variables internes initiales 'PORO'=PO *
  399. * ---------------------------------------*
  400. VAR00 = 'ZERO' MODL1 'VARINTER'                                    ;
  401. VAR01 = 'MANU' 'CHML' MODL1 'PORO' PO  'TYPE' 'VARIABLES INTERNES' 'STRESSES' ;
  402. VAR0 = VAR00 + VAR01                                               ;
  403. *
  404. CHARTOT = CHARMECA 'ET' CHARTEMP 'ET' CHARFISS             ;
  405.  
  406. *
  407.  TAB1                          = TABLE   ;
  408. * TAB1.'TEMPERATURES'           = TABLE   ;
  409.  TAB1.'VARIABLES_INTERNES'     = TABLE   ;
  410.  TAB1.'BLOCAGES_MECANIQUES'    = CLT     ;
  411.  TAB1.'MODELE'                 = MODL1   ;
  412.  TAB1.'CHARGEMENT'             = CHARTOT ;
  413.  TAB1.'VARIABLES_INTERNES' . 0 = VAR0    ;
  414.  TAB1.'CARACTERISTIQUES'       = MATR1   ;
  415.  TAB1.'TEMPS_CALCULES'         = LIST1   ;
  416.  TAB1.'TEMPS_SAUVES'           = LIST1   ;
  417. *TAB1.'TALPHA_REFERENCE'       = TALPHA  ;
  418. *
  419. TMASAU=table;
  420. tab1 . 'MES_SAUVEGARDES'=TMASAU;
  421. TMASAU .'DEFTO'=VRAI;
  422. TMASAU .'DEFIN'=VRAI;
  423.  TAB1.'HYPOTHESE_DEFORMATIONS' = 'LINEAIRE';
  424.  PASAPAS TAB1                            ;
  425. 'TEMPS' ;
  426. *
  427. *
  428. TT    = TAB1 . 'TEMPS'                      ;
  429. SS    = TAB1 . 'CONTRAINTES'                ;
  430. VV    = TAB1 . 'VARIABLES_INTERNES'         ;
  431. IN    = TAB1 . 'DEFORMATIONS_INELASTIQUES'  ;
  432. NCONT = 'DIME' TAB1 . 'CONTRAINTES'         ;
  433. *
  434. LZEIT  = 'PROG' ;
  435. LSIGZ  = 'PROG' ;
  436. LW1    = 'PROG' ;
  437. LW2    = 'PROG' ;
  438. LW3    = 'PROG' ;
  439. LEPSZF = 'PROG' ;
  440. *
  441. *
  442. 'REPE' BLOC NCONT ;
  443. *
  444.   IND  = &BLOC - 1         ;
  445.   ZEIT = TT.IND            ;
  446. *
  447.   SIG      = SS.IND            ;
  448.   SIGZ     = 'EXCO' SIG 'SMZZ' ;
  449.   SIGZ_MAX = 'MAXI' SIGZ       ;
  450. *
  451.   VI    = VV.IND                    ;
  452.   EI    = IN.IND                    ;
  453. *
  454.   W1    = 'MAXI' ('EXCO' VI 'W1')   ;
  455.   W2    = 'MAXI' ('EXCO' VI 'W2')   ;
  456.   W3    = 'MAXI' ('EXCO' VI 'W3')   ;
  457.   EPSZF = 'MAXI' ('EXCO' EI 'EIZZ') ;
  458. *
  459.   LZEIT  = LZEIT  'ET' ('PROG' ZEIT)       ;
  460.   LSIGZ  = LSIGZ  'ET' ('PROG' SIGZ_MAX)   ;
  461.   LW1    = LW1    'ET' ('PROG' W1)         ;
  462.   LW2    = LW2    'ET' ('PROG' W2)         ;
  463.   LW3    = LW3    'ET' ('PROG' W3)         ;
  464.   LEPSZF = LEPSZF 'ET' ('PROG' EPSZF)      ;
  465. *
  466. 'FIN' BLOC ;
  467. *
  468. *
  469. LSIGZ = LSIGZ/CONVSIG                                            ;
  470. 'TITR' 'CONTRAINTE DANS LA DIRECTION Z'                          ;
  471. EVSIGZ = 'EVOL' 'BLEU' 'MANU' 'Temps (s)' LZEIT 'SIGZ(MPa)' LSIGZ;          ;
  472. *
  473. 'TITR' 'OUVERTURE DANS LA DIRECTION Z'                           ;
  474. EVWZ  = 'EVOL' 'BLEU' 'MANU' 'Temps (s)' LZEIT  'WZ(m)' LW1      ;
  475. *
  476. 'TITR' 'DEFORMATION DE FISSURATION DANS LA DIRECTION Z'          ;
  477. EVEPSFZ = 'EVOL' 'BLEU' 'MANU' 'Temps (s)' LZEIT  'EPSFZ' LEPSZF ;
  478. *
  479. 'TITR' 'RELATION CONTRAINTE/OUVERTURE DANS LA DIRECTION Z'       ;
  480. EVSIGWZ = 'EVOL' 'BLEU' 'MANU' 'WZ(m)' LW1 'SIGZ(MPa)' LSIGZ     ;
  481. *
  482. *
  483. * -----------------------*
  484. * Controle des resultats *
  485. * -----------------------*
  486. *
  487. TAB               = 'TABLE'                 ;
  488. TAB . 'TITRE'     = 'TABLE'                 ;
  489. TAB . 'TITRE' . 1 = 'Resultat analytique'   ;
  490. TAB . 'TITRE' . 2 = 'Resolution simplifiee' ;
  491. *
  492. *
  493. 'SI' DESSI                                 ;
  494.    'TITR' 'CONTRAINTE DANS LA DIRECTION Z' ;
  495.    'DESS' (evs 'ET' EVSIGZ) TAB 'LEGE'     ;
  496. 'FINSI'                                    ;
  497. *
  498. 'SI' DESSI                                            ;
  499.    'TITR' 'OUVERTURE DANS LA DIRECTION Z'             ;
  500.    'DESS' (evw 'ET' EVWZ) TAB 'LEGE'                  ;
  501. 'FINSI'                                               ;
  502. *
  503. 'SI' DESSI                                                 ;
  504.    'TITR' 'DEFORMATION DE FISSURATION DANS LA DIRECTION Z' ;
  505.    'DESS' (evf 'ET' EVEPSFZ) TAB 'LEGE'                    ;
  506. 'FINSI'                                                    ;
  507. *
  508. 'SI' DESSI                                                           ;
  509.    'TITR' 'RELATION CONTRAINTE/OUVERTURE DANS LA DIRECTION Z'        ;
  510.    'DESS' (evsw 'ET' EVSIGWZ) TAB 'LEGE'                             ;
  511. 'FINSI'                                                              ;
  512. *
  513. *
  514. PREX   = 5E-2                                          ;
  515. LSOUS  = 'PROG' (0.99*TFISS) (1.06*TFISS) t1 (0.99*TFERM)  t2   (1.05*TREOUV)  t3   ;
  516. UN     = 'PROG' ('DIME' LSOUS)*1                       ;
  517. SZ_CAL = 'IPOL' LSOUS LZEIT   LSIGZ                    ;
  518. SZ_ANA = 'IPOL' LSOUS prt_th  prs_th                   ;
  519. T_SZ   = (SZ_ANA - SZ_CAL) / (SZ_ANA + UN)             ;
  520. T_SZ   = 'MAXI' ('ABS' T_SZ)                           ;
  521. 'SI' ( T_SZ '&lt;EG' PREX )                               ;
  522.    'ERRE' 0                                            ;
  523. 'SINO'                                                 ;
  524.    'MESS' 'ERREUR MAXIMALE CONTRAINTE SELON Z > ' PREX ;
  525.    'ERRE' 5                                            ;
  526. 'FINS'                                                 ;
  527. *
  528. PREX    = 17E-2                                        ;
  529. LSOUS   = 'PROG' (0.99*TFISS) (1.06*TFISS) t1 t2 t3    ;
  530. UN      = 'PROG' ('DIME' LSOUS)*1                      ;
  531. WRUPT   = (2.*XGFTR1) / XLTR1                          ;
  532. ERUPT   = WRUPT / LZ                                   ;
  533. NONZERO = (ERUPT / 1E6) * UN                           ;
  534. EFZ_CAL = 'IPOL' LSOUS LZEIT   LEPSZF                  ;
  535. EFZ_ANA = 'IPOL' LSOUS prt_th  prf_th                  ;
  536. T_FZ    = (EFZ_ANA - EFZ_CAL) / (EFZ_ANA +  NONZERO)   ;
  537. T_FZ    = 'MAXI' ('ABS' T_FZ)                          ;
  538. 'SI' ( T_FZ '&lt;EG' PREX )                               ;
  539.    'ERRE' 0                                            ;
  540. 'SINO'                                                 ;
  541.    'MESS' 'ERREUR MAXIMALE DEFORMATION DE FISSURATION  SELON Z > ' PREX                            ;
  542.    'ERRE' 5                                            ;
  543. 'FINS'                                                 ;
  544. *
  545. WZ_CAL  = 'IPOL' LSOUS LZEIT  LW1                      ;
  546. WZ_ANA  = 'IPOL' LSOUS prt_th prw_th                   ;
  547. NONZERO = (WRUPT / 1E6) * UN                           ;
  548. T_WZ    = (WZ_ANA - WZ_CAL) / (WZ_ANA +  NONZERO)      ;
  549. T_WZ    = 'MAXI' ('ABS' T_WZ)                          ;
  550. 'SI' ( T_WZ '&lt;EG' PREX )                               ;
  551.    'ERRE' 0                                            ;
  552. 'SINO'                                                 ;
  553.    'MESS' 'ERREUR MAXIMALE OUVERTURE SELON Z > ' PREX  ;
  554.    'ERRE' 5                                            ;
  555. 'FINS'                                                 ;
  556. *
  557. 'FIN';
  558.  
  559.  
  560.  
  561.  
  562.  
  563.  
  564.  
  565.  
  566.  
  567.  
  568.  
  569.  
  570.  
  571.  
  572.  
  573.  
  574.  
  575.  
  576.  
  577.  
  578.  
  579.  
  580.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales