Télécharger la plaquette Cast3M


fr en

Télécharger topoptim_04_Multicase.dgibi

Retour à la liste

Numérotation des lignes : 

  1. * fichier topoptim_04_Multicase.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4.  
  5. ************************************************************************
  6. ** Topology optimization of a simple 2D structure subjected to
  7. ** multicase mechanical loading.
  8. **
  9. ** Author:
  10. ** Guenhael Le Quilliec (LaMe - Polytech Tours)
  11. **
  12. ** Version:
  13. ** V3.0 2025/11/13 Updated to make it compatible with TOPOPTIM V4.0
  14. ** V2.0 2017/04/18 Updated to make it compatible with TOPOPTIM V2.0
  15. ** V1.0 2014/04/28 Original version compatible with TOPOPTIM V1.0
  16. ************************************************************************
  17.  
  18. * Plot results
  19. graph0 = FAUX ;
  20.  
  21. * General options
  22. OPTI 'DIME' 2 'MODE' 'PLAN' 'CONT' 'ELEM' 'QUA4' ;
  23.  
  24. * Number of elements
  25. nelx0 = 30 ;
  26. nely0 = 30 ;
  27.  
  28. * Dimensions
  29. l0 = 10.0 ;
  30. h0 = 10.0 ;
  31.  
  32. * Mesh
  33. p0 = 0.0 0.0 ;
  34. p1 = 0.0 h0 ;
  35. p2 = l0 0.0 ;
  36. lgn0 = DROI nely0 p1 p0 ;
  37. msh0 = lgn0 TRAN nelx0 p2 ;
  38. p2 = msh0 POIN 'PROC' p2 ;
  39. p3 = msh0 POIN 'PROC' (l0 h0) ;
  40.  
  41. * Model and material
  42. mod0 = MODE msh0 'MECANIQUE' 'ELASTIQUE' ;
  43. mat0 = MATE mod0 'YOUN' 210.0e9 'NU' 0.3 ;
  44.  
  45. * Boundary conditions
  46. bc0 = BLOQ 'UX' 'UY' lgn0 ;
  47.  
  48. * Multicase loading table
  49. load0 = TABL ;
  50. load0.(1) = FORC (0.3  0.6) p2 ;
  51. load0.(2) = FORC (0.0  1.0) p3 ;
  52.  
  53. * Finite element model table
  54. mdl0 = TABL ;
  55. mdl0.'MODELE'                 = mod0 ;
  56. mdl0.'CARACTERISTIQUES'       = mat0 ;
  57. mdl0.'BLOCAGES_MECANIQUES'    = bc0 ;
  58. mdl0.'CHARGEMENT'             = load0 ;
  59.  
  60. * Optimization table
  61. tab0 = TABL ;
  62. tab0.'TRAC'                   = graph0 ;
  63. tab0.'RESOLUTION_LINEAIRE'    = mdl0 ;
  64. tab0.'FRACTION_VOLUME_LIMITE' = 0.5 ;
  65. *tab0.'FILTRE'                 = MOT 'EDP' ;
  66. *tab0.'FILTRE_EDP_RAYON'       = 2.0 * l0 / (FLOT nelx0) ;
  67. *tab0.'FILTRE'                 = MOT 'CHAPEAU' ;
  68. *tab0.'FILTRE_CHAPEAU_RAYON'   = 3.5 * l0 / (FLOT nelx0) ;
  69. *tab0.'FILTRER'                = MOT 'DENSITE' ;
  70. *tab0.'OPTIMISEUR'             = MOT 'MMA' ;
  71.  
  72. * Optimization
  73. TOPOPTIM tab0 ;
  74.  
  75. * Plot final topology (physical density)
  76. topo0    = tab0.'TOPOLOGIE'.(tab0.'CYCLE') ;
  77. topomsh0 = tab0.'MAILLAGE'.(tab0.'CYCLE') ;
  78. SI graph0 ;
  79.     TRAC (REDU topo0 topomsh0) (REDU mod0 topomsh0)
  80.          (PROG 0.0 'PAS' (1.0 / 56.0) 1.0)
  81.          'TITR' 'Topologie finale' ;
  82. FINS ;
  83.  
  84. * Plot output evolutions
  85. SI graph0 ;
  86.     REPE loop0 (DIME tab0.'EVOLUTIONS_SAUVEES') ;
  87.         evoname0 = EXTR tab0.'EVOLUTIONS_SAUVEES' &loop0 ;
  88.         DESS tab0.'EVOLUTIONS'.evoname0 'POSY' 'EXCE'
  89.              'TITR' (CHAI 'Evolution de' ' ' evoname0
  90.                           ' au cours des cycles d''optimisation') ;
  91.     FIN loop0 ;
  92. FINS ;
  93.  
  94. FIN ;
  95.  
  96.  
  97.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales