Télécharger la plaquette Cast3M


fr en

Télécharger topoptim_01_MBB_beam.dgibi

Retour à la liste

Numérotation des lignes : 

  1. * fichier topoptim_01_MBB_beam.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4.  
  5. ************************************************************************
  6. ** Topology optimization of a 2D structure, the classical MBB beam
  7. ** (Messerschmitt–Bolkow–Blohm beam) under three-point bending.
  8. **
  9. ** Author:
  10. ** Guenhael Le Quilliec (LaMe - Polytech Tours)
  11. **
  12. ** Version:
  13. ** V3.0 2025/11/13 Updated to make it compatible with TOPOPTIM V4.0
  14. ** V2.0 2017/04/18 Updated to make it compatible with TOPOPTIM V2.0
  15. ** V1.0 2014/04/28 Original version compatible with TOPOPTIM V1.0
  16. ************************************************************************
  17.  
  18. * Plot results
  19. graph0 = FAUX ;
  20.  
  21. * General options
  22. OPTI 'DIME' 2 'MODE' 'PLAN' 'CONT' 'ELEM' 'QUA4' ;
  23.  
  24. * Number of elements
  25. nelx0 = 60 ;
  26. nely0 = 20 ;
  27.  
  28. * Dimensions
  29. l0 = nelx0 * 1.0 ;
  30. h0 = nely0 * 1.0 ;
  31.  
  32. * Mesh
  33. p0   = 0.0 0.0 ;
  34. p1   = 0.0 h0 ;
  35. p2   = l0 0.0 ;
  36. ln0  = DROI nely0 p0 p1 ;
  37. msh0 = ln0 TRAN nelx0 p2 ;
  38. p2   = msh0 POIN 'PROC' p2 ;
  39.  
  40. * Model and material
  41. mod0 = MODE msh0 'MECANIQUE' 'ELASTIQUE' ;
  42. mat0 = MATE mod0 'YOUN' 210.0e9 'NU' 0.3 ;
  43.  
  44. * Boundary conditions
  45. bc0 = (BLOQ 'UX' ln0) ET (BLOQ 'UY' p2) ;
  46.  
  47. * Loading
  48. load0 = FORC (0.0 -300.0e6) p1 ;
  49.  
  50. * Finite element model table
  51. mdl0 = TABL ;
  52. mdl0.'MODELE'                 = mod0 ;
  53. mdl0.'CARACTERISTIQUES'       = mat0 ;
  54. mdl0.'BLOCAGES_MECANIQUES'    = bc0 ;
  55. mdl0.'CHARGEMENT'             = load0 ;
  56.  
  57. * Optimization table
  58. tab0 = TABL ;
  59. tab0.'TRAC'                   = graph0 ;
  60. tab0.'RESOLUTION_LINEAIRE'    = mdl0 ;
  61. tab0.'FRACTION_VOLUME_LIMITE' = 0.5 ;
  62. *tab0.'FILTRE'                 = MOT 'EDP' ;
  63. *tab0.'FILTRE_EDP_RAYON'       = 3.0 * l0 / (FLOT nelx0) ;
  64. *tab0.'FILTRE'                 = MOT 'CHAPEAU' ;
  65. *tab0.'FILTRE_CHAPEAU_RAYON'   = 3.0 * l0 / (FLOT nelx0) ;
  66. *tab0.'FILTRER'                = MOT 'DENSITE' ;
  67. *tab0.'OPTIMISEUR'             = MOT 'MMA' ;
  68.  
  69. * Optimization
  70. TOPOPTIM tab0 ;
  71.  
  72. * Plot final topology (physical density)
  73. topo0    = tab0.'TOPOLOGIE'.(tab0.'CYCLE') ;
  74. topomsh0 = tab0.'MAILLAGE'.(tab0.'CYCLE') ;
  75. SI graph0 ;
  76.     TRAC (REDU topo0 topomsh0) (REDU mod0 topomsh0)
  77.          (PROG 0.0 'PAS' (1.0 / 56.0) 1.0)
  78.          'TITR' 'Topologie finale' ;
  79. FINS ;
  80.  
  81. * Plot output evolutions
  82. SI graph0 ;
  83.     REPE loop0 (DIME tab0.'EVOLUTIONS_SAUVEES') ;
  84.         evoname0 = EXTR tab0.'EVOLUTIONS_SAUVEES' &loop0 ;
  85.         DESS tab0.'EVOLUTIONS'.evoname0 'POSY' 'EXCE'
  86.              'TITR' (CHAI 'Evolution de' ' ' evoname0
  87.                           ' au cours des cycles d''optimisation') ;
  88.     FIN loop0 ;
  89. FINS ;
  90.  
  91. FIN ;
  92.  
  93.  
  94.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales