Exemples de jeux de données Cast3M

* fichier waam0.dgibi
* section : maillage
*----------------------------------------------------------------------*
*                         W A A M 0 . D G I B I                        *
*----------------------------------------------------------------------*
* Objet :                                                              
* -------
*
*  Ce Dgibi a pour but de tester le fonctionnement des procedures :
*      - SOUDAGE : definition d'une sequence de fabrication additive
*                  ou de soudage ;
*      - WAAM    : maillage d'une sequence de fabrication additive. 
*  Les affichages permettent de verifier les resultats.
*
*  Trois sequences de fabrication "academiques" sont simulees :
*      - le depot d'un mur rectiligne ;
*      - la realisation d'un tube ;
*      - la realisation d'une "forme libre" ;
*      - la realisation d'une piece en 3 "PARTs".
*
*----------------------------------------------------------------------*
opti dime 3 elem cub8 ;
 
* Pour activer les affichages, mettre IG1 a VRAI ;
ig1      = faux ;
 
*opti trac psc eptr 5 ;
 
*---------------------- Sequences de fabrication ----------------------*
 
* Parametres de fabrication :
debi1    = pi*0.6e-3*0.6e-3*10./60. ;
larg1    = 6.e-3 ;
 
* TAB1   : Table de fabrication du mur
tab1                        = tabl ;
tab1.vitesse_de_soudage     = 10.e-3 ;
tab1.vitesse_de_deplacement = 20.e-3 ;
tab1.puissance_de_soudage   = 3.e3 ;
tab1.debit_de_fil           = debi1 ;
tab1.orientation_soudure    = (0 0 1) ;
tab1.largeur_de_passe       = larg1 ;
 
* TAB2   : table de fabrication du tube
tab2                        = tabl ;
tab2.vitesse_de_soudage     = 10.e-3 ;
tab2.vitesse_de_deplacement = 20.e-3 ;
tab2.puissance_de_soudage   = 3.e3 ;
tab2.debit_de_fil           = debi1 ;
tab2.orientation_soudure    = (0 0 1) ;
tab2.largeur_de_passe       = larg1 ;
 
* TAB3   : table de fabrication de la forme libre
tab3                        = tabl ;
tab3.vitesse_de_soudage     = 10.e-3 ;
tab3.vitesse_de_deplacement = 20.e-3 ;
tab3.puissance_de_soudage   = 3.e3 ;
tab3.debit_de_fil           = debi1 ;
tab3.orientation_soudure    = (0 0 1) ;
tab3.largeur_de_passe       = larg1 ;
 
* TAB4   : table de fabrication de la forme en 3 parts
TAB4                        = tabl ;
TAB4.vitesse_de_soudage     = 10.e-3 ;
TAB4.vitesse_de_deplacement = 20.e-3 ;
TAB4.puissance_de_soudage   = 3.e3 ;
TAB4.debit_de_fil           = debi1 ;
TAB4.orientation_soudure    = (0 0 1) ;
TAB4.largeur_de_passe       = larg1 ;
puis42                      = 1.5 * 6.e3 ;
debi42                      = 1.5 * debi1 ;
larg42                      = 1.5 * larg1 ;
vite43                      = 0.5 * 10.e-3 ; 
larg43                      = 2.0 * larg1 ;
 
* Point de soudure initial :
soudage tab1 point 1. ;
soudage tab2 point 1. puis 6.e3 ;
soudage tab3 point 1. puis 6.e3 ;
soudage tab4 point 1. ;
 
* Repetition sequence de 2 passes en AR :
nb1      = 5 ;
repe b1 nb1 ;
 
* Vitesse + lente a la 1ere passe :
  si (&b1 ega 1) ;
    soudage tab1 passe droi (+100.e-3 0 0) vite 5.e-3 puis 4.e3 debi (0.5*debi1) ;
    lign1    = tab1.trajectoire ;
    p1       = (50.e-3 50.e-3 0) ;
    p2       = (0      50.e-3 0) ;
  sino ;
    soudage tab1 passe droi (+100.e-3 0 0) ;
  fins ;
  dh1      = debi1 / (tab1.vitesse_de_soudage) / larg1 ;
 
* 1er deplacement vertical :
  soudage tab1 depla couche pause (dh1 / 16.e-3) ;
 
* Passe retour option MAIL (pour tester) :
  pc1      = tab1.trajectoire poin (nbno tab1.trajectoire) ;
  pl1      = lign1 poin 1 ;
  lign2    = lign1 plus (pc1 moin pl1) ;
  lign2    = lign2 syme point pc1 ;
  elim (pc1 et lign2) 1.e-6 ;
  soudage tab1 passe mail lign2 ;
 
* Passes du tube :
  si (&b1 ega 1) ;
    repe b2 4 ;
      soudage tab2 passe cerc p1 p2 10 vite 5.e-3 puis 5.e3 ;
      P1  p2   = p1  p2 tour (0 0 0) (0 0 1) 90. ;
    fin b2 ;
  sino ;
    repe b2 4 ;
      soudage tab2 passe cerc p1 p2 10 ;
      P1  p2   = p1  p2 tour (0 0 0) (0 0 1) 90. ;
    fin b2 ;
  fins ;
  dh2      = debi1 / (tab2.vitesse_de_soudage) / larg1 ;
 
* Dernier deplacement vertical si pas derniere sequence :
  si (&b1 neg nb1) ;
    soudage tab1 depla couche ;
    soudage tab2 depla couche ;
    soudage tab2 depla cerc p1 p2 1 ;
    P1  p2   = p1  p2 tour (0 0 0) (0 0 1) 90. ;
  fins ;
 
* Passes forme libre :
  soudage tab3 passe droi (0 -100.e-3 0) ;
  soudage tab3 passe cerc (20.e-3 -20.e-3 0.) (20.e-3 0. 0.) 10 ;
  soudage tab3 passe droi (+100.e-3 0 0) ;
  soudage tab3 passe cerc (20.e-3 +20.e-3 0.) (0. 20.e-3 0.) 10 ;
  soudage tab3 passe droi (0 +100.e-3 0) ;
  soudage tab3 passe droi (+120.e-3 -120.e-3 0) ;
  soudage tab3 depla droi (0 0 0) abso ;
  soudage tab3 depla droi (&b1*(0 0 dh1)) couche ;
 
* Composant en 3 parts :
  soudage tab4 passe droi (-50.e-3 0 0) part 1 ;
  soudage tab4 passe droi (0 -100.e-3 0) ;
  soudage tab4 passe droi (+50.e-3 0 0) ;
  soudage tab4 depla droi (0.5 * (larg42 - larg1) * (0 -1 0)) ;
 
  soudage tab4 passe droi (+60.e-3 0 0) larg larg42 puis puis42 debi debi42 part 2 couche ;
  soudage tab4 passe droi (0 (larg42 - larg1 + 100.e-3) 0) larg larg42 puis puis42 debi debi42 ;
  soudage tab4 passe droi (-60.e-3 0 0) larg larg42 puis puis42 debi debi42 ;
  soudage tab4 depla droi (0.5 * larg42 * (0 -1 0)) ;
 
  soudage tab4 passe droi (0 (larg1 - 100.e-3) 0) larg larg43 vite vite43 part 3 couche ;
  soudage tab4 depla droi (0.5 * larg1 * (0 -1 0)) part 1 ;
 
  soudage tab4 depla couche ;
  soudage tab4 passe droi (-50.e-3 0 0) ;
  soudage tab4 passe droi (0 +100.e-3 0) ;
  soudage tab4 passe droi (+50.e-3 0 0) ;
  soudage tab4 depla droi (0.5 * (larg42 - larg1) * (0 +1 0)) ;
 
  soudage tab4 passe droi (+60.e-3 0 0) larg larg42 puis puis42 debi debi42 part 2 couche ;
  soudage tab4 passe droi (0 (larg1 - larg42 - 100.e-3) 0) larg larg42 puis puis42 debi debi42 ;
  soudage tab4 passe droi (-60.e-3 0 0) larg larg42 puis puis42 debi debi42 ;
  soudage tab4 depla droi (0.5 * larg42 * (0 +1 0)) ;
 
  soudage tab4 passe droi (0 (100.e-3 - larg1) 0) larg larg43 vite vite43 part 3 couche ;
  soudage tab4 depla droi (0.5 * larg1 * (0 +1 0)) part 1 ;
 
  soudage tab4 depla couche larg larg1 ;
 
fin b1 ;
soudage tab1 point 30. puis 0. ;
 
si ig1 ;
 
* Mur :
trac tab1.trajectoire           titr 'trajectoire sequence mur' ;
dess tab1.evolution_deplacement titr 'deplacement sequence mur' ;
dess tab1.evolution_puissance   titr 'puissance sequence mur' ;
dess tab1.evolution_debit       titr 'debit sequence mur' ;
 
* Tube :
trac tab2.trajectoire           titr 'trajectoire sequence tube' ;
dess tab2.evolution_deplacement titr 'deplacement sequence tube' ;
dess tab2.evolution_puissance   titr 'puissance sequence tube' ;
dess tab2.evolution_debit       titr 'debit sequence tube' ;
 
* Forme libre :
trac tab3.trajectoire           titr 'trajectoire sequence UN' ;
dess tab3.evolution_deplacement titr 'deplacement sequence UN' ;
dess tab3.evolution_puissance   titr 'puissance sequence UN' ;
dess tab3.evolution_debit       titr 'debit sequence UN' ;
 
* Composant multicouches a 3 parts :
trac tab4.trajectoire           titr 'trajectoire sequence composant multicouches a 3 parts' ;
dess tab4.evolution_deplacement titr 'deplacement sequence composant multicouches a 3 parts' ;
dess tab4.evolution_puissance   titr 'puissance sequence composant multicouches a 3 parts' ;
dess tab4.evolution_debit       titr 'debit sequence composant multicouches a 3 parts' ;
 
fins ;
 
*------------------------- Maillage avec WAAM -------------------------*
 
* Mur :
tab21    = waam tab1 mail pas 5.e-3 larg larg1 dens 2.e-3 ;
elim tab21.maillage 1.e-5 ;
 
* Tube :
tab22    = waam tab2 mail pas 5.e-3 larg larg1 dens 2.e-3 ;
elim tab22.maillage 1.e-5 ;
 
* Forme libre :
tab32    = waam tab3 mail pas 5.e-3 larg larg1 dens 2.e-3 ;
elim tab32.maillage 1.e-5 ;
 
si ig1 ;
  trac cach tab21.maillage titr 'Maillage du mur' ;
  trac cach tab22.maillage titr 'Maillage du tube' ;
  trac cach tab32.maillage titr 'Maillage de la forme libre' ;
 
  waam tab21 visu cach (tab1.trajectoire) ;
  waam tab22 visu cach (tab2.trajectoire) ;
  waam tab32 visu cach (tab3.trajectoire) ;
fins ;
 
*---------------- Tests definition orientation soudure ----------------*
 
* procedure test DIRE DIRL orthogonaux
debp orthodir tab1 ;
cgdirx = tab1.evolution_orientation ;
ltps1  = extr cgdirx lree dire ;
ltps2  = extr cgdirx lree dirl ;
si ((dime ltps2) > (dime ltps1)) ; ltps1 = ltps2 ; fins ;
repe bx (dime ltps1) ;
  tpsi1  = extr ltps1 &bx ;
  pdii1  = tire cgdirx dire tpsi1 ;
  pdli1  = tire cgdirx dirl tpsi1 ;
  mess '*** temps =' tpsi1 ; 
  si ((psca pdii1 pdli1) > 1.e-3) ; erre 21 ; fins ;
fin bx ;
finp ;
 
tfab1 = table ; 
tfab1 . puissance_de_soudage = 1000. ; 
tfab1 . vitesse_de_soudage   = 5.e-3 ; 
tfab1 . debit_de_fil         = 8.e-6 ; 
tfab1 . temps_de_coupure     = 1. ;
tfab1 . orientation_soudure  = (0 1 1) ; 
 
* POINT :
 
Pdir1    = tfab1 . orientation_soudure ;
soudage tfab1 point 1. ; 
 
soudage tfab1 point 10. puis 0. ;
 
Pdir1    = (0 0 1) ;
soudage tfab1 point 1. dire Pdir1 ;
 
soudage tfab1 point 10. puis 0. ;
 
* PASSE DROIT :
 
Pdir1    = (0 1 0) ;
soudage tfab1 passe droi (1 0 0) dire Pdir1 ;
 
* Test traitement arguments option DEPLA avec argument DIRE inutile :
Pdir1    = (0 0 1) ;
soudage tfab1 depla droi (0 1 0) dire Pdir1 vite 0.02 ;
 
Pdir1    = (0 0 1) ;
Ldir1    = enum (0 0 1) (0 1 0) ;
soudage tfab1 point 1. dire Pdir1 ;
soudage tfab1 passe droi (-1 0 0) dire Ldir1 ;
 
soudage tfab1 depla droi (0 1 0) vite 0.02 ;
 
* PASSE CERC :
 
Pdir1    = (0 0 1) ;
soudage tfab1 passe cerc (-0.5 0.5 0) (-0.5 0 0) 3 dire Pdir1 ;
soudage tfab1 passe cerc (-0.5 0.5 0) (0 +0.5 0) 3 dire Pdir1 ;
 
soudage tfab1 depla droi (0 -1 0) vite 0.02 ;
 
Pdir1    = (0 0 1) ;
soudage tfab1 passe cerc (-0.5 -0.5 0) (0 -0.5 0) 3 dire radext Pdir1 ;
 
* PASSE MAIL :
 
soudage tfab1 point 200. puis 0. ;
 
pi1      = tfab1.trajectoire poin (nbno tfab1.trajectoire) ;
vi1      = 1 -1 0 ;
lign1    = pi1 droi 2 (pi1 plus vi1) ;
Ldir1    = enum (0 0 1) (pvec (0 0 1) vi1) ;
 
soudage tfab1 passe mail lign1 dire Ldir1 ;
 
lign2    = (lign1 plus vi1) syme plan (pi1 plus vi1) (pi1 plus vi1 plus (0 1 0)) (pi1 plus vi1 plus (0 0 1)) ;
Ldir1    = enum (pvec (0 0 1) vi1) (0 0 1) ;
 
soudage tfab1 passe mail lign2 dire Ldir1 ;
 
Pdir1    = Ldir1 extr 2 ;
lign3    = (lign2 poin (nbno lign2)) droi 1 (0 -1 0) ;
soudage tfab1 passe mail lign3 dire Pdir1 ;
 
soudage tfab1 depla droi (0 0 1) vite 0.01 ;
 
lign4    = (lign3 plus (0 0 1)) inve ;
soudage tfab1 passe mail lign4 ;
 
soudage tfab1 point 10. puis 0. ;
 
lign5    = (lign4 poin (nbno lign4)) droi 2 (0 0 0) ;
ldir1    = enum (0 1 1) (0 0 1) ;
soudage tfab1 passe mail lign5 dire ldir1 ;
 
orthodir tfab1 ;
*list tfab1.evolution_orientation ; 
*list (tire tfab1.evolution_orientation dire 2551.0) ;
 
*-------------------- Tests definition macro depot --------------------*
 
* Maillage par macro-depot :
tab14    = waam tab1 macro long (50.e-3) haut 1 ;
tab24    = waam tab2 macro haut 2 dens 3.e-3 ;
tab34    = waam tab3 macro haut 3 temp maxi 120. ;
tab44    = waam tab4 macro haut 4 ;
 
si ig1 ;
  trac face tab14 . maillage titr 'Maillage du mur par macro-depot' ;
  trac face tab24 . maillage titr 'Maillage du tube par macro-depot' ;
  trac face tab34 . maillage titr 'Maillage de la forme libre par macro-depot' ;
  trac face tab44 . maillage titr 'Maillage des 3 parts par macro-depot' ;
fins ;
 
*------------------   F I N   W A A M 0 . D G I B I   -----------------*
fin ;