Télécharger la plaquette Cast3M


fr en

Télécharger faceaface.dgibi

Retour à la liste

Numérotation des lignes : 

  1. * fichier : faceaface.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4.  
  5. ************************************************************************
  6. *......../........./........./........./........./........./........./72
  7. * test de cacul FACE a FACE avec PASAPAS
  8. * Echange thermique entre deux faces proches (L/e>>10) ,
  9. * en convection, en rayonnement
  10. * et mixte rayonnement plus convection
  11. *                                          Philippe YALA le 14/12/09
  12. ************************************************************************
  13. OPTI DIME 2 MODE AXIS ELEM QUA4 ;
  14. ************************************************************************
  15. * CALCUL EN GEOMETRIE 2D
  16. * deux cylindres coaxiaux avec convection externe
  17. * 1 calcul avec CONV dans le jeu ;  H=Cd_Air/Ep
  18. * 2 calcul avec RAYO dans le jeu
  19. * 3 calcul complet avec CONV et RAYO
  20. ************************************************************************
  21. *DONNEES GEOMETRIQUES
  22. * rayon arbre
  23. rarbre = 10.e-3 ;
  24. * jeu type H7 g6 ; soit en micron : +15/0  -5/-14
  25. jeumin = 0. + 5.e-6 ;
  26. jeumax = 15.e-6 + 14.e-6 ;
  27.  graph= mot 'N';
  28. jeu = jeumax ;
  29. * ou jeu = jeumin ;
  30.  
  31. * epaisseur alesage
  32. epal = 5.e-3 ;
  33. * hauteur
  34. haut = 5.e-3 ;
  35. ************************************************************************
  36. * MAILLAGE presque sans discretisation du jeu ( noeud double)
  37. P0 = 0. 0. ;
  38. P1 = 0. haut ;
  39. laxe = P0 droit P1 DINI 0.002 DFIN 0.001 ;
  40. arbre = (laxe trans (rarbre 0. ) DINI 0.002 DFIN 0.001 ) coul vert ;
  41. lor1 lhaut lcot1 lbas = cote arbre ;
  42. EPS = 1.e-5 ;
  43. * Remarque ne fonctionne pas avec EPS=0. pour RAYO
  44. lcot2 = lcot1 plus ( EPS 0. ) ;
  45. alesage = ( lcot2 trans ( epal 0. ) DINI 0.001 DFIN 0.002 ) coul rouge ;
  46. lor2 lhaut2 lcotext lbas2 = cote alesage ;
  47. tot  = arbre et alesage ;
  48. *trac tot ;
  49. ************************************************************************
  50. *DONNEES THERMIQUES
  52. MESS 'DONNEES THERMIQUES';
  53. TK = 273.15 ;MESS 'Zero °C' TK ;
  54. EMA = 0.8  ;MESS 'Emissivité ARBRE' EMA ;
  55. EMB = 0.9  ;MESS 'Emissivité ALESAGE cote interne' EMB ;
  56. EMC = 1.0 ;MESS 'Emissivité ALESAGE cote externe ' EMC ;
  57. TAMB = 30.0 ;MESS 'Température ambiance' TAMB '°C' ;
  58. TINI = 500.0 ;MESS 'Température initiale' TINI '°C' ;
  59. TAMB = TAMB + TK ; TINI = TINI +TK ;
  60.  
  61. ************************************************************************
  62. *MODELISISATION THERMIQUES
  63. *conduction
  64. MCD1  = MODE ARBRE THERMIQUE ISOTROPE ;
  65. MCD2  = MODE ALESAGE THERMIQUE ISOTROPE ;
  66. MAT1  = MATE MCD1  'K'  15.0 'C'  500.0  'RHO' 7800.0   ;
  67. MAT2  = MATE MCD2  'K'  132. 'C'  945.0  'RHO' 2670.0  ;
  68. ************************************************************************
  69. * convection extérieure
  70. MOHEX = MODE lcotext 'THERMIQUE'  'CONVECTION' ;
  71. MAHEX = MATE MOHEX 'H' EMC ;
  72. TCHA = PROG 0.   1.e10  ;
  73. PINC = PROG 1. 1.  ;
  74. MEVOLTE = EVOL 'MANU' 'TEMP' TCHA 'AMP' PINC ;
  75. CH_TE = 'MANU' 'CHPO' lcotext 1 'T' TAMB ;
  76. CHAT = CHAR 'TECO' CH_TE MEVOLTE ;
  77. ************************************************************************
  78. * initialisation en temperature
  79. TEM0 = MANU CHPO TOT  1 T TINI ;
  80. ************************************************************************
  81. * Temps calculés
  82. PTPS1 = prog 0. 0.01 0.02 0.05  0.1 0.2  0.5 1. 2. 4. 6. pas 2. 100. ;
  83. PTPS2 = prog  20. pas 5.  50. pas 10.  100. pas 20. 600. ;
  84. PTPS = PTPS1   ;
  85. *ptps= prog 0. 0.01 0.02 0.05 ;
  86. * Temps sauvés
  87. PTPSS = prog  0. pas 4. 100. ;
  88. ************************************************************************
  89. * Convection bilatérale (face a face)
  90. *-------------------------------
  91.  rac12 = RACC 1e-4 lcot1 lcot2 ;
  92. * list rac12 ;
  93. * trac rac12 ;
  94.  mcv12 = MODE rac12 thermique CONVECTION ;
  95.  h12 = 0.004 /jeu ;
  96.  ma12 = MATE mcv12 'H' h12 ;
  97.  
  98.  
  99. *****************ASSEMBLAGE DES MATÉRIAUX ET DES MODÈLES****************
  100. *CALCUL source + convection face a face + rayo. ext.
  101.  
  102. MODU1 = MCD1 et MCD2 et MOHEX et mcv12 ;
  103. MATU1 = MAT1 et MAT2 et MAHEX et ma12;
  104.  
  105. ********************CRÉATION DE LA TABLE POUR PASAPAS*******************
  106. TAPAS = TABLE ;
  107. TAPAS.CELSIUS = FAUX ;
  108. TAPAS.CRITERE = 1E-4 ;
  109. TAPAS.MODELE = MODU1 ;
  110. TAPAS.CARACTERISTIQUES = MATU1 ;
  111. TAPAS.TEMPERATURES = TABLE ;
  112. TAPAS.TEMPERATURES . 0 = TEM0 ;
  113. TAPAS.CHARGEMENT = CHAT ;
  114. TAPAS.PROCEDURE_THERMIQUE = DUPONT  ;
  115. *TAPAS.PROCEDURE_THERMIQUE = NONLINEAIRE  ;
  116. *TAPAS.RELAXATION_THETA = 0.6 ;
  117. TAPAS.TEMPS_CALCULES = PTPS ;
  118. TAPAS.TEMPS_SAUVES = PTPSS ;
  119.  
  120.  
  121. ************************************************************************
  122. PASAPAS TAPAS ;
  123.  
  124. CTK1 = TAPAS.TEMPERATURES.((DIME PTPSS) - 1 )  ;
  125. CTC1 = CTK1 - TK ;
  126. titre  NOMCAL '-Isothermes   ' ;
  127. *TRAC CTC1 TOT ;
  128. * suivi de la temperature
  129. TEMP1 = PROG ;TEMP2 = PROG ;
  130. ITER = 0 ;
  131. NBT1 = (DIME PTPSS) ;
  132. REPETER BCL1  NBT1 ;
  133. TP1 = REDU (EXCO 'T' (TAPAS.'TEMPERATURES'.ITER ) 'T' ) arbre   ;
  134. T1 = MAXIMUM ( TP1 ) - TK ;
  135. TEMP1 = INSERER TEMP1 &BCL1 T1 ;
  136. TP2 = REDU (EXCO 'T' (TAPAS.'TEMPERATURES'.ITER ) 'T' ) alesage  ;
  137. T2 = MAXIMUM ( TP2 ) - TK ;
  138. TEMP2 = INSERER TEMP2 &BCL1 T2 ;
  139. ITER = ITER + 1;
  140. FIN BCL1 ;
  141.  
  142. TITRE ' EVOLUTION DES TEMPERATURES' ;
  143. EV1 = EVOL VERT MANU 'TEMPS (s)' PTPSS 'T (C)' TEMP1 ;
  144. EV2 = EVOL VERT MANU 'TEMPS (s)' PTPSS 'T (C)' TEMP2 ;
  145. TABDES = TABLE; TABDES.'TITRE' = TABLE ;
  146. TABDES.1 = 'MARQ TRIA' ;TABDES.'TITRE'. 1 = 'Arbre_Conv' ;
  147. TABDES.2 = 'MARQ CROI' ;TABDES.'TITRE'. 2 = 'Alesage_Conv' ;
  148. *DESS (EV1 ET EV2  ) TABDES 'MIMA' 'LEGE' ;
  149. * opti donn 5;
  150. ************************************************************************
  151. *  CALCUL 2 jeu en rayonnement pur
  152. ************************************************************************
  153. * RAYONNEMENT bilatérale (face a face)
  154. *-----------------------------------------------------------------------
  155. geor = diff ( rac12 chan ligne )  (lcot1 et lcot2) ;
  156. *list geor ;
  157. *trac geor ;
  158. mcv12r = MODE RAC12 THERMIQUE 'CONVECTION'  ;
  159.  
  160.  mora1 = mode lcot1 THERMIQUE 'RAYONNEMENT'
  161.     fac_a_fac  lcot1 lcot2 geor  mcv12r   CONS 'FACAFAC1';
  162.  mora2 = mode lcot2 THERMIQUE 'RAYONNEMENT'
  163.     fac_a_fac  lcot1 lcot2 geor  mcv12r CONS 'FACAFAC1';
  164.  
  165. MORA12 = mora1 et mora2 ;
  166.  
  167.  
  168.  
  169.  mar1 = MATE mora1 'EMIS' EMA ;
  170.  mar2 = MATE mora2 'EMIS' EMB ;
  171.  MAR12  =  mar1 et  mar2 ;
  172.  
  173. *****************ASSEMBLAGE DES MATÉRIAUX ET DES MODÈLES***************
  174.  
  175. *CALCUL source + rayonnement face a face + rayo. ext.
  176.  
  177. MODU2 = MCD1 et MCD2 et MOHEX  et mora12;
  178. MATU2 = MAT1 et MAT2 et MAHEX et MAR12 ;
  179. ******************* MODIFICATION DE LA TABLE POUR PASAPAS *************
  180. TAPAS = TABLE ;
  181. TAPAS.CELSIUS = FAUX ;
  182. TAPAS.CRITERE = 1E-4 ;
  183. TAPAS.MODELE = MODU2;
  184. TAPAS.CARACTERISTIQUES = MATU2  ;
  185. TAPAS.TEMPERATURES = TABLE ;
  186. TAPAS.TEMPERATURES . 0 = TEM0 ;
  187. TAPAS.CHARGEMENT = CHAT ;
  188. TAPAS.PROCEDURE_THERMIQUE = DUPONT  ;
  189. TAPAS.TEMPS_CALCULES = PTPS ;
  190. TAPAS.TEMPS_SAUVES = PTPSS ;
  191. ***********************************************************************
  192. PASAPAS TAPAS ;
  193. *opti donn 5;
  194. CTK1 = TAPAS.TEMPERATURES.((DIME PTPSS) - 1)  ;
  195. CTC1 = CTK1 - TK ;
  196. titre  NOMCAL '-Isothermes - '  ;
  197. *TRAC CTC1 TOT ;
  198. * suivi de la temperature
  199. TEMP1 = PROG ;TEMP2 = PROG ;
  200. ITER = 0 ;
  201. NBT1 = (DIME PTPSS) ;
  202. REPETER BCL1  NBT1 ;
  203. TP1 = REDU (EXCO 'T' (TAPAS.'TEMPERATURES'.ITER ) 'T' ) arbre   ;
  204. T1 = MAXIMUM ( TP1 ) - TK ;
  205. TEMP1 = INSERER TEMP1 &BCL1 T1 ;
  206. TP2 = REDU (EXCO 'T' (TAPAS.'TEMPERATURES'.ITER ) 'T' ) alesage  ;
  207. T2 = MAXIMUM ( TP2 ) - TK ;
  208. TEMP2 = INSERER TEMP2 &BCL1 T2 ;
  209. ITER = ITER + 1;
  210. FIN BCL1 ;
  211.  
  212. TITRE ' EVOLUTION DES TEMPERATURES' ;
  213. EV3 = EVOL BLEU MANU 'TEMPS (s)' PTPSS 'T (C)' TEMP1 ;
  214. EV4 = EVOL BLEU MANU 'TEMPS (s)' PTPSS 'T (C)' TEMP2 ;
  215.  
  216. TABDES.3 = 'MARQ TRIA' ;TABDES.'TITRE'. 3 = 'Arbre_Rayo' ;
  217. TABDES.4 = 'MARQ CROI' ;TABDES.'TITRE'. 4 = 'Alesage_Rayo' ;
  218. *DESS (EV1 ET EV2  et EV3 ET EV4 ) TABDES 'MIMA' 'LEGE' ;
  219. *opti donn 5;
  220. ************************************************************************
  221. *  CALCUL 3 jeu en convection et rayonnement
  222. ************************************************************************
  223. *****************ASSEMBLAGE DES MATÉRIAUX ET DES MODÈLES***************
  224. MODU3 = MODU1  et mora12;
  225. MATU3 = MATU1 et MAR12 ;
  226. ******************* MODIFICATION DE LA TABLE POUR PASAPAS *************
  227. TAPAS = TABLE ;
  228. TAPAS.CELSIUS = FAUX ;
  229. TAPAS.CRITERE = 1E-4 ;
  230. TAPAS.MODELE = MODU3 ;
  231. TAPAS.CARACTERISTIQUES = MATU3 ;
  232. TAPAS.TEMPERATURES = TABLE ;
  233. TAPAS.TEMPERATURES . 0 = TEM0 ;
  234. TAPAS.CHARGEMENT = CHAT ;
  235. TAPAS.PROCEDURE_THERMIQUE = DUPONT  ;
  236. TAPAS.TEMPS_CALCULES = PTPS ;
  237. TAPAS.TEMPS_SAUVES = PTPSS ;
  238. TAPAS.RAYONNEMENT = TABLE ;
  239. ***********************************************************************
  240. PASAPAS TAPAS ;
  241.  
  242. CTK1 = TAPAS.TEMPERATURES.((DIME PTPSS) - 1)  ;
  243. CTC1 = CTK1 - TK ;
  244. titre  NOMCAL '-Isothermes -  '  ;
  245. *TRAC CTC1 TOT ;
  246. * suivi de la temperature
  247. TEMP1 = PROG ;TEMP2 = PROG ;
  248. ITER = 0 ;
  249. NBT1 = (DIME PTPSS) ;
  250. REPETER BCL1  NBT1 ;
  251. TP1 = REDU (EXCO 'T' (TAPAS.'TEMPERATURES'.ITER ) 'T' ) arbre   ;
  252. T1 = MAXIMUM ( TP1 ) - TK ;
  253. TEMP1 = INSERER TEMP1 &BCL1 T1 ;
  254. TP2 = REDU (EXCO 'T' (TAPAS.'TEMPERATURES'.ITER ) 'T' ) alesage  ;
  255. T2 = MAXIMUM ( TP2 ) - TK ;
  256. TEMP2 = INSERER TEMP2 &BCL1 T2 ;
  257. ITER = ITER + 1;
  258. FIN BCL1 ;
  259. TITRE ' EVOLUTION DES TEMPERATURES' ;
  260. EV5 = EVOL ROUG MANU 'TEMPS (s)' PTPSS 'T (C)' TEMP1 ;
  261. EV6 = EVOL ROUG MANU 'TEMPS (s)' PTPSS 'T (C)' TEMP2 ;
  262. TABDES.5 = 'MARQ TRIA' ;TABDES.'TITRE'. 5 = 'Arbre_Conv&Rayo' ;
  263. TABDES.6 = 'MARQ CROI' ;TABDES.'TITRE'. 6 = 'Alesage_Conv&Rayo' ;
  264. si ( ega graph 'O');
  265. DESS (EV1 ET EV2  et EV3 ET EV4 et EV5 ET EV6) TABDES 'MIMA' 'LEGE' ;
  266. finsi;
  267. aa1 = extr ev1 ordo;aa1 = mini aa1 ;er1= abs(aa1 - 499.07);
  268. aa2 = extr ev2 ordo;aa2 = mini aa2 ;er2= abs(aa2 - 496.77);
  269. aa3= extr ev3 ordo; aa3 = mini aa3 ;er3= abs(aa3 - 499.38);
  270. aa4= extr ev4 ordo; aa4 = mini aa4 ;er4= abs(aa4 - 496.37);
  271. aa5= extr ev5 ordo; aa5 = mini aa5 ;er5= abs(aa5 - 498.83);
  272. aa6= extr ev6 ordo; aa6 = mini aa6 ;er6= abs(aa6 - 497.08);
  273.  
  274.  
  275. mess aa1 aa2 aa3  aa4  aa5    aa6 ;
  276. mess er1 er2 er3 er4 er5 er6 ;
  277. err= er1 + er2 + er3 + er4 + er5 + er6;
  278. list err;
  279. si ( err > 5.e-2) ; erreur 5; finsi;
  280.  
  281.  
  282. ************************************************************************
  283. *                             FIN DU FICHIER                           *
  284. ************************************************************************
  285. FIN ;
  286.  
  287.  
  288.  
  289.  
  290.  
  291.  
  292.  
  293.  
  294.  
  295.  
  296.  
  297.  
  298.  
  299.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales