Télécharger la plaquette Cast3M


fr en

Télécharger beton_thm3.dgibi

Retour à la liste

Numérotation des lignes : 

  1. * fichier : beton_thm3.dgibi
  2. *---------------------------------------------------------------------*
  3. *                                                                     *
  4. *             Cas-test du modele THERMOHYDRIQUE BETON_THM             *
  5. *                                                                     *
  6. * Description : Beton au jeune age. Simulation d'un essai de          *
  7. *               calorimetrie non-adiabatique avec chargement          *
  8. *               au jeune-age (2 jours) pour verifier la bonne         *
  9. *               implementation du modele de fluage                    * 
  10. *                                                                     *
  11. *               Comparaison de la solution numerique avec une         *
  12. *               solution semi-analytique de reference                 *
  13. *                                                                     *
  14. *---------------------------------------------------------------------*
  15.  
  16.  
  17. OPTI 'ECHO' 0 ;
  18.  
  19. * Traces : ITRAC1 = VRAI ;
  20. ITRAC1   = FAUX ;
  21.  
  22. *---------------------------------------------------------------------*
  23. * CONSTANT PHYSICAL PARAMEMTERS
  24. *---------------------------------------------------------------------*
  25. RGP1     = 8.3145 ;                                            
  26. MMGW1    = 18.0153E-3 ;
  27. RHOW0    = 1000. ;
  28. *---------------------------------------------------------------------*
  29.  
  30.  
  31. *---------------------------------------------------------------------*
  32. * TIME DISCRETIZATION
  33. *---------------------------------------------------------------------*
  34. hours1 = 3600.;
  35. day1   = 86400.;
  36. temps1 =  2 * day1;
  37. t_fin  = 10 * day1;
  38. LT_CALC = PROG 0. 'PAS' 60. temps1 'PAS' 600. t_fin;
  39. LT_SAUV = PROG 0. 'PAS' 600. t_fin; 
  40. *---------------------------------------------------------------------*
  41.  
  42.  
  43. *---------------------------------------------------------------------*
  44. * FE MESH
  45. *---------------------------------------------------------------------*
  46. OPTI 'DIME' 2 'ELEM' 'QUA4' 'MODE' 'PLAN' 'CONT';
  47. * Geometry
  48. L1    = 0.10      ;
  49. P1    = 0.  0.; 
  50. P2    = L1  0.;
  51. L12   = DROI 10 P1 P2;
  52. MAIL1 = L12 TRAN 10 (0. 0.10);
  53. CONTT = COTE 2 MAIL1;
  54. CONTH = COTE 2 MAIL1;
  55. *---------------------------------------------------------------------*
  56.  
  57.  
  58. *---------------------------------------------------------------------*
  59. * MATERIAL DATA (THC PART)
  60. *---------------------------------------------------------------------*
  61. * MIX DATA
  62. cem  = 400.   ;
  63. aggr = 1806.  ;
  64. wc   = 0.4625 ;
  65. sc   = 0.     ;
  66.  
  67. * HYDRATION PROCESS DATA (affinity. activation energy. hydration heat)
  68. * Ref. Scium� PhD thesis
  69. AI   = 10.     ;
  70. AP   = 1340.   ;
  71. GAMP = 0.289   ;
  72. ALFA = 32.     ;
  73. EAR1 = 5369.   ;
  74. lat1 = 1.171e8 ;
  75.  
  76. * INTRINSIC PERMEABILITY
  77. KINT = 1.E-20 ;
  78.  
  79. * DESORPTION ISOTHERME MODEL PARAMETERS
  80. a1   =  20.E6 ;
  81. b1   =  2.    ;
  82. c1   =  1.     ;
  83.  
  84. * THERMAL PARAMETERS (porous solid dryed)
  85. CS   = 730.   ;
  86. KS   = 1.386  ;
  87. *---------------------------------------------------------------------*
  88.  
  89.  
  90. *---------------------------------------------------------------------*
  91. * SELECTION OF THE MATHEMATICAL MODEL
  92. *---------------------------------------------------------------------*
  93. MODTHC  = MODE MAIL1 'THERMOHYDRIQUE' 'BETON_THM' 'CONS' 'BO_THC';
  94. MODCOT  = MODE CONTT 'THERMIQUE'      'CONVECTION';
  95. MOD_TOT =  MODCOT ET MODTHC;
  96. *---------------------------------------------------------------------*
  97.  
  98.  
  99. *---------------------------------------------------------------------*
  100. * DEFINITION OF THE MATERIAL
  101. *---------------------------------------------------------------------*
  102. * Computing of stechiometric parameters with the Powers' model
  103. WINF GAM0 POR1 APOR = @POWERS cem aggr wc sc;
  104. MATTHC = MATE MODTHC 'CS'  CS    'KS'   KS   'GAM0' GAM0 'WINF' WINF
  105. 'VGA' a1   'VGB'  b1   'VGC' c1    'K1' KINT  'AK'   7.  'BK'   1. 
  106. 'KLI1' 20000.  'AKLI'   1.  'BKLI' 1. 'POR1' POR1 'APOR' APOR 
  107. 'AFF1' Ai  'AFF2' Ap   'AFF3' GAMP 'AFF4' ALFA 'EAR'  EAR1 'QLAT' lat1;
  108. MATCOT  = MATE  MODCOT   'H'     4.;
  109. MAT_TOT = MATCOT ET MATTHC;
  110. *---------------------------------------------------------------------*
  111.  
  112.  
  113. *---------------------------------------------------------------------*
  114. * INITIAL CONDITION
  115. * - Hydratuion degree             HY_0 = 0
  116. * - Temperature                   TC_0 = 20� 
  117. * - Gaz presure                   PG_0 = p_atm
  118. * - Relative humidity             HR_0 = 0.999
  119. *---------------------------------------------------------------------*
  120. HY_0   = 0.            ;
  121. TC_0   = 20.           ;
  122. TK_0   = 273.15 + TC_0 ;
  123. PG_0   = 101325.       ;
  124. HR_0   = 0.99995       ;
  125.  
  126. ZERO1  = MANU 'CHPO' MAIL1 'SCAL' 0.       ;
  127. CHTK_0 = MANU 'CHPO' MAIL1 'T' TK_0        ;
  128. PVS_0 XX YY ZZ KK JJ= @PVSAT ZERO1 ZERO1 CHTK_0    ;
  129.  
  130. * Clapeyron
  131. PC_0   = PG_0 - PVS_0 + ((-1.)*(RGP1*TK_0*RHOW0*(LOG HR_0)/MMGW1));
  132. PC_0   = PC_0 NOMC 'PC';
  133.  
  134. * Calculation of the corresponsing saturation degree
  135. CHPC_0 = MANU 'CHPO' MAIL1 1 'SCAL' (MAXI PC_0);
  136. CHTK_0 = MANU 'CHPO' MAIL1 1 'SCAL' TK_0;
  137. HYDR   = MANU 'CHPO' MAIL1 1 'SCAL' HY_0;
  138. cha1   = MANU 'CHPO' MAIL1 1 'SCAL' a1;
  139. chb1   = MANU 'CHPO' MAIL1 1 'SCAL' b1;
  140. chc1   = MANU 'CHPO' MAIL1 1 'SCAL' c1;
  141. chgam0 = MANU 'CHPO' MAIL1 1 'SCAL' gam0;
  142. SW0    = @SATURA CHPC_0 CHTK_0 HYDR cha1 chb1 chc1 chgam0;
  143. CI_TH  = (MANU 'CHPO' MAIL1 2 'PG' PG_0 'T' TK_0)  +  PC_0;
  144. *---------------------------------------------------------------------*
  145.  
  146.  
  147. *---------------------------------------------------------------------*
  148. * BOUNDARY CONDITIONS (THC PART)
  149. * - PG_surface = p_atm (Dirichlet) 
  150. *
  151. * - TC_ext = 20°C      (Convection with h = 4.)
  152. *
  153. * - Natural condition for the mass balance of water species (Sealed)
  154. *---------------------------------------------------------------------*
  155. TK_E  = TK_0;
  156. PG_E  = PG_0;
  157.  
  158. * PG: imposed gas pressure
  159. EV_PG = EVOL 'MANU' 'TEMPS'  (PROG 0.  t_fin) (PROG 1. 1.);
  160. CLPG1 = BLOQ 'PG'         CONTH;
  161. CHPG1 = DEPI  CLPG1        PG_E;
  162. CGPG1 = CHAR 'TIMP' CHPG1 EV_PG;
  163.  
  164. * T: Thermal convection
  165. TK_EXT  = 273.15 + 20. ;
  166. CHT_EXT = MANU 'CHPO' CONTH 1 'T' 1.;
  167. EVT_EXT = EVOL 'MANU' 'TEMPS' (PROG 0.     t_fin ) 
  168.                               (PROG TK_EXT TK_EXT);
  169. CGTK1   = CHAR 'TECO' CHT_EXT  EVT_EXT ;
  170. *---------------------------------------------------------------------*
  171.  
  172.  
  173.  
  174. *---------------------------------------------------------------------*
  175. * RESOLUTION
  176. *---------------------------------------------------------------------*
  177. TAB1_THC                         = TABL ;
  178. TAB1_THC . 'MODELE'              = MOD_TOT ;
  179. TAB1_THC . 'CARACTERISTIQUES'    = MAT_TOT ;
  180. TAB1_THC . 'BLOCAGES_THERMIQUES' = CLPG1 ;
  181. TAB1_THC . 'CHARGEMENT'          = CGPG1 ET CGTK1;
  182. TAB1_THC . 'TEMPS_CALCULES'      = LT_CALC ;
  183. TAB1_THC . 'TEMPS_SAUVES'        = LT_SAUV ;
  184. TAB1_THC . 'PROCEDURE_THERMIQUE' = 'NONLINEAIRE' ;
  185. TAB1_THC . 'RELAXATION_THETA'    = 0.50 ;
  186. TAB1_THC . 'MOVA'                = 'D' ;
  187. *
  188. TAB1_THC . 'TEMPERATURES'        = TABL ;
  189. TAB1_THC . 'TEMPERATURES' . 0    = CI_TH ;
  190. TAB1_THC . 'VARIABLES_THM'       = TABL ;
  191. TAB1_THC . 'VARIABLES_THM' .  0  = MANU CHML MODTHC 'HYDR' HY_0;
  192. *---------------------------------------------------------------------*
  193. PASAPAS TAB1_THC;
  194. *---------------------------------------------------------------------*
  195.  
  196.  
  197.  
  198. *---------------------------------------------------------------------*
  199. * MATERIAL DATA (MECHANICAL PART)
  200. *---------------------------------------------------------------------*
  201. * General mechanical parameters
  202. EYOU1 =  30.e9  ;
  203. FTR1  =  3.e6 * 10.;
  204. KTR1  =  FTR1/EYOU1 ;
  205. NU1   =  0.2 ;
  206. *ATH1  =  1.E-5;
  207. ATH1  =  0.;
  208.  
  209.  
  210. * Damage model parameters (BTRA = G_fracture)
  211. ATRA = 0.   ;
  212. BTRA = 115. ;
  213. ACOM = 1.2  ;
  214. BCOM = 1500.;
  215.  
  216. * Creep chains
  217. EKV1  = 30.e9 ;
  218. ETA1  =  1.e16   ;
  219. TKV1  = ETA1/EKV1;
  220. LIST (TKV1/86400.);
  221. ETA2  = 1.e30    ;
  222. XFDE  = 0. ;
  223. BETA1 = 0. ;
  224.  
  225. * Parametres de Schutter
  226. GAM01 = 0.1;
  227. AYOU1 = 0.4;
  228. AFTR1 = 0.5;
  229. AFLU1 = 0.5;
  230. AGFT1 = 0.5;
  231.  
  232. * Biot coefficient
  233. BIOT1 = 0.; 
  234. *---------------------------------------------------------------------*
  235.  
  236. *---------------------------------------------------------------------*
  237. * SELECTION OF THE MATHEMATICAL MODEL
  238. *---------------------------------------------------------------------*
  239. MODM    = MODE MAIL1 'MECANIQUE' 'ELASTIQUE' 'VISCOPLASTIQUE' 'BETON_THM' 'CONS' 'BO_M';
  240. *---------------------------------------------------------------------*
  241.  
  242.  
  243. *---------------------------------------------------------------------*
  244. * DEFINITION OF THE MATERIAL
  245. *---------------------------------------------------------------------*
  246. MATM = MATE MODM 'YOUN' EYOU1 'NU ' NU1 'KTR0' KTR1
  247. 'ALPHA' ATH1 'ATRA' ATRA 'BTRA' BTRA 'ACOM' ACOM 'BCOM' BCOM
  248. 'EKV1' EKV1  'TKV1' TKV1  'ETA2' eta2  'NUPO' nu1  'BETA' beta1
  249. 'XFDE' XFDE  'OMEG' 1. 'LCAR' 0.1  'GAM0' GAM01 'AYOU' AYOU1 
  250. 'AFTR' AFTR1 'AFLU' AFLU1 'AGFT' AGFT1 'BIOT' BIOT1
  251. 'VGA' A1 'VGB' B1 'VGC' C1 'TREF' 20. 'TALP' 20.;
  252. *---------------------------------------------------------------------*
  253.  
  254.  
  255. *---------------------------------------------------------------------*
  256. * BOUNDARY CONDITIONS (MECHANICAL PART)
  257. *---------------------------------------------------------------------*
  258. CONTM1 = l12;
  259. CONTM2 = COTE  4   MAIL1;
  260. rig1   = BLOQ 'UY' CONTM1;
  261. rig2   = BLOQ 'UX' CONTM2;
  262. RIGTOT = rig1 ET rig2;
  263.  
  264. * Sustained load
  265. CONTM3   = COTE 3 MAIL1;
  266. CHA1     = PRES 'MASS'  MODM  CONTM3 1.;
  267. listtmp  = PROG 0.  (2*day1) ((2*day1) + 600.)   t_fin;
  268. listpre  = PROG 0.   0.         1.E6                1.E6; 
  269. EVCH     = EVOL 'MANU' 'Temps' listtmp  'Pression' listpre;
  270. CHAM_MEC = CHAR 'MECA' CHA1 EVCH;
  271. *---------------------------------------------------------------------*
  272.  
  273.  
  274.  
  275.  
  276. *---------------------------------------------------------------------*
  277. * RESOLUTION
  278. *---------------------------------------------------------------------*
  279. TAB1_MEC                         = TABL ;
  280. TAB1_MEC . 'MODELE'              = MODM ;
  281. TAB1_MEC . 'CARACTERISTIQUES'    = MATM ;
  282. TAB1_MEC . 'BLOCAGES_MECANIQUES' = RIGTOT ;
  283. TAB1_MEC . 'CHARGEMENT'          = CHAM_MEC;
  284. TAB1_MEC . 'TEMPS_CALCULES'      = LT_SAUV ;
  285. TAB1_MEC . 'MOVA'                = 'D' ;
  286. TAB1_MEC . 'TEMPERATURES'        = TAB1_THC . 'TEMPERATURES' ;
  287. * utiles ?
  288. ****TAB1_MEC . 'BETON'               = MODM;
  289. TAB1_MEC . 'THCM_SEQUENTIEL'     = VRAI ;
  290. * Solution THC
  291. TAB1_MEC . 'VARIABLES_THM'       = TAB1_THC . 'VARIABLES_THM' ;
  292. *---------------------------------------------------------------------*
  293. opti debu 1;
  294. PASAPAS TAB1_MEC;
  295. *---------------------------------------------------------------------*
  296.  
  297.  
  298.  
  299.  
  300.  
  301. *---------------------------------------------------------------------*
  302. * POST-TREATEMENT OF RESULTS
  303. *---------------------------------------------------------------------*
  304.  
  305. * Evolution of TC, PG, PC, HY and SW during 3 days at a given point
  306. nfin1 = DIME  TAB1_THC.temperatures;
  307.  
  308. n3   = 1;
  309.  
  310. PG_P0   = PROG;
  311. PC_P0   = PROG;
  312. TK_P0   = PROG;
  313. HY_P0   = PROG;
  314. SW_P0   = PROG;
  315.  
  316. REPETER BOU_T nfin1;
  317. *
  318.   n4 = n3 - 1;
  319.   tmps1 = EXTR LT_SAUV n3;
  320.   tmps1 = tmps1 ;
  321.   val1g0  =  EXTR TAB1_THC . TEMPERATURES . n4 'PG' p1;
  322.   val1p0  =  EXTR TAB1_THC.temperatures.n4 'PC' p1;
  323.   val1t0  = (EXTR TAB1_THC.temperatures.n4 'T'  p1) - 273.15;
  324.   val1tk0 = (EXTR TAB1_THC.temperatures.n4 'T'  p1);
  325.   HYDRAi  = CHAN 'CHPO' (TAB1_THC . 'VARIABLES_THM' . n4) MODTHC;
  326.   val1h0  = EXTR HYDRAi 'HYDR' p1;
  327. *  
  328. * Computing of saturation degree
  329.   CHPG1  = MANU 'CHPO' MAIL1 1 'SCAL' val1g0;
  330.   CHPC1  = MANU 'CHPO' MAIL1 1 'SCAL' val1p0;
  331.   CHTK1  = MANU 'CHPO' MAIL1 1 'SCAL' val1tk0;
  332.   HYDR   = MANU 'CHPO' MAIL1 1 'SCAL' val1h0;
  333.   cha1   = MANU 'CHPO' MAIL1 1 'SCAL' a1;
  334.   chb1   = MANU 'CHPO' MAIL1 1 'SCAL' b1;
  335.   chc1   = MANU 'CHPO' MAIL1 1 'SCAL' c1;
  336.   chgam0 = MANU 'CHPO' MAIL1 1 'SCAL' gam0;
  337.   SW0    = @SATURA CHPC1 CHTK1 HYDR cha1 chb1 chc1 chgam0;
  338.   val1sw0= MAXI SW0;
  339. *
  340.   PG_P0   =  PG_P0     ET (PROG val1g0);
  341.   PC_P0   =  PC_P0     ET (PROG val1p0);
  342.   TK_P0   =  TK_P0     ET (PROG val1t0);
  343.   HY_P0   =  HY_P0     ET (PROG val1h0);
  344.   SW_P0   =  SW_P0     ET (PROG val1sw0);
  345.   n3 = n3 + 1;
  346. *  
  347. FIN BOU_T;
  348.  
  349. evpg_P1 = EVOL 'ROUG' 'MANU' LT_SAUV PG_P0;
  350. evpc_P1 = EVOL 'ROUG' 'MANU' LT_SAUV PC_P0;
  351. evt_P1  = EVOL 'ROUG' 'MANU' LT_SAUV TK_P0;
  352. evh_P1  = EVOL 'BLEU' 'MANU' LT_SAUV HY_P0;
  353. evsw_P1 = EVOL 'BLEU' 'MANU' LT_SAUV SW_P0;
  354.  
  355. SI ITRAC1;
  356.   DESS evpg_P1;
  357.   DESS evpc_P1;
  358.   DESS evt_P1;
  359.   DESS evh_P1;
  360.   DESS evsw_P1;
  361. FINSI;
  362.  
  363. * Longitudinal deformation over the time
  364. dimet = DIME TAB1_MEC . 'DEPLACEMENTS' ;
  365. last = dimet - 1;
  366. *
  367. p2  = MAIL1 POIN PROC (L1 L1);
  368.  
  369. n6    = 0;
  370. l_def = PROG;
  371. REPETER BOUCLE dimet;
  372.    UY1   = EXTR TAB1_MEC.DEPLACEMENTS.n6 'UY' p2;
  373.    EPSY  = (UY1 * -1.E6)/L1  ;
  374.    l_def = l_def ET (PROG EPSY);
  375.    n6 = n6 + 1;
  376. FIN BOUCLE;
  377.  
  378. EV_DEF = EVOL 'ROUG' 'MANU' 'JOURS' (LT_SAUV/86400.) 'MICRON/METER' l_def;
  379. SI ITRAC1;
  380.   DESS EV_DEF;
  381. FINSI;
  382.  
  383.  
  384. TAB_LEG     = TABLE ;
  385. TAB_LEG . 1 = MOT 'MARQ ROND NOLI';
  386. *
  387. TAB_LEG . 'TITRE'     = TABLE ;
  388. TAB_LEG . 'TITRE' . 1 = 'Ref. solution';
  389. TAB_LEG . 'TITRE' . 2 = 'Num. solution';
  390. *---------------------------------------------------------------------*
  391.  
  392.  
  393. *---------------------------------------------------------------------*
  394. * REFERENCE SOLUTIONS
  395. *---------------------------------------------------------------------*
  396. L_TIME    = PROG 0. 'PAS' 1. 10.;
  397. DEF_V11   = PROG 0.  0.  0. 47.03 55.16 61.06 65.41 68.64 71.06 72.88 74.26;
  398. EV_DEF_V11 = EVOL 'ROUG' 'MANU' L_TIME DEF_V11;
  399. *---------------------------------------------------------------------*
  400.  
  401.  
  402. *---------------------------------------------------------------------*
  403. * VISUALIZATION OF RESULTS
  404. *---------------------------------------------------------------------*
  405. SI ITRAC1;
  406.   DESS (EV_DEF_V11 et EV_DEF) 'LEGE' TAB_LEG 'TITR' 'Verification test with a reference solution';
  407. FINSI;
  408. *---------------------------------------------------------------------*
  409.  
  410.  
  411. *---------------------------------------------------------------------*
  412. * COMPUTING OF NORMALIZED ERRORS
  413. *---------------------------------------------------------------------*
  414. NORM_DEP = (MAXI DEF_V11) - (MINI DEF_V11); 
  415.  
  416.  
  417. * Estraction of corresponding times
  418. l_def_RED = PROG;
  419.  
  420. n0 = 1;
  421.  
  422. REPETER BOU_EXTR 11;
  423.   l_defi = EXTR l_def n0;
  424.   l_def_RED = l_def_RED ET (PROG l_defi);
  425.   n0 = n0 + (24 * 6);
  426. FIN BOU_EXTR;
  427.  
  428.  
  429. E_DEP_R = (MAXI (ABS (DEF_V11 - l_def_RED))) / NORM_DEP; 
  430. ERR0    =  MAXI (PROG E_DEP_R) ;
  431. MESS ' ****** Ecart relatif max. solution de reference =' ERR0 ;
  432.  
  433.  
  434. SI (ERR0 '>' 2.E-2) ;
  435.   ERRE 5 ;
  436.   FIN ;
  437. SINO ;
  438.   SAUT 1 'LIGN' ;
  439.   MESS '------------------CAS-TEST BETON_THM3 REUSSI ! ------------------' ;
  440.   SAUT 1 'LIGN' ;
  441. FINS ;
  442.  
  443.  
  444. FIN ;
  445.  
  446.  
  447.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales