Procédures | Cast3M

* USCALC    PROCEDUR  MB234859  24/02/06    21:15:03     11833          
************************************************************************
*                         PROCEDURE USCALC
* 
* Procedure qui determine, pour chaque surface a user, le cisaillement, 
* la pression de contact et la densite d'energie dissipee sur le pas de 
* temps, sur le cycle courant et totale.
* Au dernier increment de chaque cycle, elle determine si les pas de 
* temps doivent etre recalcules a partir du cycle d'usure obtenu.
*  
* Entrees :
*   T1    : Table de PASAPAS
*
* Appelee par USURE
*
************************************************************************
'DEBP' USCALC T1*'TABLE' ; 
*
  BOITE_US = T1.'BOITES_USURE' ;
  IncActu  = BOITE_US.'INFOS'.'INDICE_INCREMENT_ACTUEL' ;
  DTps     = T1.'WTABLE'.'DT' ;
*-----------------------------------------------------------------------
* - LIEN ENTRE MULT. DE LAGRANGE DE CONTACT ET DE FROTTEMENT
*-----------------------------------------------------------------------
  'SI' ('NON' ('EXIS' BOITE_US.'INFOS' 'MULT_CONT'));
*
*   Maillage de contact-frottement
    MODC = 'EXTR' T1.'MODELE' 'FORM' 'CONTACT' ;
    MFRO = 'EXTR' MODC 'MAIL' ;
*
    NODEF = 'NBNO' (MFRO 'ELEM' 1) ;
    NBELT = 'NBEL' MFRO ;
*
    MLIEN = 'VIDE' 'MAILLAGE'/'SEG2' ;
    MCONT = 'VIDE' 'MAILLAGE'/'POI1' ;
    'REPE' BCL NBELT ;
      ELZ = MFRO 'ELEM' &BCL ;
      PCONT = ELZ 'POIN' 1 1 ;
      PFROT = ELZ 'POIN' NODEF 1 ;
      MAIZ = 'MANU' 'SEG2' PCONT PFROT ;
      'SI' (BOITE_US.'INFOS'.'ITRID') ;
        PFRO2 = ELZ 'POIN' (NODEF - 1) 1 ;
        MAIZ = MAIZ 'ET' ('MANU' 'SEG2' PCONT PFRO2) ;
      'FINSI' ;
      MLIEN = MLIEN 'ET' MAIZ ;
      MCONT = MCONT 'ET' PCONT ;
    'FIN' BCL ;
*
    MLIEN = 'UNIQ' MLIEN ;
    MCONT = 'UNIQ' MCONT ; 
*
    BOITE_US.'INFOS'.'MULT_CONT' = MCONT ;
    BOITE_US.'INFOS'.'CONT_FROT' = MLIEN ;
*******************************************************
    BOITE_US.'INFOS'.'DELTA_T' = 0 ;
*******************************************************
  'FINSI';
*
  MCONT = BOITE_US.'INFOS'.'MULT_CONT' ;
  MLIEN = BOITE_US.'INFOS'.'CONT_FROT' ;
*-----------------------------------------------------------------------
* - STATUT DES CONDITIONS UNILATERALES (CONTACT ET FROTTEMENT)
*-----------------------------------------------------------------------
* Resultats issus de UNPAS
  WCOF = T1.'WTABLE'.'POST_COFR';
* Mult. de Lagrange associes aux CL unil actives (contact et frottement)
  CLUA = 'EXTR' WCOF.'MULT_SOLUT' 'MAIL' ;
* Mult. de Lagrange associes aux CL de contact actives
  MLCA = CLUA 'INTE' MCONT ;
*
* Mult. de Lagrange de frottement associes a ceux de contact actifs
  MLFR = 'VIDE' 'MAILLAGE'/'POI1';
  'REPE' BCL ('NBNO' MLCA) ;
    PZ = MLCA 'POIN' &BCL ;
    ELZ = MLIEN 'ELEM' 'APPUYE' 'LARGEMENT' PZ ;
    'REPE' BCL2 ('NBEL' ELZ) ;
      ELTMP = ELZ 'ELEM' &BCL2 ;
      PFROT = ELTMP 'POIN' 2 1 ;
      MLFR = MLFR 'ET' PFROT ;
    'FIN' BCL2 ;
  'FIN' BCL ;
*
* Mult. de Lagrange associes aux CL de frottement actives
**MLFRA = MLFR 'INTE' CLUA ;
* Mult. de Lagrange de frottement inactifs avec mult. de contact actif
* MUGL = 'DIFF' MLFR MLFRA ;
*-----------------------------------------------------------------------
  DEPZ   = 'ENLE' T1.'ESTIMATION'.'DEPLACEMENTS' 'FLX' ;
  LXZ    = WCOF.'MULT_SOLUT' ;
  LCOMPF = BOITE_US.'INFOS'.'LFORCE' ;
  LZERO  = BOITE_US.'INFOS'.'LVALE0' ;
  LUN    = BOITE_US.'INFOS'.'LVALE1' ;
  LSCAL  = BOITE_US.'INFOS'.'LSCAL' ;
*
  'REPE' BU BOITE_US.'INFOS'.'N_BOITES' ;
*
*   --------------------------------------------------------------------
*   Initialisation au debut de chaque nouveau cycle
    'SI' ('EGA' IncActu 1) ;
      BOITE_US. &BU .'GLISSEMENT'       = 'TABLE' 'ESCLAVE' ;
      BOITE_US. &BU .'CISAILLEMENT'     = 'TABLE' 'ESCLAVE' ;
      BOITE_US. &BU .'PRESSION_CONTACT' = 'TABLE' 'ESCLAVE' ;
      BOITE_US. &BU .'PRESSION_MAX_INC' = 'PROG' ;
      BOITE_US. &BU .'CISAILLEMENT_MAX_INC' = 'PROG' ;
      CHPINI = 'CHAN' 'COMP' BOITE_US. &BU .'CZERO' 'ED' ;
      BOITE_US. &BU .'DENS_ENER_DISS_CYCLE' = CHPINI ;
    'FINSI' ;   
*
*   --------------------------------------------------------------------
*   Reactions normale et tangentielle et glissement
    SUR_APPL = BOITE_US. &BU .'SURFACE_APPLICATION' ;
    CHPTUN = 'MANU' 'CHPO' SUR_APPL LCOMPF LUN   'NATURE' 'DISCRET' ;
    ForceN = 'MANU' 'CHPO' SUR_APPL LCOMPF LZERO 'NATURE' 'DISCRET' ;
    ForceT = 'MANU' 'CHPO' SUR_APPL LCOMPF LZERO 'NATURE' 'DISCRET' ;
    Glismt = 'MANU' 'CHPO' SUR_APPL LCOMPF LZERO 'NATURE' 'DISCRET' ;
    Chpres = 'MANU' 'CHPO' SUR_APPL LCOMPF LZERO 'NATURE' 'DISCRET' ;
    MTMP = 'VIDE' 'MAILLAGE' ;
    'REPE' BCL ('NBNO' MLFR) ;
      PFROT = MLFR 'POIN' &BCL ;
      ELTCF = MLIEN 'ELEM' 'APPUYE' 'LARGEMENT' PFROT ;
      PCONT = ELTCF 'POIN' 1 1 ;
      WCL   = WCOF.'RIGI_UNILA' ;
*-    Reaction tangentielle
      Rtang  = 'REDU' ('REAC' WCL ('REDU' LXZ PFROT)) SUR_APPL ;
      ForceT = ForceT 'ET' Rtang ;
*-    Reaction normale
      Rnorm  = 'REDU' ('REAC' WCL ('REDU' LXZ PCONT)) SUR_APPL ;
      ForceN = ForceN 'ET' Rnorm ;
      MTMP = MTMP 'ET' ('EXTR' Rnorm 'MAIL') ;
*-    Glissement eventuel
      PscRtang = 'PSCA' Rtang Rtang LCOMPF LCOMPF ;
      NorRtang = PscRtang ** 0.5 ;
      Dirgliss = Rtang '/' NorRtang LCOMPF LSCAL LCOMPF;
      Valgliss = Dirgliss '*' ('EXTR' WCOF.'GLISSEMENT' 'FLX' PFROT) ;
      Valgliss = 'CHAN' 'ATTRIBUT' Valgliss 'NATURE' 'DISCRET' ;
*
*     Certains noeuds apparaissent dans plusieurs conditions de contact/
*     frottement, il faut alors moyenner les valeurs de glissement
      Mglis = 'EXTR' Rtang 'MAIL' ;
      CHMZ = 'MANU' 'CHPO' Mglis LCOMPF LUN 'NATURE' 'DISCRET' ;
      Chpres = Chpres 'ET' CHMZ ;
      Glismt = Glismt 'ET' Valgliss ;
    'FIN' BCL ;
*
**MTM2 = 'UNIQ' MTMP ;
**CNBF = 'MANU' 'CHPO' MTM2 1 'SCAL' 1. 'NATURE' 'DISCRET' ;
**'SI'('EGA' (BOITE_US.'INFOS'.'INDICE_INCREMENT_ACTUEL') 1) ;
**  BOITE_US. &BU .'PRESSION_NBF' = CNBF ;
**'SINON' ;
**  BOITE_US. &BU .'PRESSION_NBF' = BOITE_US. &BU .'PRESSION_NBF' + CNBF ;
**'FINSI' ;
**EVT = evol vert chpo (BOITE_US. &BU .'PRESSION_NBF') sur_appl;
**EVY = evol turq chpo CNBF sur_appl;
*
*   Moyenner les valeurs de Glismt
    Chmoye = ('MASQ' Chpres 'EGAL' 0.) 'ET' Chpres ; 
    Glismt = Glismt '/' Chmoye LCOMPF LCOMPF LCOMPF ;
*
*   Usure bilaterale : equireparition de l'energie dissipee
*   -> a prendre en compte sur le coefficient d'usure  
*      pas de coefficient ajoute sur les valeurs de glissement
*
*   --------------------------------------------------------------------
*   Pression de contact et cisaillement
    XX = 1. '/' 2 ;    
    'SI' BOITE_US.'INFOS'.'ITRID' ;
      XX = 1. '/' 4. ;
    'FINSI' ;
    CONF0 = 'FORM' ;
    'FORM' DEPZ ;
    SurfElt = 'MANU' 'CHPO' SUR_APPL 1 'SCAL' 0. 'NATURE' 'DISCRET' ;
    'REPE' BCL ('NBEL' SUR_APPL) ;
      ELTZ = SUR_APPL 'ELEM' &BCL ; SELT = 'MESU' ELTZ ;
      CHPZ = 'MANU' 'CHPO' ELTZ 1 'SCAL' (SELT '*' XX) 'NATURE' 'DISCRET';
      SurfElt = SurfElt 'ET' CHPZ ;
    'FIN' BCL ;
    'FORM' CONF0 ;
    BOITE_US. &BU .'LELT' = 'MINI' SurfElt ;
*    
*   Pression de contact
    FNsurf = ForceN '/' SurfElt LCOMPF LSCAL LCOMPF ;
    PscFNsur = 'PSCA' FNsurf FNsurf LCOMPF LCOMPF ;
    Cpress = PscFNsur ** 0.5 ;
    CPress = 'CHAN' 'ATTRIBUT' Cpress 'NATURE' 'DISCRET' ;
*
*   Cisaillement
    FTsurf = ForceT '/' SurfElt LCOMPF LSCAL LCOMPF ;
    PscFTsur = 'PSCA' FTsurf FTsurf LCOMPF LCOMPF ;
    Cshear = PscFTsur ** 0.5 ;
    CShear = 'CHAN' 'ATTRIBUT' CShear 'NATURE' 'DISCRET' ;
*    
*   Glissement
    PscGlis = 'PSCA' Glismt Glismt LCOMPF LCOMPF ;
    NorGlis = PscGlis ** 0.5 ;
    NorGlis = 'CHAN' 'ATTRIBUT' NorGlis 'NATURE' 'DISCRET' ;
*
*   --------------------------------------------------------------------
*   Densite d energie dissipee sur le pas de temps
    EnDisInc = 'PSCA' FTsurf Glismt LCOMPF LCOMPF ;
    EnDisInc = 'CHAN' 'COMP' ('ABS' EnDisInc) 'ED' ;
    EnDisInc = 'CHAN' 'ATTRIBUT' EnDisInc 'NATURE' 'DISCRET' ;
*
*   Densite d energie dissipee sur le cycle
    EnDisCyc = BOITE_US. &BU .'DENS_ENER_DISS_CYCLE' ;
    EnDisCyc = EnDisCyc + EnDisInc ;
*    
*   Densite d energie dissipee totale (ensemble des cycles)
    EnDisTot = BOITE_US. &BU .'DENS_ENER_DISS_TOTALE' ;
    EnDisTot = EnDisTot + EnDisInc ;
*
*   --------------------------------------------------------------------
*   Trace d evolutions le long de la zone de contact
    'SI' BOITE_US.'INFOS'.'TRACE_DEBUG' ;
      'SI' ('NON' BOITE_US.'INFOS'.'ITRID') ;
*
        EvCPress = 'EVOL' 'BLEU' 'CHPO' CPress SUR_APPL ;
        EvCPress = 'EXTR' EvCPress 'COUR' 1 ;
        EvCPress = 'CHAN' EvCPress 'LEGE' 'Pressure' ;
*
        EvCShear = 'EVOL' 'ROUG' 'CHPO' CShear SUR_APPL ;
        EvCShear = 'EXTR' EvCShear 'COUR' 1 ;
        EvCShear = 'CHAN' EvCShear 'LEGE' 'Shear' ;
*
        EvGlisse = 'EVOL' 'VERT' 'CHPO' NorGlis SUR_APPL ;
        EvGlisse = 'EXTR' EvGlisse 'COUR' 1 ;
        EvGlisse = 'CHAN' EvGlisse 'LEGE' 'Glissement' ;
*
        EvDltEnD = 'EVOL' 'JAUN' 'CHPO' EnDisInc SUR_APPL ;
        EvDltEnD = 'EXTR' EvDltEnD 'COUR' 1 ;
        EvDltEnD = 'CHAN' EvDltEnD 'LEGE' 'Energie_dis_Inc' ;
*
        EvEnDCyc = 'EVOL' 'GRIS' 'CHPO' EnDisCyc SUR_APPL ;
        EvEnDCyc = 'EXTR' EvEnDCyc 'COUR' 1 ;
        EvEnDCyc = 'CHAN' EvEnDCyc 'LEGE' 'Energie_dis_Cyc' ;
*
        'DESS' (EvCPress 'ET' EvCShear 'ET' (500000. * EvGlisse)
          'ET' (100. * EvDltEnD) 'ET' (100. * EvEnDCyc)) 'LEGE' 'NCLK' ; 
*
      'FINSI' ;
    'FINSI' ; 
*
*   --------------------------------------------------------------------
*   Cycle d'usure (force_tangentielle en fonction du deplacement)
    LstDelta = BOITE_US. &BU .'DELTAS' ;
    Delta_ii = 'EXTR' DEPZ BOITE_US.'INFOS'.'COMP_DEPI' 
                           BOITE_US.'INFOS'.'PTSZ_DEPI' ;
    LstDelta = LstDelta 'ET' Delta_ii ;
*    
    LstFTang = BOITE_US. &BU .'FORCES_TANGENTIELLES' ;
    FtangRes = 'PSCA' ForceT BOITE_US. &BU .'DIRE_REACTION' 
                      LCOMPF LCOMPF ;
    FTangRes = 'SOMT' FTangRes ;
    LstFTang = LstFTang 'ET' FTangRes ;
*
*   --------------------------------------------------------------------
*   Dernier instant du cycle actuel
    'SI' ('EGA' IncActu BOITE_US.'INFOS'.'NB_INCREMENTS_PAR_CYCLE') ;
*   
*     Vitesse d'usure sur le cycle (utilise dans USEXPL/USIMPL)
      ALPHA    = BOITE_US. &BU .'COEFFICIENT_USURE' ;
      VitUsure = 'CHAN' 'COMP' (ALPHA '*' EnDisCyc) 'SCAL' ;
      BOITE_US. &BU .'VITESSE_USURE' = VitUsure ;
 
      CycActu  = BOITE_US.'INFOS'.'INDICE_CYCLE_ACTUEL' ;
      CyclFret = 'EVOL' 'ROUG' 'MANU' 'Deplacement' LstDelta 
                               'Force_Tangentielle' LstFTang ;
      EnteteCF = 'CHAI' 'Cycle_de_fretting_n: ' CycActu FORMAT '(I2)' ;
      CyclFret = 'CHAN' CyclFret 'LEGE' EnteteCF ;
      BOITE_US. &BU .'CYCLE_DE_FRETTING'. CycActu = CyclFret ;
*   
*     FAUT-IL REDETERMINER LES PAS DE TEMPS
      Ampl_F_N = ('MAXI' LstFTang) '-' ('MINI' LstFTang) ; 
      Ampl_Dlt = ('MAXI' LstDelta) '-' ('MINI' LstDelta) ; 
      ECycFret = 'ABS' ('INTG' CyclFret) ;
      DltG_Est = ECycFret / 2. / Ampl_F_N ;
      DltT_Est = (Ampl_Dlt / 2.) - DltG_Est ;
      BOITE_US.'INFOS'.'DELTAP' = BOITE_US.'INFOS'.'DELTA_T' ;
      BOITE_US.'INFOS'.'DELTA_T' = DltT_Est ;
*   
      'SI' (('EGA' &BU 1) 'ET' BOITE_US.'INFOS'.'CALCUL_PAS');
        ECycGtot = Ampl_F_N * Ampl_Dlt ;
        BOITE_US.'INFOS'.'AJUSTE_PAS' = FAUX ;
*       Uniquement si regime de glissement total
        'SI' ((ECycFret / ECycGtot) '>' 0.2) ;
          BOITE_US.'INFOS'.'AJUSTE_PAS' = VRAI ;
          'SI' ('NEG' CycActu 1) ;
********    LDltTPre = BOITE_US. &BU .'DELTA_T' ;
********    DltTPre  = 'EXTR' LDltTPre ('DIME' LDltTPre) ;
            DltTPre  = BOITE_US.'INFOS'.'DELTAP' ;
            VarDltT  = 'ABS' ((DltT_Est - DltTPre) / DltTPre) ; 
            BOITE_US.'INFOS'.'AJUSTE_PAS' = (VarDltT '>' 0.1) ;
          'FINSI' ;  
          CHAZ = 'CHAI' 'Pas de temps recalcules :' ;
          CHAZ = 'CHAI' CHAZ BOITE_US.'INFOS'.'AJUSTE_PAS' ;
          'MESS' CHAZ ;
        'FINSI' ;  
      'FINSI' ; 
*
*     Reinitialisation (le dernier point est aussi premier cycle suivant)
      LstDelta = 'PROG' Delta_ii ;
      LstFTang = 'PROG' FTangRes ;
*
      'SI' BOITE_US.'INFOS'.'TRACE_DEBUG' ;
        TabDess    = TABL ;
        TabDess. 1 = 'TIRC MARQ CROI' ;
        'DESS' CyclFret TabDess 'GRIL' 'LEGE' ;
      'FINSI' ;
    'FINSI' ;
*
*   --------------------------------------------------------------------
*   Stockage des resultats
    BOITE_US. &BU .'GLISSEMENT'.       IncActu = 'ABS' NorGlis ;
    BOITE_US. &BU .'PRESSION_CONTACT'. IncActu = DTps '*' CPress ;
    BOITE_US. &BU .'CISAILLEMENT'. IncActu     = DTps '*' ('ABS' CShear);
    BOITE_US. &BU .'DENS_ENER_DISS_CYCLE'      = EnDisCyc ;
    BOITE_US. &BU .'DENS_ENER_DISS_TOTALE'     = EnDisTot ;
    BOITE_US. &BU .'DELTAS'                    = LstDelta ;
    BOITE_US. &BU .'FORCES_TANGENTIELLES'      = LstFTang ;
*    
    BOITE_US. &BU .'PRESSION_MAX_INC' =
      BOITE_US. &BU .'PRESSION_MAX_INC' 'ET' ('MAXI' CPress) ;
    BOITE_US. &BU .'CISAILLEMENT_MAX_INC' =
      BOITE_US. &BU .'CISAILLEMENT_MAX_INC' 'ET' ('MAXI' CShear 'ABS') ;
  'FIN' BU ;
*-----------------------------------------------------------------------
'FINP' ;