Télécharger la plaquette Cast3M


fr en

Télécharger topoptim_05_Frozen_area.dgibi

Retour à la liste

Numérotation des lignes : 

  1. * fichier topoptim_05_Frozen_area.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4.  
  5. ************************************************************************
  6. ** Topology optimization of a simple 2D structure subjected to a
  7. ** mechanical loading, with variable penalty factor, GSF, a hole
  8. ** and a frozen area.
  9. **
  10. ** Author:
  11. ** Guenhael Le Quilliec (LaMe - Polytech Tours)
  12. **
  13. ** Version:
  14. ** V4.0 2025/11/13 Updated to make it compatible with TOPOPTIM V4.0
  15. ** V3.0 2021/05/06 Updated to make it compatible with TOPOPTIM V3.0
  16. ** V2.0 2017/04/18 Updated to make it compatible with TOPOPTIM V2.0
  17. ** V1.0 2014/04/28 Original version compatible with TOPOPTIM V1.0
  18. ************************************************************************
  19.  
  20. * Plot results
  21. graph0 = FAUX ;
  22.  
  23. * General options
  24. OPTI 'DIME' 2 'MODE' 'PLAN' 'CONT' 'ELEM' 'QUA4' ;
  25.  
  26. * Mesh
  27. p0 = 0.0 0.0 ;
  28. p1 = 0.0 60.0 ;
  29. p2 = 30.0 0.0 ;
  30. p3 = 0.0 30.0 ;
  31. p4 = 30.0 25.0 ;
  32. p5 = 15.0 15.0 ;
  33. p6 = 19.0 15.0 ;
  34. ln0 = DROI 60 p0 p1 ;
  35. ln1 = DROI 30 p3 p1 ;
  36. ELIM ln0 ln1 0.01 ;
  37. msh0 = ln0 TRAN 30 p2 ;
  38. tmp0 = msh0 POIN 'SPHE' p5 p6 4.0 ;
  39. tmp0 = msh0 ELEM 'APPU' 'STRI' tmp0 ;
  40. msh0 = DIFF msh0 tmp0 ;
  41.  
  42. p2 = msh0 POIN 'PROC' p2 ;
  43. msh1 = msh0 POIN 'DROI' p3 p4 2.5 ;
  44. msh1 = msh0 ELEM 'APPU' 'STRI' msh1 ;
  45.  
  46. * Model and material
  47. mod0 = MODE msh0 'MECANIQUE' 'ELASTIQUE' ;
  48. mat0 = MATE mod0 'YOUN' 210.0e9 'NU' 0.3 ;
  49.  
  50. * Boundary conditions
  51. bc0 = BLOQ 'UX' 'UY' ln1 ;
  52.  
  53. * Loading
  54. load0 = FORC (1.0 0.0) p2 ;
  55.  
  56. * Penalty factor evolution
  57. pnl_p0 = EVOL 'MANU' 'CYCLES' (PROG  5 15) 'P' (PROG 1.0 3.0) ;
  58.  
  59. * OC gray scale factor evolution
  60. oc_q0 = EVOL 'MANU' 'CYCLES' (PROG 10 90) 'Q' (PROG 1.0 5.0) ;
  61.  
  62. * Finite element model table
  63. mdl0 = TABL ;
  64. mdl0.'MODELE'                 = mod0 ;
  65. mdl0.'CARACTERISTIQUES'       = mat0 ;
  66. mdl0.'BLOCAGES_MECANIQUES'    = bc0 ;
  67. mdl0.'CHARGEMENT'             = load0 ;
  68.  
  69. * Optimization table
  70. tab0 = TABL ;
  71. tab0.'TRAC'                   = graph0 ;
  72. tab0.'RESOLUTION_LINEAIRE'    = mdl0 ;
  73. tab0.'FRACTION_VOLUME_LIMITE' = 0.4 ;
  74. tab0.'ZONE_FIGEE'             = msh1 ;
  75. tab0.'FILTRE_GIBIANE_TAUX'    = 10 ;
  76. tab0.'PENALISATION_P'         = pnl_p0 ;
  77. tab0.'OC_Q'                   = oc_q0 ;
  78. *tab0.'FILTRE'                 = MOT 'EDP' ;
  79. *tab0.'FILTRE_EDP_RAYON'       = 3.0 ;
  80. *tab0.'FILTRE'                 = MOT 'CHAPEAU' ;
  81. *tab0.'FILTRE_CHAPEAU_RAYON'   = 3.0 ;
  82. *tab0.'FILTRER'                = MOT 'DENSITE' ;
  83. *tab0.'OPTIMISEUR'             = MOT 'MMA' ;
  84.  
  85. * Optimization
  86. TOPOPTIM tab0 ;
  87.  
  88. * Plot final topology (physical density)
  89. topo0    = tab0.'TOPOLOGIE'.(tab0.'CYCLE') ;
  90. topomsh0 = tab0.'MAILLAGE'.(tab0.'CYCLE') ;
  91. SI graph0 ;
  92.     TRAC (REDU topo0 topomsh0) (REDU mod0 topomsh0)
  93.          (PROG 0.0 'PAS' (1.0 / 56.0) 1.0)
  94.          'TITR' 'Topologie finale' ;
  95. FINS ;
  96.  
  97. * Plot output evolutions
  98. SI graph0 ;
  99.     REPE loop0 (DIME tab0.'EVOLUTIONS_SAUVEES') ;
  100.         evoname0 = EXTR tab0.'EVOLUTIONS_SAUVEES' &loop0 ;
  101.         DESS tab0.'EVOLUTIONS'.evoname0 'POSY' 'EXCE'
  102.              'TITR' (CHAI 'Evolution de' ' ' evoname0
  103.                           ' au cours des cycles d''optimisation') ;
  104.     FIN loop0 ;
  105. FINS ;
  106.  
  107. FIN ;
  108.  
  109.  
  110.  
  111.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales