Procédures | Cast3M

* TOPODENS  PROCEDUR  FD218221  23/11/29    21:15:07     11799          
* TOPODENS  PROCEDUR  CB215821  21/04/22    14:10:01     9715
 
************************************************************************
** Procedure called by TOPOPTIM for calculating the densitivity fields.
**
** Author:
** Guenhael Le Quilliec (LaMe - Polytech Tours)
**
** Version:
** 2.0 2021/04/22 Fixing an issue when calculating MAXDENSITE with both 
**                thermal and mechanical densities.
** 1.0 2021/04/15
************************************************************************
 
DEBP TOPODENS tab0*'TABLE' ;
 
wtab0 = tab0.'WTABLE' ;
bool0 = wtab0.'BOOL' ;
 
SI bool0.'MECANIQUE' ;
    DensM0 = wtab0.'MECANIQUE'.'CHAMP_MIN' + 
             ((1.0 - tab0.'RAPPORT_RAIDEURS_MECANIQUES') *
              (wtab0.'TOPOLOGIE' ** wtab0.'FACTEUR_P')) ;
    wtab0.'MECANIQUE'.'DENSITE' = DensM0 ;
    wtab0.'MAXDENSITE' = DensM0 ;
FINS ;
SI bool0.'THERMIQUE' ;
    DensT0 = wtab0.'THERMIQUE'.'CHAMP_MIN' + 
             ((1.0 - tab0.'RAPPORT_RAIDEURS_THERMIQUES') *
              (wtab0.'TOPOLOGIE' ** wtab0.'FACTEUR_P')) ;
    SI bool0.'MECANIQUE' ;
        tmp0 = PROI wtab0.'MAILLAGE'.'GRAVITE' DensT0 ;
        tmp1 = MAXI (PROI wtab0.'MAILLAGE'.'GRAVITE' DensM0) tmp0 ;
        wtab0.'MAXDENSITE' = MANU 'CHML' wtab0.'MECANIQUE'.'MODELE'.(1)
                                  'REPA' 'SCAL' (EXTR tmp1 'VALE') 'TYPE' 'SCALAIRE' 'GRAVITE' ;
*       Switch the model of the element field DensT0 from Mecha to Therm
*        DensT0 = TOPOCHAN DensT0 wtab0.'THERMIQUE'.'MODELE'.(1) wtab0.'MAILLAGE'.'GRAVITE' ;
        DensT0 = MANU 'CHML' wtab0.'THERMIQUE'.'MODELE'.(1)
                      'REPA' 'SCAL' (EXTR tmp0 'VALE') 'TYPE' 'SCALAIRE' 'GRAVITE' ;
    SINO ;
        wtab0.'MAXDENSITE' = DensT0 ;
    FINS ;
    wtab0.'THERMIQUE'.'DENSITE' = DensT0 ;
FINS ;
 
FINP ;