Télécharger la plaquette Cast3M


fr en

Télécharger rupt16-weib.dgibi

Retour à la liste

Numérotation des lignes : 

  1. * fichier :  rupt16-weib.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4. *----------------------------------------------------------------------
  5. *----------------------------------------------------------------
  6. *                                                               *
  7. *       Test du critère de Weibull pour un cylindre             *
  8. *       en traction modelisé en axisymétrique                   *
  9. *       sigu constante ou évolution constante                   *
  10. *                                                               *
  11. *----------------------------------------------------------------
  12. *----------------------------------------------------------------
  13. *                                                               *
  14. graph = faux ;
  15.  
  16. opti echo 1                                                     ;
  17. *            paramètres pour calculer la contrainte de Weibull *
  18. m = 22. ; v0 = 0.000125 ;  ic = 1. ; n = 2.                     ;
  19. *sigu = cste                                                    *
  20. sigu1 = 2530.                                                   ;
  21. *sigu = evol_cste                                               *
  22. lte1 = prog -1000. 1000. ; lsigu = prog 2530. 2530.             ;
  23. sigu2 = evol manu 'temper' lte1 'sigu' lsigu                    ;
  24. *                                                               *
  25. *****************************************************************
  26. *                                                               *
  27. *                       MODELE AXISYMETRIQUE                    *
  28. *                                                               *
  29. *****************************************************************
  30. *
  31. *****************************************************************
  32. *               Maillage                                        *
  33. *****************************************************************
  34. opti elem qua8 dime 2 mode axis                                 ;
  35. *                                                               *
  36. *               densites utilisees                              *
  37. l1 = 0.25 ;d1 = 50e-3 ; d2 = 120e-3 ; d11 = d1/10.              ;
  38. *                                                               *
  39. *               coordonnees des points                          *
  40. po = 0. 0. ; pb = l1 0. ; pc = 0. d1 ; pd = 0. l1               ;
  41. pa = d1 0.                                                      ;
  42. *                                                               *
  43. *               definition des lignes                           *
  44. ligoa = droi po pa 1                                            ;
  45. ligab = droi pa pb  'DINI' 0.08 'DFIN' 0.12                     ;
  46. ligob = ligoa et ligab                                          ;
  47. surf1 = ligob tran 1 pc                                         ;
  48. *
  49. lig1 = cote 3 surf1                                             ;
  50. *                                                               *
  51. *               création de la surface                          *
  52. surf3 = lig1 tran 'DINI' 0.08 'DFIN' 0.12 (0. (l1-d1))          ;
  53. surf2 = surf1 et surf3                                          ;
  54. *                                                               *
  55. *               extraction des lignes                           *
  56. lib = cote 1 surf2                                              ;
  57. lic = cote 3 surf2                                              ;
  58. *                                                               *
  59. elim surf2 1e-3                                                 ;
  60. *                                                               *
  61. *****************************************************************
  62. *               création du modéle                              *
  63. *****************************************************************
  64. mod1 = mode surf2 mecanique elastique plastique                 ;
  65. *                                                               *
  66. *****************************************************************
  67. *               définition du matériau                          *
  68. *****************************************************************
  69. *                                                               *
  70. * young :
  71. ym1  = 503./0.0026 ;
  72. *               courbe de traction                              *
  73. peps = prog 0. 0.0026 0.0027 0.0030 0.0035 0.0045 0.0065 0.0085  0.0105 0.0125 0.0176 0.0227 0.0329 ;
  74. psig = prog 0. 503. 503. 503. 503. 503. 503. 503. 503. 516. 538.  557. 594. ;
  75. tracevt = evol manu 'eps' peps 'sig' psig                       ;
  76. lsm1 = psig enle 1 ;
  77. lep1 = (peps enle 1) - (lsm1 / ym1) ;
  78. evec = evol vert manu eps lep1 sig lsm1 ;
  79. si graph ;
  80.   dess (tracevt et evec) titr ' Courbes de traction et d ecrouissage (vert)' ;
  81. fins ;
  82. *                                                               *
  83. mat1 = mate mod1 youn ym1 nu 0.3 ecro evec alpha 1.e-5 talp 20. tref 100. ;
  84. *                                                               *
  85. *****************************************************************
  86. *               rigidité                                        *
  87. *****************************************************************
  88. cdl0 = bloq uz lib                                              ;
  89. cdl2 = bloq uz lic                                              ;
  90. dep1 = depi cdl2 4e-3                                         ;
  91. forcevt = evol manu abs (prog 0. 1.) ord (prog 0. 1.)           ;
  92. char1 = char 'DIMP' dep1 forcevt                                ;
  93. *                                                               *
  94. tabtps = table ;
  95. tabtps. 0 = 0. ;
  96. tabtps. 1 = 1. ;
  97.  
  98. tabT = table ;
  99. tabT. 0 = manu 'CHPO' surf2 1 'T' 100. ;
  100. tabT. 1 = manu 'CHPO' surf2 1 'T' -100. ;
  101.  
  102. char2 = CHAR 'T' tabtps tabT ;
  103.  
  104. *****************************************************************
  105. *               definition de la table d'entree                 *
  106. *****************************************************************
  107. tab1 = table                                                    ;
  108. tab1.caracteristiques = mat1                                    ;
  109. tab1.modele = mod1                                              ;
  110. tab1.blocages_mecaniques = cdl0 et cdl2                         ;
  111. tab1.chargement = char1 et char2                                ;
  112. tab1.temps_calcules = (prog 0. pas 0.5 1.)                      ;
  113. *                                                               *
  114. *****************************************************************
  115. *               procedure de calcul                             *
  116. *****************************************************************
  117. TMASAU=table;
  118. tab1 . 'MES_SAUVEGARDES'=TMASAU;
  119. TMASAU .'DEFTO'=VRAI;
  120. TMASAU .'DEFIN'=VRAI;
  121. pasapas tab1                                                    ;
  122. *                                                               *
  123. *****************************************************************
  124. *               Calcul de la contrainte de Weibull axi          *
  125. *****************************************************************
  126. *sigu est une constante
  127. *                                                               *
  128. *               zone du critere                                 *
  129. surfcrit = elem surf2 1                                         ;
  130. zone1 = redu mod1 surfcrit;
  131. *                                                               *
  132. enttab1 = table                                                 ;
  133. enttab1.'XMULT' = 2.                                            ;
  134. enttab1.'OBJMO' = zone1                                         ;
  135. enttab1.'WEIBULL' = vrai                                        ;
  136. enttab1.'TNONL' = tab1                                          ;
  137. enttab1.'M' = m ; enttab1.'V0' = v0 ; enttab1.'SIGU' = sigu1    ;
  138. enttab1.'IC' = ic ; enttab1.'N' = n                             ;
  139. enttab1.'TEMPER'= 0                                             ;
  140. *                                                               *
  141. sortab1 = critloc enttab1;
  142. *                                                               *
  143. sigw1 = (sortab1.'SIGW').1.                                   ;
  144. *                                                               *
  145. *****************************************************************
  146. *               Calcul de la contrainte de Weibull axi          *
  147. *****************************************************************
  148. *sigu est une evolution constante
  149. *                                                               *
  150. *               zone du critere                                 *
  151. surfcrit = elem surf2 1                                         ;
  152. zone1 = redu mod1 surfcrit;
  153. *                                                               *
  154. enttab2 = table                                                 ;
  155. enttab2.'XMULT' = 2.                                            ;
  156. enttab2.'OBJMO' = zone1                                         ;
  157. enttab2.'WEIBULL' = vrai                                        ;
  158. enttab2.'TNONL' = tab1                                          ;
  159. enttab2.'M' = m ; enttab2.'V0' = v0 ; enttab2.'SIGU' = sigu2    ;
  160. enttab2.'IC' = ic ; enttab2.'N' = n                             ;
  161. enttab2.'TEMPER'= 1                                             ;
  162. enttab2.'TEREF'= 150.                                           ;
  163. *                                                               *
  164. sortab2 = critloc enttab2;
  165. *                                                               *
  166. sigw2 = (sortab2.'SIGW').1.                                    ;
  167. *                                                               *
  168. *****************************************************************
  169. *               Test d'erreur                                   *
  170. *****************************************************************
  171. ecart = ( abs(sigw1-sigw2) ) / sigw1                       ;
  172. mess 'ecart relatif : ' (ecart*100.) '%'                        ;
  173. si (ecart < 0.1 )                                               ;
  174.         erre 0                                                  ;
  175. sinon                                                           ;
  176.         erre 5                                                  ;
  177. finsi                                                           ;
  178. *                                                               *
  179. fin                                                             ;
  180.  
  181.  
  182.  
  183.  
  184.  
  185.  
  186.  
  187.  
  188.  
  189.  
  190.  
  191.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales