Exemples de jeux de données Cast3M

* fichier : contact-diapason.dgibi
************************************************************************
************************************************************************
* Modelisation du contact entre les lames d'un diapason en imposant une 
* condition de deplacement faible.
************************************************************************
GRAPH = FAUX ;
*
OPTI DIME 2 ELEM QUA8 MODE PLAN DEFO ;
*
H = 10.E-3 ;
R = 2.E-3 ;
L = 2.*R ;
E = 1.E-3 ;
P = 5.E-3 ;
*
OPTI DENS 0.2E-3 ;
*
P0 = 0. H ;
P1 = 0. 0. ;
P2 = P1 'PLUS' (R  0.) ;
P3 = P2 'MOIN' (0. R ) ;
P4 = P1 'PLUS' (L  0.) ;
P5 = P0 'PLUS' (L  0.) ;
*
L01 = 'DROI' P0 P1 ;
L13 = 'CERC' P1 P2 P3 ;
L34 = 'CERC' P3 P2 P4 ;
L45 = 'DROI' P4 P5 ;
LIN = L01 'ET' L13 'ET' L34 'ET' L45 ;
*
PA = P0 'MOIN' (E  0.) ;
PB = PA 'MOIN' (0. H ) ;
PC = P2 'MOIN' (0. (E+R)) ;
PD = P4 'PLUS' (E  0.) ;
PE = P5 'PLUS' (E  0.) ;
*
LAB = 'DROI' PA PB ;
LBC = 'CERC' ('NBEL' L13) PB P2 PC ;
LCD = 'CERC' ('NBEL' L34) PC P2 PD ;
LDE = 'DROI' PD PE ;
LEX = LAB 'ET' LBC 'ET' LCD 'ET' LDE ;
*
S1 = 'REGL' LIN LEX ;
*
ENV1 = 'CONT' S1 ;
PTSZ = ('COOR' 1 ENV1) 'POIN' 'EGINFE' ('COOR' 1 P1) ;
PTSZ = ('COOR' 1 PTSZ) 'POIN' 'EGSUPE' ('COOR' 1 P1) ;
SUR1 = ENV1 'ELEM' 'APPUYE' 'STRICTEMENT'  PTSZ ;
SUR1 = 'INVE' SUR1 ; 
*
PTSZ = ('COOR' 1 ENV1) 'POIN' 'EGINFE' ('COOR' 1 P5) ;
PTSZ = ('COOR' 1 PTSZ) 'POIN' 'EGSUPE' ('COOR' 1 P5) ;
SUR2 = ENV1 'ELEM' 'APPUYE' 'STRICTEMENT'  PTSZ ;
SUR2 = 'INVE' SUR2 ; 
*
PTSB = ('COOR' 1 ENV1) 'POIN' 'MINI' ;
PTSD = ('COOR' 1 ENV1) 'POIN' 'MAXI' ;
PTSD = ('COOR' 2 PTSD) 'POIN' 'EGSUPE' (0.6*H) ;
*
MOD1 = MODE S1 MECANIQUE ELASTIQUE ;
MAT1 = MATE MOD1 YOUN 150.E9 NU 0.3 RHO 1. ;
*
BL1 = 'BLOQ' 'DEPL' PTSB ;
*
EV1 = 'EVOL' 'MANU' ('PROG' 0. 1.) ('PROG' 0. 1.) ;
*
ELD = ENV1 'ELEM' 'APPUYE' 'STRICTEMENT' PTSD ;
RRX = 'BLOQ' 'FAIB' 'UX' ELD ;
DPX = 'DEPI' RRX -4.5E-3 ;
CDE = 'CHAR' 'DIMP' DPX EV1 ;
*
YY = 'COOR' 2 ELD ;
DY = ('MAXI' YY) '-' ('MINI' YY) ;
PMIL = ELD 'POIN' 'PROC' (PE MOIN (0. (0.5*DY)));
YMI2 = ('MINI' YY) - 1.E-6 ;
PTSZ = (COOR 2 SUR1) POIN EGSUPE YMI2 ;
LIG1 = SUR1 ELEM APPUYE STRICTEMENT PTSZ ;
PTSZ = (COOR 2 SUR2) POIN EGSUPE YMI2 ;
LIG2 = SUR2 ELEM APPUYE STRICTEMENT PTSZ ;
LIG2 = 'INVE' LIG2 ;
*
MODC = 'MODE' SUR1 'CONTACT' SUR2 ;
*
PTS = (COOR 2 ENV1) POIN MAXI ;
ELS = ENV1 ELEM APPUYE STRICTEMENT PTS ;
PT1 = (COOR 1 ELS) POIN EGSUPE 0.;
EL1 = ELS ELEM APPUYE STRICTEMENT PT1 ;
EL2 = DIFF ELS EL1 ;
*
CH1 = MANU CHPO EL1 1 'UY' 1. ;
CH2 = MANU CHPO EL2 1 'UY' 1. ;
BL2 = RELA CH1 ;
BL3 = RELA CH2 ;
*
TAB1                       = 'TABLE'; 
TAB1.'MODELE'              = MOD1 'ET' MODC ;
TAB1.'CARACTERISTIQUES'    = MAT1 ;
TAB1.'BLOCAGES_MECANIQUES' = BL1 'ET' BL2 'ET' BL3 'ET' RRX ;
TAB1.'CHARGEMENT'          = CDE ;
TAB1.'TEMPS_CALCULES'      = 'PROG' 0. PAS 0.01 0.9;
*
PASAPAS TAB1 ;
*
DEP  = TAB1.'DEPLACEMENTS' ; 
TPS  = TAB1.'TEMPS' ;
NBDP = 'DIME' DEP - 1;
'SI' GRAPH ;
  REA  = TAB1.'REACTIONS' ; 
  TPS  = TAB1.'TEMPS' ;
  LDEP = PROG 0 ; 
  LREA = PROG 0 ; 
  CONF0 = FORM ;
  'REPE' B NBDP ; 
    TITZ = 'CHAI' 'Deformee instant:'(TPS. &B)' ('&B' / 'NBDP')';
    'FORM' (DEP. &B) ;
    TRAC S1 'TITR' TITZ ;
    'FORM' CONF0 ;
    XDEP = TIRE CDE (TPS. &B) ; 
    LDEP = LDEP ET (EXTR (EXTR XDEP VALE) 1) ; 
    XREA = REAC (DEP . &B) RRX ; 
    LREA = LREA ET (EXTR (EXTR (EXCO (RESU XREA) FX FX) VALE) 1) ;
  'FIN' B; 
*
  EV0 = 'EVOL' 'TURQ' 'MANU' 'Deplacements' LDEP 'Reactions' LREA ;
  DESS EV0 'TITR' 'Reactions=f(depl)';
*
  SIGXX = 'EXCO' TAB1.'CONTRAINTES'. NBDP 'SMXX' 'SMXX' ;
  CHPXX = 'CHAN' 'CHPO' SIGXX MOD1 ;
  EVXX1 = 'EVOL' 'VERT' 'CHPO' LIG1 CHPXX ;
  EVXX2 = 'EVOL' 'ORAN' 'CHPO' LIG2 CHPXX ;
  DESS (EVXX1 'ET' EVXX2) 'TITR' 'SMXX' ;
'FINSI' ;
*
XVA0 = 'MAXI' 'ABS' ('EXCO' (DEP. NBDP '*' RRX) 'FLX') ;
XVA1 = 'ABS' ('EXTR' DEP. NBDP 'UX' PMIL) ;
XVA2 = 'MAXI' 'ABS' ('TIRE' CDE (TPS. NBDP)) ;
XERR = 'ABS' (XVA1 - XVA2) / XVA2 ;
'SI' (> XERR 0.05) ;
  'MESS' 'ERREUR SUR LA VALEUR DU DEPLACEMENT' ;
  ERREUR 5 ;
'FINSI' ;
'FIN' ;