Télécharger la plaquette Cast3M


fr en

Télécharger tran15.dgibi

Retour à la liste

Numérotation des lignes : 

  1. * fichier :  tran15.dgibi
  2.  
  3. * Calcul avec des elements 'JOI1' (support 'SEG2') et 'POI1'
  4.  
  5. *******************************************
  6. *******************************************
  7.  
  8. *******************************************
  9. *    Test tran15.dgibi: jeux de données   *
  10. *    ---------------------------------    *
  11. *                                         *
  12. *   THERMIQUE TRANSITOIRE LINEAIRE EN 2D  *
  13. *     CONDUCTION                          *
  14. *     CONVECTION                          *
  15. *                                         *
  16. *   - Verification de CAPA, COND et CONV  *
  17. *     Pour les elements JOI1 et POI1 en   *
  18. *     formulation THERMIQUE               *
  19. *                                         *
  20. *                                         *
  21. *  Description                            *
  22. *  -----------                            *
  23. *  Les noeuds de la surface S1 echangent  *
  24. *  avec le point POI2 par le bias de JOI1.*
  25. *                                         *
  26. *  Coefficient de CONDUCTION 'KT' sur les *
  27. *       elements 'JOI1'                   *
  28. *  Coefficient de CONVECTION 'H' sur le   *
  29. *       point POI2 avec une temperature   *
  30. *       exterieure 'TC'                   *
  31. *  Température initiale T_ini             *
  32. *                                         *
  33. *******************************************
  34.  
  35. 'OPTI' 'DIME' 2 'ELEM' 'QUA4' ;
  36. 'OPTI' 'TRAC' 'PSC' ;
  37.  
  38. *******************************************
  39. *** Parametrage du jeu de donnees
  40. *******************************************
  41.  Dt    = 100.     ;
  42.  Duree = 30000.   ;
  43.  
  44.  Val_KT   = 5.    ;
  45.  Val_Mass = 4.    ;
  46.  Val_Cp   = 4200. ;
  47.  Val_H    = 10.   ;
  48.  Temp_EXT = 15.   ;
  49.  
  50. *******************************************
  51. *** MAILLAGE
  52. *******************************************
  53.  P1 = 0. 0. ;
  54.  P2 = 1. 0. ;
  55.  L1 ='DROI' 1 P1 P2      ;
  56.  L2 = L1 'PLUS' (0. 0.2) ;
  57.  S1 ='REGL' 1 L1 L2      ;
  58.  
  59.  POI1 ='CHAN' 'POI1' S1 ;
  60.  POI2 = 2. 2. ;
  61.  
  62. *Creation du MAILLAGE de SEG2 reliant les noeuds de S1 aux noeuds de POI1
  63.  NBPOI   ='NBEL' POI1;
  64.  MAILJOI1='VIDE' 'MAILLAGE';
  65. 'REPE' SURPOI1 NBPOI;
  66.    MAILJOI1 = MAILJOI1 'ET' ('DROI' 1  ('POIN' POI1 &SURPOI1) POI2) ;
  67. 'FIN' SURPOI1 ;
  68.  MAILJOI1 = MAILJOI1 'COUL' 'BLEU' ;
  69.  
  70. *******************************************
  71. *** MODELE & CARACTERISTIQUES
  72. *******************************************
  73.  MOD1  ='MODE' MAILJOI1  'THERMIQUE' 'CONDUCTION' 'JOI1' ;
  74.  MOD2  ='MODE' POI1      'THERMIQUE' 'CONVECTION' ;
  75.  MODTOT= MOD1 'ET' MOD2 ;
  76.  
  77.  MAT1  ='MATE' MOD1 'M' Val_Mass 'C' Val_Cp 'KT' Val_KT ;
  78.  MAT2  ='MATE' MOD2 'H' Val_H 'TC' Temp_EXT ;
  79.  MATTOT= MAT1 'ET' MAT2 ;
  80.  
  81.  
  82. *******************************************
  83. *** CONDITIONS INITIALES ***
  84. *******************************************
  85.  T_ini ='MANU' 'CHPO' MAILJOI1 'T' 1.5 ;
  86.  
  87.  
  88. ***************************************
  89. *** RESOLUTION AVEC PASAPAS         ***
  90. ***************************************
  91.  LISTPS   ='PROG' 0. 'PAS' Dt Duree ;
  92.  
  93.  TAB1                   ='TABL' 'PASAPAS';
  94.  TAB1.'MODELE'          = MODTOT         ;
  95.  TAB1.'CARACTERISTIQUES'= MATTOT         ;
  96.  TAB1.'TEMPS_CALCULES'  = LISTPS         ;
  97.  TAB1.'TEMPERATURES'    ='TABL'          ;
  98.  TAB1.'TEMPERATURES' . 0= T_ini          ;
  99.  
  100.  PASAPAS TAB1 ;
  101.  
  102. *******************************************
  103. *** POST TRAITEMENT
  104. *******************************************
  105.  EVO1 ='EVOL' 'TEMP' TAB1 TEMPERATURES 'T' (POI2 'ET' (POIN 1 POI1));
  106. 'DESS' EVO1 ;
  107.  
  108. 'FIN';
  109.  
  110.  
  111.  
  112.  
  113.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales