Télécharger la plaquette Cast3M


fr en

Télécharger beton_thm2.dgibi

Retour à la liste

Numérotation des lignes : 

  1. * fichier : beton_thm2.dgibi
  2. *---------------------------------------------------------------------*
  3. *                                                                     *
  4. *             Cas-test du modele THERMOHYDRIQUE BETON_THM             *
  5. *                                                                     *
  6. * Description : Beton au jeune age. Simulation d'un essai de          *
  7. *               calorimetrie non-adiabatique avec calcul de           * 
  8. *               la deformation de retrait endogene.                   *
  9. *                                                                     *
  10. *               Comparaison de la solution numerique avec une         *
  11. *               solution semi-analytique de reference                 *
  12. *                                                                     *
  13. *---------------------------------------------------------------------*
  14.  
  15.  
  16. OPTI 'ECHO' 0 ;
  17.  
  18. * Traces : ITRAC1 = VRAI ;
  19. ITRAC1   = FAUX ;
  20.  
  21. *---------------------------------------------------------------------*
  22. * CONSTANT PHYSICAL PARAMEMTERS
  23. *---------------------------------------------------------------------*
  24. RGP1     = 8.3145 ;                                            
  25. MMGW1    = 18.0153E-3 ;
  26. RHOW0    = 1000. ;
  27. *---------------------------------------------------------------------*
  28.  
  29.  
  30. *---------------------------------------------------------------------*
  31. * TIME DISCRETIZATION
  32. *---------------------------------------------------------------------*
  33. hours1 = 3600.;
  34. day1   = 86400.;
  35. temps1 =  2 * day1;
  36. t_fin  = 10 * day1;
  37. LT_CALC = PROG 0. 'PAS' 60. temps1 'PAS' 600. t_fin;
  38. LT_SAUV = PROG 0. 'PAS' 600. t_fin; 
  39. *---------------------------------------------------------------------*
  40.  
  41.  
  42. *---------------------------------------------------------------------*
  43. * FE MESH
  44. *---------------------------------------------------------------------*
  45. OPTI 'DIME' 2 'ELEM' 'QUA4' 'MODE' 'PLAN' 'CONT';
  46. * Geometry
  47. L1    = 0.10      ;
  48. P1    = 0.  0.; 
  49. P2    = L1  0.;
  50. L12   = DROI 10 P1 P2;
  51. MAIL1 = L12 TRAN 10 (0. 0.10);
  52. CONTT = COTE 2 MAIL1;
  53. CONTH = COTE 2 MAIL1;
  54. *---------------------------------------------------------------------*
  55.  
  56.  
  57. *---------------------------------------------------------------------*
  58. * MATERIAL DATA (THC PART)
  59. *---------------------------------------------------------------------*
  60. * MIX DATA
  61. cem  = 400.   ;
  62. aggr = 1806.  ;
  63. wc   = 0.4625 ;
  64. sc   = 0.     ;
  65.  
  66. * HYDRATION PROCESS DATA (affinity. activation energy. hydration heat)
  67. * Ref. Scium� PhD thesis
  68. AI   = 10.     ;
  69. AP   = 1340.   ;
  70. GAMP = 0.289   ;
  71. ALFA = 32.     ;
  72. EAR1 = 5369.   ;
  73. lat1 = 1.171e8 ;
  74.  
  75. * INTRINSIC PERMEABILITY
  76. KINT = 1.E-20 ;
  77.  
  78. * DESORPTION ISOTHERME MODEL PARAMETERS
  79. a1   =  20.E6 ;
  80. b1   =  2.    ;
  81. c1   =  1.     ;
  82.  
  83. * THERMAL PARAMETERS (porous solid dryed)
  84. CS   = 730.   ;
  85. KS   = 1.386  ;
  86. *---------------------------------------------------------------------*
  87.  
  88.  
  89. *---------------------------------------------------------------------*
  90. * SELECTION OF THE MATHEMATICAL MODEL
  91. *---------------------------------------------------------------------*
  92. MODTHC  = MODE MAIL1 'THERMOHYDRIQUE' 'BETON_THM' 'CONS' 'BO_THC';
  93. MODCOT  = MODE CONTT 'THERMIQUE'      'CONVECTION';
  94. MOD_TOT = MODCOT ET MODTHC;
  95. *---------------------------------------------------------------------*
  96.  
  97.  
  98. *---------------------------------------------------------------------*
  99. * DEFINITION OF THE MATERIAL
  100. *---------------------------------------------------------------------*
  101. * Computing of stechiometric parameters with the Powers' model
  102. WINF GAM0 POR1 APOR = @POWERS cem aggr wc sc;
  103. MATTHC = MATE MODTHC 'CS'  CS    'KS'   KS   'GAM0' GAM0 'WINF' WINF
  104. 'VGA' a1   'VGB'  b1   'VGC' c1    'K1' KINT  'AK'   7.  'BK'   1. 
  105. 'KLI1' 20000.  'AKLI'   1.  'BKLI' 1. 'POR1' POR1 'APOR' APOR 
  106. 'AFF1' Ai  'AFF2' Ap   'AFF3' GAMP 'AFF4' ALFA 'EAR'  EAR1 'QLAT' lat1;
  107. MATCOT  = MATE  MODCOT   'H'     4.;
  108. MAT_TOT = MATCOT ET MATTHC;
  109. *---------------------------------------------------------------------*
  110.  
  111.  
  112. *---------------------------------------------------------------------*
  113. * INITIAL CONDITION
  114. * - Hydratuion degree             HY_0 = 0
  115. * - Temperature                   TC_0 = 20°C
  116. * - Gaz presure                   PG_0 = p_atm
  117. * - Relative humidity             HR_0 = 0.999
  118. *---------------------------------------------------------------------*
  119. HY_0   = 0.            ;
  120. TC_0   = 20.           ;
  121. TK_0   = 273.15 + TC_0 ;
  122. PG_0   = 101325.       ;
  123. HR_0   = 0.99995       ;
  124.  
  125. ZERO1  = MANU 'CHPO' MAIL1 'SCAL' 0.       ;
  126. CHTK_0 = MANU 'CHPO' MAIL1 'T' TK_0        ;
  127. PVS_0 XX YY ZZ KK JJ= @PVSAT ZERO1 ZERO1 CHTK_0    ;
  128.  
  129. * Clapeyron
  130. PC_0   = PG_0 - PVS_0 + ((-1.)*(RGP1*TK_0*RHOW0*(LOG(HR_0))/MMGW1));
  131. PC_0   = PC_0 'NOMC' 'PC';
  132.  
  133. * Calculation of the corresponsing saturation degree
  134. CHPC_0 = MANU 'CHPO' MAIL1 1 'SCAL' (MAXI PC_0);
  135. CHTK_0 = MANU 'CHPO' MAIL1 1 'SCAL' TK_0;
  136. HYDR   = MANU 'CHPO' MAIL1 1 'SCAL' HY_0;
  137. cha1   = MANU 'CHPO' MAIL1 1 'SCAL' a1;
  138. chb1   = MANU 'CHPO' MAIL1 1 'SCAL' b1;
  139. chc1   = MANU 'CHPO' MAIL1 1 'SCAL' c1;
  140. chgam0 = MANU 'CHPO' MAIL1 1 'SCAL' gam0;
  141. SW0    = @SATURA CHPC_0 CHTK_0 HYDR cha1 chb1 chc1 chgam0;
  142. CI_TH  = (MANU 'CHPO' MAIL1 2 'PG' PG_0 'T' TK_0)  +  PC_0;
  143. *---------------------------------------------------------------------*
  144.  
  145.  
  146. *---------------------------------------------------------------------*
  147. * BOUNDARY CONDITIONS (THC PART)
  148. * - PG_surface = p_atm (Dirichlet) 
  149. *
  150. * - TC_ext = 20°C      (Convection with h = 4.)
  151. *
  152. * - Natural condition for the mass balance of water species (Sealed)
  153. *---------------------------------------------------------------------*
  154. TK_E  = TK_0;
  155. PG_E  = PG_0;
  156.  
  157. * PG: imposed gas pressure
  158. EV_PG = EVOL 'MANU' 'TEMPS'  (PROG 0.  t_fin) (PROG 1. 1.);
  159. CLPG1 = BLOQ 'PG'         CONTH;
  160. CHPG1 = DEPI  CLPG1        PG_E;
  161. CGPG1 = CHAR 'TIMP' CHPG1 EV_PG;
  162.  
  163. * T: Thermal convection
  164. TK_EXT  = 273.15 + 20. ;
  165. CHT_EXT = MANU 'CHPO' CONTH 1 'T' 1.;
  166. EVT_EXT = EVOL 'MANU' 'TEMPS' (PROG 0.     t_fin ) 
  167.                               (PROG TK_EXT TK_EXT);
  168. CGTK1   = CHAR 'TECO' CHT_EXT  EVT_EXT ;
  169. *---------------------------------------------------------------------*
  170.  
  171.  
  172.  
  173. *---------------------------------------------------------------------*
  174. * RESOLUTION
  175. *---------------------------------------------------------------------*
  176. TAB1_THC                         = TABL ;
  177. TAB1_THC . 'MODELE'              = MOD_TOT ;
  178. TAB1_THC . 'CARACTERISTIQUES'    = MAT_TOT ;
  179. TAB1_THC . 'BLOCAGES_THERMIQUES' = CLPG1 ;
  180. TAB1_THC . 'CHARGEMENT'          = CGPG1 ET CGTK1;
  181. TAB1_THC . 'TEMPS_CALCULES'      = LT_CALC ;
  182. TAB1_THC . 'TEMPS_SAUVES'        = LT_SAUV ;
  183. TAB1_THC . 'PROCEDURE_THERMIQUE' = 'NONLINEAIRE' ;
  184. TAB1_THC . 'RELAXATION_THETA'    = 0.50 ;
  185. TAB1_THC . 'MOVA'                = 'D' ;
  186. TAB1_THC . 'TEMPERATURES'        = TABL ;
  187. TAB1_THC . 'TEMPERATURES' . 0    = CI_TH ;
  188. TAB1_THC . 'VARIABLES_THM'       = TABL ;
  189. TAB1_THC . 'VARIABLES_THM' .  0  = MANU 'CHML' MODTHC 'HYDR' HY_0;
  190. *****TAB1_THC . 'THM_PARAMETRES'      = MATTHC ;
  191. *---------------------------------------------------------------------*
  192. PASAPAS TAB1_THC;
  193. *---------------------------------------------------------------------*
  194.  
  195.  
  196. *---------------------------------------------------------------------*
  197. * MATERIAL DATA (MECHANICAL PART)
  198. *---------------------------------------------------------------------*
  199. * General mechanical parameters
  200. EYOU1 =  30.e9  ;
  201. FTR1  =  3.e6 * 10.;
  202. KTR1  =  FTR1/EYOU1 ;
  203. NU1   =  0.2 ;
  204. *ATH1  =  1.E-5;
  205. ATH1  =  0.;
  206.  
  207.  
  208. * Damage model parameters (BTRA = G_fracture)
  209. ATRA = 0.   ;
  210. BTRA = 115. ;
  211. ACOM = 1.2  ;
  212. BCOM = 1500.;
  213.  
  214. * Creep chains
  215. EKV1  = 30.e9 ;
  216. ETA1  =  1.e16   ;
  217. TKV1  = ETA1/EKV1;
  218. ETA2  = 1.e30    ;
  219. XFDE  = 0. ;
  220. BETA1 = 0. ;
  221.  
  222. * Parametres de Schutter
  223. GAM01 = 0.1;
  224. AYOU1 = 0.4;
  225. AFTR1 = 0.5;
  226. AFLU1 = 0.5;
  227. AGFT1 = 0.5;
  228.  
  229. * Biot coefficient
  230. BIOT1 = 0.125; 
  231. *---------------------------------------------------------------------*
  232.  
  233. *---------------------------------------------------------------------*
  234. * SELECTION OF THE MATHEMATICAL MODEL
  235. *---------------------------------------------------------------------*
  236. MODM    = MODE MAIL1 'MECANIQUE' 'ELASTIQUE' 'VISCOPLASTIQUE' 'BETON_THM' 'CONS' 'BO_M';
  237. *---------------------------------------------------------------------*
  238.  
  239.  
  240. *---------------------------------------------------------------------*
  241. * DEFINITION OF THE MATERIAL
  242. *---------------------------------------------------------------------*
  243. MATM = MATE MODM 'YOUN' EYOU1 'NU ' NU1 'KTR0' KTR1
  244. 'ALPHA' ATH1 'ATRA' ATRA 'BTRA' BTRA 'ACOM' ACOM 'BCOM' BCOM
  245. 'EKV1' EKV1  'TKV1' TKV1  'ETA2' eta2  'NUPO' nu1  'BETA' beta1
  246. 'XFDE' XFDE  'OMEG' 1. 'LCAR' 0.1  'GAM0' GAM01 'AYOU' AYOU1 
  247. 'AFTR' AFTR1 'AFLU' AFLU1 'AGFT' AGFT1 'BIOT' BIOT1
  248. 'VGA' a1 'VGB' b1 'VGC' c1
  249. 'TREF' 20. 'TALP' 20.;
  250. *---------------------------------------------------------------------*
  251.  
  252.  
  253. *---------------------------------------------------------------------*
  254. * BOUNDARY CONDITIONS (MECHANICAL PART)
  255. *---------------------------------------------------------------------*
  256. CONTM1 = l12;
  257. CONTM2 = COTE  4   MAIL1;
  258. rig1   = BLOQ 'UY' CONTM1;
  259. rig2   = BLOQ 'UX' CONTM2;
  260. RIGTOT = rig1 et rig2;
  261.  
  262. * Chargement TH
  263. CHAM_TH = CHAR 'T'  (TAB1_THC . 'TEMPS')  (TAB1_THC . 'TEMPERATURES') ;
  264. *---------------------------------------------------------------------*
  265.  
  266.  
  267.  
  268.  
  269. *---------------------------------------------------------------------*
  270. * RESOLUTION
  271. *---------------------------------------------------------------------*
  272. TAB1_MEC                         = TABL ;
  273. TAB1_MEC . 'MODELE'              = MODM ;
  274. TAB1_MEC . 'CARACTERISTIQUES'    = MATM ;
  275. TAB1_MEC . 'BLOCAGES_MECANIQUES' = RIGTOT ;
  276. TAB1_MEC . 'CHARGEMENT'          = CHAM_TH;
  277. TAB1_MEC . 'TEMPS_CALCULES'      = LT_SAUV ;
  278. TAB1_MEC . 'MOVA'                = 'D' ;
  279. TAB1_MEC . 'TEMPERATURES'        = TAB1_THC . 'TEMPERATURES' ;
  280. TAB1_MEC . 'VARIABLES_THM'       = TAB1_THC . 'VARIABLES_THM' ;
  281. *---------------------------------------------------------------------*
  282. PASAPAS TAB1_MEC;
  283. *---------------------------------------------------------------------*
  284.  
  285.  
  286.  
  287.  
  288. *---------------------------------------------------------------------*
  289. * POST-TREATEMENT OF RESULTS
  290. *---------------------------------------------------------------------*
  291.  
  292. * Evolution of TC, PG, PC, HY and SW during 3 days at a given point
  293. nfin1 = DIME  TAB1_THC.temperatures;
  294.  
  295. n3   = 1;
  296.  
  297. PG_P0   = PROG;
  298. PC_P0   = PROG;
  299. TK_P0   = PROG;
  300. HY_P0   = PROG;
  301. SW_P0   = PROG;
  302.  
  303. REPETER BOU_T nfin1;
  304. *
  305.   n4 = n3 - 1;
  306.   tmps1 = EXTR LT_SAUV n3;
  307.   tmps1 = tmps1 ;
  308.   val1g0  =  EXTR TAB1_THC . TEMPERATURES . n4 'PG' p1;
  309.   val1p0  =  EXTR TAB1_THC.temperatures.n4 'PC' p1;
  310.   val1t0  = (EXTR TAB1_THC.temperatures.n4 'T'  p1) - 273.15;
  311.   val1tk0  = (EXTR TAB1_THC.temperatures.n4 'T'  p1);
  312.   HYDRAi  = CHAN 'CHPO' (TAB1_THC . 'VARIABLES_THM' . n4) MODTHC;
  313.   val1h0  = EXTR HYDRAi 'HYDR' p1;
  314. *  
  315. * Computing of saturation degree
  316.   CHPG1  = MANU 'CHPO' MAIL1 1 'SCAL' val1g0;
  317.   CHPC1  = MANU 'CHPO' MAIL1 1 'SCAL' val1p0;
  318.   CHTK1  = MANU 'CHPO' MAIL1 1 'SCAL' val1tk0;
  319.   HYDR   = MANU 'CHPO' MAIL1 1 'SCAL' val1h0;
  320.   cha1   = MANU 'CHPO' MAIL1 1 'SCAL' a1;
  321.   chb1   = MANU 'CHPO' MAIL1 1 'SCAL' b1;
  322.   chc1   = MANU 'CHPO' MAIL1 1 'SCAL' c1;
  323.   chgam0 = MANU 'CHPO' MAIL1 1 'SCAL' gam0;
  324.   SW0    = @SATURA CHPC1 CHTK1 HYDR cha1 chb1 chc1 chgam0;
  325.   val1sw0= MAXI SW0;
  326. *
  327.   PG_P0   =  PG_P0     ET (PROG val1g0);
  328.   PC_P0   =  PC_P0     ET (PROG val1p0);
  329.   TK_P0   =  TK_P0     ET (PROG val1t0);
  330.   HY_P0   =  HY_P0     ET (PROG val1h0);
  331.   SW_P0   =  SW_P0     ET (PROG val1sw0);
  332.   n3 = n3 + 1;
  333. *  
  334. FIN BOU_T;
  335.  
  336. evpg_P1 = EVOL 'ROUG' MANU LT_SAUV PG_P0;
  337. evpc_P1 = EVOL 'ROUG' MANU LT_SAUV PC_P0;
  338. evt_P1  = EVOL 'ROUG' MANU LT_SAUV TK_P0;
  339. evh_P1  = EVOL 'BLEU' MANU LT_SAUV HY_P0;
  340. evsw_P1 = EVOL 'BLEU' MANU LT_SAUV SW_P0;
  341.  
  342. SI ITRAC1;
  343.   DESS evpg_P1;
  344.   DESS evpc_P1;
  345.   DESS evt_P1;
  346.   DESS evh_P1;
  347.   DESS evsw_P1;
  348. FINSI;
  349.  
  350.  
  351. * Longitudinal deformation over the time
  352. dimet = DIME TAB1_MEC . 'DEPLACEMENTS' ;
  353. last = dimet - 1;
  354. *
  355. p2  = MAIL1 POIN 'PROC' (L1 L1);
  356.  
  357. n6    = 0;
  358. l_def = PROG;
  359. REPETER BOUCLE dimet;
  360.    UY1   = EXTR TAB1_MEC.'DEPLACEMENTS'.n6 'UY' p2;
  361.    EPSY  = (UY1 * -1.E6)/L1  ;
  362.    l_def = l_def ET (PROG EPSY);
  363.    n6 = n6 + 1;
  364. FIN BOUCLE;
  365.  
  366. EV_DEF = EVOL 'ROUG' 'MANU' 'JOURS' (LT_SAUV/86400.) 'MICRON/METER' l_def;
  367. SI ITRAC1;
  368.   DESS EV_DEF;
  369. FINSI;
  370.  
  371.  
  372. TAB_LEG     = TABLE ;
  373. TAB_LEG . 1 = MOT 'MARQ ROND NOLI';
  374. *
  375. TAB_LEG . 'TITRE'     = TABLE ;
  376. TAB_LEG . 'TITRE' . 1 = 'Ref. solution';
  377. TAB_LEG . 'TITRE' . 2 = 'Num. solution';
  378. *---------------------------------------------------------------------*
  379.  
  380.  
  381. *---------------------------------------------------------------------*
  382. * REFERENCE SOLUTIONS
  383. *---------------------------------------------------------------------*
  384. L_TIME    = PROG 0. 'PAS' 1. 10.;
  385. DEF_V11   = PROG 0.0000 29.110 43.295 50.681 55.925 59.886 62.949 
  386. 65.346 67.236 68.737 69.933;
  387. EV_DEF_V11 = EVOL 'ROUG' 'MANU' L_TIME DEF_V11;
  388. *---------------------------------------------------------------------*
  389.  
  390.  
  391. *---------------------------------------------------------------------*
  392. * VISUALIZATION OF RESULTS
  393. *---------------------------------------------------------------------*
  394. SI ITRAC1;
  395.   DESS (EV_DEF_V11 et EV_DEF) 'LEGE' TAB_LEG 'TITR' 'Verification test with a reference solution';
  396. FINS;
  397. *---------------------------------------------------------------------*
  398.  
  399.  
  400. *---------------------------------------------------------------------*
  401. * COMPUTING OF NORMALIZED ERRORS
  402. *---------------------------------------------------------------------*
  403. NORM_DEP = (MAXI DEF_V11) - (MINI DEF_V11); 
  404.  
  405.  
  406. * Estraction of corresponding times
  407. l_def_RED = PROG;
  408.  
  409. n0 = 1;
  410.  
  411. REPETER BOU_EXTR 11;
  412.   l_defi = EXTR l_def n0;
  413.   l_def_RED = l_def_RED ET (PROG l_defi);
  414.   n0 = n0 + (24 * 6);
  415. FIN BOU_EXTR;
  416.  
  417.  
  418. E_DEP_R = (MAXI (ABS (DEF_V11 - l_def_RED))) / NORM_DEP; 
  419. ERR0    =  MAXI (PROG E_DEP_R) ;
  420. MESS ' ****** Ecart relatif max. solution de reference =' ERR0 ;
  421.  
  422. SI (ERR0 '>' 1.E-2) ;
  423.   ERRE 5 ;
  424.   FIN ;
  425. SINO ;
  426.   SAUT 1 'LIGN' ;
  427.   MESS '------------------CAS-TEST BETON_THM2 REUSSI ! ------------------' ;
  428.   SAUT 1 'LIGN' ;
  429. FINS ;
  430.  
  431.  
  432. FIN ;
  433.  
  434.  
  435.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales