Télécharger traction.dgibi

Retour à la liste

* fichier : traction.dgibi
* section : mecanique elastique plastique 
*------------------------------------------------------------------------------*
*                                   TRACTION                                   *
*------------------------------------------------------------------------------*
* Objet :
* -------
*
*   Simulation d'un essai de traction simple.
*
*   On se donne une courbe de traction force-deplacement de reference.
*
*   On simule l'essai de traction en petits et grands deplacements avec
* un modele elastoplastique a ecrouissage isotrope lineaire.
*
*   La courbe d'ecrouissage (contrainte equivalente-deformation plastique
* equivalente) fournissant les caracteristiques de la loi de comportement
* est derivee de la courbe contrainte-deformation conventionnelle a l'aide
* de la procedure ECRO.
*
*   La courbe d'ecrouissage fournie par la procedure ECRO doit etre choisie en
* fonction de l'option de calcul :
*    - En petits deplacements, il faut utiliser l'option "HPP" de la procedure ;
*    - En grands deplacements et lagrangien reactualise, il faut utiliser
*      l'option "REACTUALISE" ;
*    - En grands deplacements et lagrangien total, il faut utiliser l'option
*      "TOTAL".
*
*   Le calcul est validé en comparant la courbe force-deplacement calculee
* a celle que l'on s'est donne (consistance).
*
*   L'essai de traction est realise en deplacement impose.
*   
* Description :
* -------------
*   Essai de traction.
*
* Type de calcul : Mecanique, materiau elastique plastique isotrope.
* Mode de calcul : Tridimensionnel,
*                  - petits deplacements
*                  - grands deplacements, lagrangien reactualise
*                  - grands deplacements, lagrangien total
* Type d'element : CUB8 
* Chargement     : Deplacement impose
* Reference      : Comparaison a la courbe de traction donnee.
* Objectif       : Ecart relatif sur l'effort de traction.
* 
* Rappel :   Les courbes d'ecrouissage calculee par la procedure eponyme sont :
* --------   En petites perturbations :
*            => courbe d'ecrouissage conventionnelle :
*              . eps = dL/L
*              . sig = F/So
*            En grands deplacements, lagrangien reactualise :
*            => courbe d'ecrouissage rationnelle :
*              . eps = log (1+dL/L)
*              . sig = F/So*(1+dL/L))
*            En grands deplacements, lagrangien total :
*            => courbe d'ecrouissage deformation de Green-Lagrange,
*               contrainte de Piola-Kirchhoff 2 :
*              . eps = dL/L + 1/2(dL/L)^2
*              . sig = F/So/(1+dL/L))
*
*------------------------------------------------------------------------------*
* Pour activer les traces, mettre GRAPH a VRAI :
graph    = faux ;
*---------------------------- PETITES PERTURBATIONS ---------------------------*
opti dime 3 elem cub8 mode trid ;
*
* Donnees geometrie eprouvette a section rectangulaire (m) :
* ep1    : epaisseur 
* la1    : largeur 
* lu1    : longueur utile (base mesure deplacement vertical)
ep1      =  5.e-3 ;
la1      = 20.e-3 ;
lu1      = 25.e-3 ;
dimp1    = 0.4 * lu1 ;
* 
* Maillage :
v1       = (0 0 0) droi 1 (ep1 0 0) tran 4 (0 la1 0) volu tran 5 (0 0 lu1) ; 
x1 y1 z1 = v1 coor ;
ptx0     = x1 poin infe 1.e-4 ;
pty0     = y1 poin infe 1.e-4 ;
ptz0     = z1 poin infe 1.e-4 ;
ptz1     = z1 poin supe (0.99*lu1) ;
ptx0     = ptx0 coul bleu ;
pty0     = pty0 coul vert ;
ptz0     = ptz0 coul bleu ;
ptz1     = ptz1 coul jaun ;
si graph ;
  trac cach v1 titr 'Maillage zone de mesure eprouvette de traction' ; 
  elx0   = (enve V1) elem appu stri ptx0 ;
  ely0   = (enve V1) elem appu stri pty0 ;
  elz0   = (enve V1) elem appu stri ptz0 ;
  elz1   = (enve V1) elem appu stri ptz1 ;
  elx0   = elx0 coul bleu ;
  ely0   = ely0 coul vert ;
  elz0   = elz0 coul roug ;
  elz1   = elz1 coul jaun ;
  el0    = elx0 et ely0 et elz0 ;
  mot0   = chai 'Faces bleue : Ux = 0, verte : Uy = 0, rouge : Uz = 0' ;
  trac face (el0 et (aret v1)) titr mot0 ;
  mot0   = chai format '(F5.2)' 'Face jaune : uz =' dimp1 ;
  trac face (elz1 et (aret v1)) titr mot0 ;
fins ;
 
* Modele - Caracteristiques :
*
* Courbe de traction de reference :
* uzy1   : deplacement au seuil de plasticite (m)
* uzm1   : deplacement max. (m)
* fzy1   : effort au seuil de plasticite (N)
* fzm1   : effort max. (N)
uzy1     = 50.e-6 ;
uzm1     = dimp1 ;
fzy1     = 40.e3 ;
fzm1     = 80.e3 ;
luz1     = prog 0. uzy1 pas ((uzm1-uzy1)*0.02) uzm1 ;
lfz1     = prog 0. fzy1 pas ((fzm1-fzy1)*0.02) fzm1 ;
traref1  = evol manu 'U(m)' luz1 'F(N)' lfz1 ;
si graph ;
  dess traref1 titr 'Courbe force-deplacement fournie' posy exce ;
fins ;
 
* Caracteristiques mecaniques identifiees sur la courbe de reference :
* S0     : section initiale de l'eprouvette (m^2)
* sigy1  : Contrainte d'ecoulement (Pa)
* epsy1  : deformation a sigy1 (-)
* ym1    : module de Young (Pa)
* nu1    : coefficient de Poisson (-)
nu1      = 0.3 ; 
S0       = ep1 * la1 ;
sigy1    = fzy1 / S0 ;
epsy1    = uzy1 / lu1 ;
ym1      = sigy1 / epsy1 ;
leps1    = luz1 / lu1 ;
lsig1    = lfz1 / S0 ;
trac1    =  evol vert manu epeq leps1 smeq lsig1 ;
 
* Courbe d'écrouissage :
lepe1    = lsig1 / ym1 ;
lepp1    = (leps1 - lepe1) enle 1 ;
lsmp1    = lsig1 enle 1 ;
ecro1    = evol roug manu epeq lepp1 smeq lsmp1 ;
ecro1 ym1 = ecro hpp trac1 ;
 
tleg1    = tabl ;
tleg1 . titre = tabl ;
tleg1    = tabl ;
tleg1 . titre = tabl ;
tleg1 . titre . 1 = 'Courbe de traction' ;
tleg1 . titre . 2 = 'Courbe ecrouissage' ;
si graph ;
  dess (trac1 et ecro1) titr 'Courbes conventionelles de traction et d ecrouissage' lege tleg1 posy exce xbor 0. 0.4 ;
fins ;
 
mo1      = mode v1 mecanique elastique plastique ; 
ma1      = mate mo1 youn ym1 nu nu1 ecro ecro1 ;
 
* C.L. - Chargement :
clx0     = bloq ptx0 ux ;
cly0     = bloq pty0 uy ;
clz0     = bloq ptz0 uz ;
clz1     = bloq ptz1 uz ;
cl0      = clx0 et cly0 et clz0 et clz1 ;
 
dep1     = depi clz1 dimp1 ;
ev1      = evol manu temps (prog 0. 1.) (prog 0. 1.) ;
cg1      = char dimp dep1 ev1 ;
 
* Resolution : 
eimP1    = dimp1 / lu1 ;
ltcal1   = prog 0. (epsy1/eimp1) 0.05 pas 0.05 1. ;
ta1                       = tabl ;
ta1 . modele              = mo1 ;
ta1 . caracteristiques    = ma1 ;
ta1 . blocages_mecaniques = cl0 ;
ta1 . chargement          = cg1 ;
ta1 . temps_calcules      = ltcal1 ;
ta1 . hypothese_deformations = lineaire ;
 
pasapas ta1 ;
 
* Comparaison courbes calculee / fournie :
* luc1   : liste deplacements calcules
* lfc1   : liste efforts calcules
luc1     = prog ;
lfc1     = prog ;
nb1      = dime ta1 . temps_calcules ;
repe b1 nb1 ;
  i1       = &b1 - 1 ;
  u1       = ta1 . deplacements . i1 ;
  uc1      = maxi (exco u1 uz uz) ;
  rea1     = reac clz1 u1 ;
  fc1      = (resu rea1) maxi ;
  luc1     = luc1 et uc1 ;
  lfc1     = lfc1 et fc1 ;
fin b1 ;
tracal1  = evol vert manu 'Uc(m)' luc1 'Fc(N)' lfc1 ;
err1     = maxi abs (lfc1 - (ipol traref1 luc1)) ;
err1     = err1 / (maxi abs lfz1) ;
 
tleg1    = tabl ;
tleg1 . 1     = mot 'MARQ S ROND NOLI' ;
tleg1 . titre = tabl ;
tleg1 . titre . 1 = 'Courbe fournie' ;
tleg1 . titre . 2 = 'Courbe calculee' ;
si graph ;
  mot1     = chai format '(F5.2)'
  'Resultat en petits deplacements : max. ecart relatif effort =' (100.*err1) ' %' ;
  dess (traref1 et tracal1) titr mot1 lege tleg1 ;
fins ;
 
*---------------- GRANDS DEPLACEMENTS, LAGRANGIEN REACTUALISE -----------------*
*
* Caracteristiques mecaniques identifiees sur la courbe de reference :
* On determine la courbe de traction rationnelle :
*    - eps = ln (1+dl/)
*    - sig = F/S0x(1+dl/l)
* Avec :
* S0     : section initiale de l'eprouvette (m^2)
* sigy2  : Contrainte "vraie" d'ecoulement (Pa)
* epsy2  : deformation logarithmique a sigy2 (-)
* ym2    : module de Young (Pa) de la courbe rationnelle
* eppm2  : deformation plastique maximale (-)
* sigm2  : contrainte "vraie" maximale (Pa)
* nu2    : coefficient de Poisson (-)
nu2      = nu1 ;
sigy1    = fzy1 / S0 ;
epsy1    = uzy1 / lu1 ;
sigy2    = sigy1 * (1. + epsy1) ;
epsy2    = log (1. + epsy1) ;
ym2      = sigy2 / epsy2 ;
leps2    = luz1 / lu1 ;
lsig2    = lfz1 / S0 * (1. + leps2) ;
leps2    = log (1. + leps2) ;
trac2    =  evol vert manu epeq leps2 smeq lsig2 ;
*
** Courbe d'écrouissage :
*lepe2    = lsig2 / ym2 ;
*lepp2    = (leps2 - lepe2) enle 1 ;
*lsmp2    = lsig2 enle 1 ;
*ecro2    = evol roug manu epeq lepp2 smeq lsmp2 ;
ecro2 ym2 = ecro reac trac1 ;
 
tleg1    = tabl ;
tleg1 . titre = tabl ;
tleg1 . titre . 1 = 'Courbe de traction' ;
tleg1 . titre . 2 = 'Courbe ecrouissage' ;
si graph ;
  dess (trac2 et ecro2) titr 'Courbes rationnelles de traction et d ecrouissage' lege tleg1 posy exce xbor 0. 0.35 ;
fins ;
 
mo2      = mode v1 mecanique elastique plastique ; 
ma2      = mate mo2 youn ym2 nu nu2 ecro ecro2 ;
 
* Resolution en grands deplacements :
tepy2    = epsy2 * lu1 / dimp1 ;
ltcal2   = prog 0. (0.5*tepy2) tepy2 pas 0.02 1. ;
ta2                       = tabl ;
ta2 . modele              = mo2 ;
ta2 . caracteristiques    = ma2 ;
ta2 . blocages_mecaniques = cl0 ;
ta2 . chargement          = cg1 ;
ta2 . temps_calcules      = ltcal2 ;
ta2 . grands_deplacements = vrai ;
ta2 . lagrangien          = mot reactualise ;
*ta2 . precision           = 1.e-6 ;
 
pasapas ta2 ;
 
* Comparaison courbes calculee / fournie :
* luc2   : liste deplacements calcules
* lfc2   : liste efforts calcules
luc2     = prog ;
lfc2     = prog ;
nb1      = dime ta2 . temps_calcules ;
repe b1 nb1 ;
  i1       = &b1 - 1 ;
  u1       = ta2 . deplacements . i1 ;
  uc2      = maxi (exco u1 uz uz) ;
  rea1     = reac clz1 u1 ;
  fc2      = (resu rea1) maxi ;
  luc2     = luc2 et uc2 ;
  lfc2     = lfc2 et fc2 ;
fin b1 ;
tracal2  = evol oran manu 'Uc(m)' luc2 'Fc(N)' lfc2 ;
err2     = maxi abs (lfc2 - (ipol traref1 luc2)) ;
err2     = err2 / (maxi abs lfz1) ;
 
tleg2         = tabl ;
tleg2 . 1     = mot 'MARQ S CARR NOLI' ;
tleg2 . titre = tabl ;
tleg2 . titre . 1 = 'Courbe fournie' ;
tleg2 . titre . 2 = 'Courbe calculee' ;
si graph ;
  mot2     = chai format '(F5.2)'
  'Resultat en Lagrangien reactualise : max. ecart relatif effort =' (100.*err2) ' %' ;
  dess (traref1 et tracal2) titr mot2 lege tleg2 ;
fins ;
 
* On saute cette partie en attendant d'avoit statuer sur la solution :
si vrai ;
*------------------- GRANDS DEPLACEMENTS, LAGRANGIEN TOTAL --------------------*
*
 
* Caracteristiques mecaniques identifiees sur la courbe de reference :
* On determine la courbe de traction :
*    - eps = (dl/l) + 0.5*(dl/l)^2
*    - sig = F/S0x(1+dl/l)
* Avec :
* S0     : section initiale de l'eprouvette (m^2)
* sigy3  : Contrainte "vraie" d'ecoulement (Pa)
* epsy3  : deformation quadratique a sigy3 (-)
* ym3    : module de Young (Pa) de la courbe 
* eppm3  : deformation plastique maximale (-)
* sigm3  : contrainte "vraie" maximale (Pa)
* nu3    : coefficient de Poisson (-)
nu3      = nu1 ;
sigy1    = fzy1 / S0 ;
epsy1    = uzy1 / lu1 ;
sigy3    = sigy1 / (1. + epsy1) ;
epsy3    = 0.5 * epsy1 * epsy1 + epsy1 ;
leps3    = luz1 / lu1 ;
lsig3    = lfz1 / S0 / (1. + leps3) ;
leps3    = 0.5 * leps3 * leps3 + leps3 ;
ym3      = (lsig3 extr 2) / (leps3 extr 2);
trac3    = evol vert manu epeq leps3 smeq lsig3 ;
 
* Courbe d'écrouissage :
*lepe3    = lsig3 / ym3 ;
*lepp3    = (leps3 - lepe3) enle 1 ;
*lsmp3    = lsig3 enle 1 ;
*ecro3    = evol roug manu epeq lepp3 smeq lsmp3 ;
ecro3 ym3 = ecro tota trac1 ;
 
tleg1    = tabl ;
tleg1 . titre = tabl ;
tleg1 . titre . 1 = 'Courbe de traction' ;
tleg1 . titre . 2 = 'Courbe ecrouissage' ;
si graph ;
  dess (trac3 et ecro3) titr 'Courbes de traction et d ecrouissage' lege tleg1 posy exce xbor 0. 0.5 ;
fins ;
 
* Modele - Caracteristiques : on utilise la courbe de traction rationnelle
mo3      = mode v1 mecanique elastique plastique ; 
ma3      = mate mo3 youn ym3 nu nu3 ecro ecro3 ;
 
* Resolution en grands deplacements :
tepy3    = epsy3 * lu1 / dimp1 ;
ltcal3   = prog 0. pas (0.5*tepy3) tepy3 pas 0.02 1. ;
ta3                       = tabl ;
ta3 . modele              = mo3 ;
ta3 . caracteristiques    = ma3 ;
ta3 . blocages_mecaniques = cl0 ;
ta3 . chargement          = cg1 ;
ta3 . temps_calcules      = ltcal3 ;
ta3 . grands_deplacements = vrai ;
ta3 . lagrangien          = mot total ;
*ta3 . precision           = 1.e-6 ;
 
pasapas ta3 ;
 
* Comparaison courbes calculee / fournie :
* luc3   : liste deplacements calcules
* lfc3   : liste efforts calcules
luc3     = prog ;
lfc3     = prog ;
nb1      = dime ta3 . temps_calcules ;
repe b1 nb1 ;
  i1       = &b1 - 1 ;
  u1       = ta3 . deplacements . i1 ;
  uc3      = maxi (exco u1 uz uz) ;
  rea1     = reac clz1 u1 ;
  fc3      = (resu rea1) maxi ;
  luc3     = luc3 et uc3 ;
  lfc3     = lfc3 et fc3 ;
fin b1 ;
tracal3  = evol roug manu 'Uc(m)' luc3 'Fc(N)' lfc3 ;
err3     = maxi abs (lfc3 - (ipol traref1 luc3)) ;
err3     = err3 / (maxi abs lfz1) ;
 
tleg3         = tabl ;
tleg3 . 1     = mot 'MARQ S CARR NOLI' ;
tleg3 . titre = tabl ;
tleg3 . titre . 1 = 'Courbe fournie' ;
tleg3 . titre . 2 = 'Courbe calculee' ;
si graph ;
  mot3     = chai format '(F5.2)'
  'Resultat en Lagrangien total : max. ecart relatif effort =' (100.*err3) ' %' ;
  dess (traref1 et tracal3) titr mot3 lege tleg3 ;
fins ;
 
sino ;
  tracal3 = vide evolution ;
  err3    = 0. ;
fins ;
 
*----------------------------------- BILAN ------------------------------------*
*
* Visualisation des differentes courbes :
tleg4    = tabl ;
tleg4 . 1     = mot 'MARQ S ROND NOLI' ;
tleg4 . titre = tabl ;
tleg4 . titre . 1 = 'Courbe de reference' ;
tleg4 . titre . 2 = 'Resultat HPP' ;
tleg4 . titre . 3 = 'Resultat Lag. Reac.' ;
tleg4 . titre . 4 = 'Resultat Lag. Total' ;
mot4     = 'Courbes de traction calculees suivant differentes hypotheses' ;
si graph ;
  dess (traref1 et tracal1 et tracal2 et tracal3) titr mot4 lege tleg4 ;
fins ;
*
* Affichages ecarts relatifs sur effort :
opti echo 0 ;
saut 1 lign ;
mess                        ' ***** RESULTATS : Ecart relatif effort de traction ref./calcul :' ;
mess (chai format '(E10.3)' '            HPP  :' err1) ;
mess (chai format '(E10.3)' ' Lagragien reac. :' err2) ;
si (non (vide tracal3)) 
mess (chai format '(E10.3)' ' Lagragien total :' err3) ;
fins ;
saut 1 lign ;
opti echo 1 ;
 
* Test de validation :
err0     = maxi (prog err1 err2 err3) ;
si (err0 > 2.e-2) ;
  erre 5 ;
fins ;
 
fin ;
 
 
 
 

© Cast3M 2003 - Tous droits réservés.
Mentions légales