Exemples de jeux de données Cast3M

************************************************************************
************************************************************************
* TEST DE LECTURE DE FICHIERS CSV AVEC EN-TETE
*
* ON A MIS EXPRES :
* - 2 LIGNES BIDONS AU DEBUT DU FICHIER POUR VERIFIER L'OPTION 'DEBU'
* - DES VIRGULES A LA PLACE DU POINT A CERTAINS ENDROITS EN TANT QUE
*   SEPARATEUR DECIMAL POUR VERIFIER QUE LA SUBSTITUTION SE PASSE
*   CORRECTEMENT
************************************************************************
 
XPREC = VALE 'PREC';
 
*  repertoire des fichiers "divers"
DIVERS = VENV 'CASTEM_DIVERS';
* LECTURE EN COLONNES
TAB1 = LIRE 'CSV' ('CHAIN' DIVERS '/lire_csv.csv') 'DEBU' 3;
 
INDICES = INDE TAB1;
SI ((NEG INDICES.(1) 'toto') OU
    (NEG INDICES.(2) 'tata') OU
    (NEG INDICES.(3) '3-ti+ 4'));
    ERRE 'PROBLEME DE LECTURE DES EN-TETES (LECTURE EN COLONNES)';
FINSI;
 
L1 = PROG 120. 8.9;
L2 = PROG 3. 5.;
L3 = PROG 5.6 12.4;
SI (((MAXI 'ABS' (TAB1.'toto' - L1)) >EG XPREC) OU
    ((MAXI 'ABS' (TAB1.'tata' - L2)) >EG XPREC) OU
    ((MAXI 'ABS' (TAB1.'3-ti+ 4' - L3)) >EG XPREC));
    ERRE 'PROBLEME DE LECTURE DES FLOTTANTS (LECTURE EN COLONNES)';
FINSI;
 
* LECTURE EN LIGNES
TAB2 = LIRE 'CSV' ('CHAIN' DIVERS '/lire_csv.csv') 'LIGN' 'DEBU' 3;
 
LMOTS = MOTS 'toto' 'tata' '3-ti+ 4';
L1 = PROG 120. 3. 5.6;
L2 = PROG 8.9 5. 12.4;
SI (NON ((EXIS TAB2.(1) LMOTS 'ET') ET (EXIS LMOTS TAB2.(1) 'ET')));
    ERRE 'PROBLEME DE LECTURE DES EN-TETES (LECTURE EN LIGNES)';
FINSI;
SI (((MAXI 'ABS' (TAB2.(2) - L1)) >EG XPREC) OU
    ((MAXI 'ABS' (TAB2.(3) - L2)) >EG XPREC));
    ERRE 'PROBLEME DE LECTURE DES FLOTTANTS (LECTURE EN LIGNES)';
FINSI;
 
FIN;