Télécharger la plaquette Cast3M


fr en

Télécharger beton_thm4.dgibi

Retour à la liste

Numérotation des lignes : 

  1. * fichier : beton_thm4.dgibi
  2. *---------------------------------------------------------------------*
  3. *                                                                     *
  4. *             Cas-test du modele THERMOHYDRIQUE BETON_THM             *
  5. *                                                                     *
  6. * Description : Simulation d'un essai de sechage isotherme d'un       *
  7. *               beton durci (avancement de l'hydratation = 1).        *
  8. *                                                                     *
  9. *               Comparaison de la solution numerique avec une         *
  10. *               solution numerique de reference                       *
  11. *                                                                     *
  12. *---------------------------------------------------------------------*
  13.  
  14.  
  15. OPTI 'ECHO' 0;
  16.  
  17. * Traces : ITRAC1 = VRAI ;
  18. ITRAC1   = FAUX ;
  19.  
  20. ******************** Conditions Initiales **********************
  21. TK_0 = 20. + 273.15;
  22. PG_0 = 101325.;
  23. HR_0 = 0.75;
  24. HY_i = 1.;
  25. ****************************************************************
  26.  
  27. ******************** Condizioni esterne ************************
  28. TK_ext = TK_0 ;
  29. PG_ext = 101325. ;
  30. HR_E = 0.50;
  31. ****************************************************************
  32.  
  33. ****************************************************************
  34. * DISCRETISATION                                         *******
  35. ****************************************************************
  36. OPTI 'DIME' 2 'MODE' 'PLAN' 'CONT' 'ELEM' 'QUA4';
  37.  
  38. *---------------------------------------------------------------------*
  39. * CONSTRUCTION DU MAILLAGE 
  40. * 2 zones
  41. * - mesh_i et mesh_s sont les zones avec le gaz seul
  42. * - mesh_p est la zone avec le milieu poreux
  43. *---------------------------------------------------------------------*
  44.  
  45. L1 = 0.20 ;
  46. H1 = L1/4.;
  47. *
  48. p1    =  0.   0. ;
  49. p2    =  L1   0. ;
  50. l12   =  DROI 80 p1  p2 ;
  51. MAIL1 =  L12 TRAN 1 (0. H1);
  52. CONT_EXT = COTE 2 MAIL1;
  53. *---------------------------------------------------------------------*
  54.  
  55.  
  56. *---------------------------------------------------------------------*
  57. * DISCRETIZATION TEMPORELLE 
  58. *---------------------------------------------------------------------*
  59. heure1  = 3600.;
  60. jour1   = 24 * heure1;
  61. *
  62. TFIN    = 360 * jour1;
  63. LTEMPS1 = PROG 0. 'PAS' (0.1 * heure1) jour1 'PAS' jour1 TFIN;
  64. LTSAUV  = PROG 0. 'PAS' jour1 TFIN;
  65. *---------------------------------------------------------------------* 
  66.  
  67.  
  68. *---------------------------------------------------------------------*
  69. * DATI MATERIALE (PARTE THC)
  70. *---------------------------------------------------------------------*
  71.  
  72. * MIX DATA
  73. cem  = 400.   ;
  74. aggr = 1806.  ;
  75. wc   = 0.45   ;
  76. sc   = 0.     ;
  77.  
  78. * HYDRATION PROCESS DATA (affinity. activation energy. hydration heat)
  79. AI   = 3.8    ;
  80. AP   = 218.   ;
  81. GAMP = 0.12   ;
  82. ALFA = 13.    ;
  83. EAR1 = 5000.  ;
  84. lat1 = 1.37e8 ;
  85.  
  86. * INTRINSIC PERMEABILITY
  87. KINT = 1.E-19 ;
  88.  
  89. * DESORPTION ISOTHERME MODEL PARAMETERS
  90. a1   =  20.E6 ;
  91. b1   =  2.    ;
  92. c1   =  1.5   ;
  93.  
  94. * THERMAL PARAMETERS
  95. CS   = 835.   ;
  96. KS   = 1.386    ;
  97.  
  98. * Coefficient de CONVECTION
  99. H_CONV = 0.0002;
  100. *---------------------------------------------------------------------*
  101.  
  102.  
  103. *---------------------------------------------------------------------*
  104. * DEFINIZIONE DEL MODELLO
  105. *---------------------------------------------------------------------*
  106. MODTHC  = MODE MAIL1 'THERMOHYDRIQUE' 'BETON_THM' 'CONS' 'BO';
  107. MOD_TOT = MODTHC;
  108. * Computing of stechiometric parameters with the Powers' model
  109. WINF GAM0 POR1 APOR = @POWERS cem aggr wc sc;
  110. MATTHC = MATE MODTHC 'CS'  CS    'KS'   KS   'GAM0' GAM0 'WINF' WINF
  111. 'VGA' a1   'VGB'  b1   'VGC' c1    'K1' KINT    'AK'   1.  'BK'   1.
  112. 'KLI1' 20000.  'AKLI'   1.  'BKLI'  30000. 'POR1' POR1 'APOR' APOR 
  113. 'AFF1' Ai  'AFF2' Ap   'AFF3' GAMP 'AFF4' ALFA 'EAR'  EAR1 'QLAT' lat1;
  114. MOD_TOT = MODTHC;
  115. MAT_TOT = MATTHC;
  116. *---------------------------------------------------------------------*
  117.  
  118.  
  119. **** Assegno le condizioni iniziali
  120. PC_0    = (-1.)*(8.314*TK_0*1000*(LOG(HR_0))/18.e-3);
  121. CI_TH  = MANU 'CHPO' MAIL1 3 'PG' PG_0 'PC' PC_0 'T' TK_0 ;
  122. CI_TOT = CI_TH;
  123. ****************************************************************
  124.  
  125.  
  126. ******************** V. C.L. et Chargements ********************
  127. PC_ext = (-1.)*(8.314*TK_ext*1000*(LOG HR_E)/18.e-3);
  128. *
  129. CLPG1    = BLOQ 'PG' CONT_EXT;
  130. CHPG1    = DEPI  CLPG1     1.;
  131. EVPG1    = EVOL 'MANU' 'TEMPS' (PROG 0. TFIN ) (PROG PG_ext PG_ext );
  132. CGPG1    = CHAR 'TIMP' CHPG1 EVPG1;
  133. *
  134. CLPC1    = BLOQ 'PC' CONT_EXT;
  135. CHPC1    = DEPI  CLPC1     1.;
  136. EVPC1    = EVOL 'MANU' 'TEMPS' (PROG 0. TFIN ) (PROG PC_ext PC_ext );
  137. CGPC1    = CHAR 'TIMP' CHPC1 EVPC1;
  138. *
  139. CLTK1    = BLOQ 'T' CONT_EXT;
  140. CHTK1    = DEPI  CLTK1     1.;
  141. EVTK1    = EVOL 'MANU' 'TEMPS' (PROG 0. TFIN ) (PROG TK_ext TK_ext );
  142. CGTK1    = CHAR 'TIMP' CHTK1 EVTK1;
  143.  
  144. CLT_TOT  = CLPG1 ET CLPC1 ET CLTK1;
  145. CGT_TOT  = CGPG1 ET CGTK1 ET CGPC1;
  146. ****************************************************************
  147.  
  148.  
  149. *---------------------------------------------------------------------*
  150. * RESOLUTION PASAPAS
  151. *---------------------------------------------------------------------*
  152. TAB0                         = TABL ;
  153. TAB0 . 'MODELE'              = MOD_TOT ;
  154. TAB0 . 'BLOCAGES_THERMIQUES' = CLT_TOT ;
  155. TAB0 . 'CARACTERISTIQUES'    = MAT_TOT ;
  156. TAB0 . 'CHARGEMENT'          = CGT_TOT ;
  157. TAB0 . 'TEMPS_CALCULES'      = LTEMPS1;
  158. TAB0 . 'TEMPS_SAUVES'        = LTSAUV;
  159. TAB0 . 'PROCEDURE_THERMIQUE' = 'NOLINEAIRE' ;
  160. TAB0 . 'RELAXATION_THETA'    = 0.50 ;
  161. TAB0 . 'MOVA'                = 'D' ;
  162. *---------------------------------------------------------------------*
  163. TAB0 . 'TEMPERATURES'        = TABL ;
  164. TAB0 . 'TEMPERATURES' . 0    = CI_TOT ;
  165. TAB0 . 'VARIABLES_THM'       = TABL ;
  166. TAB0 . 'VARIABLES_THM' . 0   = MANU 'CHML' MODTHC 'HYDR' HY_i;
  167. *---------------------------------------------------------------------*
  168. PASAPAS TAB0 ;
  169.  
  170.  
  171. * Calcul humidité relative (Loi de Clapeyron) et SW
  172. TAB0 . 'HR' = TABLE;
  173. TAB0 . 'SW' = TABLE;
  174. *
  175. VGA  = MANU 'CHPO' MAIL1 1 'SCAL' a1;
  176. VGB  = MANU 'CHPO' MAIL1 1 'SCAL' b1;
  177. VGC  = MANU 'CHPO' MAIL1 1 'SCAL' c1;
  178. VGHY = MANU 'CHPO' MAIL1 1 'SCAL' 0.1; 
  179. *
  180. N1 = 0;
  181. REPETER BOU_HR (DIME  TAB0 . 'TEMPERATURES' );
  182.    CHTKi = EXCO 'T'  TAB0 . 'TEMPERATURES' . N1;
  183.    CHPCi = EXCO 'PC' TAB0 . 'TEMPERATURES' . N1;
  184.    CHPGi = EXCO 'PG' TAB0 . 'TEMPERATURES' . N1;
  185.    HYDRi = (CHAN 'CHPO' TAB0 . 'VARIABLES_THM' . N1  MODTHC) NOMC 'SCAL';
  186.    CHPVSATi CHPGWSCi RHOGWi XX YY ZZ = @PVSAT CHPGi CHPCi CHTKi;
  187.    SWi = @SATURA CHPCi CHTKi HYDRi VGA VGB VGC VGHY;
  188.    HRi = CHPGWSCi * (CHPVSATi**-1);
  189.    TAB0 . 'HR' . N1 = HRi;
  190.    TAB0 . 'SW' . N1 = SWi;
  191.    N1 = N1 + 1;
  192. FIN BOU_HR;
  193.  
  194.  
  195. SCALA_HR = PROG HR_0 'PAS' ((HR_E - HR_0)/20)  HR_E;
  196.  
  197. SI ITRAC1;
  198.    TRAC TAB0. 'HR' . 0   MAIL1 SCALA_HR;
  199.    TRAC TAB0. 'HR' . 20  MAIL1 SCALA_HR;
  200.    TRAC TAB0. 'HR' . 40  MAIL1 SCALA_HR;
  201.    TRAC TAB0. 'HR' . 60  MAIL1 SCALA_HR;
  202. FINSI;
  203.  
  204. EVSW0  =  EVOL 'BLAN' 'CHPO'  TAB0.SW.0   'SCAL' L12;
  205. EVSW1  =  EVOL 'BLEU' 'CHPO'  TAB0.SW.120 'SCAL' L12;
  206. EVSW2  =  EVOL 'VERT' 'CHPO'  TAB0.SW.240 'SCAL' L12;
  207. EVSW3  =  EVOL 'ORAN' 'CHPO'  TAB0.SW.360 'SCAL' L12;
  208. *DESS (EVSW0 ET EVSW1 ET EVSW2 ET EVSW3);
  209.  
  210. EVHR0  =  EVOL 'BLAN' 'CHPO'  TAB0.HR.0   'SCAL' L12;
  211. EVHR1  =  EVOL 'BLEU' 'CHPO'  TAB0.HR.120 'SCAL' L12;
  212. EVHR2  =  EVOL 'VERT' 'CHPO'  TAB0.HR.240 'SCAL' L12;
  213. EVHR3  =  EVOL 'ORAN' 'CHPO'  TAB0.HR.360 'SCAL' L12;
  214. *DESS (EVHR0 ET EVHR1 ET EVHR2 ET EVHR3);
  215.  
  216.  
  217. *---------------------------------------------------------------------*
  218. * REFERENCE SOLUTIONS
  219. *---------------------------------------------------------------------*
  220. SPACE = PROG 0.0E+00 2.5E-02 5.0E-02 7.5E-02 1.0E-01 1.25E-01 1.5E-01 1.75E-01 2.E-01;
  221. HR1_REF = PROG 7.37128E-01 7.35911E-01 7.32082E-01 7.25020E-01 7.13437E-01 6.94636E-01 6.62605E-01 6.03318E-01 5.00000E-01;
  222. HR2_REF = PROG 7.12263E-01 7.10750E-01 7.06020E-01 6.97449E-01 6.83736E-01 6.62360E-01 6.28584E-01 5.75191E-01 5.00000E-01;
  223. HR3_REF = PROG 6.89242E-01 6.87603E-01 6.82509E-01 6.73343E-01 6.58907E-01 6.37111E-01 6.04751E-01 5.58633E-01 5.00000E-01;
  224.  
  225. EVHR1_REF = EVOL 'MANU' SPACE HR1_REF;
  226. EVHR2_REF = EVOL 'MANU' SPACE HR2_REF;
  227. EVHR3_REF = EVOL 'MANU' SPACE HR3_REF;
  228. *---------------------------------------------------------------------*
  229.  
  230.  
  231. *---------------------------------------------------------------------*
  232. * VISUALIZATION OF RESULTS
  233. *---------------------------------------------------------------------*
  234. TAB3     = TABLE ;
  235. *TAB3 . 1 = 'MOT' 'TIRR ';
  236. *TAB3 . 2 = 'MOT' 'MARQ CROI NOLI';
  237. *TAB3 . 3 = 'MOT' 'MARQ LOSA';
  238. *TAB3 . 4 = 'MOT' 'TIRR ';
  239. TAB3 . 5 = MOT 'MARQ LOSA NOLI';
  240. TAB3 . 6 = MOT 'MARQ LOSA NOLI';
  241. TAB3 . 7 = MOT 'MARQ LOSA NOLI ';
  242.  
  243. TAB3 . 'TITRE'     = TABLE ;
  244. TAB3 . 'TITRE' . 1 = MOT 'Initial';
  245. TAB3 . 'TITRE' . 2 = MOT '120 d (full model)' ;
  246. TAB3 . 'TITRE' . 3 = MOT '240 d (full model)' ;
  247. TAB3 . 'TITRE' . 4 = MOT '360 d (full model)' ;
  248. TAB3 . 'TITRE' . 5 = MOT '120 d (simpl. model)' ;
  249. TAB3 . 'TITRE' . 6 = MOT '240 d (simpl.  model)' ;
  250. TAB3 . 'TITRE' . 7 = MOT '360 d (simpl.  model)' ;
  251.  
  252. SI ITRAC1;
  253.    DESS (EVHR0 ET EVHR1 ET EVHR2 ET EVHR3 ET EVHR1_REF ET EVHR2_REF ET EVHR3_REF) 'LOGO' 'LEGE' TAB3 'TITX' 'X (m)'  'TITY' 'R.H. / SL (-)' ;
  254. FINSI;
  255. *---------------------------------------------------------------------*
  256.  
  257.  
  258. *---------------------------------------------------------------------*
  259. * COMPUTING OF NORMALIZED ERRORS
  260. *---------------------------------------------------------------------*
  261. NORM_1 = (MAXI HR1_REF) - (MINI HR1_REF); 
  262. NORM_2 = (MAXI HR2_REF) - (MINI HR2_REF); 
  263. NORM_3 = (MAXI HR3_REF) - (MINI HR3_REF); 
  264.  
  265. * Estraction of corresponding positions
  266. HR1_RED = PROG;
  267. HR2_RED = PROG;
  268. HR3_RED = PROG;
  269.  
  270. n0 = 1;
  271.  
  272. REPETER BOU_EXTR 9;
  273.   HR1_REDi = EXTR (EXTR EVHR1 ORDO) n0;
  274.   HR2_REDi = EXTR (EXTR EVHR2 ORDO) n0;
  275.   HR3_REDi = EXTR (EXTR EVHR3 ORDO) n0;
  276.   HR1_RED = HR1_RED ET (PROG HR1_REDi);
  277.   HR2_RED = HR2_RED ET (PROG HR2_REDi);
  278.   HR3_RED = HR3_RED ET (PROG HR3_REDi);
  279.   n0 = n0 + 10;
  280. FIN BOU_EXTR;
  281.  
  282. E_HR1 = (MAXI (ABS (HR1_REF - HR1_RED))) / NORM_1;  
  283. E_HR2 = (MAXI (ABS (HR2_REF - HR2_RED))) / NORM_2;  
  284. E_HR3 = (MAXI (ABS (HR3_REF - HR3_RED))) / NORM_3;  
  285.  
  286. ERR0   =  MAXI (PROG E_HR1 E_HR2 E_HR3) ;
  287. MESS ' ****** Ecart relatif max. solution de reference =' ERR0 ;
  288. *---------------------------------------------------------------------*
  289.  
  290.  
  291. SI (ERR0 '>' 2.E-2) ;
  292.   ERRE 5 ;
  293.   FIN ;
  294. SINO ;
  295.   SAUT 1 'LIGN' ;
  296.   MESS '------------------CAS-TEST BETON_THM4 REUSSI ! ------------------' ;
  297.   SAUT 1 'LIGN' ;
  298. FINS ;
  299.  
  300.  
  301.  
  302. FIN;
  303.  
  304.  
  305.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales