Procédures | Cast3M

* TOPOVISU  PROCEDUR  FD218221  25/12/18    21:15:15     12429          
 
************************************************************************
** Procedure called by TOPOPTIM to display results on-the-fly at the end
** of each cycle.
**
** Author:
** Guenhael Le Quilliec (LaMe - Polytech Tours)
**
** Version:
** 1.0 2025/11/13 Previously defined directly in TOPOPTIM. Now shows
**                von Mises stress field when any stress constraint
**                is active and improved for compatibility with
**                TOPOPTIM V4.0.
************************************************************************
 
DEBP TOPOVISU tab*'TABLE' ;
 
* Input data
* **********
 
Wtab = tab.'WTABLE' ;
Ltab = Wtab.'LOGIQUE' ;
visu = Wtab.'VISU' ;
 
* Number of cycles since the last call to TOPOPTIM
nbritr = Wtab.'ITERATION' ;
 
* Initialization
* **************
 
SI (nbritr EGA 1) ;
 
*   Title of any printable variables
*   --------------------------------
    tmp = TABL ;
    tmp.'TEMPS_CYCLE'        = CHAI ' Temps/cycle ' ;
    tmp.'OBJECTIF'           = CHAI '   Objectif  ' ;
    tmp.'FRACTION_VOLUME'    = CHAI '  Vol. frac. ' ;
    tmp.'SIGMA_VM_MAX'       = CHAI 'Max. von Mis.' ;
    tmp.'MAX_X_CHANGE'       = CHAI ' Max X change' ;
    tmp.'PENALISATION_P'     = CHAI ' Penalisat. P' ;
    tmp.'OC_D'               = CHAI ' OC amort. D ' ;
    tmp.'OC_Q'               = CHAI 'OC fac. GSF Q' ;
    tmp.'PROJECTION_RAIDEUR' = CHAI ' Raid. proj. ' ;
    tmp.'NB_ACTIVE_ELEM'     = CHAI ' Nb. el. ' ;
 
*   Create the title line
*   ---------------------
    visu.'TITRE' = CHAI 'FORMAT' '(A8)' ' Cycle ' ;
    pos = 8 ;
    REPE itr1 (DIME visu.'VARIABLES') ;
        varnam = EXTR visu.'VARIABLES' &itr1 ;
        SI (EGA varnam 'NB_ACTIVE_ELEM') ;
            visu.'TITRE' = CHAI visu.'TITRE' '|'/pos tmp.varnam/(pos+1) ;
            pos = pos + 10;
        SINO ;
            visu.'TITRE' = CHAI visu.'TITRE' '|'/pos tmp.varnam/(pos+1) ;
            pos = pos + 14;
        FINS ;
    FIN itr1 ;
 
*   Save the cursor position
*   ------------------------
    visu.'POSITION' = pos ;
 
*   Title, separation line and history table for PASAPAS
*   ----------------------------------------------------
    SI Ltab.'PASAPAS' ;
        visu.'TITRE_PASAPAS' = CHAI '|' visu.'TITRE' '|'/(pos+1);
        line = CHAI ;
        REPE itr1 ((DIME visu.'TITRE_PASAPAS') - 3) ;
            line = CHAI line '-' ;
        FIN itr1 ;
        visu.'LIGNE_PASAPAS' = line ;
    FINS ;
    SI Ltab.'PASAPAS' ;
        visu.'HISTORIQUE' = TABL ;
    FINS ;
 
FINS ;
 
* Save progression information and prepare new string to print
* ************************************************************
 
print = CHAI Wtab.'CYCLE'*6 ;
pos = 8 ;
REPE itr1 (DIME visu.'VARIABLES') ;
    varnam = EXTR visu.'VARIABLES' &itr1 ;
*   Update its value if it is 'FRACTION_VOLUME' or 'TEMPS_CYCLE'
    SI (EGA varnam 'FRACTION_VOLUME') ;
        modD = Wtab.'MODELE_D' ;
        matD = Wtab.'CARACTERISTIQUES_D' ;
        SI (TOPOMODI tab (CHAI 'FRACTION_VOLUME') Wtab.'Y_D_PRECED' modD matD) ;
            Wtab.'FRACTION_VOLUME' = (INTG Wtab.'Y_D_PRECED' modD matD) /
                                     Wtab.'VOLUME_TOTAL_D' ;
        FINS ;
    FINS ;
    SI (EGA varnam 'TEMPS_CYCLE') ;
        Wtab.'TEMPS_CYCLE' = (TEMP 'HORL') - Wtab.'HORLOGE'  ;
    FINS ;
    SI (EXIS Wtab varnam) ;
        SI (EGA varnam 'NB_ACTIVE_ELEM') ;
            print = CHAI print '|'/pos Wtab.varnam *(pos+6) ;
            pos = pos + 10;
        SINO ;
            SI (EGA varnam 'TEMPS_CYCLE') ;
                print = CHAI print '|'/pos (TOPOTEMP Wtab.varnam) /(pos+2) ;
                pos = pos + 14;
            SINO ;
                print = CHAI print '|'/pos
                              'FORMAT' '(ES13.6E2)' Wtab.varnam /(pos+1) ;
                pos = pos + 14;
            FINS ;
        FINS ;
    FINS ;
FIN itr1 ;
 
SI Ltab.'PASAPAS' ;
    print = CHAI '|' print '|'/(pos+1) ;
    visu.'HISTORIQUE'.nbritr = print ;
FINS ;
 
* On-the-fly field visualization
* ******************************
 
* TODO to be improved for 3D
SI tab.'TRAC' ;
*   Model
*   -----
    SI Ltab.'MECANIQUE' ;
        modA = Wtab.'MECANIQUE'.'MODELE_A' ;
    SINO ;
        modA = Wtab.'THERMIQUE'.'MODELE_A' ;
    FINS ;
*   Topology
*   --------
    SI Ltab.'ZONE_FIGEE' ;
*       Combine the Y field on D with the unitary field on F
*       This creates a 2-zone field merged into a single zone
*       field using to REDU
        YA = REDU (Wtab.'Y_D' ET Wtab.'UNIT_F') modA ;
    SINO ;
        YA = REDU Wtab.'Y_D' modA ;
    FINS ;
*   Deformed mesh
*   -------------
    SI ((NON Ltab.'CAS_MULTIPLES') ET (NON Ltab.'MECANISME')
        ET Ltab.'MECANIQUE' ET Ltab.'PASAPAS') ;
        tmp = Wtab.'RESOLUTION_A'.'MAX_ID' ;
        YA modYA = YA modA PLUS Wtab.'RESOLUTION_A'.'DEPLACEMENTS'.tmp ;
    SINO ;
        modYA = modA ;
    FINS ;
*   Microscopic von Mises
*   ---------------------
    SI Ltab.'CONTRAINTE_SIGMA_VM' ;
*       Microscopic von Mises on A
*       Remark: values on F (if present) will be set to 0.0
        micvnmA = REDU Wtab.'MICROSCOPIC_VM_I' modA ;
*       Deformed mesh
        SI ((NON Ltab.'CAS_MULTIPLES') ET (NON Ltab.'MECANISME')
            ET Ltab.'MECANIQUE' ET Ltab.'PASAPAS') ;
            tmp = Wtab.'RESOLUTION_A'.'MAX_ID' ;
            micvnmA modvnmA = micvnmA modA PLUS Wtab.'RESOLUTION_A'.'DEPLACEMENTS'.tmp ;
        SINO ;
            modvnmA = modA ;
        FINS ;
*       Copy the von Mises field & model on the top of the topology
        SI (EGA (VALE 'MODE') 'TRID') ;
            tmp = (CONT (EXTR modA 'MAIL')) COOR 3 ;
            tmp = 0.0 (1.05 * ((MAXI tmp) - (MINI tmp))) 0.0 ;
        SINO ;
            tmp = (CONT (EXTR modA 'MAIL')) COOR 2 ;
            tmp = 0.0 (1.05 * ((MAXI tmp) - (MINI tmp))) ;
        FINS ;
        micvnmA modvnmA = micvnmA modvnmA PLUS tmp ;
*       Rescaling of the topology field
        min = MINI micvnmA ;
*        max = MAXI micvnmA ;
        max = tab.'SIGMA_VM_LIMITE' ;
        YA = (YA * (max - min)) + min ;
*       Rename field component
        micvnmA = EXCO 'SCAL' micvnmA 'MCVM' ;
        YA      = EXCO 'SCAL' YA 'MCVM' ;
*       Plot von Mises (top) and topology (bottom)
        TRAC (YA ET micvnmA) (modYA ET modvnmA) (PROG min 'PAS' ((max - min) / 56.0) max) 'NCLK'
             TITR (CHAI 'TOPOPTIM : trace en temps reel de la cont. de von Mises micro. et de la topologie (cycle' ' ' Wtab.'CYCLE' ')') ;
    SINO ;
*       Plot topology
        TRAC YA modYA (PROG 0.0 'PAS' (1.0 / 56.0) 1.0) 'NCLK'
             TITR (CHAI 'TOPOPTIM : trace en temps reel de la topologie (cycle' ' ' Wtab.'CYCLE' ')') ;
    FINS ;
FINS ;
 
* Print progression to screen
* ***************************
 
SI (NON Ltab.'PASAPAS') ;
    SI ((nbritr EGA 1) OU Ltab.'CAS_MULTIPLES') ;
        MESS visu.'TITRE';
    FINS ;
    MESS print ;
    SI (Ltab.'STOP' OU Ltab.'CAS_MULTIPLES') ;
        MESS visu.'TITRE';
        SAUT 1 'LIGN' ;
    FINS ;
SINO ;
    tmp = DIME print ;
    SI (NON Ltab.'STOP') ;
        SAUT 1 'LIGN' ;
        MESS (CHAI '+' visu.'LIGNE_PASAPAS' /2 '+') ;
        MESS (CHAI '|' '|'/tmp) ;
        MESS (CHAI '|' 'TOPOPTIM : Progression'/((tmp - 22) / 2) '|'/tmp) ;
        MESS (CHAI '|' '|'/tmp) ;
        MESS (CHAI '|' 'Cycle'*(tmp / 2) ' ' Wtab.'CYCLE' '|'/tmp) ;
        MESS (CHAI '|' '|'/tmp) ;
        MESS visu.'TITRE_PASAPAS' ;
        MESS print ;
        MESS (CHAI '|' '|'/tmp) ;
        MESS (CHAI '+' visu.'LIGNE_PASAPAS' /2 '+') ;
        SAUT 1 'LIGN' ;
    SINO ;
        SAUT 1 'LIGN' ;
        MESS (CHAI '+' visu.'LIGNE_PASAPAS' /2 '+') ;
        MESS (CHAI '|' '|'/tmp) ;
        MESS (CHAI '|' 'TOPOPTIM : Historique'/((tmp - 21) / 2) '|'/tmp) ;
        MESS (CHAI '|' '|'/tmp) ;
        MESS visu.'TITRE_PASAPAS';
        REPE itr1 nbritr ;
            MESS visu.'HISTORIQUE'.&itr1 ;
        FIN itr1 ;
        MESS (CHAI '+' visu.'LIGNE_PASAPAS' /2 '+') ;
    FINS ;
FINS ;
 
* Write last information before leaving
* *************************************
 
SI Ltab.'STOP' ;
*   Summary
*   -------
    SI (NON Ltab.'PASAPAS') ;
        MESS '-------------------------------------------------------------------------------' ;
    FINS ;
    SAUT 1 'LIGN' ;
    MESS 'Bilan :' ;
    MESS '=======' ;
    SI tab.'CONVERGENCE' ;
        MESS '  - Convergence apres' ' ' Wtab.'CYCLE' ' cycles.' ;
    SINO ;
        MESS '  - Nombre maximum de cycles d''optimisation atteint.' ;
    FINS ;
    SI (EGA (DIME tab.'REPRISES') 0) ;
        MESS '  - Duree de l''optimisation topologique' ' ' (TOPOTEMP (TEMP 'HORL')) ;
    SINO ;
        MESS '  - Duree de la reprise d''optimisation topologique' ' ' (TOPOTEMP (TEMP 'HORL')) ;
    FINS ;
    SAUT 1 'LIGN' ;
    MESS '+-----------------------------------------------------------------------------+' ;
    SI (EGA (DIME tab.'REPRISES') 0) ;
        MESS '|           F I N   D E   L A   P R O C E D U R E   T O P O P T I M           |' ;
    SINO ;
        MESS '|  P R O C E D U R E   T O P O P T I M  :   F I N   D E   L A  R E P R I S E  |' ;
    FINS ;
    MESS '+-----------------------------------------------------------------------------+' ;
    SAUT 1 'LIGN' ;
FINS ;
 
FINP ;