Télécharger ffor-axi.dgibi

Retour à la liste

Numérotation des lignes :

  1. ************************************************************************
  2. ************************************************************************
  3. ************************************************************************
  4. *......../........./........./........./........./........./........./72
  5. * Calcul de facteurs de forme en axisymétrique pour une cavite
  6. * comportant un jeu
  7. * Comparaison a des expressions analytiques (P.YALA)
  8. *
  9. ************************************************************************
  10.  
  11. OPTI DIME 2 MODE AXIS ELEM QUA4 ;
  12. OPTI ECHO 0 ;
  13.  
  14. ************************************************************************
  15. * CALCUL TEST EN GEOMETRIE 2D
  16. ************************************************************************
  17. MESS ' CALCUL TEST ERREUR CALCUL FACTEUR de FORME sur CAVITE AXI ' ;
  18. *
  19.  
  20. * MAILLAGE CAVITE avec NOYAU CENTRAL
  21.  
  22. xra1 = 4.0 ; xra2 = 2.0 ;
  23. larg = 0.01 ; haut = 0.01 ;
  24. ptA = 0.0 0.0 ; ptB = larg 0.0 ; ptC = larg haut ; ptD = 0.0 haut ;
  25. *
  26. * jeux
  27. jbas = 0.00025 ; jcot = 0.0005 ; jhau = 0.001 ;
  28. * autre cas: on minimise tous les jeux
  29. *jbas = 0.0001 ; jcot = 0.0001 ; jhau = 0.0001 ;
  30.  
  31. * maillage
  32. ciHAU = droit ptD ptC dini ( larg / xra1 ) dfin ( larg / xra2 ) ;
  33. ciCOT = droit ptC ptB dini ( haut / xra1 ) dfin ( haut / xra2 ) ; ;
  34. ciBAS = droit ptB ptA dini ( larg / xra2 ) dfin ( larg / xra1 ) ; ;
  35. cavint = cibas et cicot et cihau ;
  36. *trac elem cavint ;
  37. ceBAS = ( inve ciBAS ) moins ( 0.0 jbas ) ;
  38. ceCOT = ( inve ciCOT ) plus ( jcot 0.0 ) ;
  39. ceHAU = ( inve ciHAU ) plus ( 0.0 jhau ) ;
  40. cavext = ceBAS droit 1 ceCOT droit 1 ceHAU ;
  41. *trac elem cavext ;
  42.  
  43. cavi = cavint et cavext ;
  44. *trac elem cavi ;
  45.  
  46.  
  47. ************************************************************************
  48. * CALCUL ANALYTIQUE des FACTEURS de FORME
  49. *solutions analytiques sur les faces basses element 9 8 7 de CAVI
  50. ************************************************************************
  51. xr = table ; tY = table ; tZ = table ; FFD = table ; FFA = table ;
  52. xr. 1 = coor 1 ( ( cavi elem 9) poin initial ) ;
  53. xr. 2 = coor 1 ( ( cavi elem 8) poin initial ) ;
  54. xr. 3 = coor 1 ( ( cavi elem 7) poin initial ) ;
  55. *
  56. * CALCUL des FACTEURS de FORME des couples de DISQUES ELEMENTAIRES
  57. REPETER Bdef 3 ;
  58. FFD. &Bdef = table ;
  59. fin Bdef ;
  60. *
  61. REPETER BLF 3 ;
  62. X1 = xr. &BLF / jbas ;
  63. REPETER BLFF 3 ;
  64. Y1 = jbas / xr. &BLFF ;
  65. Z1 = 1.0 + ( ( 1.0 + ( X1 * X1 ) ) * ( Y1 * Y1 ) ) ;
  66. FFD. &BLFF . &BLF =
  67. 0.5 * ( Z1 - ( ( Z1 * Z1 ) - (( 4.0 * X1 * X1 * Y1 * Y1) ) ** 0.5 )) ;
  68. fin BLFF ;
  69. fin BLF ;
  70. *
  71. F9s10 = FFD. 1 . 1 ;
  72. *
  73. * CALCUL des FACTEURS de FORME des ANNEAUX
  74. REPETER BLFA 2 ;
  75. IN1 = &BLFA ; IN2 = &BLFA + 1 ;
  76. SA2 = ( xr. IN2 - xr. IN1 ) * ( xr. IN2 + xr. IN1 ) ;
  77. SD1 = xr. IN1 * xr. IN1 ; SD2 = xr. IN2 * xr. IN2 ;
  78. *
  79. FFA. &BLFA = ( ( SD2 * FFD. IN2 . IN2 )
  80. + ( SD1 * FFD. IN1 . IN1 )
  81. - ( 2.0 * SD1 * FFD. IN1 . IN2 ) ) / SA2 ;
  82. fin BLFA ;
  83. *
  84. F8s11 = FFA. 1 ;
  85. F7s12 = FFA. 2 ;
  86. *
  87. AL1 = xr. 1 / jbas ;
  88. AL2 = ( xr. 2 - xr. 1 ) / jbas ;
  89. AL3 = ( xr. 3 - xr. 2 ) / jbas ;
  90. *
  91. MESS ' RESULTATS du CALCUL ANALYTIQUE ';
  92. MESS '* Allongement pour FF(9,10) ' AL1 ' FF(9,10) = ' F9s10 ;
  93. MESS '* Allongement pour FF(8,11) ' AL2 ' FF(8,11) = ' F8s11 ;
  94. MESS '* Allongement pour FF(7,12) ' AL3 ' FF(7,12) = ' F7s12 ;
  95.  
  96. ************************************************************************
  97. * CALCUL CAST3M des FACTEURS de FORME
  98. ************************************************************************
  99. mess ' CALCUL NUMERIQUE ';
  100.  
  101. EMAC = 0.4 ;
  102.  
  103. MDRX2 = MODE cavi 'THERMIQUE' 'RAYONNEMENT' 'CAVITE' ;
  104. MARX2 = MATE MDRX2 'EMIS' EMAC ;
  105. *
  106.  
  107. *opti IMPI 2; comm pour controle du calcul;
  108. CHVRC2 = ffor MDRX2 MARX2 ;
  109. opti impi 0;
  110.  
  111. * pour les jeux faibles il peut etre necessaire d'augmenter le nombre
  112. * de points d integration:
  113. ng = 10 ; comm integration de type Gauss pour faces eloignees ;
  114. np = 50 ; comm integration de type Trapezes pour faces proches ;
  115. * opti impi 2;
  116. * CHVRC2 = ffor MDRX2 MARX2 ng np ;
  117. * opti IMPI 0 ;
  118. *
  119.  
  120. fft = CHVRC2 ;
  121.  
  122. * impression ?
  123.  
  124. nface = nbel (extr fft 'MAIL');
  125. * mess 'nface' nface;
  126.  
  127. repe iface nface;
  128. fi = extr fft MIDL 1 &iface 1;
  129. * mess ' ';
  130. * mess ' elem: ' &iface ' Fij: ' ;
  131. * list fi ;
  132. fin iface ;
  133.  
  134. * elements (7,12)
  135. i = 7 ; j = 12 ;
  136. fi = extr fft 'MIDL' 1 i 1;
  137. *list fi ;
  138. fij = extr fi 'MIDL' 1 j 1 ;
  139. mess 'faces: ' i j F fij ;
  140.  
  141. ecart1 = (fij/F7s12 ) - 1. ;
  142. mess 'faces: ' i j ' ecart relatif: ' ecart1;
  143.  
  144.  
  145. * elements (8,11)
  146. i = 8 ; j = 11 ;
  147. fi = extr fft 'MIDL' 1 i 1;
  148. *list fi ;
  149. fij = extr fi 'MIDL' 1 j 1 ;
  150. mess 'faces: ' i j F fij ;
  151. ecart2 = (fij/F8s11 ) - 1. ;
  152. mess 'faces: ' i j ' ecart relatif: ' ecart2;
  153.  
  154.  
  155. * elements (9,10)
  156. i = 9 ; j = 10 ;
  157. fi = extr fft 'MIDL' 1 i 1;
  158. *list fi ;
  159. fij = extr fi 'MIDL' 1 j 1 ;
  160. mess 'faces: ' i j F fij ;
  161.  
  162. ecart3 = (fij/F9s10 ) - 1. ;
  163. mess 'faces: ' i j ' ecart relatif: ' ecart3;
  164.  
  165. crit = 5e-3;
  166. si( ((abs ecart1) > crit) ou ((abs ecart2) > crit)
  167. ou ((abs ecart1) > crit) );
  168. mess ' probleme facteurs de forme en axis config. face a face ';
  169. erre 5 ;
  170. sinon;
  171. erre 0 ;
  172. finsi;
  173.  
  174.  
  175. FIN ;
  176.  
  177.  
  178.  
  179.  
  180.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales