Télécharger la plaquette Cast3M


fr en

Télécharger Th1D-T3D-mono.dgibi

Retour à la liste

Numérotation des lignes : 

  1. * fichier : Th1D-T3D-mono.dgibi
  2. *
  3. 'OPTI' 'ECHO' 0 ;
  4. *******************************************
  5. *******************************************
  6.  
  7. **********************************************************************************************
  8. *
  9. * NOM DE FICHIER    : Th1D-T3D-mono.dgibi
  10. *
  11. * DESCRIPTION       : Modelisation thermique 3D - thermohydraulique 1D monophasique
  12. *
  13. **********************************************************************************************
  14. * CAS TEST CORRESPONDANT AU RAPPORT DM2S/STMF/LMES/RT/12-013/A :
  15. *                  Calculs thermohydrauliques HCLL/TBM realises avec le code CAST3M "fluide"
  16. *                  Etude du refroidissement de la couverture tritigene du reacteur a fusion
  17. *                  par un ecoulement d'helium
  18. *
  19. **********************************************************************************************
  20. *       A U T E U R S
  21. **********************************************************************************************
  22. *
  23. * Giacomo AIELLO    - CEA/DEN/DANS/DM2S/SEMT/BCCR - mel : giacomo.aiello@cea.fr
  24. * Jean-Louis LASZLO - CEA/DEN/DANS/DM2S/STMF/LMES - mel : jean-louis.laszlo@cea.fr
  25. * Stephane GOUNAND  - CEA/DEN/DANS/DM2S/SFMF/LMSF - mel : gounand@semt2.smts.cea.fr
  26. *
  27. **********************************************************************************************
  28. **********************************************************************************************
  29. *
  30. *
  31. * TEST RAPIDE       : la variable logique complet = FAUX;
  32. * TEST NOMINAL      : la variable logique complet = VRAI;
  33. *
  34. *
  35. **********************************************************************************************
  36. *                   Exemple de resultats                                                     *
  37. **********************************************************************************************
  38. * Variable logique COMPLET                            FAUX              VRAI
  39. *                  *******                            ****              ****
  40. * Nombre iterations                                   1 seule           test
  41. *                                                                       convergence
  42. * Maillage                                            grossier          nominal
  43. *
  44. * Debit massique commun fluide 1 et 2                 0.11 kg/s         0.11 kg/s
  45. * Flux impose                                         92.4 kW           92.4 kW
  46. *
  47. * Temperature minimale solide                        298.8 degres C    303.5 degres C
  48. * Temperature maximale solide                        449.0 degres C    517.3 degres C
  49. *
  50. * Temperature minimale fluide 1                      300.0 degres C    300.0 degres C
  51. * Temperature maximale fluide 1                      380.5 degres C    383.7 degres C
  52. **********************************************************************************************
  53. *
  54. *
  55. *                   VARIABLES LOGIQUES
  56. *
  57. **********************************************************************************************
  58.  
  59. complet = FAUX ; comm TEST RAPIDE ;
  60. *complet = VRAI ; comm TEST NOMINAL ;
  61.  
  62. * EchColb = VRAI ;  comm loi echange thermique COLBURN ;
  63. EchColb = FAUX ;  comm loi echange thermique GNIELINSKI ;
  64.  
  65.  
  66. **********************************************************************************************
  67. **********************************************************************************************
  68. ***                          PROCEDURES
  69. **********************************************************************************************
  70. **********************************************************************************************
  71.  
  72. debproc spabas spass*flottant ori*point ;
  73. v9 = spass ** 0.5 ;
  74. P2 = ori PLUS ( v9 0. 0. ) ;
  75. Lig9 = DROI 1 ori P2 ;
  76. sp9  = Lig9 TRAN 1 ( 0. v9 0. ) ;
  77. elim sp9 1.E-6 ;
  78. finpro sp9 ;
  79.  
  80. debproc loupe eye  c0*chpoint m0*maillage tjt0*mot gross0*flottant
  81.         c/flottant ;
  83. * 1 pour UX - 2 pour UY - 3 pour UZ
  84. xmt = 'COORDONNEE' 1  m0 ;
  85. ymt = 'COORDONNEE' 2  m0 ;
  86. dxmt = 'NOMC' 'UX' ('*' xmt gross0) 'NATURE' 'DISCRET' ;
  87. dymt = 'NOMC' 'UY' ('*' ymt gross0) 'NATURE' 'DISCRET' ;
  88. orig0 = 'FORME' ;
  89. 'FORME' dxmt ;
  90. 'FORME' dymt ;
  91. SI ( EXIS c ) ;
  92.  trac cach eye c0 m0 titr tjt0 ;
  93. SINON ;
  94.  trac cach eye c0 m0 (cont m0 ) titr tjt0 ;
  95. FINSI ;
  96. 'FORME' orig0 ;
  97. finproc ;
  98.  
  99. DEBP PARTSURF TABCONV*TABLE;
  100. TABCONV . PART = TABLE;
  101.  
  102. NBOUCT = NBNO TABCONV.SURFCONV ;
  103. REPE BOUC NBOUCT ;
  104.     SI (&bouc EGA 1 );
  105.         NEWPART = ELEM TABCONV . SURFCONV APPUYE
  106.                             LARGEMENT TABCONV . SIN;
  107.         TOTPART = NEWPART;
  108.         PINI = BARY NEWPART;
  109.     SINON ;
  110.         NEWPART = ELEM TABCONV . SURFCONV APPUYE LARGEMENT TOTPART;
  111.         SI ((NBNO NEWPART) EGA (NBNO TOTPART));
  112.             QUITTER BOUC;
  113.         SINON ;
  114.             NEWPART = DIFF NEWPART TOTPART;
  115.             TOTPART = TOTPART et NEWPART;
  116.         FINSI;
  117.     PFIN = BARY NEWPART;
  118.     FINSI;
  119.     TABCONV . PART . &bouc = NEWPART;
  120. FIN bouc;
  121. FINP;
  122.  
  123. DEBPROC FLUI1D_2 TABCONV*TABLE
  124.       DECAX*FLOTTANT DECAY*FLOTTANT kdec*FLOTTANT spa9*FLOTTANT ;
  125. TABCONV . FAC0 = TABLE ;
  126. TABCONV . ELE0 = TABLE ;
  127.  
  128. DECAX = kdec * DECAX ;
  129. DECAY = kdec * DECAY ;
  130.  
  131. Npart = DIME TABCONV .'PART' ;
  132. PINI = BARY TABCONV .'PART'. 1 ;
  133. PINI = PINI PLUS ( DECAX DECAY 0. ) ;
  134. SurBas = spabas spa9 PINI ;
  135. TABCONV .'BAFLU' = SurBas ;
  136.  
  137. *mess Npart ;
  138.  
  139. kfac = 0 ; comm initialisation compteur ;
  140. REPE BOUC Npart ;
  141.  NS = NBEL TABCONV .'PART'.&bouc ;
  142. *mess NS ;
  143.  Slat = ( mesu ( TABCONV .'PART'.&bouc ));
  144.  HautF = Slat / ( 4. * ( spa9 ** 0.5 )) ;
  145. * mess &bouc spa9 hautf slat ;
  146.  opti elem cub8 ;
  147.    si ( ega &bouc 1 ) ;
  148.     NEWFLU = SurBas VOLU 1 'TRAN' ( 0. 0. HautF  ) ;
  149.     TOTFLU = NEWFLU ;
  150.     NEWSOL = TABCONV .'PART'.&bouc ;
  151.     TOTSOL = NEWSOL ;
  152.    SINON ;
  153.     NEWFLU = ( FACE 2 NEWFLU ) volu 1 'TRAN' ( 0. 0. HautF  ) ;
  154.     TOTFLU = TOTFLU ET NEWFLU ;
  155.     NEWSOL = TABCONV .'PART'.&bouc ;
  156.     TOTSOL = TOTSOL et NEWSOL ;
  157.    FINSI ;
  158.  
  159.  repe w ( NBEL TABCONV .'PART'.&bouc ) ;
  160.   kfac = kfac + 1 ;
  161. * mess &bouc &w kfac ;
  162.   TABCONV . FAC0 . kfac = TABCONV .'PART'.&bouc ELEM &w ;
  163.   TABCONV . ELE0 . kfac = NEWFLU ;
  164.  fin w ;
  165.  
  166. FIN bouc;
  167.  
  168. TABCONV .'MTFLU' = totflu ;
  169. TABCONV .'OUFLU' = FACE 2 NEWFLU ;
  170.  
  171. FINP ;
  172.  
  173.  
  174. debproc matcon0 tfa00*TABLE tel00*TABLE ;
  175. *** CREATION DE LA MATRICE DE COUPLAGE                      *
  176. *** ----------------------------------                      *
  177. nitab = 'DIME' tfa00 ;
  178. 'REPETER' iitab nitab ;
  179.    ifac = tfa00 . &iitab ;
  180.    iqfac = 'CHANGER' ifac 'QUAF' ;
  181.    miqfac = 'MODELISER' iqfac 'NAVIER_STOKES' discr ;
  182.    ciqfac = ('DOMA' miqfac 'CENTRE') 'POIN' 1 ;
  183.    iele = tel00 . &iitab ;
  184.    iqele = 'CHANGER' iele 'QUAF' ;
  185.    miqele = 'MODELISER' iqele 'NAVIER_STOKES' discr ;
  186.    ciqele = ('DOMA' miqele 'CENTRE') 'POIN' 1 ;
  187. * Attention ('MESU' iele) ne fonctionne pas en axisymetrique
  188.    volele = 'MAXIMUM' ('DOMA' miqele 'VOLUME') ;
  189.    clfc = 'MANUEL' 'SEG2' ciqfac ciqele ;
  190.    mlcf = 'MANUEL' 'RIGIDITE' clfc ('MOTS' 'T') 'QUEL'
  191.             ('PROG' 0.D0 1.D0) ('PROG' 0.D0 0.D0) ;
  192.    mlfc = 'MANUEL' 'RIGIDITE' clfc ('MOTS' 'T') 'QUEL'
  193.             ('PROG' 0.D0 0.D0)
  194.             ('PROG' ('/' 1.D0 volele) 0.D0) ;
  195.    'SI' ('EGA' &iitab 1) ;
  196.       cfc00 = clfc ;
  197.       mcf00 = mlcf ;
  198.       mfc00 = mlfc ;
  199.    'SINON' ;
  200.       cfc00 = 'ET' cfc00 clfc ;
  201.       mcf00 = 'ET' mcf00 mlcf ;
  202.       mfc00 = 'ET' mfc00 mlfc ;
  203.    'FINSI' ;
  204. 'FIN' iitab ;
  205. finpro cfc00 mcf00 mfc00 ;
  206.  
  207. DEBPROC tcpu9 a/flottant ;
  208. TABTPS = TEMP 'NOEC';
  209. tcpu = TABTPS.'TEMPS_CPU'.'INITIAL';
  210. tcpus = '/' ('FLOTTANT' tcpu) 100.D0 ;
  211. SI ( exis a ) ;
  212.  RESPRO tcpus ;
  213. SINON ;
  214.  'MESSAGE' ( et ('CHAINE' 'tcpus = ' tcpus) ' secondes') ;
  215. FINSI ;
  216. FINPROC  ;
  217. DEBPROC PRPHE8 prt7C*'LISTREEL' roo*'LISTREEL' muo*'LISTREEL'
  218.         cpo*'LISTREEL' lambo*'LISTREEL' T/'CHPOINT'
  219.         TL/'LISTREEL'  TS/'FLOTTANT' ;
  220. prt7 = prt7C + ( prog ( dime prt7C ) * 273.15 ) ; comm en Kelvin ;
  221.  
  222.    'SI' ('EXISTE' T) ;
  223.      rhohe8 = 'IPOL' T prt7 roo ;
  224.      muhe8  = 'IPOL' T prt7 muo ;
  225.      lhe8   = 'IPOL' T prt7 lambo ;
  226.      cphe8  = 'IPOL' T prt7 cpo ;
  227.     'RESPRO' rhohe8 muhe8 lhe8 cphe8 ;
  228.    'FINSI' ;
  229.  
  230.    'SI' ('EXISTE' TL) ;
  231.      rhohe8 = 'IPOL' TL prt7 roo ;
  232.      muhe8  = 'IPOL' TL prt7 muo ;
  233.      lhe8   = 'IPOL' TL prt7 lambo ;
  234.      cphe8  = 'IPOL' TL prt7 cpo ;
  235.     'RESPRO' rhohe8 muhe8 lhe8 cphe8 ;
  236.    'FINSI' ;
  237.  
  238.    'SI' ('EXISTE' TS) ;
  239.      rhohe8 = 'IPOL' TS prt7 roo ;
  240.      muhe8  = 'IPOL' TS prt7 muo ;
  241.      lhe8   = 'IPOL' TS prt7 lambo ;
  242.      cphe8  = 'IPOL' TS prt7 cpo ;
  243.     'RESPRO' rhohe8 muhe8 lhe8 cphe8 ;
  244.    'FINSI' ;
  245. 'FINPROC' ;
  246.  
  247. DEBPROC PTH_HE8 X/'CHPOINT' XL/'LISTREEL'  XS/'FLOTTANT' ;
  248. TABHE8 = TABLE ;
  249.    'SI' ('EXISTE' X) ;
  250.     rhohe8 muhe8 lhe8 cphe8 =
  251.        PRPHE8 PROGTHe PROGRHO PROGMU PROGCP PROGLAM X ;
  252.    'FINSI' ;
  253.  
  254.    'SI' ('EXISTE' XL) ;
  255.     rhohe8 muhe8 lhe8 cphe8 =
  256.        PRPHE8 PROGTHe PROGRHO PROGMU PROGCP PROGLAM XL ;
  257.    'FINSI' ;
  258.  
  259.    'SI' ('EXISTE' XS) ;
  260.     rhohe8 muhe8 lhe8 cphe8 =
  261.        PRPHE8 PROGTHe PROGRHO PROGMU PROGCP PROGLAM XS ;
  262.    'FINSI' ;
  263. TABHE8 . 'ROG'  = rhohe8 ;
  264. TABHE8 . 'MUG'  = muhe8 ;
  265. TABHE8 . 'LAMG' = lhe8 ;
  266. TABHE8 . 'CPG'  = cphe8 ;
  267. FINPRO TABHE8 ;
  268.  
  269. DEBPROC PRACIER prt7C*'LISTREEL' roo*'LISTREEL'
  270.         cpo*'LISTREEL' lambo*'LISTREEL' T/'CHPOINT'
  271.         TL/'LISTREEL'  TS/'FLOTTANT' ;
  272. prt7 = prt7C + ( prog ( dime prt7C ) * 273.15 ) ; comm en Kelvin ;
  273.    'SI' ('EXISTE' T) ;
  274.      rhoaci = 'IPOL' T prt7 roo ;
  275.      laci   = 'IPOL' T prt7 lambo ;
  276.      cpaci  = 'IPOL' T prt7 cpo ;
  277.     'RESPRO' rhoaci laci cpaci ;
  278.    'FINSI' ;
  279.  
  280.    'SI' ('EXISTE' TL) ;
  281.      rhoaci = 'IPOL' TL prt7 roo ;
  282.      laci   = 'IPOL' TL prt7 lambo ;
  283.      cpaci  = 'IPOL' TL prt7 cpo ;
  284.     'RESPRO' rhoaci laci cpaci ;
  285.    'FINSI' ;
  286.  
  287.    'SI' ('EXISTE' TS) ;
  288.      rhoaci = 'IPOL' TS prt7 roo ;
  289.      laci   = 'IPOL' TS prt7 lambo ;
  290.      cpaci  = 'IPOL' TS prt7 cpo ;
  291.     'RESPRO' rhoaci laci cpaci ;
  292.    'FINSI' ;
  293. 'FINPROC' ;
  294.  
  295. DEBPROC PTH_ACI X/'CHPOINT' XL/'LISTREEL'  XS/'FLOTTANT' ;
  296. TABACI = TABLE ;
  297.   'SI' ('EXISTE' X) ;
  298.     rhohe8 lhe8 cphe8 =
  299.        PRACIER PROGTAc ROACIER CPACIER LAMACIER X ;
  300.    'FINSI' ;
  301.  
  302.    'SI' ('EXISTE' XL) ;
  303.     rhohe8  lhe8 cphe8 =
  304.        PRACIER PROGTAc ROACIER CPACIER LAMACIER XL ;
  305.    'FINSI' ;
  306.  
  307.    'SI' ('EXISTE' XS) ;
  308.     rhohe8  lhe8 cphe8 =
  309.        PRACIER PROGTAc ROACIER CPACIER LAMACIER XS ;
  310.    'FINSI' ;
  311. TABACI . 'ROS'  = rhohe8 ;
  312. TABACI . 'LAMS' = lhe8 ;
  313. TABACI . 'CPS'  = cphe8 ;
  314. FINPRO TABACI ;
  315.  
  316. 'DEBPROC'  chpobor mess1/'MOT' T/'FLOTTANT' TC/'CHPOINT' ;
  317. *Elle permet d'afficher les valeurs minimales et maximales d'un
  318. *champoint avec message optionnel
  319. MesEx0 = EXISTE mess1 ;
  320. 'SI' ('EXISTE' TC) ;
  321.   SI MesEx0 ;
  322.   mess mess1 ' : ' ( MINI TC ) ( MAXI TC) ;
  323.  SINON ;
  324.   mess ( MINI TC ) ( MAXI TC) ;
  325.  FINSI ;
  326. FINSi ;
  327. 'SI' ('EXISTE' T) ;
  328.   SI MesEx0 ;
  329.   mess mess1 ' : ' T ;
  330.  SINON ;
  331.   mess T ;
  332.  FINSI ;
  333. FINSi ;
  334. FINPROC ;
  335.  
  336. debproc ecform c1*MOT c2*MOT c3*MOT v0*FLOTTANT ;
  337. c1 = et c1 ' = ' ;
  338. c3 = et ' ' c3 ;
  339. c20 = ( chaine 'FORMAT' c2 v0) ;
  340. mess (et (et c1 c20 ) c3) ;
  341. finproc ;
  342.  
  343. **********************************************************************************************
  344. **********************************************************************************************
  345. ***                       FIN  PROCEDURES
  346. **********************************************************************************************
  347. **********************************************************************************************
  348.  
  349.  
  350. **********************************************************************************************
  351. *
  352. *                   DONNEES GEOMETRIE
  353. *
  354. **********************************************************************************************
  355.  
  356. OPTION TRAC PSC ;
  357.  
  359. OPTI ELEM TET4;
  360.  
  361. DENS 0.003;
  362.  
  363. R = 0.575; comm profondeur radiale ;
  364. H = 1.660; comm hauteur totale ;
  365.  
  366. RFW = 0.100; comm rayon de courbure de la FW ;
  367. PITCHFW = 0.0219; comm pitch entre canaux ;
  368. EPFW = 0.030; comm epaisseur totale FW ;
  369.  
  370. DCT = 0.015; comm dimensions des canaux de refroidissement ;
  371. DCP = 0.015;
  372.  
  373. DPL = 0.0035; comm distance des canaux de la surface exposee au plasma ;
  374.  
  375. DCH = (PITCHFW - DCT) / 2.;
  376.  
  377.  
  378. EPS0 = 1.E-6 ;
  379.  
  380. ***********************************************************************
  381. *
  382. *                   MAILLAGE
  383. *
  384. ***********************************************************************
  385.  
  386. si complet ;
  387.  N1V1 = 3 ;
  388.  N2V1 = 20 ;
  389.  NV2  = 8 ;
  390.  NV3  = 40 ;
  391.  NV7  = 6 ;
  392. sinon ;
  393. * N1V1 = 3 ;
  394. * N2V1 = 3 ;
  395. * NV2  = 4 ;
  396. * NV3  = 4 ;
  397. * NV7  = 6 ;
  398. * modif gounand
  399.  N1V1 = 2 ;
  400.  N2V1 = 2 ;
  401.  NV2  = 2 ;
  402.  NV3  = 2 ;
  403.  NV7  = 2 ;
  404. FINSI ;
  405.  
  406. NV4  = NV2  ;
  407. NV5  = N2V1 ;
  408. NV6  =  N1V1 ;
  409. NV8  =  N1V1 ;
  410. NV9  = N2V1 ;
  411. NV10 = NV2 ;
  412. NV11 = NV3 ;
  413. NV12 = NV2 ;
  414. N1V13 = N2V1 ;
  415. N2V13 = N1V1 ;
  416.  
  417.  
  418. P1 = 0. 0. 0. ;
  419. P2 = 0. PITCHFW 0.;
  420. P3 = 0. PITCHFW ( -1. * EPFW );
  421. P4 = 0. 0. (-1. * EPFW);
  422.  
  423.  
  424. PC1 = 0. DCH ( -1. * DPL);
  425. PC2 = 0. (DCH + DCT) ( -1. * DPL);
  426. PC3 = 0. (DCH + DCT) ( -1. * (DPL + DCP) );
  427. PC4 = 0. DCH ( -1. * (DPL + DCP) );
  428.  
  429.  
  430.  
  431.  
  432. L1 = D P1 P2;
  433. L2 = D P2 P3;
  434. L3 = D P3 P4;
  435. L4 = D P4 P1;
  436.  
  437. LC1 = D PC1 PC2;
  438. LC2 = D PC2 PC3;
  439. LC3 = D PC3 PC4;
  440. LC4 = D PC4 PC1;
  441.  
  442. C1 = L1 et L2 et L3 et L4;
  443. C2 = LC1 et LC2 et LC3 et LC4;
  444.  
  445. S1 = SURF ( C1 et (INVE C2) ) PLAN;
  446. V1 = VOLU TRAN N1V1 (PITCHFW 0. 0.) S1;
  447. V1 = VOLU TRAN N2V1 ( (R - RFW - PITCHFW) 0. 0.) V1;
  448.  
  449.  
  450. S2 = FACE 2 V1;
  451. V2 = VOLU ROTA NV2 90. S2
  452.         ( (R - RFW) 0. (-1 * RFW))
  453.         ( (R - RFW) PITCHFW (-1 * RFW));
  454.  
  455.  
  456.  
  457. S3 = FACE 2 V2;
  458. V3 = VOLU TRAN NV3 ( 0. 0. (-1 * (H - (2. * RFW)))) S3;
  459.  
  460. S4 = FACE 2 V3;
  461. V4 = VOLU ROTA NV4 90. S4
  462.         ( (R - RFW) 0. (-1 * (H - RFW)))
  463.         ( (R - RFW) PITCHFW (-1 * (H - RFW)));
  464.  
  465. S5 = FACE 2 V4;
  466. V5 = VOLU TRAN NV5 ( (-1. * (R - RFW - PITCHFW) ) 0. 0.) S5;
  467.  
  468.  
  469. S6 = FACE 2 V5;
  470. S7 = PROJ (1. 0. 0.) S6 PLAN
  471.                 ( (0. 0. (-1. * H) ))
  472.                 ( (PITCHFW) (PITCHFW) (-1. * H) )
  473.                 ( 0. 0. 0.);
  474. V6 = VOLU NV6 S6 S7;
  475.  
  476.  
  477. S8 = PROJ S7 (0. 1. 0.) PLAN
  478.                 ( 0. (2*PITCHFW) H )
  479.                 ( PITCHFW (PITCHFW) H )
  480.                 ( 0. (2*PITCHFW) 0.);
  481. V7 = VOLU NV7 S7 S8;
  482.  
  483.  
  484.  
  485. S9 = PROJ S8 (-1. 0. 0.) PLAN
  486.                     (PITCHFW. 0. 0.)
  487.                     (PITCHFW 1. 0.)
  488.                     (PITCHFW 0. 1.);
  489. V8 = VOLU NV8 S8 S9;
  490.  
  491. V9 = VOLU TRAN NV9 ( (R - RFW - PITCHFW)  0. 0.) S9;
  492.  
  493. S10 = FACE 2 V9;
  494. V10 = VOLU ROTA NV10 -90. S10
  495.         ( (R - RFW) 0. (-1 * (H - RFW)))
  496.         ( (R - RFW) PITCHFW (-1 * (H - RFW)));
  497.  
  498. S11 = FACE 2 V10;
  499. V11 = VOLU TRAN NV11 ( 0. 0.  (H - (2. * RFW))) S11;
  500.  
  501.  
  502. S12 = FACE 2 V11;
  503. V12 = VOLU ROTA NV12 -90. S12
  504.         ( (R - RFW) 0. (-1 * RFW))
  505.         ( (R - RFW) PITCHFW (-1 * RFW));
  506.  
  507. S13 = FACE 2 V12;
  508. V13 = VOLU TRAN N1V13 ( (-1. * (R - RFW - PITCHFW)) 0. 0.) S13;
  509. V13 = VOLU TRAN N2V13 ( (-1.*PITCHFW) 0. 0.) V13;
  510.  
  511.  
  512. VTUBE = V1 ET V2 ET V3 ET V4 ET V5 ET V6 ET V7 ET V8
  513.         ET V9 ET V10 ET V11 ET V12 ET V13;
  514.  
  515. ELIM EPS0 VTUBE;
  516.  
  517. mess ( nbel vtube ) ( nbno vtube );
  518.  
  519.  
  520. VTUBE = REGE VTUBE;
  521.  
  522. VTUBE2 = VTUBE SYME PLAN
  523.         (0. 0. (H / -2.))
  524.         (0. 1. (H / -2.))
  525.         (1. 0. (H / -2.));
  526.  
  527. VTUBE2 = DEPL PLUS VTUBE2 (0. (2*PITCHFW) 0.);
  528.  
  529. VFW = VTUBE et VTUBE2;
  530. ELIM EPS0 VFW;
  531. VFW = REGE VFW;
  532.  
  533. TRAC CACH VFW;
  534.  
  535.  
  536. OPTI SAUV 'MAILLAGE.SAUV';
  537. SAUV VFW;
  538.  
  539. *******************************************************************
  540. *******************************************************************
  541. ***                                                              **
  542. ***      COUPLAGE THERMIQUE 3D - THERMOHYDRAULIQUE 1D            **
  543. ***                                                              **
  544. *******************************************************************
  545. *******************************************************************
  546.  
  547. OPTI DIME 3 ELEM CUB8 ;
  548.  
  549.  
  550. OPTI REST 'MAILLAGE.SAUV'; comm Restitution du maillage ;
  552.  
  553.  
  554. *** #################################################################*
  555. *** ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~*
  556. ***                          DECLARATIONS
  557. *** ~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~*
  558. *** #################################################################*
  559.  
  560.  
  561. oeilx = 1.e30 0.    0.    ;
  562. oeily = 0.    1.e30 0.    ;
  563. oeilz = 0.    0.    1.e30 ;
  564. oeil = 1.e30 1.e30 1.e30 ;
  565. epselim = 1.e-7 ;
  566.  
  567. discr   = 'LINE' ; comm elements lineaires ;
  568. * discr = 'QUAF' ; comm elements quadratiques ;
  569.  
  570. nomsov='Th1D-T3D-mono.sauv' ;
  571.  
  572. TFLUec  = 300.   ;
  573. PsatB  = 1.75  ; comm pression absolue en bars ;
  574. ppa   = PsatB * 1.e5 ; comm pression absolue en Pa ;
  575. CK     = 273.15 ; comm Celsius en Kelvin ;
  576. TFLUek   = TFLUec + CK ;
  577. F_SPLSM = 0.5E6 ; comm flux surface plasma ;
  578. F_SBZ   = 0.1E6 ; comm flux surface interne ;
  579.  
  580. nitr1 = 1 ;
  581. omgr1 = 1. ;
  582. SI (non complet)  ;
  583.  nb_bouc = 1 ;
  584. SINON ;
  585.  nb_bouc = 40 ; comm boucle de calcul ;
  586. FINSI ;
  587.  
  588. Nusslam = 4.364 ; comm Nusselt en laminaire tube circulaire ;
  589. seuilam = 2300. ; comm transition laminaire turbulent  ;
  590.  
  591. *** Loi de convection forcee en regime turbulent (COLBURN)
  592. A_colb = 0.023 ;
  593. B_colb = 0.8D0 ;
  594. C_colb = ('/' 1.D0 3.D0) ;
  595.  
  596. *** Loi de convection forcee en regime turbulent (Gnielinski)
  597. A_gnie = 1.7372 ;
  598. B_gnie = 1.964 ;
  599. C_gnie = -3.8215 ;
  600. s_23 = 2. / 3. ;
  601.  
  602.  
  603. *** Methode d'inversion
  604. MetInv = 'DIRECT' ; comm robuste mais lent ;
  605. *** MetInv = 'ITERAT' ; comm moins robuste mais plus rapide ;
  606. SI ( EGA MetInv 'DIRECT' ) ;
  607.  IndInv = 1 ;
  608. SINON ;
  609.  IndInv = 3 ;
  610. FINSI ;
  611.  
  612. RegEcoM = TABLE ;
  613. RegEcoD = TABLE ;
  614. RTUR = 'TURB' ;
  615. RLAM = 'LAMI' ;
  616.  
  617.  
  618. ***     DONNEES RELATIVES A L ECOULEMENT:
  619. GTUBE = 1.3 / 12. ; comm debit massique kg par seconde ;
  620. SEC = 0.015 * 0.015 ; comm section de passage ;
  621. PMOUL = 0.015 * 4. ; comm perimetre mouille ;
  622. DIAM = 4 * SEC / PMOUL ; comm diametre hydraulique ;
  623.  
  624. *****************************************************************
  625. ***        PROPRIETES MATERIAUX
  626. *****************************************************************
  627. ***       ici les temperatures PROGTAc sont en degres CELSIUS
  628. PROGTAc  = PROG 20.  100. 200. 300. 400. 500. 600. ;
  629. LAMACIER = PROG 25.9 27.0 28.1 28.8 29.2 29.0 28.5 ;
  630. CPACIER  = PROG 446.  486.  524.  564.  621. 701.  805. ;
  631. ROACIER  = PROG 7758. 7756. 7752. 7750. 7746.7 7743. 7740. ;
  632.  
  633.  
  634. *** Conducibilite Thermique ACIER
  635. EVOCDST    = EVOL MANU
  636.  'T' PROGTAc
  637.  'K' LAMACIER ;
  638.  
  639. *** On n'utilise pas ces valeurs
  640. *** Chaleur specifique ACIER
  641. EVOCPST   = EVOL MANU
  642.  'T' PROGTAc
  643.  'C' CPACIER  ;
  644. *** DENSITE ACIER
  645. EVOROST    = EVOL MANU
  646. 'T'   PROGTAc
  647. 'RHO' ROACIER  ;
  648.  
  649.  
  650. *
  651. ***                            HELIUM 8 MPA
  652. *
  653. *** ATTENTION: LES PROGRESSIONS DOIVENT AVOIR LA MEME LONGEUR
  654. ***       ici les temperatures PROGTHe sont en degres CELSIUS
  655. PROGTHe = PROG 250. 260. 270. 280. 290. 300. 310. 320. 330. 340.
  656.               350. 360. 370. 380. 390. 400. 410. 420. 430. 440. 450.
  657.               460. 470. 480. 490. 500. 510. 520. 530. 540. 550. ;
  658. PROGRHO = PROG
  659. 7.2195 7.0872 6.9596 6.8365 6.7176 6.6029 6.4919 6.3847 6.2809 6.1804
  660. 6.0831 5.9888 5.8974 5.8087 5.7227 5.6391 5.5580 5.4791 5.4025 5.3280
  661. 5.2554 5.1849 5.1162 5.0493 4.9841 4.9206 4.8587 4.7983 4.7394 4.6819
  662. 4.6258 ;
  663.  
  664. PROGCP = PROG
  665.  5183.9 5184.2 5184.5 5184.8 5185.1 5185.4 5185.6 5185.9 5186.1 5186.3
  666.  5186.5 5186.7 5186.9 5187.1 5187.3 5187.4 5187.6 5187.7 5187.9 5188.0
  667.  5188.1 5188.3 5188.4 5188.5 5188.6 5188.7 5188.8 5188.9 5188.9 5189.0
  668.  5189.1  ;
  669.  
  670. PROGLAM = PROG
  671.   0.23121 0.23432 0.23741 0.24049 0.24354
  672.   0.24658 0.24960 0.25261 0.25560 0.25857
  673.   0.26152 0.26446 0.26738 0.27029 0.27318
  674.   0.27606 0.27892 0.28176 0.28460 0.28741
  675.   0.29022 0.29300 0.29578 0.29854 0.30129
  676.   0.30402 0.30675 0.30946 0.31215 0.31484 0.31751;
  677.  
  678. PROGMU = PROG
  679.   2.86840E-05  2.90485E-05  2.94108E-05  2.97711E-05  3.01293E-05
  680.   3.04856E-05  3.08401E-05  3.11927E-05  3.15435E-05  3.18927E-05
  681.   3.22402E-05  3.25862E-05  3.29307E-05  3.32737E-05  3.36154E-05
  682.   3.39557E-05  3.42947E-05  3.46325E-05  3.49691E-05  3.53045E-05
  683.   3.56389E-05  3.59722E-05  3.63046E-05  3.66360E-05  3.69664E-05
  684.   3.72960E-05  3.76248E-05  3.79527E-05  3.82799E-05  3.86064E-05
  685.   3.89322E-05;
  686.  
  687. EVOROHE  = EVOL MANU 'T' PROGTHe 'RHO' PROGRHO;
  688. EVOCPHE  = EVOL MANU 'T' PROGTHe 'CP' PROGCP;
  689. EVOMUHE  = EVOL MANU 'T' PROGTHe 'MU' PROGMU;
  690. EVOLAMHE = EVOL MANU 'T' PROGTHe 'LAM' PROGLAM;
  691.  
  692.  
  693. *** helium : la procedure PTH_HE8 sort ro mu lambda cp
  694. *** acier  : la procedure PTH_ACI sort ro lambda cp
  695.  
  696.  
  697. ****************************************************************
  698. ***       IDENTIFICATION DES SURFACES D ECHANGE
  699. ****************************************************************
  700.  
  701.  
  702. XMIN = MINI (COOR 1 VFW);
  703. ELXMIN = ELEM (ENVE VFW) APPUYE
  704.                 (POINT VFW PLAN
  705.                         (XMIN 0. 0.)
  706.                         (XMIN 1. 0.)
  707.                         (XMIN 0. 1.));
  708.  
  709. CTUBES = CCON (CONT ELXMIN);
  710.  
  711. * SIN1 = CTUBES . 2;
  712. * SIN2 = CTUBES . 6;
  713. *bp2016 : on ne sait pas a priori comment range CCON
  714. pSIN1 = 0.0000   7.66500E-02   -1.6490     ;
  715. pSIN2 = 0.0000   1.09500E-02   -1.10000E-02;
  716. repe bccon (DIME CTUBES);
  717.    SIN1t = CTUBES . &bccon;
  718.    n1t = NBEL SIN1t;
  719.    si (n1t ega 20);
  720.      p1t = BARY SIN1t;
  721.      x1 = norm (p1t moin pSIN1);
  722.      x2 = norm (p1t moin pSIN2);
  723.      mess &bccon ': ' x1 x2;
  724.      si (x1 < 1.E-4); isin1 = &bccon;  finsi;
  725.      si (x2 < 1.E-4); isin2 = &bccon;  finsi;
  726.    finsi;
  727. fin bccon;
  728. SIN1 = CTUBES . isin1;
  729. SIN2 = CTUBES . isin2;
  730.  
  731. EXPTUBES = CCON (DIFF (ENVE VFW) ELXMIN);
  732.  
  733. list EXPTUBES ;
  734.  
  735.  
  736. * SCONV1 = EXPTUBES . 2;
  737. * SCONV2 = EXPTUBES . 3;
  738. pconv1 =  0.28682         6.57000E-02    -0.77540;
  739. pconv2 =  0.28682         2.19000E-02    -0.88460;
  740. repe bccon (DIME EXPTUBES);
  741.    SCONV1t = EXPTUBES . &bccon;
  742.    n1t = NBEL SCONV1t;
  743. *    p1t = BARY SCONV1t;
  744. *    MESS &bccon ' : ' n1t (coor p1t 1) (coor p1t 2) (coor p1t 3);
  745. *    2    :   600    0.28682         6.57000E-02    -0.77540
  746. *    3    :   600    0.28682         2.19000E-02    -0.88460
  747.    si (n1t ega 600);
  748.      p1t = BARY SCONV1t;
  749.      x1 = norm (p1t moin pconv1);
  750.      x2 = norm (p1t moin pconv2);
  751.      mess &bccon ': ' x1 x2;
  752.      si (x1 < 1.E-4); iconv1 = &bccon;  finsi;
  753.      si (x2 < 1.E-4); iconv2 = &bccon;  finsi;
  754.    finsi;
  755. fin bccon;
  756. SCONV1 = EXPTUBES . iconv1;
  757. SCONV2 = EXPTUBES . iconv2;
  758.  
  759.  
  760. ****************************************************************
  761. ***       PARTITIONNEMENT DES SURFACES D ECHANGE
  762. ****************************************************************
  763.  
  764.  
  765. TUBE1 = TABLE;
  766. TUBE2 = TABLE;
  767.  
  768. TUBE1 . 'G' = GTUBE;
  769. TUBE1 . 'PM' = PMOUL;
  770. TUBE1 . 'DH' = DIAM;
  771. TUBE1 . 'RHO' = EVOROHE;
  772. TUBE1 . 'LAM' = EVOLAMHE;
  773. TUBE1 . 'CP' = EVOCPHE;
  774. TUBE1 . 'MU' = EVOMUHE;
  775.  
  776. TUBE2 . 'G' = GTUBE;
  777. TUBE2 . 'PM' = PMOUL;
  778. TUBE2 . 'DH' = DIAM;
  779. TUBE2 . 'RHO' = EVOROHE;
  780. TUBE2 . 'LAM' = EVOLAMHE;
  781. TUBE2 . 'CP' = EVOCPHE;
  782. TUBE2 . 'MU' = EVOMUHE;
  783.  
  784. Spass1 = TUBE1 . 'PM' * TUBE1 . 'DH' / 4. ;
  785. Spass2 = TUBE2 . 'PM' * TUBE2 . 'DH' / 4. ;
  786.  
  787.  
  788. TUBE1 . SIN = SIN1;
  789. TUBE2 . SIN = SIN2;
  790. TUBE1 . SURFCONV = SCONV1;
  791. TUBE2 . SURFCONV = SCONV2;
  792.  
  793. *** Flux de chaleur sur la FW
  794. YMAX = MAXI (COOR 2 VFW);
  795. YMIN = MINI (COOR 2 VFW);
  796.  
  797. ELYMIN = ELEM (ENVE VFW) APPUYE
  798.             (POINT VFW PLAN
  799.                 (0. YMIN 0.)
  800.                 (1. YMIN 0.)
  801.                 (0. YMIN 1.) );
  802.  
  803. ELYMAX = ELEM (ENVE VFW) APPUYE
  804.             (POINT VFW PLAN
  805.                 (0. YMAX 0.)
  806.                 (1. YMAX 0.)
  807.                 (0. YMAX 1.) );
  808.  
  809. ENVEXT = DIFF (ENVE VFW)
  810.              (ELYMAX et ELYMIN et ELXMIN et
  811.               TUBE1 . SURFCONV et TUBE2 . SURFCONV);
  812.  
  813. * SFW2 = (CCON ENVEXT) . 2;
  814. * SFW1 = (CCON ENVEXT) . 1;
  815. psfw1 = 0.28310   4.38000E-02   -0.83000;
  816. psfw2 = 0.29199   4.38000E-02   -0.83000;
  817. ENVCCON = CCON ENVEXT;
  818. repe bccon (DIME ENVCCON);
  819.    sfw1t =  ENVCCON . &bccon;
  820.    n1t = NBEL sfw1t;
  821.    p1t = BARY sfw1t;
  822. *    MESS &bccon ' : ' n1t (coor p1t 1) (coor p1t 2) (coor p1t 3);
  823.      x1 = norm (p1t moin psfw1);
  824.      x2 = norm (p1t moin psfw2);
  825.      mess &bccon ': ' x1 x2;
  826.      si (x1 < 1.E-4); isfw1 = &bccon;  finsi;
  827.      si (x2 < 1.E-4); isfw2 = &bccon;  finsi;
  828. fin  bccon;
  829. SFW2 = ENVCCON . isfw2;
  830. SFW1 = ENVCCON . isfw1;
  831.  
  832. ZMAX = MAXI (COOR 3 SFW2);
  833. ELSIDE = ELEM SFW2 APPUYE
  834.             (POINT SFW2 PLAN
  835.                 (0. 0. ZMAX)
  836.                 (1. 0. ZMAX)
  837.                 (0. 1. ZMAX) 0.0001);
  838.  
  839. XMAX = MAXI (COOR 1 ELSIDE);
  840. SPLSM = ELEM SFW2 APPUYE
  841.             (POINT (COOR 1 SFW2) EGSUPE (XMAX - 0.0001));
  842.  
  843. xmil ymil zmil = coor splsm ;
  844. pmil = ( maxi xmil ) (0.5 * ((mini ymil) + ( maxi ymil)))
  845.   (0.5 * ((mini zmil ) + ( maxi zmil))) ;
  846.  
  847. ZMAX = MAXI (COOR 3 SFW1);
  848. ELSIDE = ELEM SFW1 APPUYE
  849.             (POINT SFW1 PLAN
  850.                 (0. 0. ZMAX)
  851.                 (1. 0. ZMAX)
  852.                 (0. 1. ZMAX) 0.0001);
  853.  
  854. XMAX = MAXI (COOR 1 ELSIDE);
  855. SBZ = ELEM SFW1 APPUYE
  856.             (POINT (COOR 1 SFW1) EGSUPE (XMAX - 0.0001));
  857.  
  858. W_SPLSM = F_SPLSM * ( mesu SPLSM ) ;
  859. W_SBZ   = F_SBZ   * ( mesu SBZ ) ;
  860.  
  861. XTT YTT ZTT = COOR VFW ;
  862. decx = 2. * (( MAXI XTT ) - ( MINI XTT )) ;
  863. decy = 2. * (( MAXI YTT ) - ( MINI YTT )) ;
  864.  
  865. PARTSURF TUBE1 ;
  866. FLUI1D_2 TUBE1 decx decy 1.0 Spass1 ;
  867.  
  868. PARTSURF TUBE2;
  869. FLUI1D_2 TUBE2 decx decy 1.1 Spass2 ;
  870.  
  871.  
  872.  
  873. sc1 = tube1.surfconv ;
  874. sc2 = tube2.surfconv ;
  875.  
  876. *trac cach ( vfw et tube1.mtflu et tube2.mtflu ) ;
  877.  
  878.  
  879. elim epselim  ( tube1.baflu et tube1.mtflu et sc1 ) ;
  880. pelim1 = '*' ('**' ('/' ('MESURE' tube1.mtflu) ('NBEL' tube1.mtflu))
  881.                   ('/' 1.D0 ('VALEUR' 'DIME'))) 1.D-3 ;
  882.  
  883. 'ELIMINATION' (sc1 et VFW ) pelim1 ;
  884. 'ELIMINATION' (tube1.baflu et tube1.mtflu  ) pelim1 ;
  885.  
  886. elim epselim  ( tube2.baflu et tube2.mtflu et sc2 ) ;
  887. pelim2 = '*' ('**' ('/' ('MESURE' tube2.mtflu) ('NBEL' tube2.mtflu))
  888.                   ('/' 1.D0 ('VALEUR' 'DIME'))) 1.D-3 ;
  889.  
  890. 'ELIMINATION' (sc2 et VFW ) pelim2 ;
  891. 'ELIMINATION' (tube2.baflu et tube2.mtflu  ) pelim2 ;
  892.  
  893. *** On va construire le chpoint des produits scalaires de la normale
  894. *** a la face SPLSM et le vecteur unitaire i (1. 0. 0. ), egal au cosinus
  895. *** de la normale et du vecteur i, pour ponderer le flux impose et
  896. *** faire en sorte que sa direction soit donc constante. On cree un
  897. *** nouveau maillage SPLSM2 oriente vers l'exterieur. _SPLSM2 et $SPLSM2
  898. *** sont respectivement les elements QUAF et le modele Navier-Stokes
  899. *** correspondant.
  900. *** Idem avec la face SBZ
  901.  
  902. *** On va multiplier ce produit scalaire par le flux impose.
  903.  
  904. ListXm = prog ;
  905. repe x ( nbno splsm ) ;
  906.  ListXm = ListXm et ( prog 1. 0. 0. ) ;
  907. fin x ;
  908. splsm = inve ( orie  SPLSM 'POINT' ( 0. 0. 0. )) ;
  909. SBZ   = inve ( orie  SBZ   'POINT' ( 0. 0. 0. )) ;
  910. CHPx1 = MANU 'CHPO' splsm
  911.           ('MOTS' 'UX' 'UY' 'UZ') ListXm ;
  912. CHPx2 = MANU 'CHPO' sbz
  913.           ('MOTS' 'UX' 'UY' 'UZ') ListXm ;
  914.  
  915. *** Generation des QUAFs
  916. *** --------------------
  917. _baflu1     = 'CHANGER' tube1.baflu   'QUAF' ;
  918. _mtflu1     = 'CHANGER' tube1.mtflu   'QUAF' ;
  919. _Clim1      = 'CHANGER' sc1           'QUAF' ;
  920. _VFW        = 'CHANGER' VFW           'QUAF' ;
  921.  
  922. _baflu2     = 'CHANGER' tube2.baflu   'QUAF' ;
  923. _mtflu2     = 'CHANGER' tube2.mtflu   'QUAF' ;
  924. _Clim2      = 'CHANGER' sc2           'QUAF' ;
  925. _SPLSM      = 'CHANGER' SPLSM         'QUAF' ;
  926. _SBZ        = 'CHANGER' SBZ           'QUAF' ;
  927.  
  928.  
  929. 'TEMPS' 'ZERO' ;
  930. cfc1 mcf1 mfc1 = matcon0 ( tube1 . fac0 ) ( tube1 . ele0 ) ;
  931.  
  932. *** Elimination des points doubles
  933. *** ------------------------------
  934. 'ELIMINATION' ( _baflu1  'ET' _mtflu1  'ET' cfc1 ) pelim1 ;
  935. 'ELIMINATION' ( _Clim1 'ET' _VFW 'ET' cfc1 ) pelim1 ;
  936.  
  937. mscal = 'MOTS' 'SCAL' ;
  938. 'OPTI' 'INCO' mscal mscal ;
  939. mcf1 = 'CHANGER' mcf1 'INCO' ('MOTS' 'T') ('MOTS' 'SCAL')
  940.                            ('MOTS' 'Q') ('MOTS' 'SCAL') ;
  941. mfc1 = 'CHANGER' mfc1 'INCO' ('MOTS' 'T') ('MOTS' 'SCAL')
  942.                            ('MOTS' 'Q') ('MOTS' 'SCAL') ;
  943.  
  944. cfc2 mcf2 mfc2 = matcon0 ( tube2 . fac0 ) ( tube2 . ele0 ) ;
  945.  
  946.  
  947.  
  948.  
  949. *** Elimination des points doubles
  950. *** ------------------------------
  951. 'ELIMINATION' ( _baflu2  'ET' _mtflu2  'ET' cfc2 ) pelim2 ;
  952. 'ELIMINATION' ( _Clim2 'ET' _VFW 'ET' cfc2 ) pelim2 ;
  953.  
  954. mcf2 = 'CHANGER' mcf2 'INCO' ('MOTS' 'T') ('MOTS' 'SCAL')
  955.                            ('MOTS' 'Q') ('MOTS' 'SCAL') ;
  956. mfc2 = 'CHANGER' mfc2 'INCO' ('MOTS' 'T') ('MOTS' 'SCAL')
  957.                            ('MOTS' 'Q') ('MOTS' 'SCAL') ;
  958. TCpu1 = tcpu9 0. ; comm temps ecoule ;
  959.  
  960.  
  961.  
  962. *** ***** Densite de puissance neutronique
  963. afw = 2.7116 ;
  964. bfw = 13.673 ;
  965. cfw = 3.3047 ;
  966. dfw = 5.425  ;
  967. FACTF = 0.78/0.75;
  968.  
  969.  
  970. Pr_Xfw = PROG  0. PAS 0.001 1 ;
  971. Pr_NWLfw  = FACTF * (  (afw * (EXP ( -1. * bfw * Pr_Xfw))) +
  972.                        (cfw * (EXP ( -1. * dfw * Pr_Xfw)))
  973.                     );
  974. EVQfw = EVOL MANU 'XRAD' Pr_Xfw 'FW' Pr_NWLfw  ;
  975. X_TOT = (COOR 1 VFW);
  976. NWP_fw = IPOL X_TOT Pr_Xfw Pr_NWLfw;
  977. NWP_fw = NWP_fw * 1.E6;
  978.  
  979.  
  980.  
  981. *** Recapitulatif
  982. *** -------------
  983. opti echo 0 ;
  984. Mess 'Recapitulatif : ' ;
  985. Mess '-------------' ;
  987.  
  988. SI ( EGA MetInv 'DIRECT' ) ;
  989.  Mess 'Methode d inversion directe, robuste mais lente' ;
  990. SINON ;
  992. 'Methode d inversion iterative, moins robuste mais plus rapide';
  993. FINSI ;
  994.  
  995. SI EchColb ;
  996.  MESS 'Loi echange turbulent COLBURN' ;
  997. SINON ;
  998.  MESS 'Loi echange turbulent Gnielinski' ;
  999. FINSI ;
  1000.  
  1001. SI (non complet) ;
  1002.  MESS 'Calcul test avec ' nb_bouc ' iterations' ;
  1003. SINON ;
  1004.  MESS 'Calcul nominal avec ' nb_bouc ' iterations' ;
  1005. FINSI ;
  1006.  
  1007. *gounand opti echo 1 ;
  1008.  
  1009. ***********************************************************
  1010. *                                                         *
  1011. *** PREPARATION DU CALCUL                                 *
  1012. *                                                         *
  1013. ***********************************************************
  1014. *
  1015. *** Modeles Navier-Stokes
  1016. *** ---------------------
  1017.  
  1018. $baflu1   =  'MODELISER' _baflu1  'NAVIER_STOKES' discr  ;
  1019. $mtflu1   =  'MODELISER' _mtflu1  'NAVIER_STOKES' discr  ;
  1020. $Clim1    =  'MODELISER' _Clim1   'NAVIER_STOKES' discr  ;
  1021. $baflu2   =  'MODELISER' _baflu2  'NAVIER_STOKES' discr  ;
  1022. $mtflu2   =  'MODELISER' _mtflu2  'NAVIER_STOKES' discr  ;
  1023. $Clim2    =  'MODELISER' _Clim2   'NAVIER_STOKES' discr  ;
  1024. $VFW      =  'MODELISER' _VFW     'NAVIER_STOKES' discr  ;
  1025. $SPLSM    =  'MODELISER' _SPLSM   'NAVIER_STOKES' discr  ;
  1026. $SBZ      =  'MODELISER' _SBZ     'NAVIER_STOKES' discr  ;
  1027.  
  1028.  
  1029. FSPLSM9 = F_SPLSM * ( PSCA  ( doma $SPLSM NORMALEV )
  1030. CHPx1 ('MOTS' 'UX' 'UY' 'UZ') ('MOTS' 'UX' 'UY' 'UZ')) ;
  1031. FSBZ9 = F_SBZ * ( PSCA  ( doma $SBZ NORMALEV )
  1032. CHPx2 ('MOTS' 'UX' 'UY' 'UZ') ('MOTS' 'UX' 'UY' 'UZ')) ;
  1033.  
  1034. trac cach FSPLSM9 splsm titr 'flux impose sur face SPLSM - W/m2' ;
  1035. trac cach FSBZ9   sbz   titr 'flux impose sur face  SBZ - W/m2' ;
  1036.  
  1037.  
  1038. NWP_fwe = NOEL $VFW NWP_fw ; comm sources ;
  1039. VoSol = ( maxi ( resu ( DOMA $VFW 'VOLUME' ))) ;
  1040. SouSol = ( maxi ( resu  NWP_fw  )) ;
  1041.  
  1042.  
  1043.  
  1044. *** Initialisation des tables pour les calculs Thermiques structures et fluides
  1045.  
  1046. rvsol = 'EQEX' 'ITMA' 1 'NITER' nitr1 'FIDT' 1000 'OMEGA' omgr1 ;
  1047.  
  1048. rvsol = 'EQEX' rvsol
  1049.          'OPTI' 'EF' 'IMPL'
  1050.       'ZONE' $VFW     'OPER' 'LAPN' 'Lacier'   'INCO' 'TSOL'
  1051.       'ZONE' $Clim1   'OPER' 'ECHI' 'H1' 'T1'  'INCO' 'TSOL' 'TSOL'
  1052.       'ZONE' $Clim2   'OPER' 'ECHI' 'H2' 'T2'  'INCO' 'TSOL' 'TSOL'
  1053.         ;
  1054.  
  1055.  
  1056. rvsol = 'EQEX' rvsol
  1057.          'OPTI' 'EF' 'IMPL'
  1058.          'ZONE' $VFW  'OPER' 'FIMP' 'Soursol' 'INCO' 'TSOL'
  1059.          'ZONE' $SPLSM 'OPER' 'FIMP' FSPLSM9  'INCO' 'TSOL'
  1060.          'ZONE' $SBZ   'OPER' 'FIMP' FSBZ9    'INCO' 'TSOL'
  1061.         ;
  1062.  
  1063. rvsol . 'METHINV' . 'TYPINV' = IndInv ;
  1064.  
  1065. *** Dans l'eau
  1066.  
  1067. rvflu = 'EQEX' 'ITMA' 1 'NITER' 1 'FIDT' 1000  ;
  1068. rvflu = 'EQEX' rvflu
  1069.          'OPTI' 'EF' 'IMPL' 'CENTREE' 'NOCONS'
  1070. 'ZONE' $mtflu1 'OPER' 'KONV' 'RCPFLU1' 'UFLU1' 'LFLU1' 'INCO' 'TFLU'
  1071. 'ZONE' $mtflu2 'OPER' 'KONV' 'RCPFLU2' 'UFLU2' 'LFLU2' 'INCO' 'TFLU'
  1072.         ;
  1073.  
  1074. rvflu = 'EQEX' rvflu
  1075.          'OPTI' 'EF' 'IMPL'
  1076.          'ZONE' $mtflu1 'OPER' 'LAPN' 'LFLU1' 'INCO' 'TFLU'
  1077.          'ZONE' $mtflu1 'OPER' 'FIMP' 'PFLU1' 'INCO' 'TFLU'
  1078.          'ZONE' $mtflu2 'OPER' 'LAPN' 'LFLU2' 'INCO' 'TFLU'
  1079.          'ZONE' $mtflu2 'OPER' 'FIMP' 'PFLU2' 'INCO' 'TFLU'
  1080.          ;
  1081.  
  1082.  
  1083. *** Conditions aux limites en temperature lames d'eau
  1084.  
  1085. rvflu = 'EQEX' rvflu
  1086.          'CLIM' 'TFLU' 'TIMP' ('DOMA' $baflu1 'MAILLAGE') TFLUek
  1087.          'CLIM' 'TFLU' 'TIMP' ('DOMA' $baflu2 'MAILLAGE') TFLUek
  1088.          ;
  1089.  
  1090. *** Initialisation de toutes les variables avant le calcul
  1091.  
  1092. rvi = 'TABLE' 'INCO' ;
  1093. rvsol . 'INCO' = rvi ;
  1094. rvflu . 'INCO' = rvi ;
  1095. rvi . 'TSOL' = 'KCHT' $VFW 'SCAL' 'SOMMET' TFLUek ;
  1096.  
  1097. LamAci = ( pth_aci TFLUek ) . 'LAMS' ;
  1098.  
  1099. rvi . 'Lacier'    = 'KCHT' $VFW   'SCAL' 'CENTRE' LamAci  ;
  1100. rvi . 'Soursol'  = 'KCHT' $VFW   'SCAL' 'CENTRE' NWP_fwe ;
  1101.  
  1102.  
  1103. rvi . 'T1'  = 'KCHT'  $Clim1 'SCAL' 'CENTRE' 0.D0 ;
  1104. rvi . 'F1'  = 'KCHT'  $Clim1 'SCAL' 'CENTRE' 0.D0 ;
  1105. rvi . 'H1'  = 'KCHT'  $Clim1 'SCAL' 'CENTRE' 0.D0 ;
  1106. rvi . 'T2'  = 'KCHT'  $Clim2 'SCAL' 'CENTRE' 0.D0 ;
  1107. rvi . 'F2'  = 'KCHT'  $Clim2 'SCAL' 'CENTRE' 0.D0 ;
  1108. rvi . 'H2'  = 'KCHT'  $Clim2 'SCAL' 'CENTRE' 0.D0 ;
  1109.  
  1110. rvi . 'TFLU' = 'KCHT' ( $mtflu1 et $mtflu2 ) 'SCAL' 'SOMMET' TFLUek ;
  1111. rvi . 'PFLU1'= 'KCHT' $mtflu1 'SCAL' 'CENTRE' 0.D0 ;
  1112. rvi . 'PFLU2'= 'KCHT' $mtflu2 'SCAL' 'CENTRE' 0.D0 ;
  1113.  
  1114. *** Copy of the fields to do the convergence check :
  1115. thep = 'COPIER' (rvi . 'TFLU') ;
  1116. tcbp = 'COPIER' (rvi . 'TSOL') ;
  1117.  
  1118. *** Initialisation des proprietes physiques de l'helium :
  1119. Rt_He8 = PTH_HE8 TFLUek ;
  1120. rflu  = Rt_He8 . 'ROG' ;
  1121. muflu = Rt_He8 . 'MUG' ;
  1122. lflu  = Rt_He8 . 'LAMG' ;
  1123. cpflu = Rt_He8 . 'CPG' ;
  1124.  
  1125. rvi . 'LFLU1'   =  'KCHT' $mtflu1 'SCAL' 'CENTRE' lflu ;
  1126. rvi . 'RCPFLU1' =  'KCHT' $mtflu1 'SCAL' 'CENTRE' ('*' rflu cpflu) ;
  1127. rvi . 'LFLU2'   =  'KCHT' $mtflu2 'SCAL' 'CENTRE' lflu ;
  1128. rvi . 'RCPFLU2' =  'KCHT' $mtflu2 'SCAL' 'CENTRE' ('*' rflu cpflu) ;
  1129.  
  1130.  
  1131. *** TUBEx . 'G' est un debit massique en kg/s
  1132. uflu1 = (( TUBE1 . 'G'  / Spass1 ) / rflu) ;
  1133. uflu2 = (( TUBE2 . 'G'  / Spass2 ) / rflu) ;
  1134. rvi . 'UFLU1' = 'KCHT' $mtflu1 'VECT' 'SOMMET' ( 0.D0 0.D0 uflu1 ) ;
  1135. rvi . 'UFLU2' = 'KCHT' $mtflu2 'VECT' 'SOMMET' ( 0.D0 0.D0 uflu2 ) ;
  1136.  
  1137. reyn6 = rflu * uflu1 * diam / muflu ;
  1138. mess diam reyn6  uflu1 ;
  1139.  
  1140.  
  1141.  
  1142.  
  1143. ****************************************************************************
  1144. *** BOUCLE DE CALCUL                                                       *
  1145. ***                                                                        *
  1146. ****************************************************************************
  1147.  
  1148. 'TEMPS' 'ZERO' ;
  1149.  
  1150. 'REPETER' bouc nb_bouc ;
  1151.  
  1152. MESS' 1) Calcul de la Tre moy dans les fluides' ;
  1153.    tmyflu1 = 'NOEL' $mtflu1 (rvi . 'TFLU') ;
  1154.    t_flu1 = ( REDU (rvi . 'TFLU') tube1.mtflu ) ;
  1155.    tmyflu2 = 'NOEL' $mtflu2 (rvi . 'TFLU') ;
  1156.    t_flu2 = ( REDU (rvi . 'TFLU') tube2.mtflu ) ;
  1157.  
  1158.    'MESSAGE' 'Maxi Tre moy fluide 1 (degres C)     : '
  1159.              ('-' ('MAXIMUM' tmyflu1) CK) ;
  1160.    'MESSAGE' 'Maxi Tre moy fluide 2 (degres C)     : '
  1161.              ('-' ('MAXIMUM' tmyflu2) CK) ;
  1162.    chpobor 'Tre fluide 1 mini & maxi en C    ' ( t_flu1 - CK );
  1163.    chpobor 'Tre fluide 2 mini & maxi en C    ' ( t_flu2 - CK );
  1164.  
  1165.  
  1166. MESS '*  2) Transfert sur l interface';
  1167.    tmtif1  = '*' mcf1 tmyflu1 ;
  1168.    tmtif2  = '*' mcf2 tmyflu2 ;
  1169.    rvi . 'T1'  = 'KCHT' $clim1 'SCAL' 'CENTRE' tmtif1 ;
  1170.    rvi . 'T2'  = 'KCHT' $clim2 'SCAL' 'CENTRE' tmtif2 ;
  1171. chpobor 'Tre interface 1 (Celsius )' (( rvi . 'T1' ) - CK ) ;
  1172. chpobor 'Tre interface 2 (Celsius )' (( rvi . 'T2' ) - CK ) ;
  1173.  
  1174. MESS ' 3) Calcul du coefficient d echange a l interface   ' ;
  1175. ***   3) Calcul du coefficient d'echange a l'interface
  1176. ***      et des proprietes physiques du solide
  1177. ***      a partir des temperatures a l'instant precedent.
  1178. *** Temperature de melange
  1179.    tm1 = rvi . 'T1' ;
  1180.    tm2 = rvi . 'T2' ;
  1181. *** Temperature a la paroi
  1182.    tp1 = 'NOEL' $clim1   (rvi . 'TSOL') ;
  1183.    tp2 = 'NOEL' $clim2   (rvi . 'TSOL') ;
  1184. *** Temperature de film
  1185.    tfi1 = '*' ('+' tm1 tp1) 0.5D0 ;
  1186.    tfi2 = '*' ('+' tm2 tp2) 0.5D0 ;
  1187.    pptfil1 = PTH_HE8 tfi1 ;
  1188.    mufil1 = pptfil1 . 'MUG' ;
  1189.    lfil1  = pptfil1 . 'LAMG';
  1190.    cpfil1 = pptfil1 . 'CPG' ;
  1191.    pptfil2 = PTH_HE8 tfi2 ;
  1192.    mufil2 = pptfil2 . 'MUG' ;
  1193.    lfil2  = pptfil2 . 'LAMG';
  1194.    cpfil2 = pptfil2 . 'CPG' ;
  1195.    pranfil1 = '*' ('*' mufil1 cpfil1) ('INVERSE' lfil1) ;
  1196.    pranfil2 = '*' ('*' mufil2 cpfil2) ('INVERSE' lfil2) ;
  1197.  
  1198.  
  1199. SI ( EGA &bouc 1 ) ;
  1200. *** Calcul des nombres de Reynolds a partir de la temperature fluide (une fois)
  1201. opti echo  0 ;
  1202.  
  1203.    pptfil9 = PTH_HE8 ( mini t_flu1 ) ;
  1204.    rofil9 = pptfil9 . 'ROG' ;
  1205.    mufil9 = pptfil9 . 'MUG' ;
  1206.    lfil9  = pptfil9 . 'LAMG';
  1207.    cpfil9 = pptfil9 . 'CPG' ;
  1208.    Reflu1 = ( ( TUBE1 . 'G' ) * ( TUBE1 . 'DH' ) / Spass1 ) / mufil9 ;
  1209.  
  1210.    pptfil9 = PTH_HE8 ( mini t_flu2 ) ;
  1211.    rofil9 = pptfil9 . 'ROG' ;
  1212.    mufil9 = pptfil9 . 'MUG' ;
  1213.    lfil9  = pptfil9 . 'LAMG';
  1214.    cpfil9 = pptfil9 . 'CPG' ;
  1215.    Reflu2 = ( ( TUBE2 . 'G' ) * ( TUBE2 . 'DH' ) / Spass2 ) / mufil9 ;
  1216. Mess 'Nb de Reynolds ' ;
  1217. chpobor 'interne fluide 1 ' Reflu1 ;
  1218. chpobor 'interne fluide 2 ' Reflu2 ;
  1219.  
  1220. SI ( Reflu1 > seuilam ) ;
  1221.  RegEcoM.1 = RTUR ;
  1222. SINON ;
  1223.  RegEcoM.1 = RLAM ;
  1224. FINSI ;
  1225.  
  1226. SI ( Reflu2 > seuilam ) ;
  1227.  RegEcoM.2 = RTUR ;
  1228. SINON ;
  1229.  RegEcoM.2 = RLAM ;
  1230. FINSI ;
  1231.  
  1233. *gounand opti echo 1 ;
  1234. FINSI ;  comm Calcul des nombres de Reynolds ;
  1235.  
  1236. SI ( EGA RegEcoM.1 RTUR ) ; comm fluide UN  ;
  1237.  
  1238. SI EchColb ;
  1239. *** Colburn
  1240.  nuss1 = A_colb '*' ('**' Reflu1 B_colb)
  1241.              '*' ('**' pranfil1 C_colb) ;
  1242. SINON ;
  1243.  
  1244. *** Gnielinski
  1245.  ReyGnie  = Reflu1 - 1000. ;
  1246.  ReyLogG  = LOG Reflu1 ;
  1247.  
  1248.  K_gnie = A_gnie * (LOG (Reflu1 /
  1249.                (( B_gnie * ReyLogG ) + C_gnie ))) ;
  1250.  F_frot = 0.5 / ( K_gnie ** 2. ) ;
  1251.  F_frot2 = F_frot ** 0.5 ;
  1252.  
  1253.  chpobor 'Reyn - 1000. ' ReyGnie ;
  1254.  chpobor 'coeff frott  ' ( 2. * F_frot );
  1255.  
  1256.  PrGnie = ((pranfil1 ** s_23 ) - 1. ) ;
  1257.  chpobor 'Pr**2/3 - 1  ' PrGnie ;
  1258.  nuss1 = F_frot * pranfil1 * ReyGnie /
  1259.             ( 1. + (12.7 * F_frot2 * PrGnie )) ;
  1260. FINSI ;
  1261.  
  1262. SINON ;
  1263.  nuss1 = Nusslam ;
  1264.  nuss2 = Nusslam ;
  1265. FINSI ;
  1266.  
  1267. SI ( EGA RegEcoM.1 RTUR ) ; comm fluide DEUX  ;
  1268.  
  1269. SI EchColb ;
  1270. *** Colburn
  1271.  nuss2 = A_colb '*' ('**' Reflu2 B_colb)
  1272.              '*' ('**' pranfil2 C_colb) ;
  1273. SINON ;
  1274.  
  1275. *** Gnielinski
  1276.  ReyGnie  = Reflu2 - 1000. ;
  1277.  ReyLogG  = LOG Reflu2 ;
  1278.  
  1279.  K_gnie = A_gnie * (LOG (Reflu2 /
  1280.                (( B_gnie * ReyLogG ) + C_gnie ))) ;
  1281.  F_frot = 0.5 / ( K_gnie ** 2. ) ;
  1282.  F_frot2 = F_frot ** 0.5 ;
  1283.  
  1284.  chpobor 'Reyn - 1000. ' ReyGnie ;
  1285.  chpobor 'coeff frott  ' ( 2. * F_frot );
  1286.  
  1287.  PrGnie = ((pranfil2 ** s_23 ) - 1. ) ;
  1288.  chpobor 'Pr**2/3 - 1  ' PrGnie ;
  1289.  nuss2 = F_frot * pranfil2 * ReyGnie /
  1290.             ( 1. + (12.7 * F_frot2 * PrGnie )) ;
  1291. FINSI ;
  1292.  
  1293. SINON ;
  1294.  nuss1 = Nusslam ;
  1295.  nuss2 = Nusslam ;
  1296. FINSI ;
  1297.  
  1298. mess 'regime fluide 1 : ' RegEcoM.1 ;
  1299. mess 'regime fluide 2 : ' RegEcoM.2 ;
  1300.  
  1301. *** Coefficients d'echange
  1302. cech1  = nuss1 * lfil1 / ( TUBE1 . 'DH' )  ;
  1303. cech2  = nuss2 * lfil2 / ( TUBE2 . 'DH' )  ;
  1304.  
  1305.  
  1306. mess 'Diametres hydrauliques' ;
  1307. chpobor  'fluide 1     '  ( TUBE1 . 'DH' )   ;
  1308. chpobor  'fluide 2     '  ( TUBE2 . 'DH' )   ;
  1309.  
  1310. mess 'Conductivites ' ;
  1311. chpobor  'fluide 1  ' lfil1  ;
  1312. chpobor  'fluide 2  ' lfil2  ;
  1313.  
  1314. mess 'Nb de Prandtl ' ;
  1315. chpobor  'fluide 1  ' pranfil1;
  1316. chpobor  'fluide 2  ' pranfil2;
  1317.  
  1318. mess 'Nb de Nusselt ' ;
  1319. chpobor  'fluide 1  ' nuss1;
  1320. chpobor  'fluide 2  ' nuss2;
  1321.  
  1322. rvi . 'H1' =  'KCHT' $clim1 'SCAL' 'CENTRE' cech1 ;
  1323. rvi . 'H2' =  'KCHT' $clim2 'SCAL' 'CENTRE' cech2 ;
  1324. chpobor 'champ rvi echange 1  ' ( rvi . 'H1' ) ;
  1325. chpobor 'champ rvi echange 2  ' ( rvi . 'H2' ) ;
  1326.  
  1327. *** Proprietes physiques du solide
  1328.    tinter9 = 'NOEL' $VFW  (rvi . 'TSOL') ;
  1329.    lcb = ( pth_aci tinter9 ) . 'LAMS' ;
  1330.    rvi . 'Lacier' = 'KCHT' $VFW  'SCAL' 'CENTRE' lcb ;
  1331.  
  1332.  
  1334. '3bis) Activation des sources internes dans structures (en W/m3)' ;
  1335. ***   3bis) Activation des sources internes dans les des structures (en W/m3)
  1336. *** Commentaires :
  1337. ***  Comme lors de l'initialisation : on calcule la masse volumique de
  1338. ***  chaque corps a partir de la temperature. Puis on en deduit les
  1339. ***  puissances des sources internes.
  1340.  
  1341.  
  1342.  
  1343. MESS ' 4) Resolution de la thermique dans les structures ' ;
  1344. ***   4) Resolution de la thermique dans les structures
  1345.    EXEC rvsol ;
  1346. opti echo 0 ;
  1347.  chpobor 'temperatures solides mini & maxi en Celsius (apres rvsol)'
  1348.         (( rvi.tsol ) - CK ) ;
  1349. *gounand opti echo 1 ;
  1350.  
  1351.  
  1352. MESS  '  5) Calcul du flux de chaleur aux interfaces Solides/Fluides' ;
  1353. ***   5) Calcul du flux de chaleur aux interfaces Solides/Fluides
  1354.  
  1355. *** solide/Fluide 1
  1356.    rvmdia1 = 'EQEX' 'OPTI' 'VF' 'IMPL'
  1357.              'ZONE' $clim1 'OPER' 'MDIA' 'H1' 'INCO' 'TSOL' 'F1' ;
  1358.    rvmdia1 . 'INCO' = rvi ;
  1359.    smdia1 mmdia1 = 'MDIA' (rvmdia1 . '1MDIA') ;
  1360.    rvmdia2 = 'EQEX' 'OPTI' 'VF' 'IMPL'
  1361.              'ZONE' $clim1 'OPER' 'MDIA' 'H1' 'INCO' 'T1'  'F1' ;
  1362.    rvmdia2 . 'INCO' = rvi ;
  1363.    smdia2 mmdia2 = 'MDIA' (rvmdia2 . '1MDIA') ;
  1364.    flx1 = 'NOMC' 'SCAL' ('-' ('KOPS' mmdia1 '*'
  1365.                            ('NOMC' 'TSOL' (rvi . 'TSOL')))
  1366.                            ('KOPS' mmdia2 '*'
  1367.                            ('NOMC' 'T1'  (rvi . 'T1')))) ;
  1368.    'MESSAGE'
  1369.    'Flux integre sur interface solide/Fluide 1 (W) :'
  1370.             ('MAXIMUM' ('RESULT' flx1)) ;
  1371.  
  1372. *** solide/Fluide 2
  1373.    rvmdia1 = 'EQEX' 'OPTI' 'VF' 'IMPL'
  1374.              'ZONE' $clim2 'OPER' 'MDIA' 'H2' 'INCO' 'TSOL' 'F2' ;
  1375.    rvmdia1 . 'INCO' = rvi ;
  1376.    smdia1 mmdia1 = 'MDIA' (rvmdia1 . '1MDIA') ;
  1377.    rvmdia2 = 'EQEX' 'OPTI' 'VF' 'IMPL'
  1378.              'ZONE' $clim2 'OPER' 'MDIA' 'H2' 'INCO' 'T2'  'F2' ;
  1379.    rvmdia2 . 'INCO' = rvi ;
  1380.    smdia2 mmdia2 = 'MDIA' (rvmdia2 . '1MDIA') ;
  1381.    flx2 = 'NOMC' 'SCAL' ('-' ('KOPS' mmdia1 '*'
  1382.                            ('NOMC' 'TSOL' (rvi . 'TSOL')))
  1383.                            ('KOPS' mmdia2 '*'
  1384.                            ('NOMC' 'T2'  (rvi . 'T2')))) ;
  1385.    'MESSAGE'
  1386.    'Flux integre sur interface solide/Fluide 2 (W) :'
  1387.             ('MAXIMUM' ('RESULT' flx2)) ;
  1388.  
  1389.  
  1390. ***   6) Transfert en une puissance volumique dans le fluide
  1391.    rvi . 'F1' = flx1 ; comm fluide un ;
  1392.    pflx1 = '*' mfc1 flx1 ;
  1393.    rvi . 'PFLU1' = 'KCHT' $mtflu1  'SCAL' 'CENTRE' pflx1 ;
  1394.   mess 'Puissance volumique fournie au fluide 1   : ' ;
  1395.   chpobor 'interface fluide 1 tube solide     ' pflx1 ;
  1396. chpobor ( rvi . 'PFLU1' ) ;
  1397.    rvi . 'F2' = flx2 ; comm fluide deux ;
  1398.    pflx2 = '*' mfc2 flx2 ;
  1399.    rvi . 'PFLU2' = 'KCHT' $mtflu2  'SCAL' 'CENTRE' pflx2 ;
  1400.   mess 'Puissance volumique fournie au fluide 2   : ' ;
  1401.   chpobor 'interface fluide 2 tube solide     ' pflx2 ;
  1402. chpobor ( rvi . 'PFLU2' ) ;
  1403.  
  1404. MESS '6bis) Activation des sources internes dans le fluide (en W/m3)' ;
  1405. ***   6bis) Activation des sources internes dans le fluide (en W/m3)
  1406. *** Commentaires :
  1407. ***  Comme lors de l'initialisation : on calcule la masse volumique de
  1408. ***  chaque corps a partir de la temperature. Puis on en deduit les
  1409. ***  puissances des sources internes.
  1410.  
  1411.  
  1412. MESS ' 7) Calcul des proprietes physiques fluide ' ;
  1413. ***   7) Calcul des proprietes physiques fluide
  1414. ***      a partir des variables a l'instant precedent.
  1415. ***
  1416. *** Fluide 1 :
  1417. dmtflu1 = DOMA $mtflu1 'MAILLAGE' ;
  1418. Tflus = REDU dmtflu1 (rvi . 'TFLU') ;
  1419. Tfluc = 'NOEL' $mtflu1 (rvi . 'TFLU') ;
  1420.  
  1421. ppthe8s = PTH_HE8  Tflus ;
  1422. ppthe8c = PTH_HE8  Tfluc ;
  1423. rhes  = ppthe8s . 'ROG' ;
  1424. muhes = ppthe8s . 'MUG' ;
  1425. lhes  = ppthe8s . 'LAMG' ;
  1426. cphes = ppthe8s . 'CPG' ;
  1427. rhec  = ppthe8c . 'ROG' ;
  1428. muhec = ppthe8c . 'MUG' ;
  1429. lhec  = ppthe8c . 'LAMG' ;
  1430. cphec = ppthe8c . 'CPG' ;
  1431.  
  1432. uflu1s = ELNO $mtflu1 (KOPS ( TUBE1 . 'G' / Spass1) / rhec) ;
  1433. uflu1s = NOMC 'UZ' uflu1s ;
  1434. rvi . 'RCPFLU1' =  'KCHT' $mtflu1 'SCAL' 'CENTRE' ('*' rhec cphec) ;
  1435. rvi . 'LFLU1'   =  'KCHT' $mtflu1 'SCAL' 'CENTRE' lhec ;
  1436. rvi . 'UFLU1'   =  'KCHT' $mtflu1 'VECT' 'SOMMET' uflu1s ;
  1437.  
  1438. fb1 = (exco uz (rvi . 'UFLU1')) ;
  1439. chpobor 'rvi . uflu1   : ' fb1 ;
  1440.  
  1441. *** Fluide 2 :
  1442. dmtflu2 = DOMA $mtflu2 'MAILLAGE' ;
  1443. Tflus = REDU dmtflu2 (rvi . 'TFLU') ;
  1444. Tfluc = 'NOEL' $mtflu2 (rvi . 'TFLU') ;
  1445.  
  1446. ppthe8s = PTH_HE8  Tflus ;
  1447. ppthe8c = PTH_HE8  Tfluc ;
  1448. rhes  = ppthe8s . 'ROG' ;
  1449. muhes = ppthe8s . 'MUG' ;
  1450. lhes  = ppthe8s . 'LAMG' ;
  1451. cphes = ppthe8s . 'CPG' ;
  1452. rhec  = ppthe8c . 'ROG' ;
  1453. muhec = ppthe8c . 'MUG' ;
  1454. lhec  = ppthe8c . 'LAMG' ;
  1455. cphec = ppthe8c . 'CPG' ;
  1456.  
  1457. uflu2s = ELNO $mtflu2 (KOPS ( TUBE2 . 'G' / Spass2) / rhec) ;
  1458. uflu2s = NOMC 'UZ' uflu2s ;
  1459. rvi . 'RCPFLU2' =  'KCHT' $mtflu2 'SCAL' 'CENTRE' ('*' rhec cphec) ;
  1460. rvi . 'LFLU2'   =  'KCHT' $mtflu2 'SCAL' 'CENTRE' lhec ;
  1461. rvi . 'UFLU2'   =  'KCHT' $mtflu2 'VECT' 'SOMMET' uflu2s ;
  1462.  
  1463. fb2 = (exco uz (rvi . 'UFLU2')) ;
  1464. chpobor 'rvi . uflu2   : ' fb2 ;
  1465.  
  1466.  
  1467. MESS '  8) Calcul de la temperature dans l eau' ;
  1468. ***   8) Calcul de la temperature dans l'eau
  1469.    EXEC rvflu ;
  1470. chpobor 'temperature fluide (Celsius) : '  ((rvi . 'TFLU') - CK );
  1471.  
  1472. *** Convergence :
  1473.    then = 'COPIER' (rvi . 'TFLU') ;
  1474.    tcbn = 'COPIER' (rvi . 'TSOL') ;
  1475.    errhe  = '/' ('MAXIMUM'  ('-' then thep) 'ABS')
  1476.                 ('MAXIMUM'  thep 'ABS') ;
  1477.    errcb = '/' ('MAXIMUM'  ('-' tcbn tcbp) 'ABS')
  1478.                ('MAXIMUM'  tcbp 'ABS') ;
  1479.    'MESSAGE' ('CHAINE' 'Iteration ' &bouc) ;
  1480.    'MESSAGE' ('CHAINE' '   errhe  = ' errhe) ;
  1481.    'MESSAGE' ('CHAINE' '   errcb  = ' errcb) ;
  1482.    thep = then ;
  1483.    tcbp = tcbn ;
  1484.    testcvg = 'ET' (errhe '<' 1.D-4)  (errcb '<' 1.D-4) ;
  1485.    'SI' testcvg ;
  1486.       maxiter = faux ;
  1487.       'QUITTER' bouc ;
  1488.     'FINSI' ;
  1489.  
  1490. fin bouc ;
  1491.  
  1492. TCpu2 = tcpu9 0. ;
  1493.  
  1494.  
  1495. ************************************************************************
  1496. *** **------------ FIN DU CALCUL  ------------------------------********
  1497. ************************************************************************
  1498.  
  1499.  
  1500.  
  1501. ***********************************************************************
  1502. ***   POST TRAITEMENT SOMMAIRE
  1503. ***********************************************************************
  1504.  
  1505.  
  1506. *** Calcul des Temperatures et les vitesses
  1507. *** ---------------------------------------
  1508. tk = rvi.tsol ; comm temperatures solides en K ;
  1509. tc = tk - ck ; comm temperatures solides en C ;
  1510. t_tn = rvsol . 'INCO' . 'TSOL' ;
  1511.  
  1512. TsoliC = (rvi . 'TSOL') - CK ;
  1513. TfluiC = (rvi . 'TFLU') - CK ;
  1514.  
  1515. *** Verification des bilans de puissance
  1516. Wsolid = 'MAXIMUM' ('RESULT'(( rvi . 'Soursol' ) *
  1517.         ( 'DOMA' $VFW 'VOLUME' ))) ;
  1518.  
  1519. opti echo 0 ;
  1520.  
  1521. Ecform 'Diametre passage fluide 1           '
  1522.   '(F5.3)' 'm' ( TUBE1 . 'DH' ) ;
  1523. Ecform 'Diametre passage fluide 2           '
  1524.   '(F5.3)' 'm' ( TUBE2 . 'DH' ) ;
  1525.  
  1526. Ecform 'Surface de passage fluide 1         '
  1527.   '(E12.5)' 'm2' Spass1 ;
  1528. Ecform 'Surface de passage fluide 2         '
  1529.   '(E12.5)' 'm2' Spass2 ;
  1530.  
  1531. Ecform 'Debit massique fluide 1  '
  1532.   '(F5.2)' 'kg/s' ( TUBE1 . 'G' ) ;
  1533. Ecform 'Debit massique fluide 2  '
  1534.   '(F5.2)' 'kg/s' ( TUBE2 . 'G' ) ;
  1535.  
  1536.  
  1537. Ecform 'Volume solide          '
  1538.   '(E12.5)' 'm3' VoSol  ;
  1539.  
  1540. Ecform 'Densite de puissance interne          '
  1541.   '(E12.5)' 'W/m3' Sousol  ;
  1542. chpobor 'X_TOT (pour sources) : ' X_TOT ;
  1543.  
  1544. Ecform 'Puissance surfacique plasma          '
  1545.   '(E12.5)' 'W' W_SPLSM  ;
  1546. Ecform 'Puissance surfacique interne          '
  1547.   '(E12.5)' 'W' W_SBZ  ;
  1548. WsolTot = Wsolid + W_SPLSM + W_SBZ ;
  1549. WfluTot = ('MAXIMUM' ('RESULT' flx1)) + ('MAXIMUM' ('RESULT' flx2)) ;
  1550.  
  1551. Chpobor 'Coefficient echange fluide 1 (W/m2.K) ' Cech1 ;
  1552. Chpobor 'Coefficient echange fluide 2 (W/m2.K) ' Cech2 ;
  1553.  
  1554. ecform
  1555. 'Flux interface solide/Fluide   1    '
  1556.  '(E12.5)'  'W'  ('MAXIMUM' ('RESULT' flx1)) ;
  1557. ecform
  1558. 'Flux interface solide/Fluide   2    '
  1559.  '(E12.5)'  'W'  ('MAXIMUM' ('RESULT' flx2)) ;
  1560.  
  1561. ecform
  1562. 'Puissance totale solide             '
  1563.  '(E12.5)'  'W'  WsolTot ;
  1564.  
  1565. ecform
  1566. 'Puissance totale fluide             '
  1567.  '(E12.5)'  'W'  WfluTot ;
  1568.  
  1570. chpobor 'temperatures solides min & max (Celsius)   '
  1571.   ((redu  ( rvi . 'TSOL' ) VFW) - CK ) ;
  1573.  
  1574. chpobor 'temp. fluides min & max (Celsius) fluide 1     '
  1575.   ((redu  ( rvi . 'TFLU' ) tube1.mtflu ) - CK ) ;
  1576. chpobor 'temp. fluides min & max (Celsius) fluide 2     '
  1577.   ((redu  ( rvi . 'TFLU' ) tube2.mtflu ) - CK ) ;
  1578.  
  1579.  
  1580. si complet ;
  1581.  opti echo 1 ;
  1582. sinon ;
  1583.  opti echo 0 ;
  1584. finsi ;
  1585.  
  1586. si complet ;
  1587.  
  1588. *** Evolution fluide 1
  1589. *** ------------------
  1590. tfc9 = redu TfluiC tube1.mtflu ;
  1591. tfc9c = noel $mtflu1 tfc9 ;
  1592. mtfc9c = doma $mtflu1 centre ;
  1593. repe x (nbno mtfc9c )  ;
  1594. pt = mtfc9c point &x ;
  1595. val89 = coor 3 pt ;
  1596. wal89 = extr tfc9c scal pt ;
  1597.  si ( ega &x 1 ) ;
  1598.   dqqc = val89 ;
  1599.   drrc = wal89 ;
  1600.  sinon ;
  1601.   dqqc = dqqc et val89 ;
  1602.   drrc = drrc et wal89 ;
  1603.  finsi ;
  1604. fin x ;
  1605. mindqqc = mini dqqc ;
  1606. ndqqc = dime dqqc ;
  1607. dqqc = dqqc - ( prog ndqqc  *  mindqqc ) ;
  1608. evtfint1 =   evol manu  'Z' dqqc drrc  ;
  1609.  
  1610. *** Evolution fluide 2
  1611. *** ------------------
  1612. tfc9 = redu TfluiC tube2.mtflu ;
  1613. tfc9c = noel $mtflu2 tfc9 ;
  1614. mtfc9c = doma $mtflu2 centre ;
  1615. repe x (nbno mtfc9c )  ;
  1616. pt = mtfc9c point &x ;
  1617. val89 = coor 3 pt ;
  1618. wal89 = extr tfc9c scal pt ;
  1619.  si ( ega &x 1 ) ;
  1620.   dqqc = val89 ;
  1621.   drrc = wal89 ;
  1622.  sinon ;
  1623.   dqqc = dqqc et val89 ;
  1624.   drrc = drrc et wal89 ;
  1625.  finsi ;
  1626. fin x ;
  1627. mindqqc = mini dqqc ;
  1628. ndqqc = dime dqqc ;
  1629. dqqc = dqqc - ( prog ndqqc  *  mindqqc ) ;
  1630. evtfint2 =   evol manu  'Z' dqqc drrc  ;
  1631. *** Chercher les abscisses curvilignes
  1632.  
  1633.  trac cach TsoliC VFW titr 'Temperature solide' ;
  1634.  trac cach TsoliC sc1 titr 'Temperature interface solide-fluide 1' ;
  1635.  trac cach TsoliC sc2 titr 'Temperature interface solide-fluide 2' ;
  1636.  trac cach TfluiC tube1.mtflu titr 'Temperature fluide 1' ;
  1637.  trac cach TfluiC tube2.mtflu titr 'Temperature fluide 2' ;
  1638.  trac TfluiC ( tube1.mtflu et tube2.mtflu )
  1639.      titr 'Temperatures fluides 1 et 2 ' ;
  1640.  dess ( evtfint1 et evtfint2 ) mima
  1641.         titr 'Temperatures fluides 1 et 2 vs abscisse curviligne' ;
  1642.  dess EVQfw mima titr 'sources' ;
  1643.  
  1644.  factech = 2. ;
  1645.  
  1646.  loupe oeil TsoliC VFW
  1647.      'Temperature solide' factech 0. ;
  1648.  loupe oeil TsoliC sc1
  1649.      'Temperature interface solide-fluide 1' factech ;
  1650.  loupe oeil TsoliC sc2
  1651.      'Temperature interface solide-fluide 2' factech ;
  1652.  loupe oeil TfluiC tube1.mtflu
  1653.      'Temperature fluide 1' factech 5. ;
  1654.  loupe oeil TfluiC tube2.mtflu
  1655.      'Temperature fluide 2' factech 5. ;
  1656.  loupe oeil TfluiC ( tube1.mtflu et tube2.mtflu )
  1657.      'Temperatures fluides 1 et 2' factech 0. ;
  1658.  
  1659. finsi ;
  1660. ************************************************************************
  1661. ****************FIN DU POST-TRAITEMENT SOMMAIRE*************************
  1662. ************************************************************************
  1663.  
  1664. 'TEMPS' 'ZERO' ;
  1665.  
  1666. chpvide matvide = 'KOPS' 'MATRIK' ;
  1667. rvsol . METHINV.'MATASS'=matvide;
  1668. rvsol . METHINV.'MAPREC'=matvide;
  1669. rvflu . METHINV.'MATASS'=matvide;
  1670. rvflu . METHINV.'MAPREC'=matvide;
  1671. menage;
  1672. TCpu3 = tcpu9 0. ;
  1673.  
  1674. opti echo 0 ;
  1675. mess 'Duree calcul matrices des connectivites : ' TCpu1 ;
  1676. mess 'Duree calcul iteratif                   : ' TCpu2 ;
  1677. mess 'Duree menage                            : ' TCpu3 ;
  1678. opti echo 1 ;
  1679.  
  1680. FIN ;
  1681.  
  1682.  
  1683.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales