Télécharger la plaquette Cast3M


fr en

Télécharger metallurgie_06.dgibi

Retour à la liste

Numérotation des lignes : 

  2. * fichier :  metallurgie_06.dgibi
  3. ************************************************************************
  4. ************************************************************************
  5.  
  6. *__________________________________________________________________*
  7. *   TEST METALLURGIE_06                                            *
  8. *                                                                  *
  9. *   CALCUL DES PROPORTIONS DE PHASE METALLURGIQUE                  *
  10. *                                                                  *
  11. *   Un MODELE thermo-metallurgique est cree et l'essai JOMINY      *
  12. *   est simule en 2D Axisymétrique                                 *
  13. *                                                                  *
  14. *   Utilisation de PASAPAS et d'une procedure utilisateur :        *
  15. *      - Procédure PARATHER : Mise a jour du matériaux THERMIQUE   *
  16. *                             avec la proportion de phase.         *
  17. *                                                                  *
  18. *   Le modèle métallurgique contient 5 phases ayant des cinétiques *
  19. *   de transformation différentes                                  *
  20. *      - Metal de Base (MB)                                        *
  21. *      - Austénite                                                 *
  22. *      - Martensite                                                *
  23. *      - Bainite                                                   *
  24. *      - Ferrite                                                   *
  25. *__________________________________________________________________*
  26. *   MAILLAGE :                                                     *
  27. *    - Eprouvette cylindrique de hauteur 100mm et de rayon 12,5mm  *
  28. *      P4 _____ P3                                                 *
  29. *        |  J  |    ^                                              *
  30. *        |  O  |    |                                              *
  31. *        |  M  |    |                                              *
  32. *        |  I  |    | h0      Y                                    *
  33. *        |  N  |    |         ^                                    *
  34. *        |  Y  |    |         |                                    *
  35. *      P1 _____ P2  v         o --> X                              *
  36. *                                                                  *
  37. *        <-----> r0                                                *
  38. *      Origine du repere : P1                                      *
  39. *                                                                  *
  40. *   CHARGEMENT :                                                   *
  41. *    - Montee lineaire en temperature depuis 25°C à 900°C en 1200s *
  42. *    - Maintient à 900°C jusqu'a 3000s                             *
  43. *    - Refroidissement par convection par la face cylindrique      *
  44. *      inférieure jusqu'à 3600s                                    *
  45. *                                                                  *
  46. *   CL :                                                           *
  47. *    - Blocage de la temperature (T imposee jusqu'a 3000s)         *
  48. *    - Convection de 3000s à 3600s avec h=0,1 [W.mm-2.K-1]         *
  49. *__________________________________________________________________*
  50. OPTI DIME 2 MODE AXIS ELEM QUA4 ;
  51.  
  52. 'OPTI' 'TRAC' PSC 'EPTR' 10 ;
  53.  
  54. TMAX = 900.;
  55. TMIN = 25. ;
  56. HCON = 0.1 ;
  57.  
  58. ************************************************************************
  59. *  Pour faire des beaux DESSINS
  60. ************************************************************************
  61. * LISTMOTS contenant les couleurs
  62.   LESCOUL = 'MOTS' 'VIOL' 'VERT' 'CYAN' 'BRIQ' 'BOUT' 'JAUN' 'OLIV'
  63.                    'ORAN' 'ROUG' 'BLEU' 'BRUN' 'CARA' 'GRIS' 'NOIR' ;
  64.   NBCOUL  = 'DIME' LESCOUL;
  65.  
  66. * LISTMOTS contenant les marques dans DESS
  67.   LESMARQ = 'MOTS' 'CROI' 'PLUS' 'MOIN' 'BARR' 'ETOI' 'CARR'
  68.                    'LOSA' 'ROND' 'TRID' 'TRIU' 'TRIL' 'TRIR';
  69.   NBMARQ  = 'DIME' LESMARQ;
  70. ************************************************************************
  71.  
  72. ************************************************************************
  73. * Debut de la procedure PARATHER
  74. ************************************************************************
  75. 'DEBP' PARATHER  PRECED*'TABLE' TPS1*'FLOTTANT';
  76. ************************************************************************
  77. * PROCEDURE PARATHER :
  78. *   DESCRIPTION :
  79. *   -------------
  80. *   Cette procedure permet de modifier le materiaux avant l'appel a
  81. *   VARI 'NUAG' dans TRANSNON.
  82. *     - Les composantes K, C et RHO sont une moyenne arithméthique
  83. *       pondérée par la fraction de phase des Ki, Ci et RHOi
  84. *   L'indice ETAB.'MAT_TOT' est remplacé
  85. *   L'indice ETAB . 'CHARGEMENT' est remplacé
  86. *
  87. *   ENTREES :
  88. *   ---------
  89. *   - PRECED : TABLE complete de PASAPAS
  90. *   - TPS1   : Temps courant
  91. *
  92. *   SORTIES :
  93. *   ---------
  94. *   - Aucune
  95. *
  96. ************************************************************************
  97.  
  98. *I - Mise a jour du materiau Thermique avec les proportions de phases
  99.    ETAB    = PRECED.'WTABLE';
  100.    MOD1    = ETAB.'MOD_TOT' ;
  101.    T1      = ETAB.'THER_COURANT' ;
  102.    T1      ='CHAN' 'CHAM' T1 MOD1 'RIGIDITE' 'CARACTERISTIQUES';
  103.  
  104.    MAT_ORIG= ETAB.'MAT_TOT';
  105.    COMPORIG='EXTR' MAT_ORIG 'COMP';
  106.    NBCOMP  ='DIME' COMPORIG;
  107.  
  108.    MAT0 ='VIDE' 'MCHAML';
  109.    REPE SURCOM NBCOMP;
  110.      II     = &SURCOM;
  111.      LACOMP ='EXTR' COMPORIG II;
  112.      SI(('NEG' LACOMP 'K'  ) 'ET'
  113.         ('NEG' LACOMP 'RHO') 'ET'
  114.         ('NEG' LACOMP 'C'  ));
  115.         MAT0 = MAT0 'ET' ('EXCO' LACOMP MAT_ORIG);
  116.      FINS;
  117.    FIN SURCOM;
  118.  
  119. *  Instanciation du matériaux de chaque phase
  120.    MATPHAS ='REDU'  MOD1 MATPHAS ;
  121.    MAT2    ='VARI' 'NUAG' MOD1 MATPHAS T1 'RIGIDITE';
  122.  
  123. *  On fait ensuite la moyenne qui nous interesse (Ponderation par la
  124. *  proportion de phase)
  125.    NPA ='DIME' PRECED.'TEMPS';
  126.    SI ('EXIS' PRECED.'PROPORTIONS_PHASES'   NPA )   ;
  127.      MCHPHA = PRECED.'PROPORTIONS_PHASES' . NPA     ;
  128.    SINO ;
  129.      MCHPHA = PRECED.'PROPORTIONS_PHASES' .(NPA - 1);
  130.      PRECED.'PROPORTIONS_PHASES' . NPA = MCHPHA     ;
  131.    FINS ;
  132.  
  133.    MCHPHA = 'CHAN' 'CONS' MCHPHA 'MAT1'  ;
  134.    MCHPHA = 'REDU' MCHPHA ETAB.'MOD_COND' ;
  135.    MCHPHA ='CHAN' 'RIGIDITE' MCHPHA MOD1           ;
  136.    MCHPHA ='CHAN' 'TYPE' MCHPHA 'CARACTERISTIQUES' ;
  137.  
  138.    MOPROP1='EXTR'  MCHPHA 'COMP'                   ;
  139.    MOMAT2 ='EXTR'  MAT2   'COMP'                   ;
  140.  
  141.    MCHK ='CHAN' 'TYPE' ('VIDE' 'MCHAML') 'CARACTERISTIQUES' ;
  142.    MCHR ='CHAN' 'TYPE' ('VIDE' 'MCHAML') 'CARACTERISTIQUES' ;
  143.    MCHC ='CHAN' 'TYPE' ('VIDE' 'MCHAML') 'CARACTERISTIQUES' ;
  144.  
  145. * Boucle sur les phases
  146.    NBPHA  = 'DIME' MOPROP1;
  147.    REPE SURP NBPHA;
  148.      IP = &SURP ;
  149.      PROPIP ='EXCO' MCHPHA ('EXTR' MOPROP1 IP) 'SCAL' ; 'COMM' 'Prop de la phase numero IP' ;
  150.  
  151. *    Moyenne sur les K
  152.      IB = IP;
  153.      RATIO = 'EXCO' MAT2 ('EXTR' MOMAT2 IB) 'SCAL';
  154.      MCHK = (PROPIP * RATIO) + MCHK ;
  155.  
  156. *    Moyenne sur les RHO
  157.      IB = IB + NBPHA;
  158.      RATIO2 = 'EXCO' MAT2 ('EXTR' MOMAT2 IB) 'SCAL';
  159.      MCHR = (PROPIP * RATIO2) + MCHR ;
  160.  
  161. *    Moyenne sur les CP
  162.      IB = IB + NBPHA;
  163.      RATIO3 = 'EXCO' MAT2 ('EXTR' MOMAT2 IB) 'SCAL';
  164.      MCHC = (PROPIP * RATIO3) + MCHC ;
  165.    FIN SURP;
  166.  
  167.    MCHK ='CHAN' 'COMP' 'K'   MCHK ;
  168.    MCHR ='CHAN' 'COMP' 'RHO' MCHR ;
  169.    MCHC ='CHAN' 'COMP' 'C'   MCHC ;
  170.  
  171. *  REMPLACEMENT DU MATERIAUX
  172.    ETAB.'MAT_TOT' = MCHK 'ET' MCHR 'ET' MCHC 'ET' MAT0 ;
  173.  
  174.  
  175. 'FINP';
  176. ************************************************************************
  177. * Fin de la procedure PARATHER
  178. ************************************************************************
  179.  
  180. *MAILLAGE
  181. h0 = 100.  ; COMM 'hauteur du cylindre' ;
  182. r0 = 12.5  ; COMM 'rayon du cylindre'   ;
  183. dens0 = 1. ; COMM 'densité maillage'    ;
  184.  
  185. axes = @repere (0. 0.) ('PROG' 25. 25.) 'ROUG' ;
  186. P1 = POIN 0. 0. ;
  187. P2 = POIN r0 0. ;
  188. P3 = POIN r0 h0 ;
  189. P4 = POIN 0. h0 ;
  190.  
  191. L1 = DROI P1 P2 'DINI' dens0 'DFIN' dens0 ;
  192. L2 = DROI P2 P3 'DINI' dens0 'DFIN' dens0 ;
  193. L3 = DROI P3 P4 'DINI' dens0 'DFIN' dens0 ;
  194. L4 = DROI P4 P1 'DINI' dens0 'DFIN' dens0 ;
  195.  
  196. MAILT = (DALL L1 L2 L3 L4) COUL 'BLEU' ;
  197. ELIM MAILT 1.e-3 ;
  198. CONTT = CONT MAILT ;
  199. PTBAS = CONTT POIN 'DROIT' P1 P2 1.e-3 ;
  200. SURFBAS = CONTT ELEM 'APPUYE' 'STRICTEMENT' PTBAS ;
  201.  
  202. *MODELE
  203. MODTHE = MODE MAILT   'THERMIQUE' 'CONDUCTION' 'QUA4' 'CONS' 'MAT1' ;
  204. MODCON = MODE SURFBAS 'THERMIQUE' 'CONVECTION' 'SEG2';
  205. MODTHERM = MODTHE 'ET' MODCON;
  206.  
  207. ************************************************************************
  208. * Definition de la metallurgie : DEBUT
  209. ************************************************************************
  210. *  1- Métal de base 100% initialement
  211. *  2- Martensite
  212. *  3- Bainite
  213. *  4- Ferrite
  214. *  5- Austénite
  215.  
  216. * Evolution des proprietes thermiques pour les phases pures
  217. MCHK   = VIDE 'MCHAML';
  218. MCHRHO = VIDE 'MCHAML';
  219. MCHC   = VIDE 'MCHAML';
  220. CTYP   = MOT  'CARACTERISTIQUES';
  221. ********************
  222. * 1- Métal de base *
  223. ********************
  224. IPAHS  = 1;
  225. CPHAS  = CHAI 'K' IPAHS;
  226. LTKP1  = PROG 0 55 113 162 191 243 293 392
  227.               457 507 605 655 756 795 840 856
  228.               900 950 1000 1101 1202 1303 1400 1500
  229.               1502 1600   ;
  230. LKP1   = PROG 0.0376 0.0389 0.0401 0.0407 0.0407 0.0404 0.0398 0.038
  231.               0.0364 0.0352 0.0329 0.0317 0.0291 0.0273 0.0252 0.0248
  232.               0.0253 0.0261 0.027 0.0283 0.0299 0.0314 0.0328 0.0343
  233.               0.05 0.05;
  234. EVKP1  = EVOL 'MANU' 'T' LTKP1 CPHAS LKP1;
  235. MCHK   = MCHK   ET (MANU 'CHML' MODTHE CPHAS EVKP1 'TYPE' CTYP) ;
  236.  
  237. CPHAS  = CHAI 'R' IPAHS;
  238. LTRHOP1= PROG 0 20 100 200 300 400
  239.               500 600 700 800 900 1440
  240.               2500 ;
  241. LRHOP1 = PROG 7852.D-9 7852.D-9 7815.D-9 7778.D-9 7741.D-9 7705.D-9
  242.               7668.D-9 7633.D-9 7595.D-9 7562.D-9 7527.D-9 7345.D-9
  243.               7011.D-9 ;
  244. EVRHOP1 = EVOL 'MANU' 'T' LTRHOP1 CPHAS LRHOP1;
  245. MCHRHO  = MCHRHO ET (MANU 'CHML' MODTHE CPHAS EVRHOP1 'TYPE' CTYP) ;
  246.  
  247. CPHAS  = CHAI 'C' IPAHS;
  248. LTCP1  = PROG 21 50 150 200 250 300 350 450 550
  249.               650 700 750 850 1000 1200 1300 1400 1440
  250.               1465 1490 1540 1590 1615 1640 2500 ;
  251. LCP1   = PROG 460.5 485.6 519.1 531.6 556.7 573.5 598.6 661.4 749.3
  252.               845.6 1431.6 950.2 900 845.6 800 815 840 850
  253.               1210 1840 2470 1840 1210 840 707 ;
  254. EVCP1  = EVOL 'MANU' 'T' LTCP1 CPHAS LCP1;
  255. MCHC         = MCHC   ET (MANU 'CHML' MODTHE CPHAS EVCP1 'TYPE' CTYP) ;
  256.  
  257. *****************
  258. * 2- Martensite *
  259. *****************
  260. IPAHS   = 2;
  261. CPHAS   = CHAI 'K' IPAHS;
  262. EVKP1   = EVOL 'MANU' 'T' LTKP1 CPHAS LKP1;
  263. MCHK    = MCHK   ET (MANU 'CHML' MODTHE CPHAS EVKP1 'TYPE' CTYP) ;
  264.  
  265. CPHAS   = CHAI 'R' IPAHS;
  266. EVRHOP1 = EVOL 'MANU' 'T' LTRHOP1 CPHAS LRHOP1;
  267. MCHRHO  = MCHRHO ET (MANU 'CHML' MODTHE CPHAS EVRHOP1 'TYPE' CTYP) ;
  268.  
  269. CPHAS   = CHAI 'C' IPAHS;
  270. EVCP1   = EVOL 'MANU' 'T' LTCP1 CPHAS LCP1;
  271. MCHC    = MCHC   ET (MANU 'CHML' MODTHE CPHAS EVCP1 'TYPE' CTYP) ;
  272.  
  273. **************
  274. * 3- Bainite *
  275. **************
  276. IPAHS  = 3;
  277. CPHAS   = CHAI 'K' IPAHS;
  278. EVKP1   = EVOL 'MANU' 'T' LTKP1 CPHAS LKP1;
  279. MCHK    = MCHK   ET (MANU 'CHML' MODTHE CPHAS EVKP1 'TYPE' CTYP) ;
  280.  
  281. CPHAS   = CHAI 'R' IPAHS;
  282. EVRHOP1 = EVOL 'MANU' 'T' LTRHOP1 CPHAS LRHOP1;
  283. MCHRHO  = MCHRHO ET (MANU 'CHML' MODTHE CPHAS EVRHOP1 'TYPE' CTYP) ;
  284.  
  285. CPHAS   = CHAI 'C' IPAHS;
  286. EVCP1   = EVOL 'MANU' 'T' LTCP1 CPHAS LCP1;
  287. MCHC    = MCHC   ET (MANU 'CHML' MODTHE CPHAS EVCP1 'TYPE' CTYP) ;
  288.  
  289. **************
  290. * 4- Ferrite *
  291. **************
  292. IPAHS  = 4;
  293. CPHAS   = CHAI 'K' IPAHS;
  294. EVKP1   = EVOL 'MANU' 'T' LTKP1 CPHAS LKP1;
  295. MCHK    = MCHK   ET (MANU 'CHML' MODTHE CPHAS EVKP1 'TYPE' CTYP) ;
  296.  
  297. CPHAS   = CHAI 'R' IPAHS;
  298. EVRHOP1 = EVOL 'MANU' 'T' LTRHOP1 CPHAS LRHOP1;
  299. MCHRHO  = MCHRHO ET (MANU 'CHML' MODTHE CPHAS EVRHOP1 'TYPE' CTYP) ;
  300.  
  301. CPHAS   = CHAI 'C' IPAHS;
  302. EVCP1   = EVOL 'MANU' 'T' LTCP1 CPHAS LCP1;
  303. MCHC    = MCHC   ET (MANU 'CHML' MODTHE CPHAS EVCP1 'TYPE' CTYP) ;
  304.  
  305. ****************
  306. * 5- Austénite *
  307. ****************
  308. IPAHS  = 5;
  309. CPHAS  = CHAI 'K' IPAHS;
  310. LTKP5  = PROG 0    20 100 200 400 600 800 856
  311.               900 1000 1200 1500 1502 1600   ;
  312. LKP5   = PROG 0.0121 0.0124 0.0136 0.015 0.018 0.021 0.0239 0.0248
  313.               0.0254 0.0269 0.0298 0.0343 0.05 0.05;
  314. EVKP5  = EVOL 'MANU' 'T' LTKP5 CPHAS LKP5;
  315. MCHK         = MCHK   ET (MANU 'CHML' MODTHE CPHAS EVKP5 'TYPE' CTYP) ;
  316.  
  317. CPHAS  = CHAI 'R' IPAHS;
  318. LTRHOP5= PROG 0 20 100 200 300 400
  319.               500 600 700 800 900 1440
  320.               2500 ;
  321. LRHOP5 = PROG 7852.D-9 7841.D-9 7794.D-9 7736.D-9 7680.D-9 7624.D-9
  322.               7569.D-9 7514.D-9 7458.D-9 7408.D-9 7356.D-9 7087.D-9
  323.               6613.D-9 ;
  324. EVRHOP5 = EVOL 'MANU' 'T' LTRHOP5 CPHAS LRHOP5;
  325. MCHRHO       = MCHRHO ET (MANU 'CHML' MODTHE CPHAS EVRHOP5 'TYPE' CTYP);
  326.  
  327.  
  328. CPHAS  = CHAI 'C' IPAHS;
  329. LTCP5  = PROG 21   50   150  200  250  300  350  475  575  675  800
  330.               950  1000 1100 1200 1300 1400 1440 1465 1490 1540 1590
  331.               1615 1640 2500 ;
  332. LCP5   = PROG 460.5 485.6 519.1 531.6 556.7 573.5 598.6 652 671 685 715
  333.               742 750 774 795 815 840 850 1210 1840 2470 1840
  334.               1210 840 707 ;
  335. EVCP5  = EVOL 'MANU' 'T' LTCP5 CPHAS LCP5;
  336. MCHC         = MCHC   ET (MANU 'CHML' MODTHE CPHAS EVCP5 'TYPE' CTYP) ;
  337.  
  338.  
  339. TPHASE = TABL;
  340. * Liste des transformations existantes dans un LISTENTIE
  341. TPHASE . 'PHASES' = MOTS 'MB  ' 'MART' 'BAIN' 'FERR' 'AUST' ;
  342. TPHASE . 'REACTIFS' = MOTS 'MB  ' 'MART' 'BAIN' 'FERR' 'AUST' 'AUST' 'AUST' ;
  343. TPHASE . 'PRODUITS' = MOTS 'AUST' 'AUST' 'AUST' 'AUST' 'MART' 'BAIN' 'FERR' ;
  344. TPHASE . 'TYPE'     = MOTS 'LEBL' 'LEBL' 'LEBL' 'LEBL' 'KOIS' 'LEBL' 'LEBL' ;
  345.  
  346. MODCP1 = MODE MAILT 'METALLURGIE' 'PHASES' (TPHASE . 'PHASES')
  347.                                   'REACTIFS' (TPHASE . 'REACTIFS')
  348.                                   'PRODUITS' (TPHASE . 'PRODUITS')
  349.                                   'TYPE' (TPHASE . 'TYPE')
  350.                                   'QUA4' ;
  351.  
  352. PROG_T = 'PROG' 716. 802. ;
  353. PROG_TPO = 'PROG' -1.D-6 0. ;
  354. PROG_PEQ = 'PROG' 0. 1. ;
  355. PROG_F = 'PROG' 0. 1. ;
  356. PROG_TAU = 'PROG' 12. 0.5 ;
  357.  
  358. *1ere transformation :
  359.   PEQ1 = EVOL 'MANU' 'T'   PROG_T 'PEQ1' PROG_PEQ ;
  360.   F1   = EVOL 'MANU' 'TPOI'PROG_TPO 'F1' PROG_F ;
  361.   TAU1 = EVOL 'MANU' 'T'   PROG_T 'TAU1' PROG_TAU ;
  362. *2eme transformation : parametres identiques a la premiere
  363.   PEQ2 = EVOL 'MANU' 'T'   PROG_T 'PEQ2' PROG_PEQ ;
  364.   F2   = EVOL 'MANU' 'TPOI'PROG_TPO 'F2' PROG_F ;
  365.   TAU2 = EVOL 'MANU' 'T'   PROG_T 'TAU2' PROG_TAU ;
  366. *3eme transformation : parametres identiques a la premiere
  367.   PEQ3 = EVOL 'MANU' 'T'   PROG_T 'PEQ3' PROG_PEQ ;
  368.   F3   = EVOL 'MANU' 'TPOI'PROG_TPO 'F3' PROG_F ;
  369.   TAU3 = EVOL 'MANU' 'T'   PROG_T 'TAU3' PROG_TAU ;
  370. *4eme transformation : parametres identiques a la premiere
  371.   PEQ4 = EVOL 'MANU' 'T'   PROG_T 'PEQ4' PROG_PEQ ;
  372.   F4   = EVOL 'MANU' 'TPOI'PROG_TPO 'F4' PROG_F ;
  373.   TAU4 = EVOL 'MANU' 'T'   PROG_T 'TAU4' PROG_TAU ;
  374. *5eme transformation
  375.   MS5 = 380. ;
  376.   KM5 = 0.0247 ;
  377.  
  378. *6eme transformation
  379.   PEQ6 = EVOL 'MANU' 'T'   (PROG 375 380 405 600)
  380.                      'PEQ6' (PROG 0.  1.  1.  0.  );
  381.  
  382.   F6  = 'EVOL' 'MANU' 'TPOI' (PROG -100. -80. -60. -50. -40. -30. -25. -20. -18. -15. -12. -10. -9. -5. -1. -0.05 0.D0 1.D-6)
  383.                       'F6' (PROG 0.005 1.573 2.857 3.417 3.982 4.583 4.833 5.26 5.472 6.033 7.675 11.4 18.45 17.1 0.328 0.00238 0.00238 0.) ;
  384.  
  385.   TAU6 = EVOL 'MANU' 'T'   (PROG 375  380)
  386.                      'TAU6' (PROG 1.D6 20 );
  387.  
  388. *7eme transformation
  389.   PEQ7 = 'EVOL' 'MANU' 'T' (PROG 625 630 730 735 )
  390.                        'PEQ7' (PROG 0   1   1   0   );
  391.  
  392.   F7  = 'EVOL' 'MANU' 'TPOI' (PROG -8.5  -6.2 -4.7  0.  1.D-6)
  393.                       'F7'    (PROG  0.001 0.13 1.5  1.5 0.   );
  394.  
  395.   TAU7 = EVOL 'MANU' 'T'   (PROG 625  630 )
  396.                      'TAU7' (PROG 1.D6 5   );
  397.  
  398.   MATCP1 = 'MATE' MODCP1 'PEQ1' PEQ1 'TAU1' TAU1 'F1' F1
  399.                          'PEQ2' PEQ2 'TAU2' TAU2 'F2' F2
  400.                          'PEQ3' PEQ3 'TAU3' TAU3 'F3' F3
  401.                          'PEQ4' PEQ4 'TAU4' TAU4 'F4' F4
  402.                          'MS5' MS5 'KM5' KM5
  403.                          'PEQ6' PEQ6 'TAU6' TAU6 'F6' F6
  404.                          'PEQ7' PEQ7 'TAU7' TAU7 'F7' F7;
  405.  
  406. ************************************************************************
  407. * Definition de la metallurgie : FIN
  408. ************************************************************************
  409.  
  410. MODTOT = MODTHE 'ET' MODCP1 'ET' MODCON ;
  411.  
  412. ************************************************************************
  413. * Phase 1 et 2 :
  414. *   Rampe de temperature jusqu'à 900°C d'une durée de 20min
  415. *   Palier isotherme à           900°C d'une durée de 30min
  416. ************************************************************************
  417.  
  418. *TEMPERATURE INITIALE
  419. CHPTINI = MANU 'CHPO' MAILT 1 'T' TMIN 'NATU' 'DIFFUS' ;
  420.  
  421. CTYP   ='CHAI'  'VARIABLES_INTERNES';
  422. MCHPHA  = MANU 'CHML' MODCP1 'MB  ' 0.1 'MART' 0.2 'BAIN' 0.3
  423.                              'FERR' 0.4 'AUST' 0.0
  424.                'TYPE' CTYP 'NOEUD' ;
  425.  
  426. *MATERIAUX
  427. MATPHAS = MCHK 'ET' MCHRHO 'ET' MCHC  ;
  428. MATCONV ='MATE' MODCON 'H' 0.D0 ;
  429. MATCOND ='MATE' MODTHE 'K' 0.D0 'RHO' 0.D0 'C' 0.D0;
  430. MATTOT  = MATCOND 'ET' MATCONV 'ET' MATCP1 ;
  431.  
  432. ************************************************************************
  433. * CONDITIONS aux LIMITES
  434. ************************************************************************
  435. * TEMPERATURE IMPOSE EN BAS
  436. CLTHE   = BLOQ 'T' MAILT ;
  437. TIMPO   = DEPI 1.  CLTHE ;
  438.  
  439. * CHARGEMENT THERMIQUE 'T'
  440. LTPSCHA = PROG 0.    1200. 3000.   ;
  441. LTCHA   = PROG TMIN  TMAX  TMAX    ;
  442. EVT     = EVOL 'MANU' LTPSCHA LTCHA;
  443. CHAR1   = CHAR 'TIMP' TIMPO EVT    ;
  444.  
  445. *TEMPS_CALCULES
  446. LTCAL1  = PROG 0. 'PAS' 300. 3000.  ;
  447.  
  448. *PASAPAS
  449. TPASAP                          ='TABL'         ;
  450. TPASAP.'MODELE'                 = MODTOT        ;
  451. TPASAP.'CARACTERISTIQUES'       = MATTOT        ;
  452. TPASAP.'BLOCAGES_THERMIQUES'    = CLTHE         ;
  453. TPASAP.'CHARGEMENT'             = CHAR1         ;
  454. TPASAP.'TEMPS_CALCULES'         = LTCAL1        ;
  455.  
  456. TPASAP.'TEMPS'                  ='TABL'         ;
  457. TPASAP.'TEMPERATURES'           ='TABL'         ;
  458. TPASAP.'PROPORTIONS_PHASES'     ='TABL'         ;
  459. TPASAP.'TEMPS'              . 0 ='EXTR' LTCAL1 1;
  460. TPASAP.'TEMPERATURES'       . 0 = CHPTINI       ;
  461. TPASAP.'PROPORTIONS_PHASES' . 0 = MCHPHA        ;
  462. TPASAP.'PROCESSEURS'            ='MOT' 'MONO_PROCESSEUR';
  463.  
  464. * PROCEDURES Utilisateurs
  465. TPASAP.'PROCEDURE_PARATHER'    = VRAI          ;
  466.  
  467. PASAPAS TPASAP ;
  468.  
  469. ************************************************************************
  470. * Phase 3 :
  471. *   Refroidissement par convection sur un des bords
  472. ************************************************************************
  473. * MATERIAU
  474. MATCONV  ='MATE' MODCON  'H' HCON ;
  475. MATTOT   = MATCOND 'ET' MATCONV    ;
  476.  
  477. MATTOT  = MATCOND 'ET' MATCONV 'ET' MATCP1 ;
  478.  
  479. * CHARGEMENT Thermque 'T'
  480. LTPSCHA = PROG 0.D0 1.D6 ;
  481. LTCHA   = PROG 1.D0 1.D0 ;
  482. EVTECO  = EVOL 'MANU' LTPSCHA LTCHA;
  483. CHPTECO ='MANU' 'CHPO' SURFBAS 1 'T' 20. ;
  484. CHAR1   = CHAR 'TECO' CHPTECO EVTECO ;
  485.  
  486. *TEMPS_CALCULES
  487. MTPS1    ='MAXI' LTCAL1 ;
  488. MTPS2    = MTPS1 + 600. ;
  489. LTCAL2   ='PROG' 3000. 'PAS' 1.  3040. 'PAS' 4. 3160.  'PAS' 8. 3320. 'PAS' 16. MTPS2 ;
  490.  
  491. * Remplacement des indices dans la TABLE TPASAP
  492. TPASAP.'BLOCAGES_THERMIQUES'='VIDE' 'RIGIDITE';
  493. TTPS  = TPASAP.'TEMPS';
  494. ID_IND=('DIME' TTPS) - 1;
  495. MCHPHA= TPASAP.'PROPORTIONS_PHASES' . ID_IND ;
  496. ID2   = ID_IND + 1 ;
  497.  
  498. TPASAP.'CARACTERISTIQUES'         = MATTOT ;
  499. TPASAP.'CHARGEMENT'               = CHAR1  ;
  500. TPASAP.'TEMPS_CALCULES'           = LTCAL2 ;
  501. TPASAP.'PROPORTIONS_PHASES' . ID2 = MCHPHA ;
  502.  
  503. PASAPAS TPASAP ;
  504.  
  505. ************************************************************************
  506. * POST-TRAITEMENT des résultats
  507. ************************************************************************
  508. fic_sauv = 'CHAI' 'JOMINY.sauv' ;
  509. OPTI SAUV fic_sauv ;
  511.  
  512. * Initialisations pour le POST-TRAITEMENT
  513. LISCOM ='EXTR' MCHPHA 'COMP' ;
  514. NBCOMP ='DIME' LISCOM        ;
  515. TABPHA ='TABL';
  516. REPE SURPHA NBCOMP;
  517.   IPH = &SURPHA;
  518.   TABPHA . IPH ='VIDE' 'LISTREEL' ;
  519. FIN SURPHA;
  520. LTPS ='VIDE' 'LISTREEL';
  521.  
  522. REPE BLOC0 ('DIME' TPASAP.'TEMPS')         ;
  523.   I      = &BLOC0  - 1                     ;
  524.   CHT    = TPASAP.'TEMPERATURES'      . I  ;
  525.   CHPHA  = TPASAP.'PROPORTIONS_PHASES'. I  ;
  526.   LTPS   = LTPS 'ET' (TPASAP.'TEMPS'  . I) ;
  527.  
  528. * Extraction pour chaque phase de la valeur courante
  529.   REPE SURPHA NBCOMP;
  530.     IPH = &SURPHA;
  531.     NOMP='EXTR' LISCOM IPH;
  532.     Pi  ='EXTR' CHPHA NOMP 1 1   1 ;
  533.     TABPHA . IPH = TABPHA . IPH 'ET' Pi;
  534.   FIN SURPHA;
  535. FIN BLOC0 ;
  536.  
  537. *Reconstitution des EVOL
  538. EVTOTa           ='VIDE' 'EVOLUTIO';
  539. TDESS1           ='TABL' ;
  540. TDESS1 . 'TITRE' ='TABL' ;
  541. EVOPHAS          ='VIDE' 'EVOLUTIO';
  542. CPPHAS           ='CHAN' 'CHPO' CHPHA MODTOT;
  543.  
  544. REPE SURPHA NBCOMP;
  545.   IPH          = &SURPHA;
  546.   NOMP         ='EXTR' LISCOM IPH;
  547.   ICOUL        = @MOD  IPH NBCOUL;
  548.   COUL1        ='EXTR' LESCOUL ICOUL;
  549.   Lpi          = TABPHA. IPH ;
  550.   TABPHA . IPH ='EVOL' COUL1 'MANU' 'TEMP' LTPS NOMP Lpi;
  551.   EVTOTa       = EVTOTa 'ET' TABPHA . IPH ;
  552.   IMARQ        = @MOD   IPH NBMARQ;
  553.   LAMAR        ='EXTR'  IMARQ LESMARQ;
  554.   TDESS1 . 'TITRE' . IPH = NOMP;
  555. *  TDESS1 . IPH ='CHAI' 'MARQ ' LAMAR ' REGU';
  556.   EVOPHAS      = EVOPHAS 'ET' ('EVOL' COUL1 'CHPO' CPPHAS NOMP L2);
  557. FIN SURPHA;
  558.  
  559.  EVTOTa = 'CHAN' 'NOMORD' EVTOTa 'PROP';
  560. 'DESS' EVTOTa  'LEGE' TDESS1 'TITR' ('CHAI' 'Evolution des Props en fonction du temps' ) 'YBOR' 0. 1. ;
  561.  
  562.  EVOPHAS = 'CHAN' 'NOMORD' EVOPHAS 'PROP';
  563. 'DESS' EVOPHAS 'LEGE' TDESS1 'TITR' ('CHAI' 'Props a Temps final' ) 'YBOR' 0. 1. ;
  564.  
  565. list (temp horl / 100.) ;
  566.  
  567. FIN ;
  568.  
  569.  
  570.  
  571.  
  572.  
  573.  
  574.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales