Procédures | Cast3M

* CORMASSE  PROCEDUR  SERRE     21/06/28    21:15:02     11045          
'DEBP' CORMASSE
*
* E/  $vtf  : MMODEL   : NAVIER_STOKES
* E/  RHOi  : CHPOINT  : Densité à contraindre
* E/  Mi0D  : FLOTTANT : Contrainte sur l'intégrale de la densité 
* E/  Mr    : FLOTTANT : Borne supérieure admissible de la densité (filtre)
*
*  /S dRHOi : FLOTTANT : Correction de la densité
*  /S RHOk  : CHPOINT  : RHOi corrigé
*  /S MiCFD : FLOTTANT : Intégrale avant correction
*
* On impose à l'intégrale de la densité d'être égale à la valeur cible.
* Pour cela on calcule la différence et on décalle de la densité
* volumique moyenne associée à la différence en controlant la positivité
* de la densité.
*
VOLi   = 'DOMA' $vtf 'XXDIAGSI' ;
VTotal = 'SOMT' VOLi ;
*
* On borne la densité par 1E-10 et Mr
RHOi = 'KOPS' RHOi '|<' 1.e-10 ;
RHOi = 'KOPS' RHOi '>|' Mr ;
*
* dRHOi : Correction moyenne de la densité
MiCFD  = 'SOMT' (VOLi '*' RHOi) ;
dMi    = Mi0D '-' MiCFD ;
dRHOi  = dMi '/' VTotal ;
*
* S'il manque de la masse on en ajoute partout. S'il y en a trop, on
* l'enlève partout en vérifiant la positivité : on redistribue alors
* uniformement la masse négative dans la partie positive du champ
* jusqu'à convergence. 
*
'SI' (dMi '>EG' 0.) ;
  RHOk = RHOi + dRHOi ;
'SINO' ;
  nfs = 15 ; epsim = 0. ; epsir = 1.e-20 ; epsiv = epsir '*' VTotal ;
  dMk = 'ABS' dMi ;
  RHOk = RHOi ;
  'REPE' Bcor nfs ;
    ik    = 'MASQ' RHOk 'SUPERIEUR' epsim ;
    RHOk  = ik '*' RHOk ;
    'SI' (dMk '&lt;EG' epsir) ;
       'QUIT' Bcor ;
    'SINO' ;
       'SI' (&bcor 'EGA' nfs) ;
'MESS' 'Mi0D' Mi0D ' ' 'MiCFD ' MiCFD ;
'MESS' dmk ;
'MESS' 'CORMASSE :  NON CONVERGENCE' ;
*          'ERRE' 5 ;
       'FINS' ;
    'FINS' ;
    Vk    = 'SOMT' (VOLi '*' ik) ;
    dRHOk = dMk '/' (Vk + epsiv) ;
    RHOk = RHOk '-' dRHOk ;
    ikp = 'MASQ'  RHOk 'INFERIEUR' epsim ;
    dMk = 'SOMT' (VOLi'*' ik '*' ikp '*' RHOk) 'ABS' ;
  'FIN' Bcor ;
'FINS' ;
RHOk = 'KCHT' $vtf 'SCAL' 'SOMMET' RHOk ;
*
'FINP' dRHOi RHOk MiCFD ;