Télécharger CCDLLST_3.dgibi

Retour à la liste

**********************************************************
* kich : evolution jeu de donnees 
* d'apres CalCyliqueDirect_LoiLin_SansTemp_n.dgibi
* pour mise au point stationnaire 12/25
**********************************************************
*$$$$ GELIPSE  
DEBP GELIPSE A*FLOTTANT B*FLOTTANT PSF*POINT ANGLE*FLOTTANT 
             DENSITE*ENTIER Elim1*FLOTTANT ;
 
  ANGLE1 = ANGLE ;
  pcour_in = ((COOR 1 PSF) + 0.) (a + (COOR 2 PSF)) (COOR 3 PSF);
  xcour = ((COOR 1 PSF) + 0.)                ;
  ycour = ((COOR 2 PSF) + (a * (cos ANGLE1))) ;
  zcour = ((COOR 3 PSF) + (b * (sin ANGLE1))) ;
  pcour = xcour ycour zcour     ;
  s_lff = pcour_in droi 1 pcour ;
  lff = s_lff      ;
  pcour_m1 = pcour ;
 
  repe bloc1 DENSITE ;
    ANGLE1 = ANGLE1 + ANGLE  ;
    xcour = ((COOR 1 PSF) + 0.) ;
    ycour = ((COOR 2 PSF) + (a * (cos ANGLE1))) ;
    zcour = ((COOR 3 PSF) + (b * (sin ANGLE1))) ;
    pcour = xcour ycour zcour  ;
    s_lff = pcour_m1 droi 1 pcour ;
    pcour_m1 = pcour ;
    lff = Elim Elim1 (lff et s_lff) ;
  fin bloc1 ;
 
  s_lff = pcour droi 1 pcour_in ;
  lff = Elim Elim1 (lff et s_lff) ;
 
FINP lff ;
*$$$$
DEBP GERTZ2 MO*MMODEL MA*MAILLAGE MS*MAILLAGE 
           PP*POINT PM*FLOTTANT AA*FLOTTANT BB*FLOTTANT
           A0*FLOTTANT B0*FLOTTANT OPT*MOT ;
************************************************************************
* CRÉATION DES FORCES CORRESPONDANT À UNE DISTRIBUTION DE CONTRAINTES
*   NORMALES HERTZIENNES PAR LA PROCÉDURE :
*                  GERTZ2
*        
* La forme de la distribution de pression de Hertz est :
*            - si OPT = 2D : [PM * (1-(x/AA)^2)^0.5]
*            - si OPT = 3D : [PM * (1-(x/AA)^2-(y/BB)^2)^0.5]
* Arguments d'entrée :
*      MO : modèle
*      MA : maillage
*      MS : maillage de la surface potentielle de contact 
*           (surface sup du rail par exemple)
*      PP : point central de la surface de contact
*      PM : pression maximale de Hertz
*      AA : première demi-longueur du la surface de contact
*      BB : deuxième demi-longueur du la surface de contact
*      OPT: 3D ou 2D 
* Arguments de sortie :
*      CHA : vecteur de chargement créé (second membre de K U = F)
************************************************************************
 
  X0CH = coor 1 PP ;
 
  si (ega OPT '2D') ;
*** cas 2D
    Z0CH = coor 2 PP ;
    P0CH = MS poin proc (X0CH Z0CH) ;
    XCH = (coor 1 MS) - X0CH ;
    XZCH = 1 - ((XCH / AA) ** 2) ;
    YONCH = XZCH masq egsupe 0. ;
    P_HERTZ = (PM * (( XZCH * YONCH)** 0.5)) + 1.E-20 ;
 
 
  sino ;
*** cas 3D
    si (non (existe BB)) ;
      mess 'Il manque une donnee : la 2eme demi-longueur de contact.' ;
      QUIT HERTZ ;
    fins ;
    Y0CH = coor 2 PP ;
    Z0CH = coor 3 PP ;
    P0CH = MS poin proc (X0CH Y0CH Z0CH) ;
    XCH = (coor 1 MS) -  X0CH ;
    ZCH = (coor 3 MS) -  Z0CH ;
    YCH = (coor 2 MS) -  Y0CH ;
    XZCH = 1 - (((XCH - A0) / AA) ** 2) - (((YCH - B0 ) / BB) ** 2) ;
    YONCH = XZCH masq egsupe 0. ;
    P_HERTZ = (PM * (( XZCH * YONCH)** 0.5)) + 1.E-20 ;
  fins ;
 
  CHA = pres mass MO P_HERTZ ;
 
*-----------------------------------------------------------------------
* Tracé du vecteur force sur le maillage
*-----------------------------------------------------------------------
*  si (ega OPT '2D') ;
*    vec = vect CHA 0.01E-6 fx fy bleu ;
*  sinon ;
*    vec = vect CHA 1.E-3 fx fy fz bleu ;
*  finsi ;
 
*  trace cach (-1 * vec) (MA et AX) ;
 
FINP CHA ;
*$$$$
**********************************************************
***********   Type de méthode de calcul    ***************
**********************************************************
Dim = 3 ;
* methode = 1 : pour le stationnaire
* methode = 2 : pour le cylique
 
methode = 2;
*
* Nombre de passage: = 0  : pour le stationnaire direct
* 
npass = 0;
 
OPTI TRAC 'PSC';
opti trac x ;
***
OPTI ECHO 1 DIME Dim ELEM TET4 ;
***
*OPTI sauv  'DonneesCastem2.sauv' ;
graph = faux ;
*********************************************************************
*
*       DONNEES INTRODUITES PAR L'UTILISATEUR
*
*********************************************************************
*
* 1. Choix du profil du rail; par d?faut profil UIC60
*    Ce choix conditionne le maillage.
*
*
* 2. D?finition du chargement (pression hertzienne + frottement)
*
*    Pmax : pression hertzienne maximale
*    A  : demi-longueur de l'axe de l'ellipse dans la direction de roulement
*    B  : demi-longueur de l'axe de l'ellipse dans la direction transversale
*    ndom  : choix du domaine d'?tude, elle prend la valeur:
*            1:toute la section du rail
*            2:la demi-section (sym?trie par rapport ? un plan vertical)
*            3:le quart sup?rieur du rail
*    PC : point definissant le centre de l'ellipse
*    fr : coefficient de frottement
*    TSQ : rapport effort de traction sur charge verticale
*
*****************************************************************************
*
*
*
*
si (methode ega 1) ;
PMAX  = 1000 * 1.E6 ;
sino ;
  PMAX  = 1.E6 ;
fins ;
PMAX = 1.2 * PMAX ;
A     = 0.006;
B     = 0.01 ;
Si (Dim ega 3) ;
 PC    = 0 0 0 ;
sino;
 PC    = 0 0 ;
fins ;
*
*
ndom  = 1;
*
*
*
*
*
*****************************************************************************
*
* 3. donnees concernant la discretisation
*
*    na : nombre d'?l?ments sur le demi-axe de l'ellipse de contact a
*    nb : nombre d'?l?ments sur le demi-axe de l'ellipse de contact b
*    ntr_am : nombre de tranches en amont
*    ntr_av  : nombre de tranches en aval
*    ntr_co :  nombre de tranches sous le contact
*****************************************************************************
*
*
*
*
 
 
ntr_am = 6;
ntr_av = 6;
ntr_co = 16;
nb = (4 * b) /0.01 ;
nb = ENTI nb ;
na = (8 * a) /0.006 ;
na = ENTI na ;
*****************************************************************************
*
* 4. Choix de la loi de comportement
*    - soit ?lastoplastque ? ?crouissage cin?matique lin?aire
*        dans ce cas entrer :
*         yo : module de young,
*         nn : coef de poisson,
*         sy : limite d'elasticit?
*         hh : module d'ecrouissage
*    - soit elastoplastique ? ?crouissage cin?matique non lin?aire
*        dans ce cas introduire en plus
*         aa :
*         cc :
*****************************************************************
*
*
**********************************************************
*********** 4.  Déclaration de matériau    ***************
**********************************************************
*
*
YO    = 206000000000.;
NN    = 0.3;
SY    = 505000000.; sy = 250.e6 ;
HH    = 15900000000.;
ALPH  = 0.000005 ;
*
**********************************************************
***********  Type de loi de Comportement   ***************
**********************************************************
*
*
LOI_LIN = vrai ;
*
*
*
*****************************************************************
*                          FIN DES DONNEES A INTRODUIRE
*****************************************************************
*
*
*
*
*  Table des distances de translation   *
 
Ntour  = prog ntr_am*1  ntr_co  ntr_av*1 ;
angt_co1   = prog (ntr_co/2)*(1./na) ;
angt_co    = angt_co1 et angt_co1 ;
haha3 = (ntr_co) * (1./na) ;
haha3 = haha3 * a;
aa = (3./na) ;
             haha1 = aa;
angt_av   = prog aa ;
repe bouc (ntr_av  - 1) ;
aa = aa * 2. ;
    haha1 = haha1 + aa;
    angt_av = angt_av  et (prog aa) ;
  fin bouc ;
haha1 = haha1 * a;
  aa = (3./na) ;
  haha2 = aa;
  angt_am   = prog aa ;
  repe bouc (ntr_am  - 1) ;
    aa = aa * 2. ;
    angt_am = (prog aa) et angt_am ;
     haha2 = haha2 + aa;
  fin bouc ;
haha2 = haha2 * a;
angt   =  (angt_am et angt_co) et  angt_av ;
angt   = angt * a  ;
Si (Dim ega 3) ;
  OEIL = 50. 30. 30. ;
  OEIL1 = 113. 0. 0. ;
FinS;
Si (Dim ega 3) ;
E_Y = 0. 1. 0. ;
E_Z = 0. 0. 1. ;
E_X = 1. 0. 0. ; 
P_ORI = 0. 0. 0. ;     
Sino ;
E_X = 1. 0. ;
E_Z = 0. 1. ;
P_ORI = 0. 0. ;     
FinS;
*
*
*
*
* finesse maillage section
d1 = 0.01 ;
d2 = 0.01 ;
* finesse pour elim
e_eli = 0.00001 ;
*
*
*
*
Si (Dim ega 3) ;
AXES   = coul roug 
         (( P_ORI droi 1 (50.e-3 0. 0.)) et
         ( P_ORI  droi 1 (0. 50.e-3 0.)) et
         ( P_ORI  droi 1 (0. 0. 50.e-3))) ;
Sino ;
AXES   = coul roug 
         (( P_ORI droi 1 (50.e-3 0.)) et
         ( P_ORI  droi 1 (0. 50.e-3)));
FinS;
*
*
*
*
****         Pour le UIC60 : On trouve ces valeurs:        ****
Si (Dim ega 3) ;
* Donn?s de la partie inf?rieure: *
   d_p = 150E-3 ;
   d_p1 = 100E-3 ;
   d_p2 = 31.5E-3 ;
   d_p3 = 13.3E-3 ;
   d_p4 = 11.5E-3 ;
   d_p5 = 89.5E-3 ;
   d_r1 = 4E-3 ;
   d_r2 = 7E-3 ;
   d_a  = 33E-3 ;
   d_h1 = 76.25E-3 ;
   d_h2 = 16E-3 ;
* Donn?s de la partie sup?rieure: *
  d_h = 172E-3 ;
  d_h3 = 16E-3 ;
  d_b = 74.3E-3 ;
  d_b1 = 37.5E-3 ;
  d_b2  = 51E-3 ;
  d_b3 = 21E-3 ;
  d_b4  = 70.6E-3 ;
  d_b5 = 72E-3 ;
  d_a1  = 16.5E-3 ;
  d_r3 = 7E-3 ;
  d_r4 = 3E-3 ;
  d_r5 = 13E-3 ;
Sino ;
 d_b = 74.3E-3 ;
 d_b1 = 37.5E-3 ;
 d_b2  = 51E-3 ;
 d_a  = 33E-3 ;
 d_h = 172E-3 ;
 d_r3 = 7E-3 ;
FinS;
*
nnn = 4 ;
Si (Dim ega 3) ;
* D?finition des points de la partie sup?rieure: *
 P0 = P_ORI ;
 P14 = P0 plus (d_h*e_z)  ;
 P10 = P0 PLUS ((d_b /2)*e_y) plus ((d_h - d_b1)*e_z) ;
 TG_A2 = ((d_b2 - d_b1)/(0.5*d_b)) ; CO2 = ((d_b - d_a )/2.) ;
 P9 = P10 MOIN ((CO2)*e_y) MOIN ((TG_A2*CO2)*e_z);
 P8 =  P9 MOINS ((d_r3)* E_Y) MOINS ((d_r3)* E_Z) ; 
 P8b = (coor 1 p8) (coor 2 p14) (coor 3 p8) ;
 P1314 = P14 PlUS (B*e_y) ; 
 P13 = P1314 PlUS (((d_b3/2.)-B)*e_y) ;
 P12 = P13 PLUS (((d_b4 - d_b3 - (2.*d_r5))/2.)*e_y); 
 P12 = P12 MOIN ((d_b5 - d_b4)*e_z) ;
 P11 = P12 PLUS(d_r5 *e_y) MOIN (d_r5 *e_z)  ;
 P14b = P0 PLUS ((d_h - (2.*a))* E_Z) ;
 P1314b = P14b PLUS (((coor 2 p1314) - (coor 2 p14)) * E_Y) ;
 P13b = P1314b PLUS (((coor 2 p13) - (coor 2 p1314)) * E_Y) ;
 P12b = P13b PLUS (((coor 2 p12) - (coor 2 p13)) * E_Y) ;
 P12b = P12b PLUS (((coor 3 p13b) - (coor 3 p13)) * E_Z) ; 
* D?finition du maillage pour la partie sup?rieure: *
 l_c1a = droit p13 nb p14 ;
 l_c1b = droit  p14 4 p14b ;
  l_c1c = droit p13b nb p14b ;
*
*
*
*
*
*
 l_c1d =  droit p13 4 p13b ;
 L_C2 =   P8 DROIT 1 P9 ;
 L_C3 =  P9 DROIT  nnn P10 DROIT 2 P11 COUL ROSE ;
 L_C31 =  P10 DROIT nnn P11 COUL ROSE ;
 PC1 = P12 MOINS (d_r5 * E_Z) ;
 L_C4 = P11 CERC PC1 nnn P12  ;
 L_C4_1 = p12
            DROIT nnn P13
            COUL VERT ;
 L_C4B = droit P12B nnn P13B ;
 L_C4C = droit p12 4 p12b ;
 l_evlc = (P14b DROIT nnn P8b);
 L_C0 = l_c4c et L_C4B et l_c1c et l_evlc et
 (P8b DROIT 1 p8 );
 
CONT_0 = ELIM E_ELI (L_C2 ET L_C3 ET L_C4 ET L_C0) ;
SUR_SECA = SURF PLAN CONT_0 ;
SUR_SECB = DALL l_c1a  l_c1b l_c1c l_c1d  'PLAN' ;
CONT_1 = ELIM E_ELI (l_c4b ET l_c4c ET l_c4_1 ET l_c1d) ;
SUR_SECC = SURF PLAN CONT_1 ;
SUR_SEC3  = elim 1.e-6 (SUR_SECA et SUR_SECB et SUR_SECC) ;
L_C011 =  l_c1c et l_evlc;
 
 CONT_011 = ELIM E_ELI ( L_C3 ET L_C4 ) ;
*BADRY*SUR_SECA = SURF PLAN CONT_0 ;
 SUR_SECB = DALL l_c1a  l_c1b l_c1c l_c1d  'PLAN' ;
 CONT_1 = ELIM E_ELI (l_c4b ET l_c4c ET l_c4_1 ET l_c1d) ;
 CONT_11 = l_c4_1  ;   
 contsup = CONT_011 et CONT_11 et l_c1a  ;  
 si graph ;
  titre 'contour sup' ; 
 trac contsup ;   finsi ;
***********************************************************
*                        Cas ndom = 3:
 SI   (ndom EGA 3) ;
  si graph ;
  TITRE 'Section du quart sup?rieur du rail' ;
  TRAC OEIL1 SUR_SEC3 ; finsi ;
  VOL3 =  SUR_SEC3 VOLU 1  'TRAN' ((EXTR 1 ANGT) 0. 0.) ;
*TRAC OEIL CACH VOL3 ;
  MAISTA MODSTA MOD = MAMOD2 VOL3 AXES angt
             Ntour '3D' LOI_LIN methode ;
  si graph ;
  TITRE ' Maillage de la partie sup?rieure du RAIL ' ;
  trac OEIL cach MAISTA ; finsi ;
 FINSI ;
**********************************************************
*                       Cas ndom = 2:
 SI   (ndom EGA 2) ;
* D?finition des points de la partie inf?rieure: *
  P1 = P0 PLUS ((d_p/2.) * E_Y) ;
  P2 = P1 PLUS (d_p4 * E_Z) ;
  P2a = P2 MOIN ((d_r1) * E_Z) ;
  P2b = P2 MOIN ((d_r1) * E_Y) ;
  P3 = P0 PLUS ((d_p1/2.)* E_Y) PLUS (d_p3 * E_Z) ;
  TG_A1 = ((d_p2 - d_p3)/(0.5*d_p1)) ; CO1 = ((d_p1 - d_a )/2.) ;
  P4 = P0 plus ((d_a/2)*e_y) plus ((d_p3 + (TG_A1*CO1))*e_z);
  P5 = P4 MOINS (d_r2 * E_Y) PLUS (d_r2 * E_Z) ;
  P5b = (coor 1 p5) (coor 2 p0) (coor 3 p5)  ;
  P6 = P0 PLUS ((d_a1/2.)* E_Y) PLUS ((d_h1 -d_h2) * E_Z) ;
  P7 = P0 PLUS ((d_a1/2.)* E_Y) PLUS ((d_h1 + d_h3) * E_Z) ;
* D?finition du maillage pour la partie inf?rieure: *
  l_d1 = droit p0 10 p1 ;
  l_d2 = droit  P1 2 p2a ;
  PC2 = P2 MOINS (d_r1 * E_Y) MOINS (d_r1 * E_Z) ;
  L_d3 = P2a CERC PC2 nnn P2b  ;
  l_d4 =  droit p2b 4 p3 ;
  l_d5 =  droit p3 4 p4 ;
  PC3 = P4 PLUS (d_r2 * E_Y) ;
  L_d6 = P4 CERC PC3 nnn P5  ;
  l_d7 =  droit p5 4 p6 ;
  l_d8 =  droit p6 4 p7 ;
  l_d9 =  droit p7 4 p8 ;
  l_d10 =  droit p8 1 p8b ;
  l_d11 =  droit p0 15 p8b ;
  TITRE 'Section du demi droit du rail' ;
  CONT_2 = ELIM E_ELI (l_d1 ET l_d2 ET l_d3
           ET l_d4 Et l_d5 ET l_d6 ET l_d7
           ET l_d8 Et l_d9 ET l_d10 ET l_d11) ;
  SUR_SEC2 = SURF PLAN CONT_2 ;
  si graph ;
  Trac oeil1 (SUR_SEC2 ET SUR_SEC3) ; finsi ;
  SUR_SEC = elim 1.e-6 (SUR_SEC2 ET SUR_SEC3) ;
  VOL2 =  SUR_SEC VOLU 1  'TRAN' ((EXTR 1 ANGT) 0. 0.) ;
*Trac oeil cach vol2  ;
* Maillage stationnaire de la partie droite du rail: *
  MAISTA MODSTA MOD = MAMOD2 VOL2 AXES angt Ntour '3D'
                 LOI_LIN methode;
  TITRE ' Maillage de la partie droite du rail ' ;
* trac OEIL cach MAISTA ;
*
 FINSI ;
*
**********************************************************
*                       Cas ndom = 1:
 SI   (ndom EGA 1) ;
* D?finition des points de la partie inf?rieure: *
  P1 = P0 PLUS ((d_p/2.) * E_Y) ;
  P2 = P1 PLUS (d_p4 * E_Z) ;
  P2a = P2 MOIN ((d_r1) * E_Z) ;
  P2b = P2 MOIN ((d_r1) * E_Y) ;
  P3 = P0 PLUS ((d_p1/2.)* E_Y) PLUS (d_p3 * E_Z) ;
  TG_A1 = ((d_p2 - d_p3)/(0.5*d_p1)) ; CO1 = ((d_p1 - d_a )/2.) ;
  P4 = P0 plus ((d_a/2)*e_y) plus ((d_p3 + (TG_A1*CO1))*e_z);
  P5 = P4 MOINS (d_r2 * E_Y) PLUS (d_r2 * E_Z) ;
  P5b = (coor 1 p5) (coor 2 p0) (coor 3 p5)  ;
  P6 = P0 PLUS ((d_a1/2.)* E_Y) PLUS ((d_h1 -d_h2) * E_Z) ;
  P7 = P0 PLUS ((d_a1/2.)* E_Y) PLUS ((d_h1 + d_h3) * E_Z) ;
* D?finition du maillage pour la partie inf?rieure: *
  l_d1 = droit p0 10 p1 ;
  l_d2 = droit  P1 2 p2a ;
  PC2 = P2 MOINS (d_r1 * E_Y) MOINS (d_r1 * E_Z) ;
  L_d3 = P2a CERC PC2 nnn P2b  ;
  l_d4 =  droit p2b 4 p3 ;
  l_d5 =  droit p3 4 p4 ;
  PC3 = P4 PLUS (d_r2 * E_Y) ;
  L_d6 = P4 CERC PC3 nnn P5  ;
  l_d7 =  droit p5 4 p6 ;
  l_d8 =  droit p6 4 p7 ;
  l_d9 =  droit p7 4 p8 ;
  l_d10 =  droit p8 1 p8b ;
  l_d11 =  droit p0 15 p8b ;
  L_C2 =   P8 DROIT 1 P9 ;    
  L_C31 = P9 DROIT  2 P10;   
  CONT_2 = ELIM E_ELI (l_d1 ET l_d2 ET l_d3   
           ET l_d4 Et l_d5 ET l_d6 ET l_d7   
           ET l_d8 Et l_d9 ET L_C2) ;   
  CONT_inf = CONT_2;   
  conts = contsup SYME 'PLAN' P0 P14 (1. 0. 0.) ;   
  contsu = ELIM 1.E-7 (contsup ET conts);   
  CONT_in = CONT_inf SYME 'PLAN' P0 P14 (1. 0. 0.) ;   
  CONT_inf = ELIM 1.E-7 (CONT_in ET CONT_inf);   
  Cnt_rail = ELIM 1.E-7 (CONT_inf ET contsu);   
  DEPL Cnt_rail plus ((coor 1 p_ori)   0. 0.)  ;   
*
*
*
*
*
*
*
  beta = 14.4                                                  ; 
  a1 = 0.028                                                   ;
  b1 = 0.016                                                   ;
  PCF = (coor 1 P_ORI)  0. 
(89.5E-3 + 31.5E-3 + (51E-3/2));
  lff6 = GELIPSE a1 b1 PCF beta 23 1.0E-6                      ;
  LIG3 = ELIM E_ELI (Cnt_rail et lff6)                             ; 
  SURF_E23 = SURF LIG3 'PLANE'                                 ; 
  SURF_I23 = SURF lff6 'PLANE'                                 ;
  Surftot = ELIM E_ELI (SURF_E23 et SURF_I23)                  ;
  VOL =  surftot VOLU 1  'TRAN' ((EXTR 1 ANGT) 0. 0.)          ;
*  MAISTA MODSTA MOD = MAMOD2 VOL AXES angt Ntour '3D'
*                  LOI_LIN methode ;
*
tt2 = table 'MAILLAGE' ; 
  vol_u = vol ; tt2 . 1 = vol_u ;
repeter b_mail ((dime angt) - 1) ;
  in_b = &b_mail + 1 ;
  f2_u = face 2 vol_u ;
  vol_u = f2_u volu 1 trans ((extr angt in_b) 0. 0.) ; 
  tt2 . in_b = vol_u ;
fin b_mail ;
*
 FINSI ;
Sino ;
 SI   (ndom EGA 1) ;
  P0 = P_ORI ; 
  TG_A2 = ((d_b2 - d_b1)/(0.5*d_b)) ; CO2 = ((d_b - d_a )/2.) ;  
 p8b = P0 plus ((d_h - d_b1 - (TG_A2 * CO2) - d_r3) * e_z); 
  P14b = P0 PLUS ((d_h - (2.*a))* E_Z) ;  
 P14 = P0 plus (d_h*e_z)  ;
  l_c1b = droit  p14 4 p14b ; 
 L_C0 = (P14b DROIT nnn P8b );
 l_d11 =  droit p8b 15 p0 ;
 Ligne1 = l_c1b et L_C0 et l_d11 ;
 TITRE 'Mod?le 2D de tout le rail';
 SURF1 =  Ligne1 'TRAN' 1 ((EXTR 1 ANGT) 0.) ;
 si graph ;
  Trac cach SURF1  ; finsi ;
  MAISTA MODSTA MOD = MAMOD2 SURF1 AXES angt Ntour '2D' 
              LOI_LIN  methode;
 si graph ;
   TITRE ' Maillage du mod?le 2D de tout le rail ' ;
   trac cach MAISTA ; finsi ; 
  FINS;
 SI   (ndom EGA 3) ;
 P0 = P_ORI ; 
 TG_A2 = ((d_b2 - d_b1)/(0.5*d_b)) ; CO2 = ((d_b - d_a )/2.) ;  
*
*
*
* 
 p8b = P0 plus ((d_h - d_b1 - (TG_A2 * CO2) - d_r3) * e_z);
 P14b = P0 PLUS ((d_h - (2.*a))* E_Z) ;  
 P14 = P0 plus (d_h*e_z)  ;
 l_c1b = droit  p14 4 p14b ;
 L_C0 = (P14b DROIT nnn P8b );
 Ligne1 = L_C0 et l_c1b  ;
 TITRE 'Mod?le 2D du quart sup?rieur du rail';
 SURF1 =  Ligne1 'TRAN' 1 ((EXTR 1 ANGT) 0.) ;
*Trac cach SURF1  ; 
*
 MAISTA MODSTA MOD = MAMOD2 SURF1 AXES angt Ntour '2D'
               LOI_LIN methode ;
 si graph ;
   TITRE ' Maillage du mod?le 2D du quart sup?rieur du rail ' ;
   trac cach MAISTA ;
 finsi ;
*
 FINS;
*
*
FINS;
*
*
*################################################
tabsta = table 'STATIONNAIRE' ;
tabsta . maillage = tt2 ;
si graph ;
titre 'tranche 1' ;
trac tt2 . 1 ;
finsi ;
 
MO2STA = mode tabsta mecanique elastique plastique cinematique ;
*MO2STA = mode tabsta mecanique elastique plastique cinematique advection ;
MAISTA = extr mo2sta mail ;
MODSTA = mode maista mecanique elastique plastique cinematique ; 
MODADV = mode maista mecanique elastique advection ;
 
CA2STA = mate MO2STA youn YO nu NN sigy SY h HH ;
CAADV = mate MODADV 'RHO' 7.9e3 'VITX' 1. 'VITY' 0. 'VITZ' 0. ;
 
pl_1 = point maista proc ((p9 plus p14)/2) ;
pl_i = pl_1 ;
repeter b_pl (dime angt) ;
  ind1 = &b_pl ;
  pl_ind1 = point tt2 . ind1 proc (pl_i plus ((extr angt ind1)*e_x)) ;
  si (ega 1 ind1) ;
   l_pl = pl_i d 1 pl_ind1 ;
  sinon ;
   l_pl = l_pl d 1 pl_ind1 ;
  finsi ;
  pl_i = pl_ind1 ;
fin b_pl ; 
*************************************************
****              BLOCAGES                   ****
*************************************************
Si (Dim ega 3) ;
**
 
*                       Cas ndom = 3:
*
 SI   (ndom EGA 3) ;
 
* Blocage de la surface inf?rieure: *
 SBLOQ = MAISTA POIN plan p8 p8b (p8b plus e_x)  1.E-7;             
 BLOSTA = bloq depl SBLOQ ;                                         
* Blocage de la surface de sym?trie: *                              
 SSYME = MAISTA POIN plan p14 p8b (p8b plus e_x)  1.E-7 ;           
 SLOSTA =  bloq UY   SSYME ;                                        
* TITRE ' Blocages ' ;                                              
*trace cach (MAISTA et (COUL BLEU SBLOQ) et (COUl JAUN SSYME)) ;    
 FINSI ;                                                            
*
*
*
*
*
*
*                       Cas ndom = 2:                               
*
 SI   (ndom EGA 2) ;                                                
* Blocage de la surface de sym?trie: *                              
 SSYME = MAISTA POIN plan p14 p8b (p8b plus e_x)  1.E-7 ;           
 SLOSTA =  bloq UY   SSYME ;                                        
* Blocage de la surface inf?rieure: *                               
 SBLOQ = MAISTA POIN plan p0 p1 (p1 plus e_x)  1.E-7 ;              
 BLOSTA = bloq depl rota SBLOQ ;                                    
* TITRE ' Blocages ' ;                                              
*trace cach (MAISTA et (COUL BLEU SBLOQ) et (COUl JAUN SSYME));     
 FINSI ;                                                            
*
*
*
*
*
*                       Cas ndom = 1:                               
*
 SI   (ndom EGA 1);                                                 
* -Blocage de la surface inf?rieure: *                              
 SBLOQ = MAISTA POIN plan p0 p1 (p1 plus e_x)  1.E-7;               
 BLOSTA = bloq uz SBLOQ ; 
 si graph ;                                          
 TITRE ' Blocages ';                                                
  trace cach (MAISTA et (COUL BLEU SBLOQ)) ;                         
  trace cach (COUL BLEU SBLOQ);
 finsi ;                                      
*
* - Blocage de la surface l?tarale n?1 *                            
 envrail = ENVE MAISTA ;                                            
*
 pp0i = envrail POIN 'PROC' (p0 );          
 PPT1i = envrail POIN 'PROC' (P1) ;     
 PPT10i = envrail POIN 'PROC' (P10) ;   
 surf_a1 = POIN envrail PLAN pp0i PPT1i PPT10i 1.e-15  ;            
 surf_a1 = elem  envrail appuye strictement surf_a1 ;               
 BLOSTA1 = bloq ux uy surf_a1 ;                                     
 si graph ;                                          
 TITRE ' Blocages lateral 1';                                                
  trac cach (MAISTA et (COUL 'BLEU' surf_a1)) ;                      
  trac cach (COUL 'BLEU' surf_a1) ; 
 finsi ;                                 
*
*
* - Blocage de la surface l?tarale n?2 *                            
*
 haha = haha1 + haha2 + haha3  ;            
*
*
 envrail = ENVE MAISTA ;                                            
 PP0s = POIN envrail 'PROC' (p0 plus (haha 0. 0.)) ;                
 PPT1s = POIN envrail 'PROC' ((P1) plus (haha 0. 0.)) ;            
 PPT10s = POIN envrail 'PROC' ((P10) plus (haha 0. 0.)) ;          
 surf_a2 = POIN envrail PLAN PP0s PPT1s PPT10s 1.e-15  ;            
 surf_a2 = elem  envrail appuye strictement surf_a2 ;               
 BLOSTA2 = bloq ux uy surf_a2 ;                                     
 si graph ;                                          
 TITRE ' Blocages lateral 1';                                                
  trac cach (MAISTA et (COUL BLEU surf_a2)) ;                        
  trac cach (COUL BLEU surf_a2);  
 finsi ;                                   
*
 BLOSTA = (BLOSTA et BLOSTA1 et BLOSTA2)  ;                         
*
 FINSI ;                                                            
*
*
Sino;                                                               
*
*                       Cas ndom = 1:                               
*
 SI   (ndom EGA 1) ;                                                
*
  LBLOQ = MAISTA POIN 'DROIT' p0 (p0 plus e_x)  1.E-7;              
  BLOSTA = bloq depl rota LBLOQ ;                                   
*
*
*  TITRE ' Blocages ';                                              
*  trace cach (MAISTA et (COUL BLEU LBLOQ)) ;                       
*
*
*
 FINS;                                                              
*
*                       Cas ndom = 3:                               
 SI   (ndom EGA 3) ;                                                
*
   LBLOQ = MAISTA POIN 'DROIT' p8b (p8b plus e_x)  1.E-7;           
   BLOSTA = bloq depl LBLOQ ;                                       
*   TITRE ' Blocages ' ;                                            
*   trace cach (MAISTA et (COUL BLEU LBLOQ)) ;                      
*MODADV = mode maista mecanique advection ;
 FINS;                                                              
*
*
*
FinS;                                                               
*
*
*************************************************
****             CHARGEMENT                  ****
*************************************************
*
PI = 3.141592654 ;
PC = p14 ;
angt_2 = angt_am et angt_co1 ;
angtc = extr 1 angt_2  ;
repe bouc ((dime angt_2) - 1 ) ;
    angtc = angtc + (extr (&bouc + 1) angt_2)  ;
fin bouc ;
Si (Dim ega 3) ;
 PC1 = p14 plus (((1./na)*a) 0. 0. ) ; 
 PC = POIN MAISTA PROC (p14 plus ((angtc*a) 0. 0. )) ;
 MS = MAISTA POIN PLAN  P13 P14 PC1  1.e-7 ;
 PC2 = p13 plus (((1./na)*a) 0. 0. ) ; 
 MS1 = MAISTA POIN PLAN  P13 P12 PC2  1.e-7 ;
 si (ndom EGA 1);
  p131 = p13  SYME  'DROIT' p14 pc1 ; 
  P132 = POIN maista PROC p131 ;
  p121 = p12  SYME  'DROIT' p14 pc1 ;  
  P122 = POIN maista PROC p121 ;
 
 
 
 
 
  pc3 = p131  plus (((1./na)*a) 0. 0. ) ;
  MS2 = MAISTA POIN PLAN  P122 P132 PC3  1.e-7 ;
  MS =  (ms et ms1 et ms2) ;
 SINO;
  MS =  (ms et ms1) ;
 FINS;
 
Sino;
PC1 = p14 plus (((1./na)*a) 0.) ;
PC = POIN MAISTA PROC (p14 plus ((angtc*a) 0.)) ;
MS = MAISTA POIN 'DROIT' P14 PC1  1.e-7 ;
FINS;
A0 = 0;
B0 = 0;
Si (Dim ega 3) ;
 CHAHERTZ = GERTZ2 MODSTA MAISTA MS PC PMAX A B A0 B0 '3D' ;
Sino;
 CHAHERTZ = GERTZ2 MODSTA MAISTA MS PC PMAX A B A0 B0 '2D' ;
Fins;
Si (Dim ega 3) ;
  vec = vect CHAHERTZ 1.e-2 fx fy fz orange ;
Sino;
  vec = vect CHAHERTZ 0.01E-6 fx fy bleu ;
Fins;
 si graph ;                                          
  TITRE ' Chargement d Hertz ' ;
   trac cach vec MAISTA ;
   trac vec (surf_a1 et surf_a2) ;
 finsi ;
 
ev1 = evol manu temp (prog 0. 1.) f (prog 0. 2.e3) ;
char1 = char meca chahertz ev1 ;
******
 
 
tpasta = table 'PASAPAS' ;
tpasta . 'MODELE'              = MO2STA et MODADV ;
*tpasta . 'MODELE_STATIONNAIRE' = 
tpasta . 'CARACTERISTIQUES'    = CA2STA et CAADV  ; 
tpasta . 'CHARGEMENT'          = char1 ;
*
SI   (ndom EGA 1);
  tpasta . 'BLOCAGES_MECANIQUES' = BLOSTA             ;
SINO;
  Si (Dim ega 3) ;
     tpasta . 'BLOCAGES_MECANIQUES' = (BLOSTA ET SLOSTA) ;
  SINO;
     tpasta . 'BLOCAGES_MECANIQUES' =  BLOSTA ;
  FINS ;
FINS;
tpasta . temps_calcules = prog 0. 1. ;
pasapas tpasta ;
 
si graph ;
titre 'contraintes' ;
trac cach mo2sta tpasta . contraintes . 1 cach ;
finsi ;
ma13 = tt2 . 13 ;
mo13 = redu mo2sta ma13 ; 
si13 = redu tpasta . contraintes . 1 mo13 ;
si graph ;
titre 'contraintes - modele 13 ' ; 
trac mo13 si13 cach ; 
finsi ;
 
si graph ;
titre 'variables internes' ;
trac cach mo2sta tpasta . variables_internes . 1 cach ;
finsi ;
vi13 = redu tpasta . variables_internes . 1 mo13 ;
si graph ;
titre 'variables internes - modele 13 ' ; 
trac mo13 vi13 cach ; 
finsi ;
 
 
chps1 = changer chpo mo2sta tpasta . contraintes . 1 ;
evs1x = evol vert chpo chps1 smxx l_pl ;
evs1z = evol cyan chpo chps1 smzz l_pl ;
si graph ;
dess (evs1x et evs1z) ;
finsi ;
 
l1x = extr (extr evs1x cour 1) ordo ;
l1x_12_25 = prog -6.05934E+06 -1.07189E+07 -2.50495E+07 -3.31079E+07 -3.83731E+07 -7.54869E+07 -9.65269E+07 -9.60031E+07 -1.01280E+08 -1.07190E+08
 -1.13755E+08 -1.20863E+08 -1.28333E+08 -1.36003E+08 -1.43792E+08 -1.51609E+08 -1.59343E+08 -1.66871E+08 -1.74102E+08 -1.80920E+08
 -1.87138E+08 -1.92610E+08 -2.06110E+08 -2.22569E+08 -2.03219E+08 -1.78522E+08 -1.57721E+08 -1.17859E+08 -6.62463E+07 ;
 
 del1x = l1x - l1x_12_25 ;madel1x = maxi del1x ; midel1x = mini del1x ;
 si ((abs (madel1x + midel1x)) > 3.e2) ; erre 5 ; finsi ;
 
l1z = extr (extr evs1z cour 1) ordo ;
l1z_12_25 = prog  -1.20670E+06 -5.53412E+06 -1.82301E+07 -2.61848E+07 -4.89086E+07 -1.30812E+08 -1.84398E+08 -2.00421E+08 -2.18684E+08 -2.36750E+08
 -2.54462E+08 -2.71515E+08 -2.87497E+08 -3.01973E+08 -3.14586E+08 -3.25021E+08 -3.33014E+08 -3.38371E+08 -3.41011E+08 -3.40910E+08
 -3.38054E+08 -3.32537E+08 -3.27600E+08 -2.87631E+08 -1.68153E+08 -7.30757E+07 -3.46319E+07 -6.06032E+07 -1.28230E+06 ;
 
 del1z = l1z - l1z_12_25 ; madel1z = maxi del1z ; midel1z = mini del1z ;
 si ((abs (madel1z + midel1z)) > 2.e1) ; erre 5 ; finsi ;
 
** post FATI
fm1 = 410.e6 * 0.7 ;
tm1 = 260.e6 * 0.7 ; 
beta_dv = tm1 ;
alpha_dv = (tm1 - (fm1 / 2)) / (fm1 / 3) ;
mess 'alpha_dv : ' alpha_dv ' / beta_dv : ' beta_dv ;
 
cafa_dv = manu chml mo13 'ADVK' (-1. * alpha_dv) 'BDVK' beta_dv
    type 'caracteristiques' stresses ;
 
  sig_1 = redu tpasta . contraintes . 1 mo2sta ;
chfa_dv = FATI mo13 mo2sta sig_1 cafa_dv 'DVKP' 'SEUIL' -0.1 ;    
tjdv_u = extr chfa_dv 'PTAU' 1 520 3 ;
 
SI GRAPH ;
titre ' coefficient Dang Van ' ;
trac mo13 (exco chfa_dv dvkp) ;
titre ' trajectoire diagramme element 520 ' ;
dess tjdv_u ;
FINSI ;
 
erre 0 ;
fin ;
 
 
 
 

© Cast3M 2003 - Tous droits réservés.
Mentions légales