Procédures | Cast3M

* AUTOPILO  PROCEDUR  CHAT      11/03/16    21:15:35     6902           
'DEBPROC' AUTOPILO DELT*'CHPOINT' DELA*'CHPOINT' ZMOD*'MMODEL'
 ZMAT*'MCHAML' TTT*TABLE;
*
*  cette procedure est utile en cas de limitation d'increment de
*  charge pour NONLIN option AUTOMATIQUE
*  En entree DELT est un champ de deplacements qui est l'increment de
*  deplacement que propose INCREME
*            DELA est la resolution elastqiue tangente du probleme
*  c'est a dire K-1.(F1-F0)
*            ZMOD et ZMAT contiennent le model et le champ par element
*  de materiau (et caracteristique) .
*            TTT est la table fournie en entree de NONLIN qui contient
*   notamment  TTT.'AUTOCRIT' qui est le critere de pilotage
*
*  Le but de cette procedure est de fournir un coefficient pour
*  normer DELT afin que ce dernier soit compatible avec le critere
*  de pilotage. Ce coefficient est une norme de DELT au sens du critere
*  En principe il est positif toutefois lui donner un signe permet
*  de forcer l'algorithme vers un direction donnée.
*
* EXEMPLE 1: Si on veut limiter a  TTT.'AUTOCRIT' l'increment de
*            deplacement pour un  point  P1  dans la direction
*            UY il faut faire :
*                     U1MA = ABS DELT 'EXTR' 'UR' A;
*
*
*  EXEMPLE 2 : on veut que le travail d'une force contenue dans
*              TTT.'TOTO' soit limite a TTT.'AUTOCRIT'
*              Il faut :
*                MODEP = MOTS 'UX' 'UY' 'UZ' 'RX' 'RY' 'RZ';
*                MOFOR = MOTS 'FX' 'FY' 'FZ' 'MX' 'MY' 'MZ';
*                U1MA = 'XTY' DELT  TTT.'TOTO'  MODEP MOFOR;
*
*
*  EXEMPLE 3 : On veut limiter a TTT.'AUTOCRIT' la norme de
*              l'increment de deplacement Max de epsilon
*               U1 = 'EPSI' ZMOD  DELT  ZMAT;
*               U1MA= 'MAXI' U1 'ABS';
*
*  en standard limitation sur le max de l'increment de deformation totale 
*  et de l'increment de deformation "plastique" (total - elastique) 
*
 
               U1 = 'EPSI' ZMOD  DELT  ZMAT;
               U2 = 'EPSI' ZMOD (DELT-DELA) ZMAT ;
 
            SI ( NON (TTT.PLASTIQUE OU TTT.VISCOPLASTIQUE OU
                     TTT.ENDOMMAGEMENT OU TTT.VISCODOMMAGE) ) ;
*            si on est en elastique pur on oublie les def. plas.
                  U2 = U1 ;
            FINSI ;
            U1MAX = 'MAXI' U1 'ABS';
            U2MAX = 'MAXI' U2 'ABS';
            NORM1 = MAXI ( PROG U1MAX U2MAX) ;
 
FINPROC   NORM1;