Procédures | Cast3M

* USCALC    PROCEDUR  MB234859  25/05/05    21:15:10     12260          
************************************************************************
*                         PROCEDURE USCALC
* 
* Procedure qui determine, pour chaque surface a user, le cisaillement, 
* la pression de contact et la densite d'energie dissipee sur le pas de 
* temps, sur le cycle courant et totale.
* Au dernier increment de chaque cycle, elle determine si les pas de 
* temps doivent etre recalcules a partir du cycle d'usure obtenu.
*  
* Entrees :
*   T1 : Table de PASAPAS
*
* Remarque : pour l'usure bilaterale aucun coefficient n'est ajoute 
*            dans le calcul. L'hypothese d'equireparition de l'energie 
*            dissipee est a prendre en compte sur le coefficient d'usure  
*
* Appelee par USURE
*
************************************************************************
'DEBP' USCALC T1*'TABLE' ; 
*
  BOITE_US = T1.'BOITES_USURE' ;
  IncActu  = BOITE_US.'INFOS'.'INDICE_INCREMENT_ACTUEL' ;
  DTps     = T1.'WTABLE'.'DT' ;
*-----------------------------------------------------------------------
* - STATUT DES CONDITIONS UNILATERALES (CONTACT ET FROTTEMENT)
*-----------------------------------------------------------------------
* Resultats issus de UNPAS
  WCOF = T1.'WTABLE'.'POST_COFR';
* Mult. de Lagrange associes aux CL unil actives (contact et frottement)
  CLUA = 'EXTR' WCOF.'MULT_SOLUT' 'MAIL' ;
* Mult. de Lagrange associes aux CL de contact actives
  MLCA = CLUA 'INTE' BOITE_US.'INFOS'.'MULT_CONT';
*
* Mult. de Lagrange de frottement associes a ceux de contact actifs
  LCONT = 'POSI' MLCA 'DANS' BOITE_US.'INFOS'.'MULT_CONT';
  MLFR  = BOITE_US.'INFOS'.'MULT_FROT' 'ELEM' LCONT ;
  'SI' BOITE_US.'INFOS'.'ITRID' ;
    MLF2 = BOITE_US.'INFOS'.'MULT_FRO2' 'ELEM' LCONT ;
    MLFR = MLFR 'ET' MLF2 ;
  'FINSI' ;
*
* Mult. de Lagrange associes aux CL de frottement actives
**MLFRA = MLFR 'INTE' CLUA ;
* Mult. de Lagrange de frottement inactifs avec mult. de contact actif
* MUGL = 'DIFF' MLFR MLFRA ;
*-----------------------------------------------------------------------
  DEPZ = T1.'ESTIMATION'.'DEPLACEMENTS' ;
  LXZ  = WCOF.'MULT_SOLUT' ;
  WCL  = WCOF.'RIGI_UNILA' ;
  LCF  = BOITE_US.'INFOS'.'LFORCE' ;
  LSCA = BOITE_US.'INFOS'.'LSCAL' ;
*
  'REPE' BU BOITE_US.'INFOS'.'N_BOITES' ;
*
*   --------------------------------------------------------------------
*   Initialisation au debut de chaque nouveau cycle
    'SI' ('EGA' IncActu 1) ;
      BOITE_US. &BU .'PRESSION_CONTACT'     = 'TABLE' 'ESCLAVE' ;
      BOITE_US. &BU .'CISAILLEMENT'         = 'TABLE' 'ESCLAVE' ;
      BOITE_US. &BU .'DENS_ENER_DISS'       = 'TABLE' 'ESCLAVE' ;
      BOITE_US. &BU .'DENS_ENER_DISS_CYCLE' = BOITE_US. &BU .'CZERO' ;
    'FINSI' ;
*
*   --------------------------------------------------------------------
*   Surface associee a chaque element
    SUR_APPL = BOITE_US. &BU .'SURFACE_APPLICATION' ;
    XX = 1. '/' 2 ;    
    'SI' BOITE_US.'INFOS'.'ITRID' ;
      XX = 1. '/' 4. ;
    'FINSI' ;
    CONF0 = 'FORM' ;
    'FORM' DEPZ ;
    SurfElt = 'MANU' 'CHPO' SUR_APPL 1 'SCAL' 0. 'NATURE' 'DISCRET' ;
    'REPE' BCL ('NBEL' SUR_APPL) ;
      ELTZ = SUR_APPL 'ELEM' &BCL ; SELT = 'MESU' ELTZ ;
      CHPZ = 'MANU' 'CHPO' ELTZ 1 'SCAL' (SELT '*' XX) 'NATURE' 'DISCRET';
      SurfElt = SurfElt 'ET' CHPZ ;
    'FIN' BCL ;
    'FORM' CONF0 ;
    BOITE_US. &BU .'LELT' = 'MINI' SurfElt ;   
*
*   --------------------------------------------------------------------
*   Reactions normale et tangentielle et glissement
    EnDisInc = BOITE_US. &BU .'CZERO' ;
    'REPE' BCL ('NBNO' MLFR) ;
*
*     Multiplicateur associee a la condition de frottement
      PFROT = MLFR 'POIN' &BCL ;
*
*     Reaction tangentielle
      Rtang  = 'REDU' ('REAC' WCL ('REDU' LXZ PFROT)) SUR_APPL ;
      Rtnor  = 'PSCA' Rtang Rtang LCF LCF ;
      Cshear = (Rtnor ** 0.5) '/' SurfElt ;
      CShear = 'CHAN' 'ATTRIBUT' CShear 'NATURE' 'DISCRET' ;
*
*     Glissement eventuel
      Vglis = 'EXTR' WCOF.'GLISSEMENT' 'FLX' PFROT ;
      Mglis = 'EXTR' Rtang 'MAIL' ;
      Vglis = 'MANU' 'CHPO' Mglis 1 'SCAL' Vglis 'NATURE' 'DISCRET' ;
*
*     Densite d'energie dissipee par frottement
      EnerDiss = 'ABS' (CShear '*' Vglis) ;
      EnerDiss = 'CHAN' 'ATTRIBUT' EnerDiss 'NATURE' 'DISCRET' ;
      EnDisInc = EnDisInc '+' EnerDiss ;
*
    'FIN' BCL ;
*
*   --------------------------------------------------------------------
*   Pression de contact
    ForceN = 'REDU' ('REAC' WCL ('REDU' LXZ MLCA)) SUR_APPL ;
    SigmaN = ForceN '/' SurfElt LCF LSCA LCF ;
    PscaSN = 'PSCA' SigmaN SigmaN LCF LCF ;
    Cpress = PscaSN ** 0.5 ;
    CPress = 'CHAN' 'ATTRIBUT' Cpress 'NATURE' 'DISCRET' ;
*
*   Cisaillement
    ForceT = 'REDU' ('REAC' WCL ('REDU' LXZ MLFR)) SUR_APPL ;
    SigmaT = ForceT '/' SurfElt LCF LSCA LCF ;
    PscaST = 'PSCA' SigmaT SigmaT LCF LCF ;
    Cshear = PscaST ** 0.5 ;
    CShear = 'CHAN' 'ATTRIBUT' CShear 'NATURE' 'DISCRET' ;
*
*   --------------------------------------------------------------------
*   Trace le long de la zone de contact
    'SI' BOITE_US.'INFOS'.'TRACE_DEBUG' ;
      'SI' ('NON' BOITE_US.'INFOS'.'ITRID') ;
*
        ECPress = 'EVOL' 'BLEU' 'CHPO' CPress SUR_APPL ;
        ECPress = 'EXTR' ECPress 'COUR' 1 ;
        ECPress = 'CHAN' ECPress 'LEGE' 'Pressure' ;
*
        ECShear = 'EVOL' 'ROUG' 'CHPO' CShear SUR_APPL ;
        ECShear = 'EXTR' ECShear 'COUR' 1 ;
        ECShear = 'CHAN' ECShear 'LEGE' 'Shear' ;
*
        EvDltEnD = 'EVOL' 'JAUN' 'CHPO' EnDisInc SUR_APPL ;
        EvDltEnD = 'EXTR' EvDltEnD 'COUR' 1 ;
        EvDltEnD = 'CHAN' EvDltEnD 'LEGE' 'Energie_dis_Inc' ;
*
        DESS (ECPress 'ET' ECShear 'ET' (100. * EvDltEnD)) 'LEGE' 'NCLK' ; 
*
      'FINSI' ;
    'FINSI' ; 
*
*   --------------------------------------------------------------------
*   Cycle d'usure (force tangentielle en fonction du deplacement)
    LstDelta = BOITE_US. &BU .'DELTAS' ;
    Delta_ii = 'EXTR' DEPZ BOITE_US.'INFOS'.'COMP_DEPI' 
                           BOITE_US.'INFOS'.'PTSZ_DEPI' ;
    LstDelta = LstDelta 'ET' Delta_ii ;
*    
    LstFTang = BOITE_US. &BU .'FORCES_TANGENTIELLES' ;
    FtangRes = 'PSCA' ForceT BOITE_US. &BU .'DIRE_REACTION' LCF LCF ;
    FTangRes = 'SOMT' FTangRes ;
    LstFTang = LstFTang 'ET' FTangRes ;
*
*   --------------------------------------------------------------------
*   Stockage des resultats
    BOITE_US. &BU .'PRESSION_CONTACT'. IncActu = DTps '*' CPress ;
    BOITE_US. &BU .'CISAILLEMENT'.     IncActu = DTps '*' ('ABS' CShear);
    BOITE_US. &BU .'DENS_ENER_DISS'.   IncActu = EnDisInc ;
    BOITE_US. &BU .'DELTAS'                    = LstDelta ;
    BOITE_US. &BU .'FORCES_TANGENTIELLES'      = LstFTang ;
*
    'REMP' BOITE_US. &BU .'PRESSION_MAX_INC'     IncActu ('MAXI' CPress) ;
    'REMP' BOITE_US. &BU .'CISAILLEMENT_MAX_INC' IncActu ('MAXI' CShear 'ABS') ;
*
*   --------------------------------------------------------------------
*   Dernier instant du cycle actuel
    'SI' ('EGA' IncActu BOITE_US.'INFOS'.'NB_INCREMENTS_PAR_CYCLE') ;
*
*     Cumul des densites d'energie dissipee par frottement
      EnDisCyc = 'ETG' BOITE_US. &BU .'DENS_ENER_DISS' ;
      BOITE_US. &BU .'DENS_ENER_DISS_CYCLE'  = EnDisCyc ;
      BOITE_US. &BU .'DENS_ENER_DISS_TOTALE' =
        BOITE_US. &BU .'DENS_ENER_DISS_TOTALE' + EnDisCyc ;
*   
*     Vitesse d'usure sur le cycle (utilise dans USEXPL/USIMPL)
      ALPHA    = BOITE_US. &BU .'COEFFICIENT_USURE' ;
      VitUsure = ALPHA '*' EnDisCyc ;
      BOITE_US. &BU .'VITESSE_USURE' = VitUsure ;
 
      CycActu  = BOITE_US.'INFOS'.'INDICE_CYCLE_ACTUEL' ;
      CyclFret = 'EVOL' 'ROUG' 'MANU' 'Deplacement' LstDelta
                               'Force_Tangentielle' LstFTang ;
      EnteteCF = 'CHAI' 'Cycle_de_fretting_n: ' CycActu FORMAT '(I2)' ;
      CyclFret = 'CHAN' CyclFret 'LEGE' EnteteCF ;
      BOITE_US. &BU .'CYCLE_DE_FRETTING'. CycActu = CyclFret ;
*
      'SI' BOITE_US.'INFOS'.'TRACE_DEBUG' ;
        TabDess    = TABL ;
        TabDess. 1 = 'TIRC MARQ CROI' ;
        'DESS' CyclFret TabDess 'GRIL' 'LEGE' ;
      'FINSI' ;
*   
*     Faut-il redeterminer les pas de temps
      Ampl_F_N = ('MAXI' LstFTang) '-' ('MINI' LstFTang) ; 
      Ampl_Dlt = ('MAXI' LstDelta) '-' ('MINI' LstDelta) ; 
      ECycFret = 'ABS' ('INTG' CyclFret) ;
      DltG_Est = ECycFret / 2. / Ampl_F_N ;
      DltT_Est = (Ampl_Dlt / 2.) - DltG_Est ;
      BOITE_US.'INFOS'.'DELTAP' = BOITE_US.'INFOS'.'DELTA_T' ;
      BOITE_US.'INFOS'.'DELTA_T' = DltT_Est ;
*   
      'SI' (('EGA' &BU 1) 'ET' BOITE_US.'INFOS'.'CALCUL_PAS');
        ECycGtot = Ampl_F_N * Ampl_Dlt ;
        BOITE_US.'INFOS'.'AJUSTE_PAS' = FAUX ;
*       Uniquement si regime de glissement total
        'SI' ((ECycFret / ECycGtot) '>' 0.2) ;
          BOITE_US.'INFOS'.'AJUSTE_PAS' = VRAI ;
          'SI' ('NEG' CycActu 1) ;
********    LDltTPre = BOITE_US. &BU .'DELTA_T' ;
********    DltTPre  = 'EXTR' LDltTPre ('DIME' LDltTPre) ;
            DltTPre  = BOITE_US.'INFOS'.'DELTAP' ;
            VarDltT  = 'ABS' ((DltT_Est - DltTPre) / DltTPre) ; 
            BOITE_US.'INFOS'.'AJUSTE_PAS' = (VarDltT '>' 0.1) ;
          'FINSI' ;  
          CHAZ = 'CHAI' 'Pas de temps recalcules :' ;
          CHAZ = 'CHAI' CHAZ BOITE_US.'INFOS'.'AJUSTE_PAS' ;
          'MESS' CHAZ ;
        'FINSI' ;  
      'FINSI' ; 
*
*     Reinitialisation (le dernier point est aussi premier cycle suivant)
      BOITE_US. &BU .'DELTAS'               = 'PROG' Delta_ii ;
      BOITE_US. &BU .'FORCES_TANGENTIELLES' = 'PROG' FTangRes ;
    'FINSI' ;
*   
  'FIN' BU ;
*-----------------------------------------------------------------------
'FINP' ;