Télécharger la plaquette Cast3M


fr en

Télécharger raff05.dgibi

Retour à la liste

Numérotation des lignes : 

  1. ************************************************************
  2. ** raff05.dgibi
  3. ************************************************************
  4. *                                                          *
  5. *  Calcul elastique 2D avec un changement de niveau de     *
  6. *  raffinement dans une zonne  X-FEM                       *
  7. *  Test  : Raff , MODLI, FPMASS, RIGI1, RIGIX, RIGIXR,     *
  8. *  RUSRUR,  RIGSUX, TRIELE                                 *  
  9. *                                                          *
  10. *    ^ ^ ^ ^ ^ ^ ^                                         *
  11. *    | | | | | | |                                         *
  12. *    -------------  CL de Dirichlet                        *
  13. *   |             |                                        *
  14. *   |             |                                        *
  15. *   |             |                                        *
  16. *   |             |                                        *
  17. *   |   -=====-   | Fissure horizontale                    *
  18. *   |             |                                        *
  19. *   |             |                                        *
  20. *   |             |                                        *
  21. *   |             |                                        *
  22. *  > -------------  CL de Dirichlet                        *
  23. *    ^ ^ ^ ^ ^ ^ ^                                         *
  24. *                                                          *  
  25. * creation gg le                                           *
  26. ************************************************************
  27. ************************************************************
  28. TITRE 'raff05.dgibi' ;
  29.  
  30. OPTI DIME 2 ELEM QUA4 MODE PLAN DEFO ;
  31.  
  32. OPTI 'POTR' 'HELVETICA_16';
  34.  
  35. *graph = vrai;
  36. graph = faux ;
  37.  
  38. * dimention du caree
  39. l=10.;
  40. *paramètres de raffinement
  41.  
  42.  
  43. dens1min=(l/4.0);
  44. *d1min=dens1min**1.5;
  45. dens2min=(l/8.0);
  46. *d2min=dens2min**1.5;
  47. dens3min=(l/64.0);
  48.  
  49. densmax=(l/2)*1.000001 ;
  50. densma4= 8*densmax;
  51. dmin=0.00001;
  52. *dmin = (3*l/8);
  53. dmax=(l/2)*0.99999 ;
  54. dmax2=(l)*0.99999 ;
  55.  
  56. * Points
  57. p1 = 0. (-1.0*l) ;
  58. p2 = l (-1.0*l). ;
  59. p3 = l l ;
  60. p4 = 0. l ;
  61. p5 = (-1.0*l) (-1.0*l);
  62. p6 = (-1.0*l) l;
  63.  
  64.  
  65. * Lignes
  66. l12 = p1 DROI 2 p2;
  67. l23 = p2 DROI 4 p3;
  68. l34 = p3 DROI 2 p4;
  69. l41 = p4 DROI 4 p1;
  70. l14 = p1 DROI 2 p4;
  71. l45 = p4 DROI 2 p5;
  72. l51 = p5 DROI 2 p1;
  73.  
  74. * Surface
  75. s0 = DALL l12 l23 l34 l41;
  76. t0 = surf (l14 et l45 et l51);
  77. st0= s0 et t0 ;
  78.  
  79.  
  80. * Premier raffinement
  81.  
  82. x0 y0 = coor s0 ;
  83.  
  84. DF0= abs y0;
  85.  
  86. aff2 = ((((densmax) - dens2min)*(DF0 - dmax))/(dmax - dmin)) + densmax ;
  87. dens2 = born aff2 'SCAL' 'COMPRIS'
  88. (dens2min*1.000001) (densmax*1.000001);
  89.  
  90. aff2 = ((((densmax) - (dens3min/64))*(DF0 - (dmax)))/
  91. ((dmax) - (2*dmin))) + densmax ;
  92. dens2 = born aff2 'SCAL' 'COMPRIS'
  93. (dens2min*1.000001) (densmax*1.000001);
  94.  
  95. s02 = raff s0 dens2;
  96.  
  97.  
  98.  
  99. *----------- rafinement d'un maillage isssue de 2 it de raff ---------*
  100. x2 y2 = coor s02 ;
  101.  
  102. DF2= (((y2**2)+(((X2 - (l*2/7))/8)**2))**0.5); 
  103.  
  104.  
  105. aff23 = (((densmax - dens3min)*(DF2 - dmax))/(dmax - dmin)) + densmax ;
  106. dens23 = born aff23 'SCAL' 'COMPRIS'
  107. (dens3min*1.000001) (densmax*1.000001);
  108. s23 = raff s02 dens23;
  109. *s23 =s02;
  110.  
  111. *--------- Propriété materiau                                      ---*
  112.  
  113.  
  114. E1=2.09086E+11;
  115. nu1=0.3;
  116.  
  117.  
  118. *Courbe de traction matériau éprouvette
  119. EPS1 = PROG 0. 2.50007E-3 5.39261E-3 1.40558E-2 2.28078E-2 3.17654E-2 
  120. 4.1161E-2 5.14294E-2 6.33414E-2 7.82031E-2 9.81451E-2 0.12653 0.1685 
  121. 0.23177 0.32756 0.47195 0.68754 1.0056 1.4685 2.1336 3.0765 4.3966 
  122. 6.223 8.7212 12.102 16.633 22.647 30.56 40.883 54.247 71.419 93.330 
  123. 121.10 ;
  124.  
  125. SG1 = PROG 0. 522.73 532.73 562.73 592.73 622.73 652.73 682.73 712.73 
  126. 742.73 772.73 802.73 832.73 862.73 892.73 922.73 952.73 982.73 1012.7 
  127. 1042.7 1072.7 1102.7 1132.7 1162.7 1192.7 1222.7 1252.7 1282.7 1312.7 
  128. 1342.7 1372.7 1402.7 1432.7 ;
  129. SG1=SG1*1.0E+6;
  130.  
  131. EVTRAC = EVOL 'MANU' EPS1 SG1 ;
  132.  
  133.  
  134. *-----------geometrie fissure -----------------------------------------*
  135.  
  136. pf1 = (l*2/7)  (l*3/64); 
  137. pf2 = (l*5/7) (l*3/64); 
  138. pmilieu = (l/2) (l*3/64);
  139.  
  140. lfiss =  pf1 DROI 10 pf2;
  141.  
  142.  
  143. *----------modelisation xfem ------------------------------------------*
  144. x23 y23 = coor s23 ;
  145. PSI1 PHI1 = PSIPHI s23 LFISS 'DEUX' pf1 pf2;
  146.  
  147. *PTX = POIN (abs(y23)) 'INFERIEUR' (L/4) ;
  148. PTX = POIN (abs(y23)) 'INFERIEUR' (L/8) ;
  149.  
  150.  
  151. SURFX = S23 ELEM 'APPUYE' 'LARGEMENT' PTX ;
  152. SURFFEM = S23 DIFF SURFX ;
  153.  
  154.  
  155. *MODX = MODE SURFX MECANIQUE ELASTIQUE PLASTIQUE XQ4R ;
  156. MODX = MODE SURFX MECANIQUE ELASTIQUE XQ4R ;
  157.  
  158.  
  159. *list modx;
  160. MATX = MATE MODX 'YOUN' E1 'NU' nu1 ;
  161. *MNLX = MATE MODX YOUN E1 NU nu1 TRAC EVTRAC ;
  162.  
  163. *MODFEM = MODE SURFFEM MECANIQUE ELASTIQUE PLASTIQUE ;
  164. MODFEM = MODE SURFFEM MECANIQUE ELASTIQUE ;
  165.  
  166.  
  167. MATFEM = MATE MODFEM 'YOUN' E1 'NU' nu1 ;
  168. *MNLFEM = MATE MODFEM YOUN E1 NU nu1 TRAC EVTRAC ;
  169.  
  170. *CHPENR REL1 = TRIE (MODX)  PSI1 PHI1 'DESE' ;
  171. CHPENR = TRIE (MODX)  PSI1 PHI1 ;
  172.  
  173. * constructionsion des blocages des ddl X-fem non actifs dans 
  174. * les éléments de transition.
  175. * Ainsi que des relations de conformité dues au raffinement.
  176. REL1 = RELA (MODX et MODFEM);
  177. *---------Rigidite ---------------------------------------------*
  178.  
  179. RigX = RIGI(MODX et MODFEM) (MATX et MATFEM);
  180. *RNLX = RIGI(MODX et MODFEM) (MNLX et MNLFEM);
  181.  
  182. *---------condition aux limite et chargement    ----------------*
  183.  
  184.  
  185. lb23 = s23 POIN 'DROI' p1 p2 0.001;
  186. cl23 = BLOQ lb23 uy;
  187. clx = BLOQ p1 ux;
  188.  
  189. lp23 = (cont s23) elem 'APPUYE' 'STRICTEMENT' l34;
  190. presX = PRES 'MASS' (modX et modfem) -2.0E10 lp23 ;
  191.  
  192. clp = bloq lp23 uy  ;
  193. f1 = depi clp 1. ;
  194. LI1 = PROG 0. 1. ;
  195. LI2 = PROG 0. 1. ;
  196.  
  197. CHPO1 = MANU  'CHPO' lp23 'FY'  -2.0E11 ;
  198. EV1 = EVOL MANU T LI1 F(T) LI2 ;
  199. CHA1 = CHAR 'DIMP' F1 EV1 ;
  200.  
  201. *---------- resolution d'un pb linéaire sur le maillage X-FEM----------*
  202.  
  203. resX = reso (rigX et cl23 et clx et CLP et REL1) F1;
  204. SIGX = SIGM (MODX et MODFEM ) (MATX et MATFEM) resx 'LINE';
  205. defX  = defo 1.0 resX s23 ;
  206. FOR1 = BSIG (MODX et MODFEM) SIGX;
  207. EPS1 = EPSI  (MODX et MODFEM) resX 'LINE' ;
  208.  
  209. resXR = XFEM 'RECO' resx (MODX et MODFEM) ;
  210. defXR  = defo 1.0 resXr s23 ;
  211. DPSUP DPINF = XFEM 'FISS' lfiss resX (MODX et MODFEM) ;
  212. DEFfiss = (DEFO 1.  DPSUP lfiss'VERT') et
  213.  (DEFO 1.   DPINF lfiss 'ROUG')  ;
  214.  
  215. si (graph);
  216.     trac (s23 et (coul bleu surfX) et  (coul roug Lfiss)) 
  217.     (vect presx 'FORC' 'ROUG') TITR ' Maillage raffine et enrichi' ;
  218.     trac (DEFfiss et defxR)  TITR 'Deformee';
  219.     trac resx (surfx et lfiss) TITR 'Champ de deplacement XFEM';
  220.     trac sigx (modx) TITR 'Champ de contraintes ';
  221.     trac FOR1 S23 TITR 'Forces Nodales';
  222.     trac EPS1 (MODX et MODFEM) TITR 'DEFORMATIONS';
  223.     trac resxR (surfx et lfiss) TITR 'Champ de deplacement FEM' ;
  224. finsi ;
  225.  
  226. *---------- resolution d'un pb non linéaire sur le maillage X-FEM------*
  227.  
  228. *Résolution PASAPAS
  229. TABPAP = TABLE ;
  230. TABPAP . 'TEMPS_CALCULES' = PROG 0. pas 0.1 1. ;
  231. TABPAP . 'CARACTERISTIQUES' = (MATX et MATFEM) ;
  232. TABPAP . 'CHARGEMENT' = CHA1 ;
  233. TABPAP . 'BLOCAGES_MECANIQUES' = cl23 et clx  ET CLP et REL1;
  234. TABPAP . 'MODELE' = (MODX et MODFEM) ;
  235. TABPAP . 'LAGRANGIEN' = mot 'REACTUALISE' ;
  236. PASAPAS TABPAP ;
  237.  
  238. Udiff = resx - (tabpap.deplacements.10);
  239. diffy = exco Udiff 'UY';
  240. diffy2 =  chan 'CHAM' (diffy **2) s23;
  241. si (graph);
  242.    trac Udiff (surfx et lfiss) TITR 'différence entre reso et pasapas';
  243. finsi ;
  244.  
  245. * geometrie pour le post traitement
  246. phaut = (L/2) L;
  247. pbas = (L/2) 0;
  248.  
  249. * symetrie
  250.  
  251. uy1 = exco resxR 'UY';
  252. S23sym uysym1  = s23 uy1 SYME 'DROIT' phaut pbas;
  253. * passage a un chamelem aux noeuds
  254. uysym2 = chan 'CHAM' uysym1 S23sym;
  255. * projection
  256. uysym3 = PROI uysym2 s23;
  257.  
  258. * passage de uproj en chpoin
  259. uy3= chan 'CHAM' uy1 s23;
  260.  
  261. diffy =  (uysym3-uy1)**2;
  262. diffy1 = chan 'CHAM' diffy s23;
  263.  
  264. unor = CHAN 'CHAM' ((uy1)**2) s23;
  265.  
  266.  
  267. ptsym = poin y23 compris 1.0 1.5;
  268. ssym = elem s23 appu larg ptsym ;
  269. modsym = redu  MODFEM ssym;
  270. erry1 = (INTG (modsym) diffy1) / (INTG (modsym) unor);
  271. list erry1;
  272.  
  273. si (graph);
  274.  trac (abs (uysym3 - uy1)) ssym TITR 'Defaut de symetrie de la composante Uy';
  275. finsi ;
  276.  
  277. SI  (erry1 < (1.0E-5));
  278.   'MESS' ' ----------------------' ;
  279.   'MESS' '  SUCCES DU CAS-TEST !' ;
  280.   'MESS' ' ----------------------' ;
  281.   Erre 0;
  282. Sinon ;
  283.   'MESS' ' ---------------------' ;
  284.   'MESS' '  ECHEC DU CAS-TEST !' ;
  285.   'MESS' ' ---------------------' ;
  286.   Erre 5;
  287. finsi ;
  288.  
  289. erry2 = (INTG (MODsym) diffy2) / (INTG (MODsym) unor);
  290. list erry2;
  291. SI  (erry2 < (1.0E-15)) ;
  292.   'MESS' ' ----------------------' ;
  293.   'MESS' '  SUCCES DU CAS-TEST !' ;
  294.   'MESS' ' ----------------------' ;
  295.   Erre 0 ;
  296. Sinon ;
  297.   'MESS' ' ---------------------' ;
  298.   'MESS' '  ECHEC DU CAS-TEST !' ;
  299.   'MESS' ' ---------------------' ;
  300. optio donn 5;
  301.   Erre 5;
  302. finsi;
  303. FIN;
  304.  
  305.  
  306.  
  307.  
  308.  
  309.  
  310.  
  311.  
  312.  
  313.  
  314.  
  315.  
  316.  
  317.  
  318.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales