Exemples de jeux de données Cast3M

* fichier : cneq_elem.dgibi
 
************************************************************************
*          Petit cas test pour l'opérateur CNEQ option 'ELEM'          *
*                                                                      *
* Cette option permet d'obtenir les forces équivalentes à une          *
* densité volumique d'efforts où le résultat est sous la forme d'un    *
* MCHAML aux noeuds du maillage                                        *
*                                                                      *
* On teste ici que ce MCHAML donne bien les memes forces nodales quand *
* on le transforme en CHPOINT avec sommation, c-a-d est-ce-que :       *
* CHAN 'CHPO' (CNEQ 'ELEM' mod f) mod  =   CNEQ mof d  ???             *
*                                                                      *
* L'exemple utilisé ici est un cas de forces centrifuges dans un       *
* cylindre d'acier en rotation                                         *
************************************************************************
 
 
 
*----------------- P A R M E T R E S   G E N E R A U X ----------------*
 
** Indicateur de tracé
itrac  = faux ;
** Paramètres géométriques
rint   = 0.1 ;
rext   = 0.6 ;
h      = 0.1 ;
** Vitesse de rotation du cylindre (radians / secondes)
omega  = 100. * 2. * pi ;
** Paramètres du matériau
yo     = 200.E9 ;
nu     = 0.3 ;
rho    = 7800. ;
** Paramètres du maillage
OPTI 'DENS' ((rext - rint) / 30.) ;
 
 
 
*------------------------ C A S   1 D   A X I -------------------------*
 
** Options de calcul
OPTI 'DIME' 1 'MODE' 'UNID' 'AXIS' 'ELEM' 'SEG2' ;
** Maillage
p1     = POIN rint ;
p2     = POIN rext ;
mail   = DROI p1 p2 ;
** Modèle et matériau
mo     = MODE mail 'MECANIQUE' ;
ma     = MATE mo 'YOUN' yo 'NU' nu ;
** Chargement (avec CNEQ défaut et CNES 'ELEM')
r      = COOR mail ;
w      = NOMC 'FR' (rho * omega * omega * r) ;
f1     = CNEQ mo w ;
f2     = CNEQ 'ELEM' mo w ;
f2n    = CHAN 'CHPO' mo f2 'SOMM' ;
SI itrac ;
  vec    = VECT f2n 'FORC' 'ROUG' ;
  TRAC vec mail 'TITR' 'Forces nodales imposees (1d axi)' ;
FINSI ;
** Calcul de l'écart entre les deux
err1a  = MAXI 'ABS' (f1 - f2n) ;
** Résolution du problème mécanique (calcul du déplacement)
ri     = RIGI mo ma ;
u      = RESO ri f2n ;
e1a    = EVOL 'ROUG' 'CHPO' u 'UR' mail ;
 
 
 
*------------------------ C A S   2 D   A X I -------------------------*
** Options de calcul
OPTI 'DIME' 2 'MODE' 'AXIS' 'ELEM' 'QUA4' ;
** Maillage
l1     = mail ;
mail   = l1 TRAN (0. h) ;
l2     = mail COTE 3 ;
con    = CONT mail ;
** Modèle et matériau
mo     = MODE mail 'MECANIQUE' ;
ma     = MATE mo 'YOUN' yo 'NU' nu ;
** Chargement (avec CNEQ défaut et CNES 'ELEM')
r z    = COOR mail ;
w      = (NOMC 'FR' (rho * omega * omega * r)) ET (NOMC 'FZ' (0. * z)) ;
f1     = CNEQ mo w ;
f2     = CNEQ 'ELEM' mo w ;
f2n    = CHAN 'CHPO' mo f2 'SOMM' ;
SI itrac ;
  vec    = VECT f2n 'FORC' 'VERT' ;
  TRAC vec con 'TITR' 'Forces nodales imposees (2d axi)' ;
FINSI ;
** Calcul de l'écart entre les deux
err2a  = MAXI 'ABS' (f1 - f2n) ;
** Résolution du problème mécanique (calcul du déplacement)
bl     = BLOQ 'UZ' (l1 ET l2) ;
ri     = RIGI mo ma ;
u      = RESO (ri ET bl) f2n ;
e2a    = EVOL 'VERT' 'CHPO' u 'UR' l1 ;
 
 
 
*----------------------------- C A S   3 D ----------------------------*
** Options de calcul
OPTI 'DIME' 3 'ELEM' 'CUB8' ;
** Maillage
s1     = l1 TRAN (0. 0. h) ;
mail   = s1 VOLU 'ROTA' 90. (0. 0. 0.) (0. 0. 1.) ;
s2     = mail FACE 2 ;
are    = ARET mail ;
** Modèle et matériau
mo     = MODE mail 'MECANIQUE' ;
ma     = MATE mo 'YOUN' yo 'NU' nu ;
** Chargement (avec CNEQ défaut et CNES 'ELEM')
x y z  = COOR mail ;
r      = ((x * x) + (y * y)) ** 0.5 ;
theta  = ATG y x CHAN 'ATTRIBUT' 'NATURE' 'DIFFUS' ;
w      = (NOMC 'FX' (rho * omega * omega * r * (COS theta))) ET
         (NOMC 'FY' (rho * omega * omega * r * (SIN theta))) ET
         (NOMC 'FZ' (0. * z)) ;
f1     = CNEQ mo w ;
f2     = CNEQ 'ELEM' mo w ;
f2n    = CHAN 'CHPO' mo f2 'SOMM' ;
SI itrac ;
  vec    = VECT f2n 'FORC' 'JAUN' ;
  TRAC vec are 'TITR' 'Forces nodales imposees (3d)' ;
FINSI ;
** Calcul de l'écart entre les deux
err3   = MAXI 'ABS' (f1 - f2n) ;
** Résolution du problème mécanique (calcul du déplacement)
pz1    = z POIN 'EGAL' 0. ;
pz2    = z POIN 'EGAL' h ;
bl     = (BLOQ 'UX' s2) ET (BLOQ 'UY' s1) ET (BLOQ 'UZ' (pz1 ET pz2)) ;
ri     = RIGI mo ma ;
u      = RESO (ri ET bl) f2n ;
e3     = EVOL 'JAUN' 'CHPO' u 'UX' l1 ;
 
 
 
*----------------------------- B I L A N  -----------------------------*
 
** Écart max entre les forces (CNEQ) et (CNEQ 'ELEM' + CHAN 'CHPO' 'SOMM')
err = MAXI 'ABS' (PROG err1a err2a err3) ;
MESS 'Ecart max. =' err ;
 
** Tracé des déplacements Ur dans l'épaisseur du cylindre
SI itrac ;
  tl = TABL ;
  tl . 1 = 'MARQ ROND NOLI' ;
  tl . 2 = 'MARQ CARR NOLI' ;
  tl . 3 = 'MARQ LOSA NOLI' ;
  tl . 'TITRE' = TABL ;
  tl . 'TITRE' . 1 = '1d axi' ;
  tl . 'TITRE' . 2 = '2d axi' ;
  tl . 'TITRE' . 3 = '3d' ;
  DESS (e1a ET e2a ET e3) 'LEGE' tl 'TITR' 'Deplacement radial dans l''epaisseur' ;
FINSI ;
 
** Test
SI (err > 1.E-12) ;
  ERRE 5 ;
FINSI ;
 
 
FIN ;