Télécharger la plaquette Cast3M


fr en

Télécharger pasapas.procedur

Retour à la liste

Numérotation des lignes : 

  1. * PASAPAS   PROCEDUR  SP204843  26/04/22    21:15:02     12521          
  2.  
  3. 'DEBP' PASAPAS  PRECED*'TABLE';
  4. 'SAUT' 1 'LIGNE';
  6. '------------------ DEBUT DE LA PROCEDURE PASAPAS --------------------';
  7. ************************************************************************
  8. *                                                                      *
  9. *   PRECED      objet de type TABLE                                    *
  10. *               C'est une table donnant , les arguments d'entrees, les *
  11. *               options, puis les  resultats des pas precedents        *
  12. *                                                                      *
  13. * champs de materiaux :                                                *
  14. *     WTAB.'MAT_REF' materiau etat a la temperature de REFERENCE       *
  15. *     WTAB.'MAT0'    materiau etat debut de calcul                     *
  16. *     WTAB.'MAT1'    materiau fin du pas de temps                      *
  17. *                                                                      *
  18. ************************************************************************
  19.  
  20. ****************   I PARTIE   ******************************************
  21. * Verifications des infos transmises et valeurs par defaut
  22. PAS_DEFA PRECED ;
  23. * Creation des tables de sortie et initialisations
  24. PAS_INIT PRECED ;
  25.  
  26. WTAB  = PRECED.'WTABLE'      ;
  27. conti = PRECED.'CONTINUATION';
  28. estim = PRECED.'ESTIMATION'  ;
  29. *-----------------------------------------------------------------------
  30. *              Appel aux procedures utilisateurs
  31. *-----------------------------------------------------------------------
  32. 'SI' WTAB.'PROCEDURE_PERSO1';
  33.   PRECED.'PERSO1_APPEL' = 1 ;
  34.   PERSO1 PRECED ;
  35.   'SI' ('EXIS' PRECED 'ARRET') ;
  36.     WTAB.'ARRET' = PRECED.'ARRET' ;
  37.   'FINSI' ;
  38. 'FINSI';
  39. *
  40. 'SI' WTAB.'PROCEDURE_REEV_MEC' ;
  41.   REEV_MEC PRECED 0 ;
  42. 'FINSI' ;
  43. *
  44. 'SI' WTAB.'PROCEDURE_REEV_THE' ;
  45.   REEV_THE PRECED 0 ;
  46. 'FINSI' ;
  47. *-----------------------------------------------------------------------
  48. *              Initialisation ETAT et MATERIAUX
  49. *-----------------------------------------------------------------------
  50. TEMP0       = conti.'TEMPS';
  51. ETAT0       = PAS_ETAT PRECED TEMP0 ;
  52. WTAB.'MAT0' = PAS_MATE PRECED ETAT0 ;
  53. WTAB.'MAT1' = WTAB.'MAT0' ;
  54. *
  55. *---------   initialisation deformation thermique de reference
  56. 'SI' WTAB.'FOR_MECA' ;
  57.   'SI' WTAB.'ITHER' ;
  58.     'SI' ('EGA' WTAB.'ETREF' 'INCONNU');
  59.       WTAB.'ETAT_REF' = PAS_ETAT PRECED TEMP0 'T_REFERENCE';
  60.       WTAB.'MAT_REF'  = PAS_MATE PRECED WTAB.'ETAT_REF'  ;
  61.       WTAB.'ETREF'    = 'EPTH' WTAB.'MO_TOT' WTAB.'MAT_REF' WTAB.'TEMPERATURE_REFERENCE' ;
  62.     'FINS' ;
  63. *
  64.     TET1 = WTAB.'TET1' ;
  65.     'SI' ('EGA' ('TYPE' TET1) 'CHPOINT');
  66.       TET1 ='CHAN' 'CHAM' TET1 WTAB.'MO_TOT' 'STRESSES' 'TEMPERATURES' ;
  67.     'FINS';
  68.     ETT0  = 'EPTH' WTAB.'MO_TOT' WTAB.'MAT0' TET1 ;
  69.     WTAB.'ETHER1' = ETT0 - WTAB.'ETREF' ;
  70. *
  71.     'SI' WTAB.'POR1';
  72.       WTAB.'MSRTHER1'= PAS_EPTH PRECED WTAB.'MO_TOT' WTAB.'MAT0' TET1 ;
  73.     'FINS' ;
  74.   'FINS' ;
  75. 'FINS' ;
  76.  
  77. **************************   II PARTIE  *************************
  78. ******************************************************************
  79. ******************* boucle sur les pas de temps  *****************
  80. ******************************************************************
  81. * ------------quelques initialisations de l'algorithme
  82. IPAS  = 0 ;
  83. IAUTO = 1 ;
  84. ISAUV = VRAI;
  85. DTV   = ('EXTR' WTAB.'TEMPS_CALCULES' 1) - TEMP0 ;
  86. 'SI' ( DTV '<' 1.e-15 );
  87.   'SI' WTAB.'FREQUENTIEL' ;
  88.     DTV = 1.e-14 ;
  89.   'SINON' ;
  90.     DTV =('EXTR' WTAB.'TEMPS_CALCULES' 2) - TEMP0 ;
  91.   'FINSI';
  92. 'FINSI';
  93. * Pour l'option PAS_AJUSTE
  94. DT_AVANT = DTV ;
  95. IREREDU  = VRAI;
  96. PASFINAL = 0 ;
  97. *-----------------------------------------------------------------------
  98. *              Debut de la boucle sur les pas de temps
  99. *-----------------------------------------------------------------------
  100. 'REPETER' BEXTERN  ;
  101. *
  102. * ----- Determiner le nouvel instant a calculer TI
  103. *
  104.   TEMP0 = conti.'TEMPS' ;
  105.   NPAS  = 'DIME' WTAB.'TEMPS_CALCULES';
  106.   ICHG  = WTAB.'ICHG'; ICHG = ICHG + 1; WTAB.'ICHG' = ICHG;
  107.   'SI' ( ICHG '>' NPAS) ; 'QUITTER' BEXTERN; 'FINSI';
  108.   TI = 'EXTRAIRE'  WTAB.'TEMPS_CALCULES' ICHG ;
  109.   ITERTPS = (TI '<' TEMP0 ) ;
  110.   'SI' ('NON' WTAB.'FREQUENTIEL') ;
  111.     ITERTPS = ITERTPS 'OU' (TI 'EGA' PRECED.'TEMPS'. 0) ;
  112.     'SI' ('NON' WTAB.'REEQUILIBRAGE') ;
  113.       ITERTPS = ITERTPS 'OU' ('EGA' TI TEMP0) ;
  114.     'FINSI';
  115.   'FINSI';
  116.   'SI' ITERTPS ;
  117.     'ITERER' BEXTERN ;
  118.   'FINSI';
  119. *
  120. * ----- Ajustement du pas en fonction du nb d iteration du pas precedent
  121. *
  122.   'SI' WTAB.'PAS_AJUSTE';
  123.     PASFINAL=PASFINAL+1;
  124.     TIV=TI;
  125.     DTV=DT_AVANT;
  126.     'SI' WTAB.'CONV';
  127.       'SI' (WTAB.'NOMBRE_ITERATIONS' > 20);
  128.         DTV=DTV'/' (2. ** 0.5);
  129.       'FINSI';
  130.       'SI' (WTAB.'NOMBRE_ITERATIONS' <  7);
  131.         'SI' IREREDU;
  132.           DTV=DTV '*' (2. ** 0.5);
  133.         'FINSI';
  134.       'FINSI';
  135.       DT_AVANT= DTV;
  136.       IREREDU=VRAI;
  137.     'SINON';
  138.       DTV=0.0000000001D0* DT_AVANT;
  139.       DT_AVANT= DT_AVANT /2.;
  140.       IREREDU=FAUX;
  141.     'FINSI';
  142.     TTI = DTV* 1.0000000001 + TEMP0;
  143.     'SI' ( TTI '&lt;EG' TIV );
  144.       TI=TTI;
  145.       PASFINAL=0;
  146.     'FINSI';
  147.     'SI' (PASFINAL '>EG' 1.5) ; 
  148.       DT_AVANT = TI-TEMP0; 
  149.     'FINSI';
  150.   'FINSI';
  151. *
  152.   estim.'TEMPS' = TI;
  153.   WTAB.'DT'     = TI '-' TEMP0 ;
  154.   'SI'((WTAB.'CONSOLIDATION' 'OU' WTAB.'DYNAMIQUE') 'ET' (WTAB.'DT' 'EGA' 0.));
  155.     WTAB.'DT' = WTAB.'DTPREC' ;
  156.     'ITERER' BEXTERN;
  157.   'FINSI';
  158. *
  159. * ----- Compteur IPAS des pas de temps calcules
  160.   IPAS = IPAS + 1;
  161.   WTAB.'PAS'=IPAS;
  162.  
  163. * ----- Mise a jour du modele si chargement de type MODE :
  164.   'SI' WTAB.'CHAR_MODE' ;
  165.     MOD1P     =  WTAB.'MODELE' ;
  166.     MODEVOL1  = 'TIRE' PRECED.'MODELE' 'MODE' TI ;
  167.     WTAB.'MODELE' = MODEVOL1 ;
  168.  
  169.     'SI' WTAB.'CHAR_MATE' ;
  170.       MATEVOL1  = 'TIRE' PRECED.'CARACTERISTIQUES' 'MATE' TI ;
  171.       WTAB.'CARACTERISTIQUES' = MATEVOL1 ;
  172.     'FINSI' ;
  173.  
  174.     PAS_MODL PRECED ;
  175.  
  176. *   MaJ table rayonnement :
  177.     'SI' WTAB.'RAYO' ;
  178.       WTAB.'RAYONNEMENT' = 'PRRA' WTAB.'MOD_RAY' ;
  179.     'FINSI' ;
  180.  
  181. *   On sauvegarde les modeles successifs pour analyse resultats :
  182.     ESTIM.'MODELES' = WTAB.'MODELE' ;
  183.  
  184. *   Initialisation TINI si thermique :
  185.     'SI' WTAB.'THE1' ;
  186.       MODX      = WTAB.'MOD_COND' ;
  187.       MODXP     = MOD1P 'EXTR' 'MATE' 'CONDUCTION' ;
  188.       GEO1      = MODX  'EXTR' 'MAIL' ;
  189.       GEO1P     = MODXP 'EXTR' 'MAIL' ;
  190.       DGEO1     = GEO1  'DIFF' GEO1P ;
  191.  
  192. *     Adapation du modele : transport de la solution
  193.       'SI' ((WTAB.'ADAP_MODE') 'ET' ('NON' (TI '<' (WTAB.'TPS1_ADAP')))) ;
  194.         mess '*****  Transport solution adaptation' ;
  195.         IADAP1    = (WTAB.'INDI_ADAP') + 1 ;
  196.         'SI' (IADAP1 '&lt;EG' ('DIME' (WTAB.'LTPS_ADAP'))) ;
  197.           WTAB.'TPS1_ADAP' = WTAB.'LTPS_ADAP' 'EXTR' IADAP1 ;
  198.           WTAB.'INDI_ADAP' = IADAP1 ;
  199.         'SINON' ;
  200.           WTAB.'TPS1_ADAP' = 'MAXI' WTAB.'TEMPS_CALCULES' + 1. ;
  201.         'FINSI' ;
  202.  
  203. *       Projection du champ de temperature sur la partie adaptee :
  204.         DGEO1P    = DGEO1 'INTE' GEO1P ;
  205.         DGEO2P    = (DGEO1 'INTE' GEO1) 'INCLU' DGEO1P 'VOLU' 'BARY'  ;
  206.         CHT1P     = CONTI.'TEMPERATURES' 'EXCO' 'T' 'T' ;
  207.         CHAMT1P   = 'CHAN' 'CHAM' DGEO1P CHT1P ;
  208.         CHT2P     = 'PROI' CHAMT1P  DGEO2P ;
  209.         CHT1P     = ('REDU' CHT1P (GEO1P 'DIFF' DGEO1P)) 'ET' CHT2P ;
  210.         CONTI.'TEMPERATURES' = CHT1P ;
  211.  
  212. *       Calcul de la capacite courante sur la partie adaptee :
  213.         DMODX     = 'REDU' MODX DGEO2P ;
  214.         DMATX     = 'REDU' (WTAB.'CARACTERISTIQUES') DMODX ;
  215.         DMATX     = 'VARI' 'NUAG' DMODX DMATX CHT2P ;
  216.         CAPAX     = 'CAPA' DMODX DMATX ;
  217.         CAPA1P    = ('REDU' (WTAB.'CAPA_COURANTE') (GEO1P 'DIFF' DGEO1P)) 'ET' CAPAX ;
  218.         WTAB.'CAPA_COURANTE' = CAPA1P ;
  219.  
  220.         DGEO1     = (DGEO1 'INTE' GEO1) 'DIFF' DGEO2P ;
  221.       'FINSI' ;
  222.  
  223. *     Calcul temperature dans partie apportee du modele :
  224.       'SI' ('NON' (('VIDE' DGEO1) 'OU' ('VIDE' (DGEO1 'INTE' GEO1)))) ;
  225. *       Quantite de chaleur sur geometrie GEO1P :
  226.         CHT1P     = CONTI.'TEMPERATURES' 'EXCO' 'T' 'T' ;
  227.         CAPA1P    = WTAB.'CAPA_COURANTE' 'LUMP' ;
  228.         CHQ1P     = CAPA1P * CHT1P ;
  229. *       Quantite de chaleur dans apport :
  230.         DMODX     = 'REDU' MODX DGEO1 ;
  231.         DMATX     = 'REDU' (WTAB.'CARACTERISTIQUES') DMODX ;
  232.         CHTINIX   = DMATX 'EXCO' 'TINI' 'T' ;
  233.         CHTINIX   = 'CHAN' 'CHPO' CHTINIX DMODX 'MOYE' ;
  234.         DMATX     = 'VARI' 'NUAG' DMODX DMATX CHTINIX ;
  235.         CAPAX     = ('CAPA' DMODX DMATX) lump ;
  236.         CHQX      = CAPAX * CHTINIX ;
  237. *       Calcul T sur GEO1 :
  238.         CAPA1     = CAPA1P et CAPAX ;
  239.         CHTX1     = 'MANU' 'CHPO' GEO1 1 'T' 1. 'NATURE' 'DIFFUS' ;
  240.         CHQX1     = CAPA1 * CHTX1;
  241.         CHT1      = (CHQ1P + CHQX) * ('INVE' CHQX1) ('MOTS' 'Q') ('MOTS' 'Q') ('MOTS' 'T') ;
  242.         CHT1      = CHT1 'CHAN' 'ATTRIBUT' 'NATURE' 'DIFFUS' ;
  243. *        CHT1      = reso CAPA1 (CHQ1P + CHQX) ; comm plus lent avec RESO ;
  244.         CONTI.'TEMPERATURES' = CHT1 ;
  245.  
  246.         CHTAPP1  = CHT1 'EXCO' 'T' 'TAPP' ;
  247.         IND1     = 'DIME' PRECED.'TEMPERATURES_APPORT' ;
  248.         ESTIM .'TEMPERATURES_APPORT'        = CHTAPP1 ;
  249.       'SINON' ;
  250.         IND1     = 'DIME' PRECED.'TEMPERATURES_APPORT' ;
  251.         CHTAPP1  = PRECED.'TEMPERATURES_APPORT' . (IND1 - 1) ;
  252.         ESTIM .'TEMPERATURES_APPORT'        = CHTAPP1 ;
  253.       'FINSI' ;
  254.  
  255. *   Finsi formulation thermiquue
  256.     'FINSI' ;
  257.  
  258. *   Initialisation PROPORTIONS_PHASES si metallurgie :
  259.     'SI' WTAB.'FOR_METALLU' ;
  260.       MODX      = WTAB.'MODELE' 'EXTR' 'FORM' 'METALLURGIE' ;
  261.       MODXP     = MOD1P         'EXTR' 'FORM' 'METALLURGIE' ;
  262.       GEO1      = MODX  'EXTR' 'MAIL' ;
  263.       GEO1P     = MODXP 'EXTR' 'MAIL' ;
  264.       DGEO1     = GEO1 'DIFF' GEO1P ;
  265.       'SI' ('NON' (('VIDE' DGEO1) 'OU' ('VIDE' (DGEO1 'INTE' GEO1)))) ;
  266.         CHMET0    = CONTI.'PROPORTIONS_PHASES' ;
  267.         DMODX     = 'REDU' MODX DGEO1 ;
  268.         CHMET1    = 'ZERO' DMODX 'VARINTER' ;
  269.         LISCO     = 'EXTR' DMODX 'VARI' ;
  270.         CMP1      = 'EXCO' CHMET1 ('EXTR' LISCO 1) ('EXTR' LISCO 1) ;
  271.         CHMET1    = CHMET1 + (CMP1 + 1.D0);
  272.         CHMET1    = CHMET0 'ET' CHMET1 ;
  273.         CONTI.'PROPORTIONS_PHASES' = CHMET1 'REDU' MODX ;
  274.       'FINSI' ;
  275.     'FINS' ;
  276.  
  277. *   Initialisation MECA si besoin :
  278.     'SI' WTAB.'FOR_MECA' ;
  279.       MODM1    = 'VIDE' 'MMODEL' ;
  280.       MODM1P   = 'VIDE' 'MMODEL' ;
  281.       'SI'  WTAB.'MEC1' ;
  282.         MODM1    = MODM1 'ET' WTAB.'MOD_MEC' ;
  283.         MODM1P   = MODM1P 'ET' ('EXTR' MOD1P 'FORM' 'MECANIQUE') ;
  284.       'FINSI' ;
  285.       'SI'  WTAB.'POR1' ;
  286.         MODM1    = MODM1 'ET' WTAB.'MOD_POR' ;
  287.         MODM1P   = MODM1P 'ET' ('EXTR' MOD1P 'FORM' 'POREUX') ;
  288.       'FINSI' ;
  289.       'SI' ('NON' ('VIDE' MODM1)) ;
  290.         GEOM1    = 'EXTR' MODM1  'MAIL' ;
  291.         GEOM1P   = 'EXTR' MODM1P 'MAIL' ;
  292.         DGEOM1   = GEOM1 'DIFF' GEOM1P ;
  293.         'SI' ('NON' (('VIDE' DGEOM1) 'OU' ('VIDE' (DGEOM1 'INTE' GEOM1)))) ;
  294.           DMODM1   = 'REDU' MODM1 DGEOM1 ;
  295.  
  296. *         Mise a jour ETREF :
  297.           TREF1    = 'EXCO' WTAB.'CARACTERISTIQUES' 'TREF' 'T' ;
  298.           WTAB.'TEMPERATURE_REFERENCE' = 'CHAN' 'STRESSES' MODM1 TREF1 'TEMPERATURES' ;
  299.           WTAB.'ETAT_REF'= PAS_ETAT PRECED TEMP0 'T_REFERENCE' ;
  300.           WTAB.'MAT_REF' = PAS_MATE PRECED WTAB.'ETAT_REF'   ;
  301.           DETREF1  = 'EPTH' DMODM1 WTAB.'MAT_REF' WTAB.'TEMPERATURE_REFERENCE' ;
  302.           WTAB.'ETREF' = WTAB.'ETREF' 'ET' DETREF1 ;
  303.  
  304. *         Mise a jour ETHER1 :
  305.           'SI' ('NON' ('EXIS' PRECED.'CHARGEMENT' 'TAPP')) ;
  306.             'ERREUR' '***** Il manque la donnee du chargement TAPP !' ;
  307.           'FINSI' ;
  308.           TET1     = ('TIRE' PRECED.'CHARGEMENT' 'TAPP' TI) 'EXCO' 'TAPP' 'T' ;
  309.           ETAT1    = PAS_ETAT PRECED TI ;
  310.           MAT1     = PAS_MATE PRECED ETAT1 ;
  311.           DETHER1  = ('EPTH' DMODM1 MAT1 TET1) - DETREF1 ;
  312.           WTAB.'ETHER1' = WTAB.'ETHER1' 'ET' DETHER1 ;
  313.  
  314. *         Mise a jour deplacements et deformations :
  315.           DEPDGEO1 = ('EXCO' ETAT1 ('EXTR' DMODM1 'DEPL')) 'CHAN' 'CHPO' DMODM1 ;
  316.           DEPSL1   = ('EPSI' DMODM1 DEPDGEO1) - DETHER1 ;
  317.  
  318. *         Mise a jour table estimation :
  319.           estim.DEPLACEMENTS               = conti.DEPLACEMENTS 'ET' DEPDGEO1 ;
  320.           estim.CONTRAINTES                = conti.CONTRAINTES  'ET' ('ZERO' DMODM1 'CONTRAIN') ;
  321.           estim.VARIABLES_INTERNES         = conti.VARIABLES_INTERNES  'ET' ('ZERO' DMODM1 'VARINTER') ;
  322.           estim.DEFORMATIONS_INELASTIQUES  = conti.DEFORMATIONS_INELASTIQUES  'ET' ('ZERO' DMODM1 'DEFINELA') ;
  323.           estim.DEFORMATIONS               = conti.DEFORMATIONS 'ET' ('ZERO' DMODM1 'DEFORMAT') ;
  324.           estim.DEFORMATIONS_APPORT        = conti.DEFORMATIONS_APPORT 'ET' DEPSL1 ;
  325.  
  326. *         Correction deformation apport avec CHAR_DEFI :
  327.           CGDEFAP1 = 'CHAR' 'DEFI' (-1. * (estim.DEFORMATIONS_APPORT)) ;
  328.           WTAB . 'CHARGEMENT' = WTAB . 'CHARGEMENT_I' 'ET' CGDEFAP1 ;
  329.           'SI' ('NON' WTAB.CHAR_DEFI) ;
  330.             WTAB.CHAR_DEFI = VRAI ;
  331.             WTAB.DEFOR1    = 'ZERO' MODM1 'DEFORMAT' ;
  332.           'FINSI' ;
  333.         'FINSI' ;
  334.  
  335.       'SINON' ;
  336.           estim.DEFORMATIONS_APPORT      = conti.DEFORMATIONS_APPORT ;
  337.  
  338.       'FINSI' ;
  339.     'FINSI' ;
  340.  
  341. * Fin traitement CHAR_MODE
  342.   'FINSI' ;
  343. *
  344. * ++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
  345. * +++++++++++++++++ BOUCLE interne de bouclage mec_ther ++++++++++++++++
  346. * ++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
  347.   I_BOTH = 0 ;
  348.   'REPETER' BO_BOTH WTAB.'BOU_METH' ;
  349.     I_BOTH = I_BOTH + 1 ;
  350. *
  351. *   Re-initialisation de WTAB.'CHARGEMENT' en tete de boucle mec-ther
  352.     'SI' WTAB.'CONVERGENCE_MEC_THE' ;
  353.       WTAB.'CHARGEMENT' = WTAB.'CHARGEMENT_I' ;
  354.     'FINSI';
  355. *
  356. *   ####################################################################
  357. *   ########### RESOLUTION D'UN PAS SI THERMIQUE/DIFFUSION #############
  358. *   ####################################################################
  359.     'SI' (WTAB.'FOR_THER' 'OU' WTAB.'FOR_DIFF') ;
  360. *
  361. *     Se placer dans la configuration adequate
  362.       'SI' WTAB.'FOR_MECA' ;
  363.         'SI' (I_BOTH > 1) ;
  364.           'SI' WTAB.'GRANDS_DEPLACEMENTS' ;
  365.             WTAB.'RECARI'   = VRAI ;
  366.             WTAB.'REA_GEOM' = VRAI ;
  367.             'FORM' WTAB.'FOR' ;
  368.           'FINSI';
  369.         'SINON' ;
  370.           'FORM' WTAB.'GE0_DEB' ;
  371.         'FINSI' ;
  372.       'FINSI' ;
  373. *
  374.       'SI' (TI 'NEG' TEMP0);
  375.         WTAB.'TEM_CALC' = 'PROG' TI;
  376.         'SI' ('EXISTE' PRECED 'PAS_MAX');
  377.           'SI' ((TEMP0 + PRECED.'PAS_MAX') '<' TI);
  378.             WTAB.'TEM_CALC' = 'PROG' TEMP0 'PAS' PRECED.'PAS_MAX' TI ;
  379.             WTAB.'TEM_CALC' = 'ENLE' WTAB.'TEM_CALC' 1;
  380.           'FINSI';
  381.         'FINSI';
  382.  
  383. *       Mise a jour blocages passes dans chargement
  384. *       -> ISO AVANT MAIS A FAIRE A CHAQUE FOIS SI DEPEND DE LA MECA ??
  385.         'SI' ('EGA' I_BOTH 1) ;
  386. *         Cas BLOCAGES_THERMIQUES (BLOT) :
  387.           'SI' WTAB.'CHAR_BLOT' ;
  388.             BLOT1 = 'TIRE' PRECED.'BLOCAGES_THERMIQUES' 'BLOT' TI ;
  389.             WTAB.'BLOCAGES_THERMIQUES' = BLOT1 ;
  390.           'FINSI' ;
  391. *
  392. *         Cas BLOCAGES_DIFFUSIONS (BLOD) :
  393.           'SI' WTAB.'CHAR_BLOD' ;
  394.             BLOD1 = 'TIRE' PRECED.'BLOCAGES_DIFFUSIONS' 'BLOD' TI ;
  395.             WTAB.'BLOCAGES_DIFFUSIONS' = BLOD1 ;
  396.           'FINSI' ;
  397.         'FINSI' ;
  398. *
  399. * ----- Appel a la procedure thermique (lineaire ou nonlineaire) ----
  400. *
  401.         'SI' ('NON' WTAB.'COUPLAGE'); 'MENAGE'; 'FINSI';
  402.         'SI' ('EGA' WTAB.'PROCEDURE_THERMIQUE' 'NONLINEAIRE');
  403.           CHTER = TRANSNON PRECED;
  404.         'FINSI';
  405.         'SI' ('EGA' WTAB.'PROCEDURE_THERMIQUE' 'LINEAIRE');
  406.           CHTER = TRANSLIN PRECED;
  407.         'FINSI';
  408.         'SI' ('EGA' WTAB.'PROCEDURE_THERMIQUE' 'DUPONT');
  409.           WTAB.'NOUV_PAS' = ('EXTR' WTAB.'TEM_CALC' 1) - TEMP0;
  410.           CHTER = DUPONT2 PRECED;
  411.         'FINSI';
  412. *
  413. *       Verification d'une erreur en sortie
  414.         'SI' CHTER.'ERREUR';
  415.           'ERREUR' ' ';
  416.         'FINSI';
  417. *
  418. *       Se placer sur la configuration de reference (appel proc ut.)
  419.         'FORM' WTAB.'FOR0' ;
  420. *
  421. *        Reevaluation des donnees du calcul dependant de la temperature
  422.         'SI' WTAB.'PROCEDURE_REEV_THE' ;
  423.           REEV_THE PRECED  1 ;
  424.         'FINSI' ;
  425.       'FINS';
  426. *
  427.     'FINSI' ;
  428. *   ####################################################################
  429. *   ###### RESOLUTION D'UN PAS SI MECANIQUE/MECANIQUE DES FLUIDES ######
  430. *   ####################################################################
  431.     'SI' (WTAB.'FOR_MECA' 'OU' WTAB .'NVSTNL') ;
  432.       'SAUT' 1 'LIGN';
  433.       'MESSAGE' ' Numero du pas : ' IPAS '  Indice d evolution : ' ICHG ' -> temps :' TI;
  434. *
  435. *     Se placer sur la configuration de debut de pas
  436.       'FORM' WTAB.'GE0_DEB' ;
  437. *
  438.       'MENA' ;
  439.       IERRMEC = UNPAS PRECED;
  440. *
  441. *     Se placer sur la configuration de reference
  442.       'FORM' WTAB.'FOR0' ;
  443. *
  444. *     Test si on a converge
  445.       'SI' IERRMEC ;
  446.         'ERREUR' 997 ;
  447.       'FINSI';
  448. *
  449. *     Reevaluation des donnees du calcul dependant de la mecanique
  450.       'SI' WTAB.'PROCEDURE_REEV_MEC' ;
  451.         REEV_MEC PRECED 1;
  452.       'FINSI' ;
  453. *
  454.     'FINSI';
  455. *   ####################################################################
  456. *   ############ TEST DE LA CONVERGENCE MECANIQUE THERMIQUE ############
  457. *   ####################################################################
  458.     'SI' WTAB.'CONVERGENCE_MEC_THE' ;
  459. *      je cherche la convergence thermo-mecanique : je dois au moins
  460. *      calculer deux fois mon probleme
  461.       WTAB.'CONV_THMEC' = FAUX ;
  462.       'SI' (I_BOTH > 1) ;
  463. *       Test sur toutes les composantes (notamment, si DIFFUSION)
  464.         CHT1     = WTAB.'THER_COURANT' ;
  465.         DUABS2   = 'ABS' (WTAB.'THER_COURANTP' - CHT1) ;
  466.         CRICOH1  = 0. ;
  467.         NBINCO1  = 'DIME' WTAB.'PRIM_TOT' ;
  468.         'REPE' BINCO1 NBINCO1 ;
  469.           LINCOI1  = 'MOTS' ('EXTR' WTAB.'PRIM_TOT' &BINCO1) ;
  470.           MDUABSI1 = 'MAXI' DUABS2 'AVEC' LINCOI1 ;
  471.           NORMI1   = 'MAXI' 'ABS' CHT1 'AVEC' LINCOI1 ;
  472.           'SI' (NORMI1 '&lt;EG' (1.E-14 * MDUABSI1)) ;
  473.             NORMI1 = 1. ;
  474.           'FINS' ;
  475.           CRICOHI1 = MDUABSI1 / NORMI1 ;
  476.           'SI' (CRICOHI1 '>' CRICOH1) ;
  477.             CRICOH1  = CRICOHI1 ;
  478.          'FINS' ;
  479.         'FIN' BINCO1 ;
  480.  
  481.         WTAB.'CONV_THMEC' = CRICOH1 '<' (WTAB . 'CRITERE_COHERENCE') ;
  482. *       Fin de boucle Si ne converge Pas
  483.         'SI'('NON' WTAB.'CONV_THMEC') ;
  484.           'SI' (I_BOTH >EG WTAB.'BOU_METH');
  485.             'MESS' 'PAS DE COHERENCE TROUVEE MECANIQUE THERMIQUE' ;
  486.             'ERREUR' 999;
  487.           'FINSI' ;
  488.         'FINSI' ;
  489.       'FINSI' ;
  490. *     THER_COURANTPrecedent dans WTAB pour test CONVERGENCE_MEC_THE
  491.       WTAB.'THER_COURANTP' = WTAB.'THER_COURANT' ;
  492.     'FINSI' ;
  493. *
  494.     'SI' WTAB.'CONV_THMEC' ;
  495.       'QUITTER' BO_BOTH ;
  496.     'FINSI' ;
  497. *
  498.   'FIN' BO_BOTH ;
  499. * ++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
  500. * +++++++++++++++++ BOUCLE interne de bouclage mec_ther ++++++++++++++++
  501. * ++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
  502. *
  503. * ----------------------------------------------------------------------
  504. *       Mise a jour de quantites de WTAB a partir de celles a TI
  505. * ----------------------------------------------------------------------
  506. *
  507. * Formulation THERMIQUE
  508.   'SI' WTAB.'FOR_THER';
  509.     'SI' ('EGA' WTAB.'PROCEDURE_THERMIQUE' 'DUPONT');
  510.       WTAB.'TET0'              = estim.'TEMPERATURES' ;
  511.       WTAB.'VIEUXPAS'          = WTAB.'NOUV_PAS' ;
  512.       WTAB.'RELAXATION_DUPONT' = CHTER.'RELAXATION_DUPONT';
  513.     'FINSI';
  514.   'FINSI' ;
  515.  
  516. * Cas du modele THERMOHYDRIQUE BETON_THM (Sciume) : mise a jour des variables internes
  517.   ITHM1=WTAB.'THM1';
  518.   'SI' ITHM1;
  519.          'SI' ('EXIS' WTAB 'VAR_THM1') ;
  520.          WTAB . 'VAR_THM1' = WTAB . 'VAR_THM2' ; 
  521.          'FINS';
  522.   'FINS';  
  523.  
  524. *
  525. * Formulation MECANIQUE
  526.   'SI' WTAB.'FOR_MECA' ;
  527. *
  528.     'SI' WTAB.'ITHER' ;
  529.       WTAB.'TET1'   = WTAB.'TET2';
  530.       WTAB.'ETHER1' = WTAB.'ETHER2';
  531.       'SI' WTAB.'POR1';
  532.         WTAB.'MSRTHER1'= WTAB.'MSRTHER2';
  533.       'FINSI';
  534.     'FINSI' ;
  535. *       
  536. * Cas du modle VISCOPLASTIQUE BETON_THM (Sciume)
  537.     'SI' WTAB.'BETON_THM';
  538.        WTAB.'BETON_MCR1' =  WTAB.'BETON_MCR2';
  539.     'FINS' ; 
  540. *
  541.     'SI' WTAB.'CHAR_DEFI' ; 
  542.       WTAB.'DEFOR1' = WTAB.'DEFOR2';
  543.     'FINSI';
  544. *
  545.     'SI' WTAB.'DYNAMIQUE' ;
  546.       'SI' ('NON' WTAB.'LIAISON_PERSISTANTE') ;
  547.         WTAB.'FREA1' = WTAB.'FOPL' ;
  548.       'FINSI';
  549.       WTAB.'REAPREC' = estim.'REACTIONS';
  550.     'FINSI';
  551. *
  552. *   Actualiser la configuration de debut de pas
  553.     'SI' ( WTAB.'GRANDS_DEPLACEMENTS' 'OU'
  554.           (WTAB.'FEFP_FORMULATION' 'ET' WTAB.'UPDATE_LAGRANGIAN')) ;
  555.       WTAB.'GE0_DEB' = WTAB.'FOR' ;
  556.     'FINSI';
  557. *
  558.   'FINSI';
  559. *
  560. * Option AUTOMATIQUE : temps effectivement calcule
  561.   'SI' (WTAB.'AUTOMATIQUE' 'OU' ('NON' WTAB.'CONV'));
  562.     TEMP0 = (TI '-' TEMP0) '*' WTAB.'AUTOCOEF' '+' TEMP0;
  563.     estim.'TEMPS' = TEMP0 ;
  564.     MSGZ = 'CHAI' ' Temps effectivement calcule';
  565.     'SI' ('NON' WTAB.'CONV');
  566.       MSGZ = 'CHAI' MSGZ ' et non converge';
  567.     'FINSI';
  568.     'MESS' MSGZ ' : 'TEMP0;
  569.   'FINSI';
  570.  
  571. * Procedure utilisateur
  572.   'SI' WTAB.'FOR_MECA' ;
  573.     'SI' WTAB.'PROCEDURE_PERSO1' ;
  574.       PRECED.'PERSO1_APPEL' = 2 ;
  575.       PERSO1 PRECED;
  576.       'SI' ('EXIS' PRECED 'ARRET') ;
  577.         WTAB.'ARRET' = PRECED.'ARRET' ;
  578.       'FINSI' ;
  579.     'FINSI';
  580. *
  581. *   Redefinir WTAB.'CHARGEMENT_I'
  582.     'SI' WTAB.'CONVERGENCE_MEC_THE' ;
  583.       WTAB.'CHARGEMENT_I' = WTAB.'CHARGEMENT' ;
  584.     'FINSI';
  585.   'FINSI';
  586. *
  587. * pour ne pas sauvegarder la matrice de raideur si on doit la recalculer
  588.   'SI' ('EXIS' WTAB 'RRRR') ;
  589.     'SI' WTAB.'RECARI' ;
  590.       'OUBL' WTAB 'RRRR' ;
  591.     'FINSI';
  592.   'FINSI';
  593. *
  594. * ----------------------------------------------------------------------
  595. *        Remplir CONTINUATION et table de resultats + sauvegarde
  596. * ----------------------------------------------------------------------
  597.   ISAUV = PAS_RESU iauto PRECED ;
  598. *
  599. * Option AUTOMATIQUE
  600.   'SI' WTAB.'AUTOMATIQUE'; 
  601.     'SI' ((WTAB.'AUTOCOEF' 'EGA'  0.9999999D0) 'OU' (TEMP0 '>EG' TI)) ;
  602.       'MESS' ' Objectif atteint '; 'MESS' ' ';
  603.       WTAB.'AUTODEUX' = FAUX ;
  604.       WTAB.'AUTORED1' = 0 ;
  605.       WTAB.'AUTOREDU' = 1. ;
  606.       IAUTO = 1;
  607.     'SINON';
  608.       'MESS' ' Objectif non atteint: On recommence'; 'MESS' '  ';
  609.       IAUTO = IAUTO+1;
  610.       'SI' (IAUTO >EG WTAB.'AUTOPAS');
  611.         'ERREUR' 1000;
  612. *       'MESS' 'Pilotage non converge  apres ' IAUTO ' pas.';
  613.       'FINSI';
  614.       WTAB.'AUTODEUX'=VRAI;
  615.       ICHG=ICHG - 1; WTAB.'ICHG' = ICHG ;
  616.     'FINSI';
  617.   'FINSI';
  618. *
  619. * Option PAS_AJUSTE
  620.   'SI' WTAB.'PAS_AJUSTE';
  621.     'SI' ((TI < TIV) 'OU' ('NON' WTAB.'CONV')); 
  622.       ICHG=ICHG-1; WTAB.'ICHG' = ICHG ;
  623.     'FINSI';
  624.   'FINSI';
  625. *
  626.   'SI' WTAB.'ARRET';
  627.     'QUITTER' BEXTERN;
  628.   'FINSI';
  629. *
  630. 'FIN' BEXTERN;
  631. *-----------------------------------------------------------------------
  632. *              Fin de la boucle sur les pas de temps
  633. *-----------------------------------------------------------------------
  634. 'SI' ('NEG' WTAB.'AMORTISSEMENT' 'INCONNU');
  635.   WTAB.'AMORTISSEMENT' = TOTO ;
  636. 'FINSI';
  637. *
  638. 'SI' ('NEG' ('TYPE'  WTAB.'GE0_DEB') 'MOT') ;
  639.   'OUBL' WTAB 'GE0_DEB' ;
  640. 'FINSI' ;
  641. *
  642. * pour forcer le calcul de la rigidite si on  rappele  pasapas
  643. 'SI' ('EXIS' WTAB 'RRRR') ;
  644.   'OUBL' WTAB 'RRRR';
  645. 'FINSI';
  646. *
  647. * on tue WTAB.'MAT1' s'il existe car il peut etre tres gourmand en place
  648. WTAB.'MAT1' = 'MOT' 'INCONNU';
  649. *
  650. 'MESS' ' ';
  652. '------------------- FIN DE LA PROCEDURE PASAPAS ---------------------';
  653. 'SAUT' 1 'LIGNE';
  654. ************************************************************************
  655. 'FINPROC' PRECED ;
  656.  
  657.  
  658.  
  659.  
  660.  
  661.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales