Télécharger la plaquette Cast3M


fr en

Télécharger signsynt.procedur

Retour à la liste

Numérotation des lignes : 

  1. * SIGNSYNT  PROCEDUR  BP208322  16/05/24    21:15:17     8932           
  2. 'DEBPROC'   SIGNSYNT  MOT1*'MOT '   ZTAB*'TABLE   ' ;                           
  3. *******************************************************************             
  4. *******************************************************************             
  5. *                                                                               
  6. *            PROCEDURE   S I G N S Y N T                                        
  7. *            ---------------------------                                        
  8. *                                                                               
  9. *    AUTEUR D.BROCHARD  (DEMT/EMSI) TEL 6994                                    
  10. *                                                                               
  11. *           CREATION DE SIGNAUX SYNTHETIQUES PAR RECOMBINAISON                  
  12. *                   DE SINUSOIDES A PHASES ALEATOIRES                           
  13. *                                                                               
  14. *                         DATE : 09/09/1988                                     
  15. *                                                                               
  16. *    REMARQUES                                                                  
  17. *    ---------                                                                  
  18. *                                                                               
  19. *       1-  LA METHODE DE GENERATION UTILISE LA TFR. ON DOIT DONC               
  20. *           UTILISER 2**NPT                                                     
  21. *       2-  ON PEUT GENERER   :                                                 
  22. *                        -  UN BRUIT BLANC        : OPTION BBLANC
  23. *                        -  UN SIGNAL SYNTHETIQUE : OPTION FABR
  24. *                                                                               
  25. *******************************************************************             
  26. *                                                                               
  27. *        SIGNSYNT    TAB1                                                       
  28. *                                                                               
  29. *                  - TAB1      :   OBJET DE TYPE TABLE                          
  30. *                                                                               
  31. *                                                                               
  32. *******************************************************************             
  33. *   OPTION   MOT1 = 'FABR'                                                      
  34. *                                                                               
  35. *    TAB1  :  objet de type TABLE contenant                                     
  36. *                                                                               
  37. *       Indice       Type            Commentaires                               
  38. *                                                                               
  39. *        MOTIT        MOT            TEXTE SUR 16 CARACT}RES                    
  40. *        SEISME      TABLE                                                      
  41. *                            Indice       Type          Commentaires            
  42. *                                                                               
  43. *                            SPECTRE    EVOLUTION   Spectre de r{f{rence        
  44. *                            AMORT      LISTREEL    Les amortissements          
  45. *                            TYPSP      MOT         'ACCE' 'VITE' 'DEPL'        
  46. *        SIGNAL      TABLE
  47. *                            Indice       Type          Commentaires            
  48. *                                                                               
  49. *                            ENVE       MOT         Type de l'enveloppe         
  50. *                            NP         ENTIER      Puissance de 2              
  51. *                            DUREE      FLOTTANT    Dur{e du signal             
  52. *                            FRCOUP     FLOTTANT    FREQ. LIMITE                
  53. *                                                                               
  54. *        NBITER      ENTIER           Nombre d'it{rations                       
  55. *        NBSIGN      ENTIER           Nombre de signaux                         
  56. *        NALEAT      ENTIER           Param}tre d'initialisation des            
  57. *                                     phases                                    
  58. *                                                                               
  59. *******************************************************************             
  60. *                                                                               
  61. *    ZTITRE          TITRE                                                      
  62. *    ZNP             NOMBRE DE POINTS EN PUISSANCE DE 2                         
  63. *                                                                               
  64. *    ZEVSPE1(ZFREQ)       SP. DE REF. ENTRE EN DONNEES  DE TYPE TYPSP           
  65. *    ZEVSPEC(ZFREQ,ZSPEC)        IDEM EN DEPLACEMENT                            
  66. *                                                                               
  67. *    ZEVSPREF(ZFRQ,ZSPREF)  SP. DE REF. APRES INTERPOLATION EN DEPL             
  68. *                             (SERT POUR LA CORRECTION,CALCUL DE RAP)           
  69. *                                                                               
  70. *    ZEVSPRE1(ZFRQ)         SP. DE REF. APRES INTERPOLATION EN TYPSP            
  71. *                                  (NE SERT QUE POUR LE TRACE)                  
  72. *                                                                               
  73. *    ZEVSPO(ZFRQ)           SP. D'OSCILLATEUR EN DEPLACEMENT                    
  74. *    ZEV1(ZFRQ)              IDEM DE TYPE TYPSP POUR LE TRACE                   
  75. *                                                                               
  76. *    ZEPS            AMORTISSEMENT                                              
  77. *    ZNITER          NOMBRE D'ITERATIONS                                        
  78. *                                                                               
  79. *    ZNPT            NOMBRE DE POINTS DU SIGNAL                                 
  80. *                                           = 2 ** ZNP                          
  81. *    ZDF             PAS EN FREQUENCE       = 1 / ZDUREE                        
  82. *    ZDT             PAS EN TEMPS           = ZDUREE / (2 ** ZNP)               
  83. *                                                                               
  84. *    ZFRQ0  ZFRQ     TABLE DES FREQUENCES (AVEC ET SANS FREQUENCE NULLE)        
  85. *                     ZFRQ0 = ZFRC1 + ZFRC2  ET DE LONGUEUR ZNBFR               
  86. *    ZNBFR           (ZNPT / 2 ) + 1          : NB DE PTS DU SPECTRE            
  87. *    ZLRTEMP           TABLE DES TEMPS  AYANT  ZNPT POINTS                      
  88. *                                                                               
  89. *                                                                               
  90. *******************************************************************             
  91. *    OPTION   BBLANC  :   SIGNAL BRUIT BLANC COMBINAISON DE SINUSOIDES          
  92. *                         A PHASES  ALEATOIRES                                  
  93. *    TAB1  :  objet de type TABLE contenant                                     
  94. *                                                                               
  95. *       Indice       Type            Commentaires                               
  96. *                                                                               
  97. *        MOTIT        MOT            TEXTE SUR 16 CARACTERES                    
  98. *        OPTION       MOT            'BBLANC'                                   
  99. *        NP          ENTIER          nombre de points en puissance de 2         
  100. *        DELTAF      FLOTTANT        Pas en fr{quence                           
  101. *        NALEAT      ENTIER          Param}tre d'initialisation des             
  102. *                                    phases                                     
  103. *                                                                               
  104. *******************************************************************             
  105. *                                                                               
  106. *   ZTITRE         TITRE                                                        
  107. *   ZNP            NOMBRE DE POINTS EN PUISSANCE DE 2                           
  108. *   ZNPT           NB DE FREQUENCES = (2**ZNP)                                  
  109. *   ZDELTAF        PAS EN FREQUENCE                                             
  110. *   ZINIT          PARAMETRE INITIALISATION DES PHASES                          
  111. *                                                                               
  112. *         SORTIE                                                                
  113. *   EVBB0 'EVOLUTIO' CONTENANT LE SIGNAL                                        
  114. *                                                                               
  115. *=========================================================                      
  116. *                                                                               
  117. ZOPTION = MOT1 ;   IMPII   = 'VALEUR' 'IMPI'     ;                              
  118. MOTIT   = 'MOT' 'MOTIT'    ;   ZTITRE  = ZTAB. MOTIT      ;                     
  119. 'SI' ( 'EGA' ZOPTION 'FABR' ) ;                                                 
  120.   SEISME  = 'MOT' 'SEISME'    ;    SPECTRE = 'MOT' 'SPECTRE'  ;                 
  121.   AMORT   = 'MOT' 'AMORT'     ;    TYPSP   = 'MOT' 'TYPSP'  ;                   
  122.   SIGNAL  = 'MOT' 'SIGNAL'    ;    DUREE   = 'MOT' 'DUREE'    ;                 
  123.   NP      = 'MOT' 'NP'        ;    TDEBUT  = 'MOT' 'TDEBUT'   ;                 
  124.   TFIN    = 'MOT' 'TFIN'      ;    ENVE    = 'MOT'  'ENVE'    ;                 
  125.   NBITER  = 'MOT' 'NBITER'    ;    NBSIGN  = 'MOT' 'NBSIGN'   ;                 
  126.   NALEAT  = 'MOT' 'NALEAT'    ;    FRCOUP  = 'MOT' 'FRCOUP'   ;                 
  127.   OPTSORT = 'MOT' 'OPTSORT' ;                                                   
  128. *                                                                               
  129.   ZEVSPE1 = ZTAB. SEISME . SPECTRE  ;                                           
  130.   ZEPS    = ZTAB. SEISME . AMORT    ;                                           
  131.   ZTYPSP  = ZTAB. SEISME . TYPSP  ;                                             
  132.   ZNP     = ZTAB. SIGNAL . NP       ;                                           
  133.   ZDUREE  = ZTAB. SIGNAL . DUREE    ;                                           
  134.   ZNITER  = ZTAB. NBITER     ;      ZNBSIGN = ZTAB. NBSIGN   ;                  
  135.   ZNALEAT = ZTAB. NALEAT     ;      ZFRCOUP = ZTAB. FRCOUP   ;                  
  136.   ZOPTSOR = 'MOT' ZTAB. OPTSORT    ;
  137. *    TEST LONGUEUR DU TITRE                                                     
  138.   'TITR' ZTITRE 'SPECTRE ITERATION NUM' ZNITER                                  
  139.                 'MOYENNE DE'   ZNBSIGN  'SIGNAUX' ;                             
  140.   'SI' ( 'NON' ( 'EXIS' ZOPTSOR )  ) ;  ZOPTS = 0 ;                             
  141.   'SINON'  ;                                                                    
  142.      'SI' ( 'EGA' ZOPTSOR 'SIGNAUX' )  ;  ZOPTS = 2 ;  'FINSI' ;                
  143.      'SI' ( 'EGA' ZOPTSOR 'SPECTRE' )  ;  ZOPTS = 1 ;  'FINSI' ;                
  144.   'FINSI' ;                                                                     
  145.   ZPTLIN  = 'MOT' 'PLATLIN'    ;                                                
  146.   'SI' ( 'NON' ( 'EXIS'  ZTAB SIGNAL  ENVE  ) ) ;
  147.        ZENVE = 'MOT' 'N' ;                                                      
  148.   'SINON' ;                                                                     
  149.     ZENVE   = ZTAB. SIGNAL . ENVE     ;
  150.       'SI' ( 'EGA' ZENVE ZPTLIN )  ;                                            
  151.           ZTDEB   = ZTAB. SIGNAL. TDEBUT ;                                      
  152.           ZTFIN   = ZTAB. SIGNAL. TFIN ;                                        
  153.       'FINSI' ;                                                                 
  154.   'FINSI' ;                                                                     
  155. *                                                                               
  156. *     TRANSFORMATION SI BESOIN EST DU SRO EN SRO EN DEPL                        
  157. *                                                                               
  158.   ZDEPL = 'MOT' 'DEPL' ;                                                        
  159.   'SI'  ( 'EGA' ZTYPSP ZDEPL ) ;                                                
  160.        ZEVSPEC = ZEVSPE1 ;                                                      
  161.   'SINON' ;                                                                     
  162.        ZEVSPEC = 'CHSP' ZEVSPE1 'ENTR' ZTYPSP 'SORT' ZDEPL ;                    
  163.   'FINSI' ;                                                                     
  164. *                                                                               
  165.   ZPI = PI ;  ZE = EXP 1. ;                                            
  166. *                                                                               
  167.   ZNPT = 2 '**' ZNP ; ZNPTP1 = ZNPT '+' 1 ; ZDF = 1. '/' ZDUREE;                
  168.   ZNBFRM1 = ZNPT '/' 2  ;  ZNBFRM2 = ZNBFRM1 '-' 1 ;                            
  169.   ZNBFR = ZNBFRM1 '+' 1 ;                                                       
  170.   ZDT = ZDUREE '/' ZNPT ;       ZFMAX = 0.5 '/' ZDT  ;                          
  171. *            CALCUL DES TABLES DES FREQUENCES ET DES TEMPS                      
  172.   ZLRFRQ0  =  'PROG'  0.     'PAS'  ZDF   'NPAS'  ZNBFRM1 ;                     
  173.   ZLRFRQ   =  'PROG'  ZDF    'PAS'  ZDF   'NPAS'  ZNBFRM2 ;                     
  174. * 'MESS' 'DUREE ET DT        = '  ZDUREE    ZDT    ;                            
  175.   'SI' ( 'EGA' ZENVE ZPTLIN )  ;                                                
  176.      'MESS' 'DEBUT ET FIN DE L ENVELOPPE PLATEAU' ZTDEB ZTFIN ;                 
  177.   'FINSI' ;                                                                     
  178. * 'MESS' 'FREQUENCE MAXIMALE       = '  ZFMAX  ;                                
  179. * 'MESS' 'NOMBRE DE PTS DU SPECTRE = ' ZNBFRM1 ;                                
  180. * 'MESS' 'NOMBRE DE PTS DU SIGNAL  = '   ZNPT  ;                                
  181. *                                                                               
  182.   ZFC = ( 2. '*' ZEPS  ) '**' .5  ;                                             
  183.   ZFC =  ZE  '/' ( 2. '*' ZDUREE '*' ZFC ) ;                                    
  184.   ZNBC1 = 'ENTI' ( ZFC '/' ZDF ) ; ZNBC11 = ZNBC1 '-' 1 ;                       
  185.   ZNBC2 = ZNBFR '-' ZNBC1 ;                                                     
  186.   ZNBC21 = ZNBC2 '-' 1; ZNBC22 = ZNBC21 '-' 1 ;                                 
  187.   ZLRFRC1 = 'PROG' 0. 'PAS' ZDF 'NPAS' ZNBC11 ;                                 
  188.   ZDF1 = ( ZNBC1 '+' 1 ) '*' ZDF              ;                                 
  189.   ZLRFRC2 = 'PROG' ZDF1 'PAS' ZDF  'NPAS' ZNBC22  ;                             
  190. *                                                                               
  191.   ZLRTEMP = 'PROG' 0. 'PAS' ZDT 'NPAS' ( ZNPT '-' 1) ;                          
  192. *                                                                               
  193. *      CREATION DE L'ENVELOPPE                                                  
  194. *                                                                               
  195.   ZTABENV1 = 'TABLE'  ;                                                         
  196.   ZTABENV1.'TYPENVE' = ZENVE ;                                                  
  197.   ZTABENV1.'NPT'     = ZNPT  ;  ZTABENV1.'DUREE' = ZDUREE ;                     
  198.   'SI' ( 'EGA' ZENVE ZPTLIN ) ;                                                 
  199.      ZTABENV1.'TDEBUT' = ZTDEB ; ZTABENV1.'TFIN' = ZTFIN ;                      
  200.   'FINSI' ;                                                                     
  201.   ZTABENV1.'EPS'     = ZEPS  ;                                                  
  202. *                                                                               
  203.   ZTABENV2  =  SIGNENVE    ZTABENV1      ;                                      
  204. *                                                                               
  205.   ZLRENV = ZTABENV2.'LRENV' ; ZLRCORR = ZTABENV2.'LRCORR' ;                     
  206.   ZEVENV  = 'EVOL' 'MANU' 'TEMPS' ZLRTEMP 'ENVELOPPE' ZLRENV ;                  
  207.   ZEVCORR = 'EVOL' 'MANU' 'TEMPS' ZLRFRQ  'ENVELOPPE' ZLRCORR ;                 
  208. *                                                                               
  209. *      INTERPOLATION LOGARITHMIQUE SUR LE SPECTRE DE REFERENCE EN DEPL          
  210. *               AVEC ZNBFR POINTS SANS FREQUENCE NULLE                          
  211. *                                                                               
  212.   ZLRFREQ = 'EXTR' ZEVSPEC 'ABSC' 1; ZLRSPEC = 'EXTR' ZEVSPEC 'ORDO' 1;         
  213.   ZLOGFRQ  = 'LOG' ZLRFRQ ; ZLOGFREQ = 'LOG' ZLRFREQ ;                          
  214.   ZLOGSPEC = 'LOG' ZLRSPEC ;                                                    
  215.   ZLRSPREF = 'IPOL'  ZLOGFRQ   ZLOGFREQ    ZLOGSPEC    ;                        
  216.   ZLRSPREF = 'EXP'  ZLRSPREF  ;                                                 
  217.   'TITR' 'SP. DE REF. APRES INTERPOLATION EN DEPL ' ;                           
  218.   ZEVSPREF = 'EVOL' ROUG 'MANU' 'FREQU.' ZLRFRQ 'SPEC DE REF' ZLRSPREF ;        
  219.   'OUBLIER' ZLRSPREF  ;                                                         
  220. ******                                                                          
  221. *           CALCUL DU SPECTRE DE REFERENCE DE TYPE TYPSP POUR TRACES            
  222.   'SI'  ( 'EGA' ZTYPSP ZDEPL ) ;  ZEVSPRE1 = ZEVSPREF ;                         
  223.   'SINON' ; ZEVSPRE1 = 'CHSP' ZEVSPREF 'ENTR' ZDEPL 'SORT' ZTYPSP ;             
  224.   'FINSI' ;                                                                     
  225. *          PAS DE FREQUENCES AU DELA DE FRCOUP                                  
  226.   ZNN = 'DIME' ZLRFRQ ;                                                         
  227.   ZN1 = 'ENTI' ( ZFRCOUP  '/'  ZDF )  ;                                         
  228.   ZN2 = ZNN  '-' ZN1 ;                                                          
  229.   ZC1 = 'PROG' ZN1 '*' 1.  ;      ZC2 = 'PROG' ZN2 '*' 0. ;                     
  230.   ZLRCOUP = ZC1 'ET' ZC2 ;                                                      
  231.   ZEVCOUP = 'EVOL' 'MANU' 'FREQU.' ZLRFRQ 'SPEC DE REF' ZLRCOUP ;               
  232.   ZEVSPREF = ZEVSPREF '*' ZEVCOUP ;                                             
  233.   'OUBLIER' ZLRCOUP ; 'OUBLIER' ZEVCOUP ;                                       
  234. *                                                                               
  235. *        CALCUL DE L' ACCELERATION MAXIMALE                                     
  236. *                                                                               
  237.   ZN     = 'DIME' ZLRFREQ    ;                                                  
  238.   ZFM    = 'EXTR' ZLRFREQ ZN ;   ZSPM   = 'EXTR' ZLRSPEC ZN ;                   
  239.   ZGAMMA =  ZSPM '*' 4. '*' ZPI '*' ZPI '*' ZFM '*' ZFM ;                       
  240.   'MESS' 'ACCELERATION MAXIMALE  = '   ZGAMMA  ;                                
  241. *                                                                               
  242. *                 CREATION DES PHASES ALEATOIRES                                
  243. *                                                                               
  244.   ZTABPHI = 'TABLE' ;                                                           
  245.   ZI = 0 ;                                                                      
  246.   'REPETER' LOOPHI ZNBSIGN ;                                                    
  247.      ZI =  ZI '+' 1 ;                                                           
  248.      ZNALEAT1 = ZNALEAT '+' 1 ;                                                 
  249.      ZEVPHI = 'BRUI' 'BLAN' 'UNIF'  0. 180. ZNALEAT1 ZLRFRQ0 ;                  
  250.      ZLRPHI = 'EXTR' ZEVPHI 'ORDO' 1                 ;                          
  251.      'REMP' ZLRPHI 1 0.                  ;                                      
  252.      ZTABPHI. ZI = ZLRPHI ;                                                     
  253.   'FIN'  LOOPHI ;                                                               
  254. *                                                                               
  255.   ZCB = 2. '*' ZEPS ; ZCB = ZCB '**' 0.5 ; ZCB = 2. '*' ZDUREE '*' ZCB ;        
  256.   ZLRCBF1 = 'PROG'  ZNBC1 '*'  ZE ;  ZLRCBF2 = ZCB  '*'  ZLRFRC2 ;              
  257.   ZLRCBF = ZLRCBF1 'ET' ZLRCBF2 ;                                               
  258. *                                                                               
  259.   ZLRMU2 =  2. '*' ( 'LOG'  ZLRCBF )   ;                                        
  260.   'TITRE' ZTITRE 'MU 2' ;                                                       
  261.   ZEVMU2 = 'EVOL' MANU 'ABSC' ZLRFRQ 'ORDO' ZLRMU2 ;                            
  262.   'SI' ( 'NON' ( IMPII '<' 1 ) ) ;  DESS ZEVMU2 LOGX LOGY MIMA ;                
  263.   'FINSI' ;                                                                     
  264. *                                                                               
  265.   ZEVCOEFR = ZEVCORR '*' ZEVMU2 ;                                               
  266.   ZLRCOEFR = 'EXTR' ZEVCOEFR 'ORDO' 1 ;                                         
  267.   ZEVSPP   = ZEVSPREF       ;                                                   
  268.   ZEVDSP = ZEVSPP '*' ZEVSPP '*' ZDUREE '*' ZDUREE '*' .5  '/' ZEVCOEFR;        
  269.   ZLRDSP   = 'EXTR' ZEVDSP 'ORDO' 1 ;                                           
  270.   ZLRTFR   = ZLRDSP  '**' 0.5  ;                                                
  271.       ZLRTFR = 'INSERER'    ZLRTFR 1 0.     ;                                   
  272. *                                                                               
  273. *                   CREATION DES SIGNAUX AVANT ITERATION                        
  274. *                                                                               
  275.   ZI = 0 ;                                                                      
  276.   'REPETER' LOOP1 ZNBSIGN  ;                                                    
  277.      ZI = ZI '+' 1 ;                                                            
  278.      ZLRPHI = ZTABPHI. ZI ;                                                     
  279.      ZEVTFR = 'EVOL' 'COMP' 'MOPH' 'FREQ' ZLRFRQ0 'MODU' ZLRTFR 'PHASE'         
  280.               ZLRPHI;                                                           
  281.      'TITR' 'SIGNAL NO : ' ZI 'AVANT ITERATION' ;                               
  282.      ZEVSIG = ( 'TFRI' ZEVTFR ) '*' ZEVENV   ;                                  
  283.     'SI' ( '>'  ZOPTS  1  ) ; DESS ZEVSIG MIMA ;  'FINSI' ;                     
  284. *                                                                               
  285.     'TITR' ZTITRE ' SPECTRE AVANT ITERATION '   ;                               
  286.      ZEVSPI = 'SPO' ZEVSIG 'AMOR' ( 'PROG' ZEPS ) 'FREQ' ZLRFRQ ZDEPL ;         
  287.     'SI'  ('EGA' ZI  1 ) ;   ZEVSPO = ZEVSPI ;                                  
  288.     'SINON' ;                ZEVSPO = ZEVSPI '+' ZEVSPO ;                       
  289.     'FINSI' ;                                                                   
  290.   'FIN' LOOP1 ;                                                                 
  291.   ZEVSPO = ZEVSPO '/' ZNBSIGN ;                                                 
  292.   'SI'  ( 'EGA' ZTYPSP ZDEPL ) ;  ZEV1 = ZEVSPO ;                               
  293.   'SINON' ;  ZEV1 = 'CHSP' ZEVSPO 'ENTR' ZDEPL 'SORT' ZTYPSP ;                  
  294.   'FINSI' ;                                                                     
  295.   'TITR' 'PREMIERS SPECTRES   '  ;                                              
  296.      ZEV = ZEV1 'ET' ZEVSPRE1 ;    'DESS' ZEV LOGX LOGY MIMA   ;                
  297. *                                                                               
  298. *                           ITERATIONS                                          
  299. *                                                                               
  300.   ZTEVSIG = 'TABLE' ;                                                           
  301.   ZITER = 0 ;                                                                   
  302.   'REPETER'   BOUCL  ZNITER   ;                                                 
  303.      ZITER = ZITER '+' 1 ;                                                      
  304. *                                                                               
  305. *          MODIFICATION DU MODULE DE LA TFR DU PROCESSUS STATIONNAIRE           
  306. *                                                                               
  307.      ZLRRAP = 'EXTRAIRE' (  ZEVSPREF '/' ZEVSPO  )  'ORDO'  1  ;                
  308.        ZLRRAP = INSERER ZLRRAP 1 0. ;                                           
  309.      ZEVRAP = 'EVOL' MANU 'ABSC' ZLRFRQ0  'ORDO'  ZLRRAP ;                      
  310.      ZLRTFR =  ZLRTFR  '*'  ZLRRAP ;                                            
  311. *                                                                               
  312. *                          CREATION DES SIGNAUX                                 
  313. *                                                                               
  314.      ZI = 0 ;                                                                   
  315.      'REPETER' LOOP2 ZNBSIGN  ;                                                 
  316.         ZI = ZI '+' 1 ;                                                         
  317.        'TITR' 'ITERATION ' ZITER  'SIGNAL' ZI ;                                 
  318.         ZLRPHI = ZTABPHI. ZI ;                                                  
  319.         'TITR' ZTITRE 'ITERATION NUM : ' ZITER ' SIGNAL NUM : ' ZI ;            
  320.         ZEVTFR = 'EVOL' 'COMP' 'MOPH' 'FREQ' ZLRFRQ0 'MODU' ZLRTFR              
  321.                  'PHASE' ZLRPHI ;                                               
  322.         'TITR' ZTITRE 'SIGNAL NO :' ZI ' ITERATION' ZITER ;                     
  323.         ZTEVSIG.ZI = ( 'TFRI' ZEVTFR ) '*' ZEVENV ;                             
  324.         'SI' ( 'NON' ( IMPII '<' 1 ) ); 'DESS' ZTEVSIG.ZI MIMA; 'FINSI';        
  325.         'SI' ( '>' ZITER 1 ) ;                                                  
  326. *                           CORRECTION DES POINTES DU SIGNAL                    
  327.            ZTABCOR1 = 'TABLE' ;                                                 
  328.            ZTABCOR1.'EVSIG1' = ZTEVSIG.ZI ; ZTABCOR1.'GAMMA' = ZGAMMA ;         
  329.            ZTABCOR2  =  SIGNCORR   ZTABCOR1 ;                                   
  330.            ZTEVSIG.ZI = ZTABCOR2.'EVSIG2' ;                                     
  331.         'FINSI' ;                                                               
  332. *                           SIGNAL APRES CORRECTION                             
  333.         'SI' ( '>' ZOPTS 1 ) ; 'DESS' ZTEVSIG.ZI 'MIMA' ; 'FINSI' ;             
  334.         'TITR' ZTITRE 'SPECTRE ITERATION NUM' ZITER                             
  335.                       'MOYENNE DE' ZNBSIGN 'SIGNAUX' ;                          
  336.         ZEVSPI = 'SPO' ZTEVSIG.ZI 'AMOR' ( 'PROG' ZEPS )                        
  337.                  'FREQ' ZLRFRQ ZDEPL ;                                          
  338.         'SI'  ('EGA' ZI  1 ) ;  ZEVSPO = ZEVSPI ;                               
  339.         'SINON' ;               ZEVSPO = ZEVSPI '+' ZEVSPO ;                    
  340.         'FINSI' ;                                                               
  341.      'FIN' LOOP2 ;                                                              
  342.      ZEVSPO = ZEVSPO '/' ZNBSIGN ;                                              
  343.     'SI'  ( 'EGA' ZTYPSP ZDEPL ) ;  ZEV1 = ZEVSPO ;                             
  344.     'SINON' ;  ZEV1 = 'CHSP' ZEVSPO 'ENTR' ZDEPL 'SORT' ZTYPSP ;                
  345.     'FINSI' ;                                                                   
  346.      ZEV   = ZEV1 'ET' ZEVSPRE1 ;  'DESS'  ZEV LOGX LOGY  MIMA   ;              
  347. *   'SI'  ( 'NEG' ZTYPSIG ZACCE ) ;                                             
  348. *      ZI = 0 ;                                                                 
  349. *     'REPETER' LOOP3 ZNBSIGN  ;                                                
  350. *         ZI = ZI '+' 1 ;                                                       
  351. *     'FIN' LOOP3 ;                                                             
  352. *   'FINSI' ;                                                                   
  353. FIN BOUCL   ;                                                                   
  354. 'MESS' '**********   FIN   ************' ;     'TEMPS'  ;                       
  355. 'SINON' ;                                                                       
  356.         'SI' ( 'EGA' ZOPTION 'BLAN' )       ;                                   
  357. *                                                                               
  358. DELTAF = 'MOT' 'DELTAF' ; NALEAT = 'MOT' 'NALEAT' ; NP = 'MOT' 'NP' ;           
  359. *'MESS' 'LECTURE' NALEAT  NP  DELTAF ;                                          
  360. ZINIT = ZTAB. NALEAT  ; ZEFRQ   = ZTAB. NP ; ZDFRQ   = ZTAB. DELTAF ;           
  361. *                                                                               
  362. *TEST ZINIT EXISTE T IL                                                         
  363. 'SI' ( 'NON' ( 'EXIS' ZINIT ) )  ; ZINIT = 1 ; 'FINSI' ;                        
  364. *                                                                               
  365. ZNFRQ = 2 '**' ZEFRQ ;                                                          
  366. ZLRFREQ = 'PROG' 0.  'PAS' ZDFRQ 'NPAS'  ZNFRQ   ;                              
  367. ZEVPHI = 'BRUI' 'BLAN' 'UNIF'  0. 180. ZINIT ZLRFREQ  ;                         
  368. 'SI' ( 'NON' ( IMPII '<' 1 ) ) ; 'DESS' ZEVPHI MIMA ; 'FINSI' ;                 
  369. ZLRPHI = 'EXTR' ZEVPHI 'ORDO' 1 ;                                               
  370. 'REMP' ZLRPHI 1 0. ;                                                            
  371. 'REMP' ZLRPHI ('DIME' ZLRPHI) 0.;                                               
  372. ZMOD = 1.0 '/' ( ( ( 2. '*' ZDFRQ ) '*' ( ZNFRQ '+' 1 ) )                       
  373.         '**' 0.5 ) ;                                                            
  374. ZLRMO = 'PROG' ( ZNFRQ '+' 1 ) '*' ZMOD ;                                       
  375. 'TITR' 'BRUIT BLANC' ZTITRE ;                                                   
  376. ZEVTFR = 'EVOL' 'COMP' 'MOPH' 'FREQ' ZLRFREQ 'MODU'  ZLRMO                      
  377.                                             'PHASE' ZLRPHI ;                    
  378. ZEVBB00 = 'TFRI' ZEVTFR;                                                        
  379. *                                                                               
  380. *               NORMALISATION DU SIGNAL(ECART-TYPE= 1)                          
  381. *                                                                               
  382. ZLRDSP0 = 'DSPR' ( ZEFRQ '+' 1 )  ZEVBB00 ;                                     
  383. 'SI' ( 'NON' ( IMPII '<' 1 ) ) ; 'DESS' ZLRDSP0 MIMA ; 'FINSI' ;                
  384. ZLCOEF = ( 'INTG' ZLRDSP0 ) '**' 0.5 ; ZCOEF = 'EXTR' ZLCOEF 1 ;                
  385. ZTEVSIG = ZEVBB00 '/'  ZCOEF  ;                                                 
  386. *                                                                               
  387. *******************************************************************             
  388.         'SINON'   ;                                                             
  389.          ERREUR ' MOT CLE NON PREVU ACTUELLEMENT ' ;                            
  390.         'FINSI' ;                                                               
  391. 'FINSI'         ;                                                               
  392. ***********************************************************************         
  393. 'FINPROC'  ZTEVSIG   ;                                                          
  394.  
  395.  
  396.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales