Télécharger lire_med_02.dgibi

Retour à la liste

Numérotation des lignes :

  1. * fichier : lire_med_02.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4.  
  5. * Presentation : Ce cas-test permet de :
  6. * SORTIR des MAILLAGES, CHPOINT, MCHAML et TABLE PASAPAS
  7. * au format MED
  8. * LIRE les fichiers MED generes
  9. * VERIFIE et VALIDE les echanges au format MED
  10. * - Les valeurs lues sont identiques aux valeurs
  11. * attendues (Champs de coordonnees facile a comparer)
  12. *
  13. * Ameliorations a prevoir :
  14. * - Sortir et lire les MCHAML en d'autres points supports
  15. * - Sortir et lire les CONSTITUANTS dans les MCHAML
  16. * - Sortir et lire les NATURES dans les CHPOINT
  17. *
  18. * Creation : 17/02/2017
  19. * Createur : C. BERTHINIER
  20. *
  21. * Modifications :
  22. * CB215821 01/02/2018 : Sortie, Relecture & Validation des MAILLAGES
  23. * : Sortie, Relecture & Validation des CHPOINTS
  24. * : Sortie, Relecture & Validation des MCHAML
  25. * - Aux GRAVITE
  26. * - Aux NOEUDS
  27. * CB215821 13/03/2019 : Sortie, Relecture & Validation des TABLES PASAPAS
  28. ************************************************************************
  29.  
  30. * repertoire des fichiers "divers"
  31. DIVERS = VENV 'CASTEM_DIVERS';
  32. *
  33. 'OPTI' 'TRAC' 'PSC';
  34.  
  35. ************************************************************************
  36. * PROCEDURE POUR VERIFIER UN MAILLAGE
  37. ************************************************************************
  38. 'DEBP' VERMAI M_CAS*'MAILLAGE' M_MED*'MAILLAGE' NOM_MAI*'MOT';
  39. * TRACE des MAILLAGES
  40. CHAI1 ='CHAI' 'MAILLAGE' ' ' NOM_MAI ' ' 'CAST3M';
  41. CHAI2 ='CHAI' 'MAILLAGE' ' ' NOM_MAI ' ' 'LU MED';
  42. 'TRAC' 'QUAL' M_CAS 'TITR' CHAI1;
  43. 'TRAC' 'QUAL' M_MED 'TITR' CHAI2;
  44.  
  45. * Nombre d''elements
  46. NE_CAS ='NBEL' M_CAS;
  47. NE_MED ='NBEL' M_MED;
  48. 'ELIM' M_MED M_CAS 1.D-6;
  49. NE_DIF ='NBEL' ('DIFF' M_CAS M_MED);
  50.  
  51. * Nombre de noeuds
  52. NN_CAS ='NBNO' M_CAS;
  53. NN_MED ='NBNO' M_MED;
  54.  
  55. * Verification Nombre d''elements
  56. 'SI' (NE_CAS 'NEG' NE_MED);
  57. 'OPTI' 'ECHO' 0;
  58. 'MESS' '############################################################';
  59. 'MESS' '# LE MAILLAGES MED RELUS N EST PAS CONFORME #';
  60. 'MESS' '# ERREUR NOMBRE ELEMENTS #';
  61. 'MESS' '############################################################';
  62. 'OPTI' 'ECHO' 1;
  63. 'ERRE' 5;
  64. 'FINS';
  65. * Verification Nombre de Noeuds
  66. 'SI' (NN_CAS 'NEG' NN_MED);
  67. 'OPTI' 'ECHO' 0;
  68. 'MESS' '############################################################';
  69. 'MESS' '# LE MAILLAGES MED RELUS N EST PAS CONFORME #';
  70. 'MESS' '# ERREUR NOMBRE DE NOEUDS #';
  71. 'MESS' '############################################################';
  72. 'OPTI' 'ECHO' 1;
  73. 'ERRE' 5;
  74. 'FINS';
  75. * Verification coordonnees identiques
  76. 'SI' (NE_DIF 'NEG' 0);
  77. 'OPTI' 'ECHO' 0;
  78. 'MESS' CHAI2;
  79. 'MESS' '############################################################';
  80. 'MESS' '# LE MAILLAGES MED RELUS N EST PAS CONFORME #';
  81. 'MESS' '# ERREUR CONNECTIVITE #';
  82. 'MESS' '############################################################';
  83. 'OPTI' 'ECHO' 1;
  84. 'ERRE' 5;
  85. 'FINS';
  86. 'FINP';
  87. ************************************************************************
  88. * PROCEDURE POUR VERIFIER UN CHPOINT
  89. ************************************************************************
  90. 'DEBP' VERCHP CHP_CAS*'CHPOINT' CHP_MED*'CHPOINT' NOM_CHP*'MOT';
  91. * A FAIRE !!!
  92. 'FINP';
  93. ************************************************************************
  94. * PROCEDURE POUR VERIFIER UN MCHAML
  95. ************************************************************************
  96. 'DEBP' VERCHM CHM_CAS*'MCHAML' CHM_MED*'MCHAML' LIEU*'MOT' NOM_CHM*'MOT' LENT1*'LISTENTI' LMOT1*'LISTMOTS' XTEMPS*'FLOTTANT';
  97. MOD_CAS ='MODE' ('EXTR' CHM_CAS 'MAILLAGE') 'MECANIQUE' 'CONS' 'MED';
  98. MOD_MED ='MODE' ('EXTR' CHM_MED 'MAILLAGE') 'MECANIQUE' 'CONS' 'MED';
  99. CHM_CAS ='CHAN' 'CONS' CHM_CAS 'MED';
  100.  
  101. CHAI1 ='CHAI' 'MCHAML' ' ' LIEU ' ' NOM_CHM ' ' 'CAST3M';
  102. CHAI2 ='CHAI' 'MCHAML' ' ' LIEU ' ' NOM_CHM ' ' 'LU MED';
  103. 'TRAC' MOD_CAS CHM_CAS 'TITR' CHAI1;
  104. 'TRAC' MOD_MED CHM_MED 'TITR' CHAI2;
  105.  
  106. * Verification : Le champ lu est un champ de coordonnees, on le recree
  107. CHM_TMP='MANU' 'CHML' MOD_MED 'SCAL' 1.0 'TYPE' 'SCALAIRE' LIEU ;
  108. CHM_VER='VIDE' 'MCHAML';
  109. 'REPE' SURI (DIME LMOT1);
  110. ID ='EXTR' LENT1 &SURI;
  111. IMO ='EXTR' LMOT1 &SURI;
  112. CHM_VER=('NOMC' (('COOR' ID CHM_TMP) * (1.D0 + XTEMPS)) IMO) 'ET' CHM_VER ;
  113. 'FIN' SURI;
  114. XDIFF ='MAXI' 'ABS' (CHM_MED - CHM_VER) ;
  115.  
  116. 'SI' (XDIFF 'NEG' 0.D0);
  117. 'OPTI' 'ECHO' 0;
  118. 'MESS' CHAI2;
  119. 'MESS' '############################################################';
  120. 'MESS' '# LE MCHAML MED RELUS N EST PAS CONFORME #';
  121. 'MESS' '# ERREUR DE VALEURS #';
  122. 'MESS' '############################################################';
  123. 'ERRE' 5;
  124. 'FINS';
  125. 'FINP';
  126.  
  127. ***********************************************************************
  128. * Lecture d'un MAILLAGE 'NASTRAN' avec plusieurs types d'elements
  129. ***********************************************************************
  130. TAB2 ='LIRE' 'NAS' ('CHAINE' DIVERS '/nastran_long.nas') ;
  131. TAB21 ='INDE' (TAB2.'MAILLAGES');
  132.  
  133. ***********************************************************************
  134. * Fabrication des MAILLAGES avant d'exporter au format MED *
  135. ***********************************************************************
  136. MAILTOT ='VIDE' 'MAILLAGE';
  137. 'REPE' SURI ('DIME' TAB21);
  138. MAILTOT = MAILTOT 'ET' (TAB2.'MAILLAGES' . (TAB21 . &SURI));
  139. 'FIN' SURI;
  140.  
  141. * Le MAILLAGE MAILTOT contient 11 types d'elements :
  142. * - 29 element(S) de type SEG2
  143. * - 93 element(S) de type TRI3
  144. * - 164 element(S) de type QUA4
  145. * - 271 element(S) de type TET4
  146. * - 36 element(S) de type PRI6
  147. * - 84 element(S) de type CUB8
  148. *
  149. * - 29 element(S) de type TRI6
  150. * - 27 element(S) de type QUA8
  151. * - 271 element(S) de type TE10
  152. * - 24 element(S) de type PR15
  153. * - 12 element(S) de type CU20
  154.  
  155. P1 = 'NOEU' 1 ;
  156. P2 = 'NOEU' 10 ;
  157. P3 = 'NOEU' 100 ;
  158.  
  159. MSEG2 ='ELEM' MAILTOT 'SEG2';
  160. MTRI3 ='ELEM' MAILTOT 'TRI3';
  161. MQUA4 ='ELEM' MAILTOT 'QUA4';
  162. MTET4 ='ELEM' MAILTOT 'TET4';
  163. MPRI6 ='ELEM' MAILTOT 'PRI6';
  164. MCUB8 ='ELEM' MAILTOT 'CUB8';
  165. MTRI6 ='ELEM' MAILTOT 'TRI6';
  166. MQUA8 ='ELEM' MAILTOT 'QUA8';
  167. MTE10 ='ELEM' MAILTOT 'TE10';
  168. MPR15 ='ELEM' MAILTOT 'PR15';
  169. MCU20 ='ELEM' MAILTOT 'CU20';
  170.  
  171. ***********************************************************************
  172. * Sortie MED des MAILLAGES (SIMPLES & COMPLEXES)
  173. ***********************************************************************
  174. 'OPTI' 'SORT' 'MED_MAILLAGE_simple.med';
  175. 'SORT' 'MED' MTRI3 ;
  176.  
  177. 'OPTI' 'SORT' 'MED_MAILLAGE_complexe.med';
  178. 'SORT' 'MED' MAILTOT ;
  179.  
  180. ***********************************************************************
  181. * Sortie MED des CHPOINTS
  182. ***********************************************************************
  183. CHPX1 ='CHAN' 'COMP' ('COOR' 1 MTRI3 ) 'UX';
  184. CHPY1 ='CHAN' 'COMP' ('COOR' 2 MAILTOT) 'UY';
  185.  
  186. CHPTOT= CHPX1 'ET' CHPY1 ;
  187. 'OPTI' 'SORT' 'MED_CHPOIN_simple.med';
  188. 'SORT' 'MED' CHPX1;
  189.  
  190. 'OPTI' 'SORT' 'MED_CHPOIN_complexe.med';
  191. 'SORT' 'MED' CHPTOT;
  192.  
  193. 'OPTI' 'SORT' 'MED_CHPOIN_melange.med';
  194. 'SORT' 'MED' CHPX1 CHPY1 CHPTOT;
  195.  
  196. ***********************************************************************
  197. * Sortie MED des MCHAML
  198. ***********************************************************************
  199. * MCHAML au GRAVITE (1 SOUS-ZONE et 11 SOUS-ZONES)
  200. MOD1a ='MODE' MTRI3 'MECANIQUE' ;
  201. MOD1b ='MODE' MAILTOT 'MECANIQUE' ;
  202. CHA1a ='MANU' 'CHML' MOD1a 'SCAL' 1.0 'GRAVITE';
  203. CHA1b ='MANU' 'CHML' MOD1b 'SCAL' 1.0 'GRAVITE';
  204.  
  205. CHAX1 ='NOMC' ('COOR' 1 CHA1a) 'UX';
  206. CHAY1 ='NOMC' ('COOR' 2 CHA1b) 'UY';
  207.  
  208. 'OPTI' 'SORT' 'MED_MCHAML_GRAVITE_SZ1.med';
  209. 'SORT' 'MED' CHAX1 ;
  210.  
  211. 'OPTI' 'SORT' 'MED_MCHAML_GRAVITE_SZ11.med';
  212. 'SORT' 'MED' CHAY1 ;
  213.  
  214. * MCHAML au NOEUD (1 SOUS-ZONE et 11 SOUS-ZONES)
  215. CHA2a ='MANU' 'CHML' MOD1a 'SCAL' 1.0 'NOEUD';
  216. CHA2b ='MANU' 'CHML' MOD1b 'SCAL' 1.0 'NOEUD';
  217. CHAZ1 ='NOMC' ('COOR' 3 CHA2a) 'UZ';
  218. CHAZ2 ='NOMC' ('COOR' 3 CHA2b) 'UZ';
  219.  
  220. 'OPTI' 'SORT' 'MED_MCHAML_NOEUD_SZ1.med';
  221. 'SORT' 'MED' CHAZ1 ;
  222.  
  223. 'OPTI' 'SORT' 'MED_MCHAML_NOEUD_SZ11.med';
  224. 'SORT' 'MED' CHAZ2;
  225.  
  226. * MCHAML melange (NOEUD & GRAVITE, 1 SOUS-ZONE et 11 SOUS-ZONES)
  227. 'OPTI' 'SORT' 'MED_MCHAML_melange.med';
  228. 'SORT' 'MED' CHAX1 CHAY1 CHAZ1 CHAZ2;
  229.  
  230.  
  231.  
  232. ***********************************************************************
  233. * Sortie MED d'une TABLE de SOUS-TYPE PASAPAS
  234. ***********************************************************************
  235. COO1 COO2 COO3 ='COOR' MAILTOT;
  236. COO1 ='NOMC' COO1 'CX';
  237. COO2 ='NOMC' COO2 'CY';
  238. COO3 ='NOMC' COO3 'CZ';
  239. COOCHP = COO1 'ET' COO2 'ET' COO3 ;
  240.  
  241. COO1 COO2 COO3 ='COOR' CHA1b ;
  242. COO1 ='NOMC' COO1 'MX';
  243. COO2 ='NOMC' COO2 'MY';
  244. COO3 ='NOMC' COO3 'MZ';
  245. COOCHMG = COO1 'ET' COO2 'ET' COO3 ;
  246.  
  247. COO1 COO2 COO3 ='COOR' CHA2b ;
  248. COO1 ='NOMC' COO1 'NX';
  249. COO2 ='NOMC' COO2 'NY';
  250. COO3 ='NOMC' COO3 'NZ';
  251. COOCHMN = COO1 'ET' COO2 'ET' COO3 ;
  252.  
  253. LTPS1 ='PROG' 0.D0 'PAS' 0.5D0 1.5D0 ;
  254. NBTPS ='DIME' LTPS1;
  255.  
  256. TPASAP ='TABL';
  257. TPASAP.'SOUSTYPE'='MOT' 'PASAPAS' ;
  258. TPASAP.'MODELE' = MOD1b ;
  259.  
  260. TPASAP.'TEMPS' ='TABL' ;
  261. TPASAP.'COORDONNEES_CHPOINT1'='TABL' ;'COMM' 'Un seul MSOUPO dans le CHPOINT';
  262. TPASAP.'MCHAML_GRAVI1' ='TABL' ;'COMM' 'Un seul constituant dans le MCHAML aux GRAVITE';
  263. TPASAP.'MCHAML_NOEUD1' ='TABL' ;'COMM' 'Un seul constituant dans le MCHAML aux NOEUDS' ;
  264. 'REPE' SURI NBTPS;
  265. II =&SURI;
  266. Xtps ='EXTR' LTPS1 II ;
  267.  
  268. TPASAP.'TEMPS' . (II - 1) = Xtps ;
  269. TPASAP.'COORDONNEES_CHPOINT1'. (II - 1) =(COOCHP + 1.D0) * ( 1.D0 + Xtps) ;
  270. TPASAP.'MCHAML_GRAVI1' . (II - 1) =(COOCHMG + 1.D0) * ( 1.D0 + Xtps) ;
  271. TPASAP.'MCHAML_NOEUD1' . (II - 1) =(COOCHMN + 1.D0) * ( 1.D0 + Xtps) ;
  272. 'FIN' SURI;
  273.  
  274. * TABLE de SOUSTYPE 'PASAPAS' avec CHPOINT, MCHAML (GRAVITE & NOEUDS)
  275. 'OPTI' 'SORT' 'MED_PASAPAS.med';
  276. 'SORT' 'MED' TPASAP ;
  277.  
  278.  
  279. *#####################################################################*
  280. * Verification relecture des MAILLAGES
  281. *#####################################################################*
  282. TAB1 ='LIRE' 'MED' 'MED_MAILLAGE_simple.med' ;
  283. TAB2 ='LIRE' 'MED' 'MED_MAILLAGE_complexe.med';
  284.  
  285. *#####################################################################*
  286. * Validation relecture des MAILLAGES
  287. *#####################################################################*
  288. 'LIST' TAB1;
  289. MTRI3a = TAB1.'MTRI3' ;
  290. VERMAI MTRI3 MTRI3a 'MTRI3';
  291.  
  292. 'LIST' TAB2;
  293. MAILTOTa= TAB2.'MAILTOT';
  294. MSEG2a = TAB2.'MSEG2' ;
  295. MCU20a = TAB2.'MCU20' ;
  296. MPR15a = TAB2.'MPR15' ;
  297. MTE10a = TAB2.'MTE10' ;
  298. MQUA8a = TAB2.'MQUA8' ;
  299. MTRI6a = TAB2.'MTRI6' ;
  300. MCUB8a = TAB2.'MCUB8' ;
  301. MPRI6a = TAB2.'MPRI6' ;
  302. MTET4a = TAB2.'MTET4' ;
  303. MQUA4a = TAB2.'MQUA4' ;
  304. MTRI3a = TAB2.'MTRI3' ;
  305.  
  306. VERMAI MAILTOT MAILTOTa 'MAILTOT';
  307. VERMAI MSEG2 MSEG2a 'MSEG2' ;
  308. VERMAI MCU20 MCU20a 'MCU20' ;
  309. VERMAI MPR15 MPR15a 'MPR15' ;
  310. VERMAI MTE10 MTE10a 'MTE10' ;
  311. VERMAI MQUA8 MQUA8a 'MQUA8' ;
  312. VERMAI MTRI6 MTRI6a 'MTRI6' ;
  313. VERMAI MCUB8 MCUB8a 'MCUB8' ;
  314. VERMAI MPRI6 MPRI6a 'MPRI6' ;
  315. VERMAI MTET4 MTET4a 'MTET4' ;
  316. VERMAI MQUA4 MQUA4a 'MQUA4' ;
  317. VERMAI MTRI3 MTRI3a 'MTRI3' ;
  318.  
  319. *#####################################################################*
  320. * Verification relecture des CHPOINT
  321. *#####################################################################*
  322. TAB3 ='LIRE' 'MED' 'MED_CHPOIN_simple.med' ;
  323. TAB4 ='LIRE' 'MED' 'MED_CHPOIN_complexe.med';
  324. TAB5 ='LIRE' 'MED' 'MED_CHPOIN_melange.med' ;
  325.  
  326. *#####################################################################*
  327. * Validation relecture des CHPOINT
  328. *#####################################################################*
  329. * CONTROLE VISUEL POUR LE MOMENT, COMPARER LES VALEURS !!! A FAIRE !!!
  330. 'LIST' TAB3;
  331. CHPX2 = TAB3.'CHPX1';
  332. 'TRAC' CHPX1 MTRI3 'TITR' 'CHPOINT_SIMPLE CAST3M';
  333. 'TRAC' CHPX2 TAB3.'MTRI3' 'TITR' 'CHPOINT_SIMPLE LU MED';
  334.  
  335. *Verification : Le champ lu est un champ de coordonnees, on le recree
  336. MMED ='EXTR' CHPX2 'MAILLAGE' ;
  337. MORI ='EXTR' CHPX1 'MAILLAGE' ;
  338. NBMED ='NBEL' MMED;
  339. NBORI ='NBEL' MORI;
  340. 'SI' ('NEG' NBMED NBORI);
  341. 'OPTI' 'ECHO' 0;
  342. 'MESS' '############################################################';
  343. 'MESS' '# LE CHPOINT MED CHPX1 RELUS EST NON CONFORMES AU #';
  344. 'MESS' '# CHPOINT EXPORTE : NOMBRE ELEMENTS INCORRECT #';
  345. CHA1 ='CHAI' '# :' NBORI ':' NBMED ':';
  346. 'MESS' CHA1 ;
  347. 'MESS' '############################################################';
  348. 'OPTI' 'ECHO' 1;
  349. 'ERRE' 5;
  350. 'FINS';
  351.  
  352. CHPX2v ='CHAN' 'COMP' ('COOR' 1 MMED ) 'UX';
  353. ValX2 ='MAXI' 'ABS' (CHPX2 - CHPX2v) ;
  354. 'SI' ('NEG' ValX2 0.D0);
  355. 'OPTI' 'ECHO' 0;
  356. 'MESS' '############################################################';
  357. 'MESS' '# LE CHPOINT MED CHPX1 RELUS EST NON CONFORMES AU #';
  358. 'MESS' '# CHPOINT EXPORTE : VALEURS INCORRECTES #';
  359. 'MESS' '############################################################';
  360. 'OPTI' 'ECHO' 1;
  361. 'ERRE' 5;
  362. 'FINS';
  363.  
  364. 'LIST' TAB4;
  365. CHPTO2 = TAB4.'CHPTOT_1' 'ET' TAB4.'CHPTOT_2';
  366. CHPX2 ='CHAN' 'COMP' ('COOR' 1 TAB4.'MTRI3' ) 'UX';
  367. CHPY2 ='CHAN' 'COMP' ('COOR' 2 TAB4.'MAILTOT') 'UY';
  368. 'TRAC' CHPX1 MTRI3 'TITR' 'CHPOINT_COMPLEXE CAST3M, UX';
  369. 'TRAC' CHPX2 TAB4.'MTRI3' 'TITR' 'CHPOINT_COMPLEXE LU MED, UX';
  370. 'TRAC' CHPY1 MAILTOT 'TITR' 'CHPOINT_COMPLEXE CAST3M, UY';
  371. 'TRAC' CHPY2 TAB4.'MAILTOT' 'TITR' 'CHPOINT_COMPLEXE LU MED, UY';
  372.  
  373. *Verification : Le champ lu est un champ de coordonnees, on le recree
  374. CHPX2v ='CHAN' 'COMP' ('COOR' 1 ('EXTR' CHPX2 'MAILLAGE')) 'UX';
  375. CHPY2v ='CHAN' 'COMP' ('COOR' 2 ('EXTR' CHPY2 'MAILLAGE')) 'UY';
  376. ValX2 ='MAXI' 'ABS' (CHPX2 - CHPX2v);
  377. ValY2 ='MAXI' 'ABS' (CHPY2 - CHPY2v);
  378.  
  379. 'SI' ('NEG' ValX2 0.D0);
  380. 'OPTI' 'ECHO' 0;
  381. 'MESS' '############################################################';
  382. 'MESS' '# LE CHPOINT MED CHPX1 RELUS EST NON CONFORMES AU #';
  383. 'MESS' '# CHPOINT EXPORTE : VALEURS INCORRECTES #';
  384. 'MESS' '############################################################';
  385. 'OPTI' 'ECHO' 1;
  386. 'ERRE' 5;
  387. 'FINS';
  388. 'SI' ('NEG' ValY2 0.D0);
  389. 'OPTI' 'ECHO' 0;
  390. 'MESS' '############################################################';
  391. 'MESS' '# LE CHPOINT MED CHPY1 RELUS EST NON CONFORMES AU #';
  392. 'MESS' '# CHPOINT EXPORTE : VALEURS INCORRECTES #';
  393. 'MESS' '############################################################';
  394. 'OPTI' 'ECHO' 1;
  395. 'ERRE' 5;
  396. FINS ;
  397.  
  398. 'LIST' TAB5;
  399. CHPX2 = TAB5.'CHPX1';
  400. CHPY2 = TAB5.'CHPY1';
  401. CHPTOX ='EXCO' (TAB5.'CHPTOT_1' 'ET' TAB5.'CHPTOT_2') 'UX' 'UX';
  402. CHPTOY ='EXCO' (TAB5.'CHPTOT_1' 'ET' TAB5.'CHPTOT_2') 'UY' 'UY';
  403. 'TRAC' CHPX1 MTRI3 'TITR' 'MED CHPOIN MELANGE : CHPX1 CAST3M' ;
  404. 'TRAC' CHPX2 TAB5.'MTRI3' 'TITR' 'MED CHPOIN MELANGE : CHPX1 LU MED' ;
  405. 'TRAC' CHPY1 MAILTOT 'TITR' 'MED CHPOIN MELANGE : CHPY1 CAST3M' ;
  406. 'TRAC' CHPY2 TAB5.'MAILTOT' 'TITR' 'MED CHPOIN MELANGE : CHPY1 LU MED' ;
  407. 'TRAC' CHPX1 MTRI3 'TITR' 'MED CHPOIN MELANGE : CHPTOT CAST3M, UX';
  408. 'TRAC' CHPTOX TAB5.'MTRI3' 'TITR' 'MED CHPOIN MELANGE : CHPTOT LU MED, UX';
  409. 'TRAC' CHPY1 MAILTOT 'TITR' 'MED CHPOIN MELANGE : CHPTOT CAST3M, UY';
  410. 'TRAC' CHPTOY TAB5.'MAILTOT' 'TITR' 'MED CHPOIN MELANGE : CHPTOT LU MED, UY';
  411.  
  412. *#####################################################################*
  413. * Verification relecture des MCHAML
  414. *#####################################################################*
  415. TAB6 ='LIRE' 'MED' 'MED_MCHAML_GRAVITE_SZ1.med' ;
  416. TAB7 ='LIRE' 'MED' 'MED_MCHAML_GRAVITE_SZ11.med';
  417. TAB8 ='LIRE' 'MED' 'MED_MCHAML_NOEUD_SZ1.med' ;
  418. TAB9 ='LIRE' 'MED' 'MED_MCHAML_NOEUD_SZ11.med' ;
  419. TAB10='LIRE' 'MED' 'MED_MCHAML_melange.med' ;
  420.  
  421. *#####################################################################*
  422. * Validation relecture des MCHAML
  423. *#####################################################################*
  424. 'LIST' TAB6;
  425. CHAX1a = TAB6.'CHAX1';
  426. VERCHM CHAX1 CHAX1a 'GRAVITE' 'CHAX1' (LECT 1) (MOTS 'UX') 0.D0;
  427.  
  428. 'LIST' TAB7;
  429. CHAY1a = TAB7.'CHAY1';
  430. VERCHM CHAY1 CHAY1a 'GRAVITE' 'CHAY1' (LECT 2) (MOTS 'UY') 0.D0;
  431.  
  432. 'LIST' TAB8;
  433. CHAZ1a = TAB8.'CHAZ1';
  434. VERCHM CHAZ1 CHAZ1a 'NOEUD' 'CHAZ1' (LECT 3) (MOTS 'UZ') 0.D0;
  435.  
  436. 'LIST' TAB9;
  437. CHAZ2a = TAB9.'CHAZ2';
  438. VERCHM CHAZ2 CHAZ2a 'NOEUD' 'CHAZ2' (LECT 3) (MOTS 'UZ') 0.D0;
  439.  
  440. 'LIST' TAB10;
  441. CHAX1a = TAB10.'CHAX1';
  442. CHAY1a = TAB10.'CHAY1';
  443. CHAZ1a = TAB10.'CHAZ1';
  444. CHAZ2a = TAB10.'CHAZ2';
  445.  
  446. VERCHM CHAX1 CHAX1a 'GRAVITE' 'CHAX1' (LECT 1) (MOTS 'UX') 0.D0;
  447. VERCHM CHAY1 CHAY1a 'GRAVITE' 'CHAY1' (LECT 2) (MOTS 'UY') 0.D0;
  448. VERCHM CHAZ1 CHAZ1a 'NOEUD' 'CHAZ1' (LECT 3) (MOTS 'UZ') 0.D0;
  449. VERCHM CHAZ2 CHAZ2a 'NOEUD' 'CHAZ2' (LECT 3) (MOTS 'UZ') 0.D0;
  450.  
  451. *#####################################################################*
  452. * Verification relecture des TABLES de SOUSTYPE 'PASAPAS'
  453. *#####################################################################*
  454. TAB11='LIRE' 'MED' 'MED_PASAPAS.med';
  455. 'LIST' TAB11;
  456.  
  457. *#####################################################################*
  458. * Validation relecture des TABLES de SOUSTYPE 'PASAPAS'
  459. *#####################################################################*
  460.  
  461. FIN;
  462.  
  463.  
  464.  
  465.  
  466.  
  467.  
  468.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales