Télécharger la plaquette Cast3M


fr en

Télécharger sta2d.dgibi

Retour à la liste

Numérotation des lignes : 

  1. * fichier :  sta2d.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4. complet = faux ;
  5. *                      PROGRAMMME STATIONNAIRE 2D                      *
  6.  
  7. * 29/11/1998                     Marta DRAGON/LMS-Ecole Polytechnique  *
  8.  
  9. *                  RAIL SOUMIS AU PASSAGE D'UNE ROUE :
  10.  
  11. *                   chargement mobile, de type Hertz
  12. *   on cherche l'etat stationnaire atteint par le rail apres un grand 
  13. *    nombre de passages de la roue, en particulier les deformations 
  14. *                             plastiques
  15.  
  16. * maillage :   MAISTA : pave maille regulierement par des quadrangles,
  17. *                       finement dans la zone superieure
  18. *
  19. *
  20. *  V : deplacement du chargement
  21. *     ---------------------->
  22. *             Y
  23. *             |
  24. *     ________|_________________________ X
  25. *      P4|    |P0           | |     | |P1    } maillage fin
  26. *        |    |             | |     | |      } hauteur : haut
  27. *        |____|_____________|_|_____|_|      } nb elts : Ncote1
  28. *        |    |             | |     | |         }
  29. *        |    |             | |     | |         }
  30. *        |    |             | |     | |         } nb elts : Ncote2
  31. *        |    |             | |     | |         }
  32. *      P3|____|_____________|_|_____|_|P2       }
  33. *             |              i       1
  34. *                             \_________ colonne d'elements i
  35. *
  36. *               nb elts : Nbase
  37. *
  38. *
  39. * modele :     MODSTA : modele entier
  40. *              MOD    : tableau contenant les Nbase colonnes d'elts, nu-
  41. *                       merotees de droite a gauche (sens oppose a V)
  42. *
  43. * materiau :   MATSTA : materiau du pave, elasto-plastique a ecrouissage
  44. *                       cinematique
  45. *              YO :     module d'Young
  46. *              NN :     coefficient de Poisson
  47. *              SY :     limite d'elasticite
  48. *              HH :     module d'ecrouissage
  49. *
  50. * blocages :   BLOSTA : tout deplacement des noeuds de la base (P2-P3)
  51. *
  52. * chargement : CHASTA : pression du contact de Hertz ; au point distant
  53. *                       de x du point de contact :
  54. *                                p(x) = PMAX * [1 - (x/a)^2]^0.5
  55. *              a :      demi-longueur du contact
  56. *              PC :     point central du contact
  57. *              PMAX :   pression maximale 
  58. *
  59. *
  60. * PROCEDURE DE CALCUL :
  61. * l'ensemble des donnees est stocke dans le tableau CALST :
  62. *
  63. *   - CALST . MODELE                : MODSTA
  64. *   - CALST . MODELE_TABLE          : MOD
  65. *   - CALST . CARACTERISTIQUES      : MATSTA
  66. *   - CALST . BLOCAGES_MECANIQUES   : BLOSTA
  67. *   - CALST . CHARGEMENT            : CHASTA (type CHPOINT)
  68. *   - CALST . PRECISION             : precision dans le test de 
  69. *                                     plasticite (ici a 0.001)
  70. *   - CALST . MAXITERATION          : nb maximal d'iterations (ici a 20)
  71. *
  72. * puis pour chaque iteration i :
  73. *
  74. *   - CALST . DEPLACEMENTS            . i : deplacements
  75. *   - CALST . DEFORMATIONS            . i : deformations
  76. *   - CALST . CONTRAINTES             . i : contraintes
  77. *   - CALST . CRITERE_PLASTICITE      . i : tableau issu de la procedure
  78. *                                           de calcul du critere
  79. *   - CALST . DEFORMATIONS_PLASTIQUES . i : deformations plastiques
  80. *   - CALST . VARIABLES_INTERNES      . i : variables internes
  81. *   - CALST . CONTRAINTES_PLASTIQUES  . i : contraintes plastiques 
  82. *                                           (L:epsp)
  83. *   - CALST . FORCES_PLASTIQUES       . i : forces plastiques
  84. *   - CALST . CONVERGENCE             . i : logique (faux tant que le 
  85. *                                           calcul n'a pas converge)
  86.  
  87. OPTI ECHO 0 DIME 2 MODE PLAN DEFO ELEM QUA8 ;
  88. GRAPH = 'N';
  89.  
  90. ****           MAILLAGE FONDAMENTAL DE LA PREMIERE COLONNE          ****
  91.  
  92. A    =   1.E-3 ;
  93. haut = -2. * A ;
  94.  
  95. N      =     10 ;
  96. Ncote1 =  2 * N ;
  97. Ncote2 =      N ;
  98. Nbase  = 10 * N ;
  99.  
  100. P0 =        0.        0. ;
  101. P1 =  (5. * A)        0. ;
  102. P2 =  (5. * A) (-5. * A) ;
  103. P3 = (-5. * A) (-5. * A) ;
  104. P4 = (-5. * A)        0. ;
  105.  
  106. AXES = coul roug 
  107.        ((((-5.1 * A) 0.) droi 1 ((5.1 * A) 0.)) et 
  108.         ((0. (-5.1 * A)) droi 1 (0. (0.1 * A)))) ;
  109.  
  110. tra0 = ((coor 1 P1) - (coor 1 P4)) / Nbase ;
  111. lig  = P2 droi Ncote2 ((coor 1 P1) haut) droi Ncote1 P1 ;
  112. part = lig tran 1 ((-1. * tra0) 0.) ;
  113.  
  114.  
  115. ****            MAILLAGE TOTAL PAR TRANSLATION ET MODELE            ****
  116. *
  117. tm1 = table 'MAILLAGE' ;
  118. *
  119. repeter colon Nbase ;
  120.   tra = tra0 * (&colon - 1) ;
  121.   si (&colon ega 1) ;
  122.     MAISTA = part ;
  123.     MOD = tabl ;
  124.     MOD . &colon = mode part mecanique elastique isotrope
  125.                                        plastique cinematique cons un ;
  126.     MODSTA = MOD . &colon ;
  127. *
  128.     tm1 . 1 = part ;
  129. *    
  130.   sinon ;
  131.     morc = part moin (tra 0.) ;
  132.     MAISTA = MAISTA et morc ;
  133.     elim 1.e-6 MAISTA ;
  134.     MOD . &colon = mode morc mecanique elastique isotrope
  135.                                        plastique cinematique cons un ;
  136.     MODSTA = MODSTA et (MOD . &colon) ;
  137. * 
  138.     tm1 . &colon = morc ;
  139. *
  140.   finsi ;
  141. fin colon ;
  142.  
  143. mess '** NB DE NOEUDS  DU MAILLAGE : ' (nbno MAISTA) ' **' ;
  144. mess '** NB D ELEMENTS DU MAILLAGE : ' (nbel MAISTA) ' **' ;
  145. titre ' maillage stationnaire : ' (nbno MAISTA) ' noeuds ' (nbel MAISTA) ' elements' ;
  146. *trace cach (MAISTA et AXES) ;
  147.  
  148. *
  149. mo_part = mode part mecanique elastique isotrope plastique cinematique ;
  150. MO_STA = mode tm1 mecanique stationnaire mo_part ;
  151. MA_STA = extr mo_sta mail ;
  152. *
  153. SI (NEG GRAPH 'N');
  154. titre ' maillage stationnaire : ' (nbno ma_sta) ' noeuds /' (nbel ma_sta) ' elements' ;
  155. trace cach (MA_STA et AXES) nclk;
  156. FINSI ;
  157. *MODSTA = mo_sta ; MAISTA = ma_sta ;
  158. *
  159. ****                            MATERIAU                            ****
  160.  
  161. YO = 2.E11  ;
  162. NN = 0.34   ;
  163. SY = 200.E6 ;
  164. HH = 60.E3  ;
  165. MATSTA = mate MODSTA youn YO nu NN sigy SY h HH ;
  166. CA_STA = mate MO_STA youn YO nu NN sigy SY h HH ;
  167.  
  168.  
  169.  
  170. ****                            BLOCAGES                            ****
  171.  
  172. BAS = MAISTA poin droi P2 P3 1.E-6 ;
  173. *trace (MAISTA et (COUL BLEU BAS) et AXES);
  174. BLOSTA = bloq depl BAS ;
  175.  
  176.  
  177. ****                           CHARGEMENT                           ****
  178.  
  179. *A = 1.E-3 ;
  180. PC = 0. 0. ;
  181. PMAX = 400.E6 ;
  182.  
  183. X0CH    = coor 1 PC ;
  184. Y0CH    = 0. ;
  185. SUR     = MAISTA poin droi (0. 0.) (1. 0.) 1.E-6 ;
  186. P0CH    = MAISTA poin proc (X0CH Y0CH) ;
  187. XCH     = (coor 1 SUR) - (1. * X0CH) ;
  188. XYCH    = 1 - ((XCH / A) ** 2) ;
  189. ZONCH   = XYCH masq egsupe 0. ;
  190. P_HERTZ = (PMAX * ((XYCH * ZONCH) ** 0.5)) + 1.E-20 ;
  191. CHASTA  = pres mass MODSTA P_HERTZ ;
  192.  
  193. vec = vect CHASTA 0.01E-6 fx fy bleu ;
  194. SI (NEG GRAPH 'N');
  195. titre 'pression hertzienne ' ;
  196. trace cach vec (MAISTA et AXES) nclk ;
  197. FINSI ;
  198. *
  199. ev1 = evol manu t (prog 0. 1.) f (prog 0. 1.) ;
  200. CH_STA = char meca ev1 CHASTA  ;  
  201.  
  202.  
  203. ****               INITIALISATION DU TABLEAU DE CALCUL              ****
  204.  
  205. CALST = table ;
  206. CALST . 'MODELE'              = MODSTA ;
  207. CALST . 'MODELE_TABLE'        = MOD    ;
  208. CALST . 'CARACTERISTIQUES'    = MATSTA ;
  209. CALST . 'BLOCAGES_MECANIQUES' = BLOSTA ;
  210. CALST . 'CHARGEMENT'          = CHASTA ;
  211. CALST . 'PRECISION'           = 1.E-3  ;
  212. si complet ;
  213. CALST . 'MAXITERATION'        = 20     ;
  214. sinon ;
  215. CALST . 'MAXITERATION'        = 1     ;
  216. finsi ;
  217.  
  218. CAL_ST = table ;
  219. CAL_ST . 'MODELE'              = MO_STA ;
  220. cal_st . 'MODELE_STATIONNAIRE' = mo_part ;
  221. CAL_ST . 'CARACTERISTIQUES'    = CA_STA ;
  222. CAL_ST . 'BLOCAGES_MECANIQUES' = BLOSTA ;
  223. CAL_ST . 'CHARGEMENT'          = CH_STA  ;
  224. CAL_ST . 'TEMPS_SAUVES'        = prog 0. 1. ;
  225. *jk148537 10/24 : il faudra adapter algorithme unpas 
  226. pasapas CAL_ST ;
  227.  
  228. SI (NEG GRAPH 'N');
  229. titre 'pasapas  / contraintes ' ;
  230. trac mo_sta cal_st . contraintes . 1 nclk ;
  231. titre 'pasapas / variable interne : epse ' ;
  232. trac mo_sta cal_st . variables_internes . 1 nclk ;
  233. FINSI ;
  234. *==========================================================
  235. *   Critère de Dang Van
  236. fm1 = 410.e6 * 0.7 ;
  237. tm1 = 260.e6 * 0.7 ; 
  238. beta_dv = tm1 ;
  239. alpha_dv = (tm1 - (fm1 / 2)) / (fm1 / 3) ;
  240. mess 'alpha_dv : ' alpha_dv ' / beta_dv : ' beta_dv ;
  241.  
  242. el_14 = part elem 14 ; el_29 = part elem 29 ;
  243.  
  244. cafa_dv = manu chml mo_sta 'ADVK' (-1. * alpha_dv) 'BDVK' beta_dv
  245.     type 'caracteristiques' stresses ;
  246. * CHargement FAtigue Dang Van
  247. chfa_dv = FATI mo_part mo_sta cal_st . contraintes . 1 cafa_dv 'DVKP' 'SEUIL' -0.55 ;
  248. * Réduire le résultat élément à étudier
  249. SI (NEG GRAPH 'N');
  250. titre ' coefficient Dang Van ' ;
  251. trac mo_part (exco chfa_dv dvkp) ;
  252. titre 'maillage tranche stationnaire ' ;
  253. trac (part et (el_14 coul rouge) et (el_29 coul oran)) ;
  254. FINSI ;
  255. chfa_14 = redu chfa_dv el_14 ; chfa_29 = redu chfa_dv el_29 ;
  256. * Indice où la valeur est maximale
  257. *ind_dv = ind_max chfa_dv dvkp nbpg;
  258. ind_dv = 3 ;
  259. * Valeur de Dang Van
  260. vdv_14 = extr chfa_14 dvkp 1 1 ind_dv ; vdv_29 = extr chfa_29 dvkp 1 1 ind_dv ;
  261. mess 'coef Dang Van / 14 : ' vdv_14 ' / 29 : ' vdv_29 ;
  262. * octobre 2024 / jk
  263. v0_14 = -3.88541E-01 ; v0_29 = -6.57884E-01 ;
  264. err14 = (vdv_14 - v0_14)/v0_14 ; err29 = (vdv_29 - v0_29)/v0_29 ;
  265. SI ( (abs(err14) <EG 1.e-5) et (abs(err29) <EG 1.e-5)) ;
  266.   ERRE 0;
  267. SINON;
  268.   ERRE 5;
  269. FINSI;
  270.  
  271. * TRAJectoir Dang Van
  272. tjdv_14 = extr chfa_14 'PTAU' 1 1 ind_dv ; tjdv_29 = extr chfa_29 'PTAU' 1 1 ind_dv ;
  273. SI (NEG GRAPH 'N');
  274.     titr 'Dang Van / rouge : ' vdv_14 ' / orange : ' vdv_29  ;
  275.     dess ((tjdv_14 coul rouge) et (tjdv_29 coul oran))   ;
  276. FINSI ;
  277. ****            CALCUL EN ELASTO-PLASTICITE STATIONNAIRE            ****
  278. @STATIO CALST ;
  279. *
  280. SI (NEG GRAPH 'N');
  281. titre '@calst / contraintes ' ;
  282. trac modsta calst . contraintes . 1 ; 
  283. titre '@calst / variable_interne : epse ' ;
  284. trac modsta calst . variables_internes . 1 ; 
  285. FINSI ;
  286.  
  287. ****    VISUALISATION DES ISOVALEURS DES DEFORMATIONS PLASTIQUES    ****
  288.  
  289. defpl = CALST . 'DEFORMATIONS_PLASTIQUES' ;
  290. ii    = (dime defpl) - 1 ;
  291. SI (NEG GRAPH 'N');
  292. 'TITR' 'deformations plastiques : EIXX' ;
  293. trace (chan 'CHPO' MODSTA (exco 'EIXX' (defpl . ii))) MAISTA ;
  294.  
  295. 'TITR' 'deformations plastiques : EIYY' ;
  296. trace (chan 'CHPO' MODSTA (exco 'EIYY' (defpl . ii))) MAISTA ;
  297.  
  298. 'TITR' 'deformations plastiques : EIZZ' ;
  299. trace (chan 'CHPO' MODSTA (exco 'EIZZ' (defpl . ii))) MAISTA ;
  300.  
  301. 'TITR' 'deformations plastiques : GIXY' ;
  302. trace (chan 'CHPO' MODSTA (exco 'GIXY' (defpl . ii))) MAISTA ;
  303. FINSI ;
  304.  
  305. ****    LIEU DES POINTS OU LA DEFORMATION PLASTIQUE EST MAXIMALE    ****
  306.  
  307. plmax = (exco 'EIYY' (defpl . ii)) poin 'MAXI' 'ABS' ;
  308. yymax = extr (coor 2 plmax) 'SCAL' (plmax poin 1) ;
  309.  
  310. VCAL = (-1. * YYMAX / A) ;
  311. VTHE =  0.7 ;
  313. mess '*********************************************************' ;
  315. mess '    Deformation plastique maximale a la profondeur : ' ;
  317. mess '                  '     VCAL          ' *    a' ;
  319. mess '              (valeur theorique : 0.7 * a)' ;
  321. mess '*********************************************************' ;
  322.  
  323.  
  324. ERG = ( VCAL - VTHE ) / VTHE ;
  325. SI ( ERG <EG 0.02);
  326.   ERRE 0;
  327. SINON;
  328.   ERRE 5;
  329. FINSI;
  330. FIN;
  331.  
  332.  
  333.  
  334.  
  335.  
  336.  
  337.  
  338.  
  339.  
  340.  
  341.  
  342.  
  343.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales