Télécharger la plaquette Cast3M


fr en

Télécharger panneau-auto.dgibi

Retour à la liste

Numérotation des lignes : 

  1. *----------------------------------------------------------------------
  2. * Cas-test de flambage d'un panneau
  3. *
  4. * Comparaison entre les solutions, obtenues avec PASAPAS et
  5. * - l'option AUTOMATIQUE
  6. * - une relation non associee
  7. *----------------------------------------------------------------------
  8. * Maillage
  9. *----------------------------------------------------------------------
  10. 'OPTI' 'DIME' 3 'ELEM' 'CUB8' ;
  11. IDESS = FAUX ;
  12. *
  13. Rayon = 2.540 ;
  14. Longu = 0.254 ;
  15. haute = 12.7E-3 ;
  16. angle = 180. / pi * 0.1 ;
  17. *
  18. xshift = Rayon '*' (sin angle) ; 
  19. zshift = ( (Rayon**2) - (xshift**2)) ** 0.5 ;
  20. *
  21. P0 =     0. 0. 0. ;
  22. P1 =     0. 0. Rayon  ;
  23. P2 = xshift 0. zshift ;
  24. P3 =     0. 0. (Rayon  - haute) ;
  25. P4 = xshift 0. (zshift - haute) ;
  26. *
  27. NEL1 = 30 ;
  28. NEL2 = 4 ;
  29. L12 = 'CERC' NEL1 P1 P0 P2 ;
  30. L43 = 'CERC' NEL1 P4 P0 P3 ;
  31. *
  32. ST = 'REGL' NEL2 L12 ('INVE' L43) ;
  33. VT = 'VOLU' NEL1 ST 'TRAN' (0. Longu 0.) ;
  34. *
  35. EVT = 'ENVE' VT ;
  36. XVT = 'COOR' 1 EVT ;
  37. XGAU = XVT 'POIN' 'MINI' ;
  38. ZGAU = XVT 'POIN' 'MAXI' ;
  39. ZZZ  = 'COOR' 3 ZGAU ;
  40. ZGAU = ZZZ 'POIN' 'MINI' ;
  41. *
  42. YVT = 'COOR' 2 EVT ;
  43. YGAU = YVT 'POIN' 'MINI' ;
  44. *----------------------------------------------------------------------
  45. * Modele
  46. *----------------------------------------------------------------------
  47. XYOUN = 3.1E9 ; XNU  = 0.3 ;
  48. MOD1 = 'MODE' VT 'MECANIQUE' 'ELASTIQUE' ;
  49. MAT1 = 'MATE' MOD1 'YOUN' XYOUN 'NU' XNU ;
  50. *----------------------------------------------------------------------
  51. * Conditions aux limites
  52. *----------------------------------------------------------------------
  53. CL1 = 'SYMT' 'DEPL' XGAU P1 P0 (P0 PLUS (0. 1. 0.)) 1.E-6 ;
  54. CL2 = 'SYMT' 'DEPL' YGAU P1 P2 P0 1.E-6 ;
  55. CL3 = 'BLOQ' ZGAU 'DEPL' ;
  56. CLT = CL1 'ET' CL2 'ET' CL3 ;
  57. *----------------------------------------------------------------------
  58. * Chargement
  59. *----------------------------------------------------------------------
  60. FP1 = 'FORC' (0. 0. -2000) P1 ;
  61. EV1 = 'EVOL' 'MANU' 'Temps' ('PROG' 0. 1.) 'Coeff' ('PROG' 0. 1.) ;
  62. CH1 = 'CHAR' 'MECA' FP1 EV1 ;
  63. *----------------------------------------------------------------------
  64. * Resolution 1 : option AUTOMATIQUE
  65. *----------------------------------------------------------------------
  66. LTPS = 'PROG' 0. 1. ;
  67. TAB1 = 'TABLE' ;
  68. TAB1.'MODELE'              = MOD1 ;
  69. TAB1.'CARACTERISTIQUES'    = MAT1 ;
  70. TAB1.'BLOCAGES_MECANIQUES' = CLT ;
  71. TAB1.'GRANDS_DEPLACEMENTS' = VRAI ;
  72. TAB1.'K_SIGMA'             = FAUX ;
  73. TAB1.'CHARGEMENT'          = CH1 ;
  74. TAB1.'TEMPS_CALCULES'      = LTPS ;
  75. TAB1.'AUTOMATIQUE'         = VRAI ;
  76. TAB1.'AUTORESU'            = 1 ;
  77. TAB1.'AUTOCRIT'            = 0.7E-3 ;
  78. TAB1.'AUTOPAS'             = 200 ;
  79. *
  80. 'DEBP' AUTOPILO DELT*'CHPOINT' DELA*'CHPOINT' ZMOD*'MMODEL'
  81.                 ZMAT*'MCHAML'  TTT*TABLE ; 
  82.   NORM1 = ABS ('EXTR' delt p1 'UZ') ;
  83. 'FINP' NORM1;
  84. *
  85. PASAPAS TAB1 ;
  86. *
  87. * Post-traitement
  88. DEP  = TAB1.'DEPLACEMENTS' ;
  89. LDEP1 = 'PROG' 0. ; LFOR1 = 'PROG' 0. ;
  90. NBPAS = ('DIME' DEP) '-' 1 ;
  91. REPE B1 NBPAS ;
  92.   DEPZ = EXTR (DEP. &B1) 'UZ' P1 ;
  93.   REAZ = TAB1.'REACTIONS'. &B1 ;
  94.   LDEP1 = LDEP1 ET (-1. * DEPZ) ;
  95.   LFOR1 = LFOR1 ET (+1. * (EXTR (EXTR (EXCO (RESU (REDU REAZ ZGAU)) FZ) VALE) 1)) ;
  96. FIN B1 ;
  97. EVFD1 = 'EVOL' 'OR  ' 'MANU' LDEP1 LFOR1 ;
  98. *----------------------------------------------------------------------
  99. * Resolution 2 : relation non associee
  100. *----------------------------------------------------------------------
  101. CHU = 'MANU' 'CHPO' P1 1 'UZ' -1 ;
  102. CL4 = 'RELA' CHU 'DUAL' FP1 ;
  103. DP4 = 'DEPI' CL4 (-1 '*' DEPZ) ;
  104. CLT = CLT 'ET' CL4 ;
  105. CH1 = 'CHAR' 'DIMP' DP4 EV1 ;
  106. *
  107. LTPS = 'RAFF' LTPS NBPAS ;
  108. TAB2 = 'TABLE' ;
  109. TAB2.'MODELE'              = MOD1 ;
  110. TAB2.'CARACTERISTIQUES'    = MAT1 ;
  111. TAB2.'BLOCAGES_MECANIQUES' = CLT ;
  112. TAB2.'GRANDS_DEPLACEMENTS' = VRAI ;
  113. TAB2.'K_SIGMA'             = FAUX ;
  114. TAB2.'CHARGEMENT'          = CH1 ;
  115. TAB2.'TEMPS_CALCULES'      = LTPS ;
  116. *
  117. PASAPAS TAB2 ;
  118. *
  119. * Post-traitement
  120. DEP  = TAB2.'DEPLACEMENTS' ;
  121. LDEP2 = 'PROG' 0. ; LFOR2 = 'PROG' 0. ;
  122. REPE B2 NBPAS ;
  123.   DEPZ = EXTR (DEP. &B2) 'UZ' P1 ;
  124.   REAZ = TAB2.'REACTIONS'. &B2 ;
  125.   LDEP2 = LDEP2 ET (-1. * DEPZ) ;
  126.   LFOR2 = LFOR2 ET (+1. * (EXTR (EXTR (EXCO (RESU (REDU REAZ ZGAU)) FZ) VALE) 1)) ;
  127. FIN B2 ;
  128. EVFD2 = 'EVOL' 'CYAN' 'MANU' LDEP2 LFOR2 ;
  129. *----------------------------------------------------------------------
  130. * Comparaison des solutions - Courbe force-deplacement
  131. *----------------------------------------------------------------------
  132. 'SI' IDESS ;
  133.   DESS (EVFD1 'ET' EVFD2) 'TITR' 'Courbe Force-deplacement' ;
  134. 'FINSI' ;
  135. *
  136. XECART = EVFD2 '-' EVFD1 ;
  137. XIND XABS1 XORD1 = 'MAXI' 'ABS' XECART ;
  138. XIND XABS2 XORD2 = 'MAXI' 'ABS' EVFD2  ;
  139. XERREL = XORD1 '/' XORD2 ;
  140. 'MESS' 'Erreur relative='XERREL ;
  141. 'SI' (XERREL '>' 3.E-2) ;
  142.   'ERRE' 5 ;
  143. 'FINSI' ;
  144. FIN ;
  145.  
  146.  
  147.  
  148.  
  149.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales