Télécharger la plaquette Cast3M


fr en

Télécharger plas6.dgibi

Retour à la liste

Numérotation des lignes : 

  1. * fichier :  plas6.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4. *           Test Plas6.dgibi: Jeux de données         *
  5. *           ---------------------------------         *
  6. *                                                     *
  7. * CAS TEST DU 91/07/23     PROVENANCE : BIRET
  8.  
  9. *******************************************************
  10. *           Test plas6.dgibi: Jeux de données         *
  11. *           ---------------------------------         *
  12. *******************************************************
  13.  
  14. * SI GRAPH = N PAS DE GRAPHIQUE AFFICHE
  15. * SINON SI GRAPH DIFFERENT DE N TOUS
  16. * LES GRAPHIQUES SONT AFFICHES
  17.  
  18. GRAPH = 'N' ;
  19.  
  20. SAUT PAGE;
  21. SI (NEG GRAPH 'N') ;
  22.   OPTI ECHO 1   ;
  23.   OPTI TRAC PSC   ;
  24. SINO ;
  25.   OPTI ECHO 0   ;
  26. FINSI ;
  27.  
  28. SAUT PAGE;
  29. *******************************************************
  30. *                                                     *
  31. *  TEST PLAS6                                         *
  32. *                                                     *
  33. *  RECTANGLE EN FLEXION PURE (CONTRAINTES PLANES,     *
  34. *  PLASTICITE PARFAITE)                               *
  35. *                                                     *
  36. *  Test V.P.C.S. numero SSNP11/89                     *
  37. *                                                     *
  38. *  References : R. Hill, Mathematical theory of       *
  39. *  plasticity, Oxford, Oxford Clavendon Press, 1950.  *
  40. *                                                     *
  41. *  Description :                                      *
  42. *  -----------                                        *
  43. *                                                     *
  44. *           axe y                                     *
  45. *          D |      A                                 *
  46. *            |----- ----  UA    epaisseur a = 12.5 mm *
  47. *            |     |   /        hauteur b = 100.0 mm  *
  48. *            |     |  /                               *
  49. *            |     | /                                *
  50. *            |     |/                                 *
  51. *          O |-----/-----> axe x                      *
  52. *            |    /|                                  *
  53. *            |   / |                                  *
  54. *            |  /  |                                  *
  55. *            | /   |                                  *
  56. *             -----                                   *
  57. *           C  UB   B                                 *
  58. *                                                     *
  59. *  Chargement : Deplacement impose variant            *
  60. *  lineairement de UA a -UA entre A et B,             *
  61. *  UA croissant jusqu'a : UAmax = 0.5 mm .            *
  62. *                                                     *
  63. *  Conditions aux limites :                           *
  64. *       sur CD : u = 0.                               *
  65. *       au point O : v = 0.                           *
  66. *                                                     *
  67. *  Proprietes des materiaux :                         *
  68. *       Materiau elastique, parfaitement plastique    *
  69. *        E = 210 000 MPa , NU = 0.3 , SIGY = 483 MPa  *
  70. *                                                     *
  71. *******************************************************
  73. OPTI MODE PLAN CONT;
  74. OPTI ELEM QUA4;
  75.  
  76. GRAPH2 = GRAPH;
  77.  
  78. TEMPS;
  79. *******************************************************
  80. *                 geometrie : maillage                *
  81. *******************************************************
  82. PA = 12.5E-3  50.E-3;
  83. PB = 12.5E-3 -50.E-3;
  84. PC =  0.     -50.E-3;
  85. PD =  0.      50.E-3;
  86.  
  87. NB1 = 32; NB2 = 4;
  88. D1 = PA DROI NB1 PB;
  89. D2 = PB DROI NB2 PC;
  90. D3 = PC DROI NB1 PD;
  91. D4 = PD DROI NB2 PA;
  92.  
  93. SUR1 = DALL D1 D2 D3 D4 PLAN;
  94.  
  95. SI (NEG GRAPH 'N');
  96.    TITR 'PLAS6 : MAILLAGE';
  97.    TRAC QUAL SUR1;
  98. FINSI;
  99.  
  100. NBNO1 = NBNO SUR1;
  101. NBEL1 = NBEL SUR1;
  102.  
  103. *******************************************************
  104. *            calcul du modele,caracteristiques        *
  105. *******************************************************
  106. MOD1 = MODE SUR1 MECANIQUE ELASTIQUE PLASTIQUE PARFAIT;
  107. MAT1 = MATE MOD1 YOUN 2.1E11 NU 0.3 SIGY 483.E6;
  108.  
  109. *******************************************************
  110. *                   conditions aux limites            *
  111. *******************************************************
  112. CL1 = BLOQ UX D3;
  113. CL2 = BLOQ UY (SUR1 POIN PROC (0. 0.));
  114. CL3 = BLOQ UX D1;
  115. CL = CL1 ET CL2 ET CL3;
  116.  
  117. * Creation du chpoint de deplacement impose variable :
  118. *   deplacement impose variant lineairement de u a -u
  119. *   entre A et B, u croissant jusqu'a 0.5 mm .
  120. I = 0.;
  121. LISD1 = PROG 1.;
  122. REPETER BLOC10 NB1;
  123.   I = I + 1.;
  124.   YY = 1. - (2. * (I / NB1));
  125.   LISD1 = LISD1 ET (PROG YY);
  126. FIN BLOC10;
  127.  
  128. LISD1 = LISD1 * 1.E-3;
  129. CHPO1 = MANU CHPO (CHAN 'POI1' D1) 1 UX LISD1;
  130.  
  131. CHA1 = DEPI CL3 CHPO1;
  132. *******************************************************
  133. *      objets relatifs a la procedure PASAPAS         *
  134. *******************************************************
  135. TAB1 = TABL ;
  136.  
  137. *On prend comme liste des pseudo-temps le deplacement u
  138. LREEL1= PROG 0.02875 0.05 0.1 0.15 0.2 0.3 0.4 0.5 1.0;
  139.  
  140. * Chargement
  141. EVOL1 = EVOL MANU UA LREEL1 COEFF LREEL1;
  142. CHAR1 = CHAR DIMP CHA1 EVOL1;
  143.  
  144. *******************************************************
  145. *                     resolution                      *
  146. *******************************************************
  147. TAB1.'CARACTERISTIQUES'    = MAT1;
  148. TAB1.'CHARGEMENT'          = CHAR1;
  149. TAB1.'MODELE'              = MOD1;
  150. TAB1.'TEMPS_CALCULES'      = LREEL1;
  151. TAB1.'BLOCAGES_MECANIQUES' = CL;
  152. PASAPAS TAB1;
  153.  
  154. *******************************************************
  155. *               extraction des resultats              *
  156. *******************************************************
  157.  
  158. * Initialisation
  159. MOM1  = TABL       ;
  160. LISD2 = LISD1 * 50.;
  161. MOM2  = TABL       ;
  162. ERG   = TABL       ;
  163.  
  164. MOM2.1 = 805.0; MOM2.2 = 1074.;
  165. MOM2.3 = 1174.; MOM2.4 = 1193.;
  166. MOM2.5 = 1199.; MOM2.6 = 1204.;
  167. MOM2.7 = 1205.; MOM2.8 = 1206.;
  168. MOM2.9 = 1207.5;
  169.  
  170. *Boucle pour chaque pas de chargement : fonction de UA.
  171. I = 0;
  172. REPETER BLOC1 9;
  173.   I = I + 1;
  174.   CONT1 = TAB1.CONTRAINTES.I;
  175.   DEPL1 = TAB1.DEPLACEMENTS.I;
  176.  
  177. * Passage du champs de contrainte en chpoints
  178. *   (utilisation des nouveaux chamelems)
  179.   CHPO10 = CHAN CHPO MOD1 CONT1;
  180.  
  181. *       Trace facultatif de la repartition
  182. *             de la contrainte SMXX
  183. SI (I EGA 9);
  184.   SI (NEG GRAPH2 'N');
  185.     TITR 'PLAS6 : CONTRAINTE SMXX';
  186.     BB = EXCO 'SMXX' CONT1;
  187.     TRAC BB MOD1;
  188.   FINSI;
  189. FINSI;
  190.  
  191. *         Trace facultatif de la deformee
  192. *          (verification du chargement)
  193. SI (I EGA 9);
  194.   SI (NEG GRAPH2 'N');
  195.      TITR 'PLAS6 : DEFORMEE';
  196.      DEF0 = DEFO SUR1 DEPL1 0.;
  197.      DEF1 = DEFO SUR1 DEPL1 2. VERT;
  198.      TRAC SUR1 (DEF0 ET DEF1);
  199.   FINSI;
  200. FINSI;
  201.  
  202. *    Calcul du moment de flexion du aux contraintes
  203. * smxx s'exercant le long de AB.
  204.   LIST2 = PROG;
  205.   J = 0;
  206.   NB = NB1 + 1;
  207.   REPETER BLOC4 NB;
  208.     J     = J + 1;
  209.     D     = EXTR LISD2 J;
  210.     POI1  = SUR1 POIN PROC (12.5E-3 D);
  211.     SM    = EXTR CHPO10 SMXX POI1;
  212.     LIST2 = LIST2 ET (PROG SM);
  213.   FIN BLOC4;
  214.  
  215.   LIST3 = LIST2 * LISD2;
  216.   TITR 'CONTRAINTE SMXX';
  217.   ESMXX = EVOL MANU Y LISD2 SMXX LIST2;
  218.   TITR 'PRODUIT Y * SMXX';
  219.   EYSMXX = EVOL MANU Y LISD2 YSMXX LIST3;
  220.  
  221. SI (I EGA 9);
  222.   SI (NEG GRAPH2 'N');
  223.     DESS ESMXX;
  224.     DESS EYSMXX;
  225.   FINSI;
  226. FINSI;
  227.   MOM1.I = INTG EYSMXX;
  228.  
  229.   MOM1.I = -1.E-3 * MOM1.I;
  230.   ERG.I = 100. * (ABS ((MOM1.I - MOM2.I) / MOM2.I));
  231.  
  232. FIN BLOC1;
  233.  
  234. *******************************************************
  235. *              affichage des resultats                *
  236. *******************************************************
  237. MESS 'RESULTATS : PLAS6';
  238. MESS '-------------------';
  240.  
  241. MESS 'Moment de flexion du aux contraintes SMXX le long de AB.';
  242. MESS '--------------------------------------------------------';
  244.  
  245. MESS '  UAmax = 0.02875 mm :';
  246. MESS '  ------------------';
  247. MESS '    Moment theorique :' MOM1.1 'N.m';
  248. MESS '    Moment calcule   :' MOM2.1 'N.m';
  249. MESS '    Soit un ecart de :' ERG.1 '%';
  251.  
  252. MESS '  UAmax = 0.05 mm :';
  253. MESS '  ---------------  ';
  254. MESS '    Moment theorique :' MOM1.2 'N.m';
  255. MESS '    Moment calcule   :' MOM2.2 'N.m';
  256. MESS '    Soit un ecart de :' ERG.2 '%';
  258.  
  259. MESS '  UAmax = 0.1 mm :';
  260. MESS '  --------------';
  261. MESS '    Moment theorique :' MOM1.3 'N.m';
  262. MESS '    Moment calcule   :' MOM2.3 'N.m';
  263. MESS '    Soit un ecart de :' ERG.3 '%';
  265.  
  266. MESS '  UAmax = 0.15 mm :';
  267. MESS '  ---------------';
  268. MESS '    Moment theorique :' MOM1.4 'N.m';
  269. MESS '    Moment calcule   :' MOM2.4 'N.m';
  270. MESS '    Soit un ecart de :' ERG.4 '%';
  272.  
  273. MESS '  UAmax = 0.2 mm :';
  274. MESS '  --------------';
  275. MESS '    Moment theorique :' MOM1.5 'N.m';
  276. MESS '    Moment calcule   :' MOM2.5 'N.m';
  277. MESS '    Soit un ecart de :' ERG.5 '%';
  279.  
  280. MESS '  UAmax = 0.3 mm :';
  281. MESS '  --------------';
  282. MESS '    Moment theorique :' MOM1.6 'N.m';
  283. MESS '    Moment calcule   :' MOM2.6 'N.m';
  284. MESS '    Soit un ecart de :' ERG.6 '%';
  286.  
  287. MESS '  UAmax = 0.4 mm :';
  288. MESS '  --------------';
  289. MESS '    Moment theorique :' MOM1.7 'N.m';
  290. MESS '    Moment calcule   :' MOM2.7 'N.m';
  291. MESS '    Soit un ecart de :' ERG.7 '%';
  293.  
  294. MESS '  UAmax = 0.5 mm :';
  295. MESS '  --------------';
  296. MESS '    Moment theorique :' MOM1.8 'N.m';
  297. MESS '    Moment calcule   :' MOM2.8 'N.m';
  298. MESS '    Soit un ecart de :' ERG.8 '%';
  300.  
  301. MESS '  UAmax = 1.0 mm :';
  302. MESS '  --------------';
  303. MESS '    Moment theorique :' MOM1.9 'N.m';
  304. MESS '    Moment calcule   :' MOM2.9 'N.m';
  305. MESS '    Soit un ecart de :' ERG.9 '%';
  307.  
  308. MESS 'Donnees sur le maillage';
  309. MESS '-----------------------';
  310. MESS '    Nombre d elements :' NBEL1 'QUA4';
  311. MESS '    Nombre de noeuds  :' NBNO1 ;
  313.  
  314. *******************************************************
  315. *                   code fonctionnement               *
  316. *******************************************************
  317. ERGMAX = MAXI (PROG ERG.1 ERG.2 ERG.3 ERG.4 ERG.5 ERG.6 ERG.7 ERG.8 ERG.9);
  318.  
  319. SI (ERGMAX <EG 0.5);
  320.   ERRE 0;
  321. SINON;
  322.   ERRE 5;
  323. FINSI;
  325.  
  326. TEMPS;
  327. FIN;
  328.  
  329.  
  330.  
  331.  
  332.  
  333.  
  334.  
  335.  
  336.  
  337.  
  338.  
  339.  
  340.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales