Télécharger la plaquette Cast3M


fr en

Télécharger topoptim_09_Remeshing.dgibi

Retour à la liste

Numérotation des lignes : 

  1. * fichier topoptim_09_Remeshing.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4.  
  5. ************************************************************************
  6. ** Topology optimization of a simple 2D structure subjected to a
  7. ** mechanical loading, with imposed initial topology and remeshing.
  8. **
  9. ** Author:
  10. ** Guenhael Le Quilliec (LaMe - Polytech Tours)
  11. **
  12. ** Version:
  13. ** V2.0 2025/11/13 Updated to make it compatible with TOPOPTIM V4.0
  14. ** V1.0 2017/04/18 Original version compatible with TOPOPTIM V2.1
  15. ************************************************************************
  16.  
  17. * Plot results
  18. graph0 = FAUX ;
  19.  
  20. * General options
  21. OPTI 'DIME' 2 'MODE' 'PLAN' 'CONT' 'ELEM' 'QUA4' ;
  22.  
  23. * Number of mesh refinement iterations
  24. nb0 = 5 ;
  25.  
  26. * Dimensions
  27. l1 = 60.0 ;
  28. l2 = 20.0 ;
  29.  
  30. * Initialize the optimization table
  31. tab0 = TABL ;
  32. tab0.'TRAC'                   = graph0 ;
  33. tab0.'FRACTION_VOLUME_LIMITE' = 0.5 ;
  34. tab0.'MAX_CYCLES'             = 0 ;
  35. *tab0.'OPTIMISEUR'             = MOT 'MMA' ;
  36.  
  37. * Remeshing loop
  38. REPE loop1 nb0 ;
  39.  
  40. *   Number of elements
  41.     nelx0 = 15 * &loop1 ;
  42.     nely0 = 5 * &loop1 ;
  43.  
  44. *   Mesh
  45.     p0 = 0.0 0.0 ;
  46.     p1 = 0.0 l2 ;
  47.     p2 = l1 0.0 ;
  48.     ln0 = DROI nely0 p1 p0 ;
  49.     msh0 = ln0 TRAN nelx0 p2 ;
  50.     p2 = msh0 POIN 'PROC' p2 ;
  51.  
  52. *   Model and material
  53.     mod0 = MODE msh0 'MECANIQUE' 'ELASTIQUE' ;
  54.     mat0 = MATE mod0 'YOUN' 210.0e9 'NU' 0.3 ;
  55.  
  56. *   Boundary conditions
  57.     bc0 = (BLOQ 'UX' ln0) ET (BLOQ 'UY' p2) ;
  58.  
  59. *   Loading
  60.     load0 = FORC (0.0 -1.0) p1 ;
  61.  
  62. *   Finite element model table
  63.     mdl0 = TABL ;
  64.     mdl0.'MODELE'               = mod0 ;
  65.     mdl0.'CARACTERISTIQUES'     = mat0 ;
  66.     mdl0.'BLOCAGES_MECANIQUES'  = bc0 ;
  67.     mdl0.'CHARGEMENT'           = load0 ;
  68.  
  69. *   Add the finite element model to the optimization table
  70.     tab0.'RESOLUTION_LINEAIRE'  = mdl0 ;
  71.  
  72. *   Filtering options
  73. *    tab0.'FILTRE'               = MOT 'EDP' ;
  74. *    tab0.'FILTRE_EDP_RAYON'     = 2.0 * l1 / (FLOT nelx0) ;
  75. *    tab0.'FILTRE'               = MOT 'CHAPEAU' ;
  76. *    tab0.'FILTRE_CHAPEAU_RAYON' = 2.5 * l1 / (FLOT nelx0) ;
  77. *    tab0.'FILTRER'              = MOT 'DENSITE' ;
  78.  
  79. *   Progressively increase the maximum number of cycles
  80.     SI (&loop1 < nb0) ;
  81.         tab0.'MAX_CYCLES' = tab0.'MAX_CYCLES' + 4 * &loop1 ;
  82.     SINO ;
  83.         tab0.'MAX_CYCLES' = tab0.'MAX_CYCLES' + 50 ;
  84.     FINS ;
  85.  
  86. *   Optimization
  87.     TOPOPTIM tab0 ;
  88.  
  89. FIN loop1 ;
  90.  
  91. * Plot final topology (physical density)
  92. topo0    = tab0.'TOPOLOGIE'.(tab0.'CYCLE') ;
  93. topomsh0 = tab0.'MAILLAGE'.(tab0.'CYCLE') ;
  94. SI graph0 ;
  95.     TRAC (REDU topo0 topomsh0) (REDU mod0 topomsh0)
  96.          (PROG 0.0 'PAS' (1.0 / 56.0) 1.0)
  97.          'TITR' 'Topologie finale' ;
  98. FINS ;
  99.  
  100. * Plot output evolutions
  101. SI graph0 ;
  102.     REPE loop0 (DIME tab0.'EVOLUTIONS_SAUVEES') ;
  103.         evoname0 = EXTR tab0.'EVOLUTIONS_SAUVEES' &loop0 ;
  104.         DESS tab0.'EVOLUTIONS'.evoname0 'POSY' 'EXCE'
  105.              'TITR' (CHAI 'Evolution de' ' ' evoname0
  106.                           ' au cours des cycles d''optimisation') ;
  107.     FIN loop0 ;
  108. FINS ;
  109.  
  110. FIN ;
  111.  
  112.  
  113.  
  114.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales