Télécharger la plaquette Cast3M


fr en

Télécharger faceaface3.dgibi

Retour à la liste

Numérotation des lignes : 

  1. * fichier : faceaface3.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4.  
  5. ************************************************************************
  6. *......../........./........./........./........./........./........./72
  7. * test de calcul FACE a FACE avec PASAPAS
  8. * Echange thermique entre deux faces proches (L/e>>10) ,
  9. * en convection, en rayonnement
  10. * et mixte rayonnement plus convection
  11. *                                          Philippe YALA le 14/12/09
  12. *
  13. *    VERSION 3D de faceaface.dgibi
  14. ************************************************************************
  15. OPTI DIME 3 ELEM CUB8 ;
  16. ************************************************************************
  17. * CALCUL EN GEOMETRIE 3D
  18. * deux cylindres coaxiaux avec convection externe
  19. * 1 calcul avec CONV dans le jeu ;  H=Cd_Air/Ep
  20. * 2 calcul avec RAYO dans le jeu
  21. * 3 calcul complet avec CONV et RAYO
  22. ************************************************************************
  23. *DONNEES GEOMETRIQUES
  24. * rayon arbre
  25. rarbre = 10.e-3 ;
  26. * jeu type H7 g6 ; soit en micron : +15/0  -5/-14
  27. jeumin = 0. + 5.e-6 ;
  28. jeumax = 15.e-6 + 14.e-6 ;
  29.  graph= mot 'N';
  30. jeu = jeumax ;
  31. * ou jeu = jeumin ;
  32.  
  33. * epaisseur alesage
  34. epal = 5.e-3 ;
  35. * hauteur
  36. haut = 5.e-3 ;
  37. ************************************************************************
  38. * MAILLAGE presque sans discretisation du jeu ( noeud double)
  39. P0 = 0. 0. 0.;
  40. P1 = 0. haut 0.;
  41. laxe = P0 droit P1 DINI 0.002 DFIN 0.001 ;
  42. arbre = (laxe trans (rarbre 0. 0.) DINI 0.002 DFIN 0.001 ) coul vert ;
  43. lor1 lhaut lcot1 lbas = cote arbre ;
  44. EPS = 1.e-5 ;
  45. * Remarque ne fonctionne pas avec EPS=0. pour RAYO
  46. *lcot2 = lcot1 plus ( EPS 0. 0.) ;
  47. lcot2 = lcot1 plus ( EPS*10 0. 0.) ;
  48. alesage = ( lcot2 trans ( epal 0. 0.) DINI 0.001 DFIN 0.002 )
  49. coul rouge ;
  50. lor2 lhaut2 lcotext lbas2 = cote alesage ;
  51.  
  52. arbre = VOLU arbre 60 ROTA -360 (0. 0. 0.) (0. -1. 0.) ;
  53. alesage = VOLU alesage 60 ROTA -360 (0. 0. 0.) (0. -1. 0.) ;
  54.  
  55. ARBRE = ARBRE COUL VERT ;
  56. ALESAGE = ALESAGE COUL ROUG;
  57.  
  58. elim arbre  0.000001 ;
  59. elim  alesage 0.000001 ;
  60.  
  61. arbre = REGENERER ARBRE ;
  62.  
  63. tot  = arbre et alesage ;
  64. si ( ega graph 'O');
  65.   trac  CACHE TOT face;
  66. FINSI ;
  67. LCOTEXT = LCOTEXT ROTA 60 -360 (0. 0. 0.) (0. -1. 0.) ;
  68. ELIM ( ALESAGE ET LCOTEXT) 0.000001 ;
  69.  
  70.  
  71.  
  72.  
  73. ************************************************************************
  74. *DONNEES THERMIQUES
  76. MESS 'DONNEES THERMIQUES';
  77. TK = 273.15 ;MESS 'Zero °C' TK ;
  78. EMA = 0.8  ;MESS 'Emissivité ARBRE' EMA ;
  79. EMB = 0.9  ;MESS 'Emissivité ALESAGE cote interne' EMB ;
  80. EMC = 1.0 ;MESS 'Emissivité ALESAGE cote externe ' EMC ;
  81. TAMB = 30.0 ;MESS 'Température ambiance' TAMB '°C' ;
  82. TINI = 500.0 ;MESS 'Température initiale' TINI '°C' ;
  83. TAMB = TAMB + TK ; TINI = TINI +TK ;
  84.  
  85. ************************************************************************
  86. *MODELISISATION THERMIQUES
  87. *conduction
  88. MCD1  = MODE ARBRE THERMIQUE ISOTROPE ;
  89. MCD2  = MODE ALESAGE THERMIQUE ISOTROPE ;
  90. MAT1  = MATE MCD1  'K'  15.0 'C'  500.0  'RHO' 7800.0   ;
  91. MAT2  = MATE MCD2  'K'  132. 'C'  945.0  'RHO' 2670.0  ;
  92. ************************************************************************
  93. * convection extérieure
  94. MOHEX = MODE lcotext 'THERMIQUE'  'CONVECTION' ;
  95. MAHEX = MATE MOHEX 'H' EMC ;
  96. TCHA = PROG 0.   1.e10  ;
  97. PINC = PROG 1. 1.  ;
  98. MEVOLTE = EVOL 'MANU' 'TEMP' TCHA 'AMP' PINC ;
  99. CH_TE = 'MANU' 'CHPO' lcotext 1 'T' TAMB ;
  100. CHAT = CHAR 'TECO' CH_TE MEVOLTE ;
  101. ************************************************************************
  102. * initialisation en temperature
  103. TEM0 = MANU CHPO TOT  1 T TINI ;
  104. ************************************************************************
  105. * Temps calculés
  106. PTPS1 = prog 0. 0.01 0.02 0.05  0.1 0.2  0.5 1. 2. 4. 6. pas 2. 100. ;
  107. PTPS2 = prog  20. pas 5.  50. pas 10.  100. pas 20. 600. ;
  108. PTPS = PTPS1   ;
  109. *ptps= prog 0. 0.01 0.02 0.05 ;
  110. * Temps sauvés
  111. PTPSS = prog  0. pas 4. 100. ;
  112. ************************************************************************
  113.  
  114. * Convection bilatérale (face a face)
  115. *-------------------------------
  116. cont1 = enve arbre ;
  117. elim (cont1 et arbre) eps ;
  118. PT1 = point cont1 cyli ( 0 0 0 ) (0 -1. 0 ) (rarbre 0. 0.) 0.0001 ;
  119. lcot1 = elem cont1 appu strict PT1 ;
  120. elim (lcot1 et cont1 et arbre) 0.0001 ;
  121. cont2 = enve alesage ;
  122. elim (cont2 et alesage) eps ;
  123. PT2 = point cont2 cyli ( 0 0 0 ) (0 -1. 0)
  124. ((rarbre+(EPS*10)) 0. 0.) 0.0001 ;
  125. lcot2 = elem cont2 appu strict PT2 ;
  126. elim (lcot2 et cont2 et alesage) 0.0001 ;
  127. rac12 = LIAI 1.1e-4 lcot1 lcot2 ;
  128.  
  129.  mcv12 = MODE rac12 thermique CONVECTION ;
  130.  h12 = 0.004 /jeu ;
  131.  ma12 = MATE mcv12 'H' h12 ;
  132.  
  133.  
  134. *****************ASSEMBLAGE DES MATÉRIAUX ET DES MODÈLES****************
  135. *CALCUL source + convection face a face + rayo. ext.
  136.  
  137. MODU1 = MCD1 et MCD2 et MOHEX et mcv12 ;
  138. MATU1 = MAT1 et MAT2 et MAHEX et ma12;
  139.  
  140. ********************CRÉATION DE LA TABLE POUR PASAPAS*******************
  141. TAPAS = TABLE ;
  142. TAPAS.CELSIUS = FAUX ;
  143. TAPAS.CRITERE = 1E-4 ;
  144. TAPAS.MODELE = MODU1 ;
  145. TAPAS.CARACTERISTIQUES = MATU1 ;
  146. TAPAS.TEMPERATURES = TABLE ;
  147. TAPAS.TEMPERATURES . 0 = TEM0 ;
  148. TAPAS.CHARGEMENT = CHAT ;
  149. TAPAS.PROCEDURE_THERMIQUE = DUPONT  ;
  150. *TAPAS.PROCEDURE_THERMIQUE = NONLINEAIRE  ;
  151. *TAPAS.RELAXATION_THETA = 0.6 ;
  152. TAPAS.TEMPS_CALCULES = PTPS ;
  153. TAPAS.TEMPS_SAUVES = PTPSS ;
  154.  
  155.  
  156. ************************************************************************
  157. PASAPAS TAPAS ;
  158.  
  159. CTK1 = TAPAS.TEMPERATURES.((DIME PTPSS) - 1 )  ;
  160. CTC1 = CTK1 - TK ;
  161. titre  NOMCAL '-Isothermes   ' ;
  162. *TRAC CTC1 TOT ;
  163. * suivi de la temperature
  164. TEMP1 = PROG ;TEMP2 = PROG ;
  165. ITER = 0 ;
  166. NBT1 = (DIME PTPSS) ;
  167. REPETER BCL1  NBT1 ;
  168. TP1 = REDU (EXCO 'T' (TAPAS.'TEMPERATURES'.ITER ) 'T' ) arbre   ;
  169. T1 = MAXIMUM ( TP1 ) - TK ;
  170. TEMP1 = INSERER TEMP1 &BCL1 T1 ;
  171. TP2 = REDU (EXCO 'T' (TAPAS.'TEMPERATURES'.ITER ) 'T' ) alesage  ;
  172. T2 = MAXIMUM ( TP2 ) - TK ;
  173. TEMP2 = INSERER TEMP2 &BCL1 T2 ;
  174. ITER = ITER + 1;
  175. FIN BCL1 ;
  176.  
  177. TITRE ' EVOLUTION DES TEMPERATURES' ;
  178. EV1 = EVOL VERT MANU 'TEMPS (s)' PTPSS 'T (C)' TEMP1 ;
  179. EV2 = EVOL VERT MANU 'TEMPS (s)' PTPSS 'T (C)' TEMP2 ;
  180. TABDES = TABLE; TABDES.'TITRE' = TABLE ;
  181. TABDES.1 = 'MARQ TRIA' ;TABDES.'TITRE'. 1 = 'Arbre_Conv' ;
  182. TABDES.2 = 'MARQ CROI' ;TABDES.'TITRE'. 2 = 'Alesage_Conv' ;
  183. *DESS (EV1 ET EV2  ) TABDES 'MIMA' 'LEGE' ;
  184. * opti donn 5;
  185. ************************************************************************
  186. *  CALCUL 2 jeu en rayonnement pur
  187. ************************************************************************
  188. * RAYONNEMENT bilatérale (face a face)
  189. *-----------------------------------------------------------------------
  190. geor = diff ( rac12 chan ligne ) (CHAN LIGN (lcot1 et lcot2)) ;
  191. *list geor ;
  192. *trac geor ;
  193. mcv12r = MODE RAC12 THERMIQUE 'CONVECTION'  ;
  194.  
  195.  mora1 = mode lcot1 THERMIQUE 'RAYONNEMENT'
  196.     fac_a_fac  lcot1 lcot2 geor  mcv12r   CONS 'FACAFAC1';
  197.  mora2 = mode lcot2 THERMIQUE 'RAYONNEMENT'
  198.     fac_a_fac  lcot1 lcot2 geor  mcv12r CONS 'FACAFAC1';
  199.  
  200. MORA12 = mora1 et mora2 ;
  201.  
  202.  
  203.  
  204.  mar1 = MATE mora1 'EMIS' EMA ;
  205.  mar2 = MATE mora2 'EMIS' EMB ;
  206.  MAR12  =  mar1 et  mar2 ;
  207.  
  208. *****************ASSEMBLAGE DES MATÉRIAUX ET DES MODÈLES***************
  209.  
  210. *CALCUL source + rayonnement face a face + rayo. ext.
  211.  
  212. MODU2 = MCD1 et MCD2 et MOHEX  et mora12;
  213. MATU2 = MAT1 et MAT2 et MAHEX et MAR12 ;
  214. ******************* MODIFICATION DE LA TABLE POUR PASAPAS *************
  215. TAPAS = TABLE ;
  216. TAPAS.CELSIUS = FAUX ;
  217. TAPAS.CRITERE = 1E-4 ;
  218. TAPAS.MODELE = MODU2;
  219. TAPAS.CARACTERISTIQUES = MATU2  ;
  220. TAPAS.TEMPERATURES = TABLE ;
  221. TAPAS.TEMPERATURES . 0 = TEM0 ;
  222. TAPAS.CHARGEMENT = CHAT ;
  223. TAPAS.PROCEDURE_THERMIQUE = DUPONT  ;
  224. TAPAS.TEMPS_CALCULES = PTPS ;
  225. TAPAS.TEMPS_SAUVES = PTPSS ;
  226. ***********************************************************************
  227. PASAPAS TAPAS ;
  228. *opti donn 5;
  229. CTK1 = TAPAS.TEMPERATURES.((DIME PTPSS) - 1)  ;
  230. CTC1 = CTK1 - TK ;
  231. titre  NOMCAL '-Isothermes - '  ;
  232. *TRAC CTC1 TOT ;
  233. * suivi de la temperature
  234. TEMP1 = PROG ;TEMP2 = PROG ;
  235. ITER = 0 ;
  236. NBT1 = (DIME PTPSS) ;
  237. REPETER BCL1  NBT1 ;
  238. TP1 = REDU (EXCO 'T' (TAPAS.'TEMPERATURES'.ITER ) 'T' ) arbre   ;
  239. T1 = MAXIMUM ( TP1 ) - TK ;
  240. TEMP1 = INSERER TEMP1 &BCL1 T1 ;
  241. TP2 = REDU (EXCO 'T' (TAPAS.'TEMPERATURES'.ITER ) 'T' ) alesage  ;
  242. T2 = MAXIMUM ( TP2 ) - TK ;
  243. TEMP2 = INSERER TEMP2 &BCL1 T2 ;
  244. ITER = ITER + 1;
  245. FIN BCL1 ;
  246.  
  247. TITRE ' EVOLUTION DES TEMPERATURES' ;
  248. EV3 = EVOL BLEU MANU 'TEMPS (s)' PTPSS 'T (C)' TEMP1 ;
  249. EV4 = EVOL BLEU MANU 'TEMPS (s)' PTPSS 'T (C)' TEMP2 ;
  250.  
  251. TABDES.3 = 'MARQ TRIA' ;TABDES.'TITRE'. 3 = 'Arbre_Rayo' ;
  252. TABDES.4 = 'MARQ CROI' ;TABDES.'TITRE'. 4 = 'Alesage_Rayo' ;
  253. *DESS (EV1 ET EV2  et EV3 ET EV4 ) TABDES 'MIMA' 'LEGE' ;
  254. *opti donn 5;
  255. ************************************************************************
  256. *  CALCUL 3 jeu en convection et rayonnement
  257. ************************************************************************
  258. *****************ASSEMBLAGE DES MATÉRIAUX ET DES MODÈLES***************
  259. MODU3 = MODU1  et mora12;
  260. MATU3 = MATU1 et MAR12 ;
  261. ******************* MODIFICATION DE LA TABLE POUR PASAPAS *************
  262. TAPAS = TABLE ;
  263. TAPAS.CELSIUS = FAUX ;
  264. TAPAS.CRITERE = 1E-4 ;
  265. TAPAS.MODELE = MODU3 ;
  266. TAPAS.CARACTERISTIQUES = MATU3 ;
  267. TAPAS.TEMPERATURES = TABLE ;
  268. TAPAS.TEMPERATURES . 0 = TEM0 ;
  269. TAPAS.CHARGEMENT = CHAT ;
  270. TAPAS.PROCEDURE_THERMIQUE = DUPONT  ;
  271. TAPAS.TEMPS_CALCULES = PTPS ;
  272. TAPAS.TEMPS_SAUVES = PTPSS ;
  273. TAPAS.RAYONNEMENT = TABLE ;
  274. ***********************************************************************
  275. PASAPAS TAPAS ;
  276.  
  277. CTK1 = TAPAS.TEMPERATURES.((DIME PTPSS) - 1)  ;
  278. CTC1 = CTK1 - TK ;
  279. titre  NOMCAL '-Isothermes -  '  ;
  280. *TRAC CTC1 TOT ;
  281. * suivi de la temperature
  282. TEMP1 = PROG ;TEMP2 = PROG ;
  283. ITER = 0 ;
  284. NBT1 = (DIME PTPSS) ;
  285. REPETER BCL1  NBT1 ;
  286. TP1 = REDU (EXCO 'T' (TAPAS.'TEMPERATURES'.ITER ) 'T' ) arbre   ;
  287. T1 = MAXIMUM ( TP1 ) - TK ;
  288. TEMP1 = INSERER TEMP1 &BCL1 T1 ;
  289. TP2 = REDU (EXCO 'T' (TAPAS.'TEMPERATURES'.ITER ) 'T' ) alesage  ;
  290. T2 = MAXIMUM ( TP2 ) - TK ;
  291. TEMP2 = INSERER TEMP2 &BCL1 T2 ;
  292. ITER = ITER + 1;
  293. FIN BCL1 ;
  294. TITRE ' EVOLUTION DES TEMPERATURES' ;
  295. EV5 = EVOL ROUG MANU 'TEMPS (s)' PTPSS 'T (C)' TEMP1 ;
  296. EV6 = EVOL ROUG MANU 'TEMPS (s)' PTPSS 'T (C)' TEMP2 ;
  297. TABDES.5 = 'MARQ TRIA' ;TABDES.'TITRE'. 5 = 'Arbre_Conv&Rayo' ;
  298. TABDES.6 = 'MARQ CROI' ;TABDES.'TITRE'. 6 = 'Alesage_Conv&Rayo' ;
  299. si ( ega graph 'O');
  300. DESS (EV1 ET EV2  et EV3 ET EV4 et EV5 ET EV6) TABDES 'MIMA' 'LEGE' ;
  301. finsi;
  302. aa1 = extr ev1 ordo;aa1 = mini aa1 ;er1= abs(aa1 - 499.07);
  303. aa2 = extr ev2 ordo;aa2 = mini aa2 ;er2= abs(aa2 - 496.77);
  304. aa3= extr ev3 ordo; aa3 = mini aa3 ;er3= abs(aa3 - 499.38);
  305. aa4= extr ev4 ordo; aa4 = mini aa4 ;er4= abs(aa4 - 496.37);
  306. aa5= extr ev5 ordo; aa5 = mini aa5 ;er5= abs(aa5 - 498.83);
  307. aa6= extr ev6 ordo; aa6 = mini aa6 ;er6= abs(aa6 - 497.08);
  308.  
  309.  
  310. mess aa1 aa2 aa3  aa4  aa5    aa6 ;
  311. mess er1 er2 er3 er4 er5 er6 ;
  312. err= er1 + er2 + er3 + er4 + er5 + er6;
  313. list err;
  314. si ( err > 5.e-2) ; erreur 5; finsi;
  315.  
  316.  
  317. ************************************************************************
  318. *                             FIN DU FICHIER                           *
  319. ************************************************************************
  320. FIN ;
  321.  
  322.  
  323.  
  324.  
  325.  
  326.  
  327.  
  328.  
  329.  
  330.  
  331.  
  332.  
  333.  
  334.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales