Télécharger dyna_nl3.dgibi

Retour à la liste

Numérotation des lignes :

  1. * fichier : dyna_nl3.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4.  
  5.  
  6. * Test Dyna_nl3.dgibi: Jeux de données *
  7. * ------------------------------------ *
  8. * *
  9. complet = vrai;
  10. *
  11. *************************************************
  12. * pour calcul complet mettre complet à : vrai;
  13. ***************************************************
  14. *======================================================
  15. * TEST DES LA PRESSION SUIVEUSE EN DYNAMIQUE
  16. *
  17. * FLOTTEMENT D'UNE POUTRE ENCASTREE-LIBRE
  18. *
  19. * On etudie la reponse de la poutre à un lacher quand
  20. * elle est soumise à une force de compression axiale
  21. * legerement superieure à la valeur theorique de la
  22. * force critique de flottement (Fcr = 20.05*E*I/l**2)
  23. * On doit obtenir une reponse d'amplitude croissante.
  24. *
  25. *******************************************************
  26. * ==
  27. * /|aa___________________bb ==
  28. * /|______________________|<----- F ==
  29. * /| cc ==
  30. * EQUIVALENT A /| ==
  31. * dd / | ==
  32. * /|aa_________________bb|<-- ==
  33. * /|_____________________|<-- PRESSION ==
  34. * /| |<-- ==
  35. * ee |/ ff ==
  36. * ==
  37. * ==
  38. *======================================================
  39. graph = faux;
  40. option dime 3 elem seg2 ;
  41. *tri3 ;
  42. *======================================================
  43. * definition de la geometrie
  44. * la force suiveuse est modelisee par une pression équi
  45. * valente appliquée sur une petite plaque fixée à l'ex
  46. * trémité de la poutre
  47. *======================================================
  48. aa = 0 0 0 ;
  49. bb = 12 0 0;
  50. cc = 12 0.01 0.01 ;
  51. dd = 12 0.01 -0.01 ;
  52. ee = 12 -0.01 -0.01 ;
  53. ff = 12 -0.01 0.01 ;
  54. dens1 = 10 ;
  55. lig1 = aa d dens1 bb ;
  56. lig2 = cc d 2 dd d 2 ee d 2 ff d 2 cc ;
  57. surf1 = surf plan lig2 ;
  58. geo = lig1 et surf1 ;
  59. elim 1.e-4 geo ;
  60. *=====================================================
  61. *definition des conditions aux limites
  62. * encastrement à la base de la poutre et mouvement
  63. * dans le plan xOy
  64. *=====================================================
  65. cl1 = bloq rota depla aa ;
  66. cl2 = bloq uz rx ry surf1 ;
  67. cl3 = bloq bb uy ;
  68. *======================================================
  69. * definition du modele, du materiau et
  70. * des caracteristiques
  71. *======================================================
  72. mo1 = mode lig1 mecanique pout ;
  73. mo2 = mode surf1 mecanique coq3 ;
  74. ma1 = mate mo1 youn 2.1e7 nu 0.3 rho 7.8e-3 ;
  75. ma2 = mate mo2 youn 2.1e10 nu 0.3 rho 7.8e-10 ;
  76. ca1 = cara mo1 sect 0.15 inry 2.8125e-4 inrz 2.8125e-4
  77. tors 1.e-5;
  78. ca2 = cara mo2 epai 0.01 ;
  79. mat1 = ma1 et ca1 ;
  80. mat2 = ma2 et ca2 ;
  81. *
  82. * Chargement de pression
  83. MOPRE = 'MODE' SURF1 'CHARGEMENT' 'PRESSION' 'COQ3' ;
  84. CHMZ = pres MOPRE pres (2050781.25*1.05) ;
  85. *
  86. TTPS = 'TABL' ;
  87. TTPS. 0 = 0. ;
  88. TTPS. 1 = 0.00001 ;
  89. TTPS. 2 = 100. ;
  90. TPRE = 'TABL' ;
  91. TPRE. 0 = 0.*CHMZ ;
  92. TPRE. 1 = 1.*CHMZ ;
  93. TPRE. 2 = TPRE. 1 ;
  94. CHAA = 'CHAR' 'PRES' TTPS TPRE ;
  95. *
  96. mattotal = mat1 et mat2 ;
  97. mototal = mo1 et mo2 et mopre ;
  98. *======================================================
  99. * calcul des matrices de rigidite et de masse
  100. *======================================================
  101. ri1 = rigi mototal mattotal ;
  102. ritotal = ri1 et cl1 et cl2 ;
  103. masst = masse mototal mattotal ;
  104. *======================================================
  105. * chargement par pression equivalente a la force
  106. * critique de flottement pondérée par un coefficient
  107. * de 1.05 pour se placer legerement au dessus de
  108. * l'instabilité.
  109. *
  110. * on impose un petit deplacement transverse pour
  111. * perturber le systeme.
  112. *======================================================
  113. fo2 = depi cl3 .01 ;
  114. fo0 = manu chpo surf1 1 p (2050781.25*1.05)
  115. nature discret ;
  116. *======================================================
  117. * calcul non lineaire
  118. * calcul statique sous la force de compression et la
  119. * force transversale de perturbation
  120. *======================================================
  121. dt = 0.00001 ;
  122. li1 = prog 0. dt ;
  123. li2 = prog 0. 1 ;
  124. ev = evol manu t (li1 ) f(t) (li2 ) ;
  125. fco = char dimp fo2 ev ;
  126. lis1a = prog 0. pas (dt/5) dt ;
  127.  
  128.  
  129. tab3 = table ;
  130. tab3.grands_deplacements = vrai ;
  131. tab3.chargement = fco et chaa ;
  132. tab3.blocages_mecaniques = cl1 et cl2 et cl3 ;
  133. tab3.modele = mototal ;
  134. tab3.caracteristiques = mattotal ;
  135. tab3.temps_calcules = lis1a ;
  136. tab3.precision = 1e-6 ;
  137. tab3.deltaiter = 20 ;
  138. tab3.maxdefor=1e-3;
  139. tab3.k_sigma=faux;
  140. * raideur negative ==>
  141. *tab3.'STABILITE' = faux;
  142. *tab3.hypothese_deformations='LINEAIRE';
  143.  
  144. *optio veri 1;
  145. pasapas tab3 ;
  146.  
  147. oeil = 0 0 10000 ;
  148. dim1 = dime (tab3.deplacements) ;
  149. lisx = prog ; lisy = prog ;
  150. repeter bou1 dim1 ;
  151. n = &bou1 - 1 ;
  152. uy1 = extr tab3.deplacements.n 'UY' bb ;
  153. lisy = lisy et (prog uy1) ;
  154. lisx = lisx et (prog tab3.temps. n);
  155. def1 = defo tab3.deplacements.n geo 100 ;
  156. si (&bou1 ega 1) ; deft = def1 ; sinon ;
  157. deft = deft et def1 ; finsi ;
  158. fin bou1 ;
  159. ev1 = evol manu 'temps' lisx 'depl' lisy ;
  160. si graph ; trac deft oeil cach anime ; finsi ;
  161.  
  162.  
  163. *======================================================
  164. * calcul non lineaire dynamique
  165. *======================================================
  166. * definition de l'évolution du chargement
  167. * durée de la phase de chargement statique :dt
  168.  
  169. ev2 = evol manu (prog dt 100) (prog 1 1 ) ;
  170. *
  171. *fncons = char psui fo0 ev2 ;
  172.  
  173. si complet;
  174. lis1c = prog dt pas .0003 .045 ;
  175. sinon;
  176. lis1c = prog dt pas .001 0.005;
  177. finsi;
  178. ffbi= force (0 0 0) dd;
  179. fbidon = 'CHAR' 'MECA' ffbi ev2;
  180. tab3.'CHARGEMENT'= fbidon et chaa ;
  181. vv = manu chpo ( surf1 et lig1 ) 1 'UX' 0.;
  182. tab3.'VITESSES' = table;
  183. nso= dime tab3.'TEMPS'; tab3.'VITESSES'. ( nso + 1 ) = vv;
  184. tab3. 'CONTINUATION' . 'VITESSES' = vv;
  185. tab3.'ACCELERATIONS' = table;
  186. tab3.'ACCELERATIONS'. ( nso + 1 ) = vv;
  187. tab3. 'CONTINUATION' . 'ACCELERATIONS' = vv;
  188. tab3.blocages_mecaniques = cl1 et cl2 ;
  189. tab3.dynamique = vrai ;
  190. tab3.temps_calcules = lis1c ;
  191. tab3.hypothese_deformations='LINEAIRE';
  192.  
  193. pasapas tab3 ;
  194.  
  195. *====================================================
  196. * exploitation des resultats : deplacement de l'
  197. * extrémité de la poutre (point bb)
  198. *====================================================
  199.  
  200. dim1 = dime (tab3.deplacements) ;
  201. lisx = prog ; lisy = prog ;
  202. repeter bou1 dim1 ;
  203. n = &bou1 - 1 ;
  204. uy1 = extr tab3.deplacements.n 'UY' bb ;
  205. lisy = lisy et (prog uy1) ;
  206. lisx = lisx et (prog tab3.temps. n);
  207. fin bou1 ;
  208. ev1 = evol manu 'temps' lisx 'depl' lisy ;
  209. list lisy;
  210. si graph ; dess ev1 ; finsi ;
  211.  
  212. * la reference pour le test est le resultat d'une
  213. * certaine version de C2000
  214. dmax = maxi abs lisy ; list dmax ;
  215. si complet ;
  216. valtes = 5.8565;
  217. sinon;
  218. valtes = .082;
  219. finsi;
  220. err1 = abs ((dmax - valtes)/valtes);
  221. list err1 ;
  222. si (err1 > .05) ; erreur 5 ;
  223. sinon ; erre 0 ; finsi ;
  224. fin ;
  225.  
  226.  
  227.  
  228.  
  229.  
  230.  
  231.  
  232.  
  233.  
  234.  
  235.  
  236.  
  237.  
  238.  
  239.  
  240.  
  241.  
  242.  
  243.  
  244.  
  245.  
  246.  
  247.  
  248.  
  249.  
  250.  
  251.  
  252.  
  253.  
  254.  
  255.  
  256.  
  257.  
  258.  
  259.  
  260.  
  261.  
  262.  
  263.  
  264.  
  265.  
  266.  
  267.  
  268.  
  269.  
  270.  
  271.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales