Exemples de jeux de données Cast3M

* fichier topoptim_03_Thermal.dgibi
************************************************************************
************************************************************************
 
************************************************************************
** Topology optimization of a simple 2D structure subjected to a
** thermal loading.
**
** Author:
** Guenhael Le Quilliec (LaMe - Polytech Tours)
**
** Version:
** V3.0 2025/11/13 Updated to make it compatible with TOPOPTIM V4.0
** V2.0 2017/04/18 Updated to make it compatible with TOPOPTIM V2.0
** V1.0 2014/04/28 Original version compatible with TOPOPTIM V1.0
************************************************************************
 
* Plot results
graph0 = FAUX ;
 
* General options
OPTI 'DIME' 2 'ELEM' 'QUA4' ;
 
* Number of elements
nelx0 = 40 ;
nely0 = 40 ;
 
* Dimensions
l0 = nelx0 * 1.0 ;
h0 = nely0 * 1.0 ;
u0 = 2.0 ;
 
* Mesh
p0   = 0.0 0.0 ;
p1   = 0.0 h0 ;
p2   = l0 0.0 ;
ln0  = DROI nely0 p0 p1 ;
msh0 = nelx0 TRAN ln0 p2 ;
p2   = msh0 POIN 'PROC' p2 ;
ln1  = ln0 PLUS p2 ;
ELIM (CONT msh0) ln1 0.01 ;
ln2 = ln0 ELEM 'APPU' 'STRI'
               (ln0 POIN 'DROI' (0.0 (h0/2)) (1.0 (h0/2)) (u0 + 0.01)) ;
 
* Model and material
mod0 = MODE msh0 'THERMIQUE' 'CONDUCTION' ;
mat0 = MATE mod0 'K' 50.0 ;
 
* Boundary conditions and loading
bc0 = BLOQ 'T' ln2 ;
load0 = SOUR mod0 0.01 msh0 ;
 
* Finite element model table
mdl0 = TABL ;
mdl0.'MODELE'                 = mod0 ;
mdl0.'CARACTERISTIQUES'       = mat0 ;
mdl0.'BLOCAGES_THERMIQUES'    = bc0 ;
mdl0.'CHARGEMENT'             = load0 ;
 
* Optimization table
tab0 = TABL ;
tab0.'TRAC'                   = graph0 ;
tab0.'RESOLUTION_LINEAIRE'    = mdl0 ;
tab0.'FRACTION_VOLUME_LIMITE' = 0.4 ;
tab0.'RAPPORT_RAIDEURS_THERMIQUES' = 26.0e-3 / 50.0 ;
*tab0.'FILTRE'                 = MOT 'EDP' ;
*tab0.'FILTRE_EDP_RAYON'       = 3.0 * l0 / (FLOT nelx0) ;
*tab0.'FILTRE'                 = MOT 'CHAPEAU' ;
*tab0.'FILTRE_CHAPEAU_RAYON'   = 3.0 * l0 / (FLOT nelx0) ;
*tab0.'FILTRER'                = MOT 'DENSITE' ;
*tab0.'OPTIMISEUR'             = MOT 'MMA' ;
 
* Optimization
TOPOPTIM tab0 ;
 
* Plot final topology (physical density)
topo0 = tab0.'TOPOLOGIE'.(tab0.'CYCLE') ;
topomsh0 = tab0.'MAILLAGE'.(tab0.'CYCLE') ;
SI graph0 ;
    TRAC (REDU topo0 topomsh0) (REDU mod0 topomsh0)
         (PROG 0.0 'PAS' (1.0 / 56.0) 1.0) ;
FINS ;
 
* Plot output evolutions
SI graph0 ;
    REPE loop0 (DIME tab0.'EVOLUTIONS_SAUVEES') ;
        evoname0 = EXTR tab0.'EVOLUTIONS_SAUVEES' &loop0 ;
        DESS tab0.'EVOLUTIONS'.evoname0 'POSY' 'EXCE'
             'TITR' (CHAI 'Evolution de' ' ' evoname0
                          ' au cours des cycles d''optimisation') ;
    FIN loop0 ;
FINS ;
 
FIN ;