Télécharger la plaquette Cast3M


fr en

Télécharger raff02.dgibi

Retour à la liste

Numérotation des lignes : 

  1. ************************************************************
  2. ** raff02.dgibi
  3. ************************************************************
  4. * TEST de la procedure de raffinement en cour de calcul    *
  5. *       RAFF - PASAPAS - PROI en 3D avec plasticite        *
  6. *                  un seul raffinements                    *
  7. *   Calcul sur une CT comparaison avec l'essais 520RY-AT   *
  8. *   realise au DM2S/SEMT/LISN                              *
  9. *                                                          *
  10. *création : gg, le 15.03.2017                              *
  11. ************************************************************
  12.  
  13.  
  14. ************************************************************
  15. *                                                          *
  16. *                       MAILLAGE CT25                      *
  17. *       Metal de base 707 + cordon de soudure              *
  18. *                                                          *
  19. ************************************************************
  20. ************************************************************
  21.  
  22. TITRE 'EPROUVETTE CT25 3D' ;
  23. OPTI DIME 3 ELEM CUB8 ;
  25. *---------------------------------------------------
  26. *---------------------------------------------------
  27. * Option de trace
  28. graph = faux;
  29. *graph = vrai;
  30. graph_ps = faux;
  31. *graph_ps = vrai;
  32. *---------------------------------------------------
  33.  
  34. *---------------------------------------------------
  35. *---------------------------------------------------
  36. *     DONNEES
  37. *     unites = m N Pa
  38. *---------------------------------------------------
  39. *---------------------------------------------------
  40.  
  41. dn = 1.0E-7;
  42.  
  43. *      Fissure
  44. *---------------------------------------------------
  45. * Taille de maille fissure ;
  46.  
  47. tm =5.0E-5;
  48. * longueur prefissure
  49.  
  50. lpfis = 0.02482;
  51.  
  52.  
  53. * CHOISIR longueur fissure maillage
  54. xfis10 = lpfis;
  55.  
  56.  
  57. *      Eprouvettete
  58. *---------------------------------------------------
  59. a=0.02;
  60.  
  61. le = 0.004;
  62.  
  63. ep = 0.025 ;
  64.  
  65. *paramètres de raffinement
  66.  
  67. dmin=0.0030;
  68. densmax=0.008 ;
  69. densmin=densmax/8;
  70. *densmin=densmax/16.;
  71. dmax=dmin + (2*densmax) ;
  72.  
  73. *---------------------------------------------------
  74. *      Nb elements
  75. *---------------------------------------------------
  76.  
  77. * epaisseur eprouvette
  78. ne_ep = 3 ;
  79. np_ep =ne_ep + 1;
  80. * maillage fissure
  81. nf1 = 59;
  82.  
  83. nf2 = 2;
  84.  
  85.  
  86.  
  87. * cercle goupille
  88. * nc1 multiple de 4
  89. nc1 = 32 ;
  90. *
  91. * nc2 multiple de 2
  92. nc2 = 2 ;
  93. ne1 = 2 ;
  94. ne2 = 2 ;
  95. ne3 = 4 ;
  96.  
  97.  
  98. *---------------------------------------------------
  99. *      Eprouvette
  100. *---------------------------------------------------
  101.  
  102. * rayons
  103. r2 = 0.005 ;
  104.  
  105. r3 = 0.00625 ;
  106.  
  107. * angles
  108. a1 = 15. ;
  109. a2 = 30. ;
  110.  
  111. * ordonnees
  112. y1 = 0.0015 ;
  113. y2 = le/2. ;
  114. y3 = 0.006 ;
  115. y5 = 0.0155 ;
  116. y6 = 0.03 ;
  117. *
  118. yf1 = tm*3*3*2;
  119. list yf1;
  120.  
  121. * abscisses
  122. x1 = -0.0125 ;
  123. x2 = 0.00458 ;
  124. x3 = x2 + r2 ;
  125. x5 = a;
  126. x6 = 0.05;
  127. *
  128. xf1 = x6 - (nf1*3*3*tm);
  129. list xf1;
  130.  
  131. * coordonnees supplementaires
  132. y4 = y3 + ((-1.)*(x1*(tan(a1))))  ;
  133. x4 = x5 + ((-1.)*(y1/(tan(a2))))  ;
  134. x7 = x3 + (y3 - y2);
  135.  
  136.  
  137.  
  138.  
  139. *---------------------------------------------------
  140. *---------------------------------------------------
  141. *     MAILLAGE
  142. *
  143. *---------------------------------------------------
  144. *---------------------------------------------------
  145.  
  146. *---------------------------------------------------
  147. *      Les points
  148. *---------------------------------------------------
  149.  
  150. * centres des cercles
  151. O1 = 0. y5 0.;
  152. O2 = x2 0. 0.;
  153.  
  154. * contour eprouvette
  155. p1 = x6 0. 0.;
  156. p2 = x6 y6 0.;
  157. p3 = x1 y6 0.;
  158. p4 = x1 y4 0.;
  159. p5 = 0. y3 0.;
  160. p7 = 0. y2 0.;
  161. p8 = x3 y1 0.;
  162. p9 = x4 y1 0.;
  163. p10 = x5 0. 0.;
  164.  
  165. * sous decoupe eprouvette
  166. p11 = x7 y6 0.;
  167. p12 = (p11 COOR 1) (p5 COOR 2) 0.;
  168. p13 = (p11 COOR 1) (p9 COOR 2) 0.;
  169. p14 = x4 y6 0.;
  170. p15 = (p14 COOR 1) (p5 COOR 2) 0.;
  171. p16 = (p1 COOR 1) (p9 COOR 2) 0.;
  172. p17 = (p1 COOR 1) (p15 COOR 2) 0.;
  173. p18 = (r3*((2**(0.5))/2)) (y5+(r3*((2**(0.5))/2))) 0.;
  174. p19 = ((-1.)*(p18 COOR 1)) (p18 COOR 2) 0.;
  175.  
  176. p20 = xfis10 0. 0. ;
  177. p21 = xfis10 y1 0. ;
  178. p22 = xfis10 y3 0. ;
  179. p23 = xfis10 y6 0. ;
  180.  
  181. *--------------------------------------------------
  182. *      Les lignes
  183. *---------------------------------------------------
  184. * eprouvette (sans fissure) ----------
  185. * se1
  186. p9p13 = p9 DROI ne2 p13;
  187. p15p12 = P15 DROI ne2 p12;
  188. * se2
  189. p14p11 = p14 DROI ne2 p11;
  190. * se3
  191. p13p12 = p13 DROI ne1 p12;
  192. p12p5 = p12 DROI (1+(nc1/8)) p5;
  193. p13p5 = p13p12 ET p12p5;
  194. ELIM dn p13p5 ; p13p5 = REGE p13p5;
  195. *p8p7 = CERC ((-1)*(ne1+1+(nc1/8))) p8 O2 p7 'DINI' 0.1 'DFIN' 2.;
  196. p8p7 = CERC ((-1)*(ne1+1+(nc1/8))) p8 O2 p7 'DINI' 0.0001 'DFIN' 0.002;
  197. p13p8 = p13 DROI nc2 p8;
  198. p7p5 = p7 DROI (nc2) p5;
  199. ELIM dn p7p5 ; p7p5 = REGE p7p5;
  200. *se4
  201. p18p19 = CERC (nc1/4) p18 O1 p19;
  202. p11p3 = p11 DROI (nc1/4) p3;
  203. c11 = CERC ((3*(nc1/4))/2) p19 O1 (O1 PLUS (0. ((-1)*r3) 0.));
  204. c12 = CERC ((3*(nc1/4))/2) (O1 PLUS (0. ((-1)*r3) 0.)) O1 p18;
  205. c1 = c11 ET c12;
  206. ELIM dn c1; c1 = REGE c1;
  207. p3p4 = p3 DROI (nc1/4) p4;
  208. p4p5 = p4 DROI ((-1)+(nc1/8)) p5;
  209. p5p12 = p5 DROI ((+1)+(nc1/8)) p12;
  210. p12p11 = p12 DROI (nc1/4) p11;
  211. c1bis = p3p4 ET p4p5 ET p5p12 ET p12p11;
  212.  
  213.  
  214. *--------------------------------------------------
  215. *     Les surfaces
  216. *---------------------------------------------------
  217.  
  218. * eprouvette (sans fissure) *-----------------------
  219. se1 = p9p13 REGL ne1 p15p12;
  220. se2 = p15p12 REGL (nc1/4) p14p11;
  221. se3 = DALL (INVE p13p5) p13p8 p8p7 p7p5;
  222. se4a = p18p19 REGL 4 p11p3;
  223. se4b = c1 REGL 4 c1bis;
  224. se4 = se4a ET se4b;
  225. ELIM dn se4; se4 = REGE se4;
  226.  
  227. * eprouvette avec fissure   *-----------------------
  228.  
  229. p15p22 = droi 3 p15 p22;
  230. p14p23 = droi 3 p14 p23;
  231. se5 = regl 8 p15p22 p14p23;
  232. elim dn se2 se5;
  233.  
  234. p22p17 = droi 9 p22 p17;
  235. p23p2 = droi 9 p23 p2;
  236. se6 = regl 8 p22p17 p23p2;
  237. elim dn se5 se6;
  238.  
  239. p9p21 = droi 3 p9 p21;
  240. se7 = regl 1 p9p21 p15p22;
  241. elim dn se1 se7;
  242. elim dn se6 se7;
  243.  
  244. p21p16 = droi 9 p21 p16;
  245. se8 = regl 1 p21p16 p22p17;
  246. elim dn se6 se8;
  247. elim dn se7 se8;
  248.  
  249. p10p20 = droi 3 p10 p20;
  250. se9 = regl 1 p10p20 p9p21;
  251. elim dn se9 se7;
  252.  
  253. p20p1 = droi 9 p20 p1;
  254. se10 = regl 1 p20p1 p21p16;
  255. elim dn se10 se9;
  256. elim dn se10 se8;
  257.  
  258. si (graph) ;
  259.    trac (se1 et se2 et se3 et se4 et se5 et se6 et se7 et se8 et se9 et se10);
  260. finsi ;
  261. * eprouvette totale *--------------------------------
  262. seprou = se1 et se2 et se3 et se4 et se5 et se6 et se7 et se8 et se9 et se10;
  263. ELIM dn seprou;
  264. seprou = REGE seprou;
  265.  
  266.  
  267. * goupille *-----------------------------------------
  268. O1p18 = O1 DROI 1 p18;
  269. sgoup= O1p18 ROTA (nc1/4) (90.) O1 (O1 PLUS (0. 0. 1.));
  270. ELIM dn sgoup; sgoup = REGE sgoup;
  271. * ELIM dn (vgoupet seprou);
  272. *ELIM 0.001 (vgoupet seprou);
  273. ELIM 0.000001 (sgoup et seprou);
  274. *ELIM 0.001 seprou ;
  275. ELIM 0.000001 seprou ;
  276.  
  277. *--------------------------------------------------
  278. *     Les volumes
  279. *---------------------------------------------------
  280. veprou= seprou VOLU ne_ep 'TRAN' (0. 0. (ep/2.));
  281. vcub8 = veprou;
  282.  
  283. vgoup = sgoup VOLU ne_ep 'TRAN' (0. 0. (ep/2.));
  284.  
  285. ELIM 0.000001 (vgoup et veprou );
  286.  
  287. *--------------------------------------------------
  288. *     Boite pour la visualisation
  289. *--------------------------------------------------
  290. p24 = (1.2*xfis10) 0. 0. ;
  291. p9p24 = droi 1 p9 p24;
  292. sboit = p9p24 TRAN 1 (0. 0. (ep/2.));
  293.  
  294.  
  295. *----------------------------------------------------
  296. *     Geometries pour CL en 3D et fissure
  297. *----------------------------------------------------
  298. xeprou yeprou  zeprou = coor veprou ;
  299. pmil = yeprou poin 'INFERIEUR' (1.E-4*tm);
  300. lmil = (enve veprou) elem 'APPUYE' pmil ;
  301. fronfis = DROI ne_ep p20  (xfis10 0. (ep/2.));
  302. psym1 = xeprou poin 'SUPERIEUR' xfis10;
  303. pfis1 = xeprou poin 'INFERIEUR' xfis10;
  304. ssym1 = lmil elem 'APPUYE' 'LARGEMENT' psym1 ;
  305. sfis10 = lmil elem 'APPUYE' 'LARGEMENT' pfis1 ;
  306. surfz0= seprou;
  307.  
  308. xgoup ygoup zgoup  = coor vgoup;
  309. lchar = ygoup poin 'INFERIEUR' (y5+(1.E-4*tm));
  310.  
  311. si (graph) ;
  312.  
  313.   trac (vcub8 et (vgoup coul bleu) et (ssym1 coul roug) et (sfis10 coul vert)) 'CACH';
  314.   OPTI TRAC PSC ;
  315. *  OPTI FTRA 'proj_images/mail_n.ps';
  316.   trac (vcub8 et (vgoup coul bleu) et (ssym1 coul roug) et (sfis10 coul vert)) 'CACH';
  318. finsi ;
  319.  
  320. *----------------------------------------------------
  321. *     Modèle + Matériau
  322. *----------------------------------------------------
  323.  
  324. *Modèles éprouvette
  325. MODEPR = MODE VEPROU MECANIQUE ELASTIQUE PLASTIQUE ;
  326. MODC8  = MODE VCUB8  MECANIQUE ELASTIQUE PLASTIQUE ;
  327.  
  328. *Caractéristique materiaux
  329.  
  330. E1=2.09086E+11;
  331. nu1=0.3;
  332.  
  333. *Courbe de traction matériau éprouvette
  334. EPS1 = PROG 0. 2.50007E-3 5.39261E-3 1.40558E-2 2.28078E-2 3.17654E-2 4.1161E-2 5.14294E-2 6.33414E-2 7.82031E-2 9.81451E-2 0.12653 0.1685 0.23177 0.32756 0.47195 0.68754 1.0056 1.4685 2.1336 3.0765 4.3966 6.223 8.7212 12.102 16.633 22.647 30.56 40.883 54.247 71.419 93.330 121.10 ;
  335.  
  336. SG1 = PROG 0. 522.73 532.73 562.73 592.73 622.73 652.73 682.73 712.73 742.73 772.73 802.73 832.73 862.73 892.73 922.73 952.73 982.73 1012.7 1042.7 1072.7 1102.7 1132.7 1162.7 1192.7 1222.7 1252.7 1282.7 1312.7 1342.7 1372.7 1402.7 1432.7 ;
  337. SG1=SG1*1.0E+6;
  338. EVTRAC = EVOL 'MANU' EPS1 SG1 ;
  339. lsm1   = sg1 enle 1 ;
  340. Lep1   = ((eps1 enle 1) - (lsm1 / E1)) born mini 0. ;
  341. evec   = evol vert manu eps lep1 sig lsm1 ;
  342.  
  343. si (graph);
  344.    dess (evtrac et evec) titr ' Courbes de tracation et d ecrouissage (vert)' ;
  345. finsi ;
  346.  
  347. *Matériaux éprouvette
  348. MATEPR = MATE MODEPR YOUN E1 NU nu1 ECRO evec ;
  349.  
  350.  
  351. *Modèle goupille
  352. MODGOUP = MODE VGOUP MECANIQUE ELASTIQUE ;
  353.  
  354. *Matériau goupille
  355. MATGOUP = MATE MODGOUP YOUN E1 NU nu1 ;
  356.  
  357.  
  358. MODold=(MODEPR et MODGOUP);
  359.  
  360.  
  361.  
  362. *----------------------------------------------------
  363. *     CL + Chargement
  364. *----------------------------------------------------
  365.  
  366.  
  367.  
  368.  
  369.  
  370. cl1 = bloq ssym1 uy ;
  371. cl2 = bloq lchar uy  ;
  372. cl3 = bloq (surfz0 et sgoup) uz;
  373. cl4 = bloq lchar ux ;
  374. CL = CL1 ET CL2 et cl3 et CL4;
  375. CLodl=CL;
  376.  
  377. uchar=0.0016;
  378. f1 = depi cl2 uchar/2;
  379.  
  380.  
  381. LI1 = PROG 0. 1. ;
  382. LI2 = PROG 0. 1. ;
  383. EV1 = EVOL MANU T LI1 F(T) LI2 ;
  384.  
  385. CHA1 = CHAR 'DIMP' F1 EV1 ;
  386. list CHA1;
  387. *----------------------------------------------------
  388. *     Résolution de tout le problème
  389. *     sur le maillage grossier
  390. *----------------------------------------------------
  391. f4 = depi cl2 uchar;
  392. LI4 = PROG 0.0 1.0 ;
  393. EV4 = EVOL MANU T LI1 F(T) LI4 ;
  394. CHA4 = CHAR 'DIMP' F4 EV4 ;
  395.  
  396. TABPAP4=0.;
  397. TABPAP4= TABL;
  398. TABPAP4 . 'TEMPS_CALCULES' = PROG 0. pas 0.05 1. ;
  399. TABPAP4 . 'CARACTERISTIQUES' = (MATEPR et matgoup) ;
  400. TABPAP4 . 'CHARGEMENT' = CHA4 ;
  401. TABPAP4 . 'BLOCAGES_MECANIQUES' = CL ;
  402. TABPAP4 . 'MODELE' = (MODEPR et modgoup) ;
  403. TABPAP4 . 'LAGRANGIEN' = mot 'REACTUALISE' ;
  404. PASAPAS TABPAP4 ;
  405.  
  406. eglo4=PROG;
  407. I=0;
  408. repe bcl4 20 ;
  409.    I=I+1;
  410.  
  411.    sig1 = TABPAP4 . 'CONTRAINTES' . i;
  412.    eps1 = EPSI (MODEPR et modgoup) TABPAP4 . 'DEPLACEMENTS'. i  'LINE';
  413.    eloc1 = ENER (MODEPR et modgoup)  eps1 sig1;
  414.    eglo1 = INTG eloc1 (MODEPR et modgoup) ;
  415.    eglo4 = eglo4 et eglo1 ;
  416.  
  417.  
  418.  
  419. fin bcl4;
  420.  
  421. *DESS ev1;
  422. *----------------------------------------------------
  423. *     Premier pas de résolution résolution
  424. *----------------------------------------------------
  425. temps=TABL;
  426.  
  427. *Résolution PASAPAS
  428. TABPAP = TABLE ;
  429. TABPAP . 'TEMPS_CALCULES' = PROG 0. pas 0.1 1. ;
  430. TABPAP . 'CARACTERISTIQUES' = (MATEPR et matgoup) ;
  431. TABPAP . 'CHARGEMENT' = CHA1 ;
  432. TABPAP . 'BLOCAGES_MECANIQUES' = CL ;
  433. TABPAP . 'MODELE' = (MODEPR et modgoup) ;
  434. TABPAP . 'LAGRANGIEN' = mot 'REACTUALISE' ;
  435. PASAPAS TABPAP ;
  436. TABRAF=TABL;
  437. TABRAF.1=TABPAP;
  438.  
  439.  
  440. ouv2 = PROG 0.0;
  441. for2 = PROG 0.0;
  442. eglo2= PROG 0.0;
  443. KI2 = PROG 0.0;
  444. Sig_m2 = PROG 0.0;
  445. KIamorc = 1213.;
  446.  
  447. repe bcl1 10 ;
  448.  
  449.    ouv2 = ouv2 ET (2*(EXTR (TABPAP . 'DEPLACEMENTS' . &bcl1)  'UY' P7));
  450.  
  451.    for1=0  ;
  452.    REPE bcl11 4;
  453.       for1 = for1 + ((EXTR (TABPAP. 'REACTIONS' . &bcl1 )'FY' (POIN lchar &bcl11))*2);
  454.    fin bcl11;
  455.    for2 = for2 ET for1;
  456.    sig1 = TABPAP . 'CONTRAINTES' . &bcl1;
  457.    eps1 = EPSI (MODEPR et modgoup) TABPAP . 'DEPLACEMENTS'. &bcl1  'LINE';
  458.    eloc1 = ENER (MODEPR et modgoup)  eps1 sig1;
  459.    eglo1 = INTG eloc1 (MODEPR et modgoup) ;
  460.    eglo2 = eglo2 et eglo1 ;
  461.  
  462.  
  463. fin bcl1;
  464. *-----------------------------------------------------------------------
  465. *                                       - raffiner le maillage
  466. *                                       - receer le mod et le mat
  467. *                                       - recreer les cl
  468. *                                       - incrémenter le chargement
  469. *                                       - projeter les variables issu
  470. *                                       du dernier pas de pasapas
  471. *                                       - réaliser la suite du calcul
  472. *                                       pasapas
  473. *-----------------------------------------------------------------------
  474.  
  475.  
  476. *-----------------------------------------------------------------------
  477. *      Raffinement autour de la pointe de fissure
  478. *-----------------------------------------------------------------------
  479.  
  480. xeprou yeprou  zeprou= coor veprou ;
  481.  
  482. DF1= (((yeprou**2) + ((xfis10 -xeprou)**2.))**0.5);
  483. *DF1= (((yeprou**2) + ((BORN  ((xfis10 - 0.0032)-xeprou)
  484. *'SCAL' 'MINIMUM' 0.0)**2.))**0.5);
  485.  
  486. aff = (((densmax - densmin)*(DF1 - dmax))/(dmax - dmin)) + densmax ;
  487. dens1 = born aff 'SCAL' 'COMPRIS' (densmin*1.000001) (densmax*1.000001);
  488.  
  489. si (graph) ;
  490.     trac dens1 veprou ;
  491. finsi ;
  492.  
  493. VOLD= (VEPROU et VGOUP);
  494.  
  495. veprou = raff veprou dens1 ;
  496. *    LIST (NBEL SEPROU);
  497.  
  498.  
  499. VOLURL = ELEM VEPROU SURE ;
  500. VCUB8 = VEPROU DIFF VOLURL ;
  501.  
  502. ELIM 0.000001 (Vgoup et Veprou);
  503. ELIM 0.000001 Veprou ;
  504. ELIM 0.000001 VCUB8 ;
  505. *----------------------------------------------------
  506. *     Geometries pour CL en 3D et fissure
  507. *----------------------------------------------------
  508.  
  509. xeprou yeprou  zeprou = coor veprou ;
  510. pmil = yeprou poin 'INFERIEUR' (1.E-4*tm);
  511. lmil = (enve veprou) elem 'APPUYE' pmil ;
  512. fronfis = DROI ne_ep (xfis10 0. 0.)  (xfis10 0. (ep/2.));
  513. psym1 = xeprou poin 'SUPERIEUR' xfis10;
  514. pfis1 = xeprou poin 'INFERIEUR' xfis10;
  515. ssym1 = lmil elem 'APPUYE' 'LARGEMENT' psym1 ;
  516. sfis10 = lmil elem 'APPUYE' 'LARGEMENT' pfis1 ;
  517. poiz0 = zeprou poin 'INFERIEUR' (1.E-4*tm);
  518. surfz0 = (enve veprou) elem 'APPUYE' poiz0 ;
  519.  
  520. si (graph) ;
  521.  
  522.   trac (vcub8 et (vgoup coul bleu) et (ssym1 coul roug) et (sfis10 coul vert)) 'CACH';
  523.  
  524. finsi ;
  525.  
  526. *----------------------------------------------------
  527. *     Modèle + Matériau
  528. *----------------------------------------------------
  529.  
  530. MODOLD = MODEPR;
  531. MODEPR = MODE VEPROU MECANIQUE ELASTIQUE PLASTIQUE ;
  532. MODC8  = MODE VCUB8  MECANIQUE ELASTIQUE PLASTIQUE ;
  533. MATEPR = MATE MODEPR YOUN E1 NU nu1 ECRO evec ;
  534. MATC8  = MATE MODC8  YOUN E1 NU nu1 ECRO evec ;
  535. *----------------------------------------------------
  536. *     CL + Chargement
  537. *----------------------------------------------------
  538.  
  539. KEPR = RIGI MODEPR MATEPR ;
  540.  
  541. *----------------------------------------------------
  542. * Matrice de Raideur (relation de conrformité géom)
  543. *----------------------------------------------------
  544.  
  545. KRELA = RELA MODEPR ;
  546.  
  547. *----------------------------------------------------
  548. *     CL + Chargement
  549. *----------------------------------------------------
  550.  
  551. cl1 = bloq ssym1 uy ;
  552.  
  553. cl2 = bloq lchar uy  ;
  554.  
  555. cl3 = bloq (surfz0 et sgoup) uz;
  556. cl4 = bloq lchar ux ;
  557. CL = CL1 ET CL2 et cl3 et CL4;
  558. CLodl=CL;
  559.  
  560. f1 = depi cl2 (uchar/2);
  561. LI2 = PROG (1.0) (2.0) ;
  562. EV1 = EVOL MANU T LI1 F(T) LI2 ;
  563. CHA1 = CHAR 'DIMP' F1 EV1 ;
  564. list CHA1;
  565.  
  566.  
  567. *-----------------------------------------------------------------------
  568. *     Projection des champs issues de l'iteration précédente
  569. *-----------------------------------------------------------------------
  570.  
  571. *    DEPLACEMENT
  572. uold=tabpap.continuation.deplacements;
  573. ugoup= redu uold vgoup;
  574. * passage de u en chamelem
  575. uproj1 = chan 'CHAM' (redu vold uold) vold;
  576. * projection
  577. uproj2 = PROI uproj1 VEPROU;
  578. * passage de uproj en chpoin
  579. uproj3 = chan 'CHPO' uproj2 MODEPR;
  580.  
  581. uproj= uproj3 et ugoup ;
  582.  
  583. si (graph) ;
  584.     trac uold vold TITR 'u old';
  585.     trac uproj VEPROU  TITR 'u proj';
  586. finsi;
  587.  
  588. *CONTRAINTES
  589.  
  590. sigold=tabpap.continuation.contraintes;
  591. siggoup= redu sigold vgoup;
  592.  
  593. * passage point de gausses -> noeuds du chaml
  594. sigproj1 = CHAN  'NOEUD' MODOLD  (redu vold sigold)  ;
  595. * projection
  596. sigproj2= PROI modepr sigproj1 'STRESSES';
  597. * passage noeuds -> point de gausses du chaml
  598.  
  599. *list sigproj2;
  600. sigproj4 = CHAN 'TYPE' sigproj2 'CONTRAINTES';
  601. sigproj = sigproj4 et siggoup ;
  602.  
  603.  
  604.  
  605. si (graph) ;
  606.      trac sigold modold TITR 'sig old';
  607.      trac sigproj modepr TITR 'sig proj';
  608.  
  609. finsi;
  610.  
  611. *VARIABLES_INTERNES
  612.  
  613. pold=tabpap.continuation.variables_internes;
  614. pgoup= redu pold vgoup;
  615.  
  616. * passage point de gausses -> noeuds du chaml
  617. pproj1 = CHAN  'NOEUD' MODOLD  (redu vold pold)  ;
  618. * projection
  619. pproj2= PROI modepr pproj1 'STRESSES';
  620.  
  621. * positivité de p
  622. pproj3= born pproj2 'EPSE' 'MINIMUM' 0.0;
  623.  
  624. pproj= pgoup et pproj3;
  625.  
  626. si (graph) ;
  627.     trac pold modold TITR 'p old';
  628.     trac pproj modepr TITR 'p proj';
  629. finsi;
  630.  
  631. * calcul de l'énergie de déformation
  632.  
  633. epsold = EPSI (MODOLD et modgoup)  uold 'LINE';
  634. elocold = ENER (MODOLD et modgoup) epsold sigold;
  635. egloold = INTG elocold (MODOLD et modgoup) ;
  636.  
  637. epsproj = EPSI (modepr et modgoup )  uproj 'LINE';
  638. elocproj = ENER (modepr et modgoup ) epsproj sigproj;
  639. egloproj = INTG elocproj (MODEPR et modgoup) ;
  640.  
  641. step1=(0.0 + 5.0E06)/22 ;
  642. liii1= PROG (0.0) PAS step1 5.0E06;
  643. step1=(0.0 + 3.50E08)/22 ;
  644. liii1= PROG (0.0) PAS step1 3.50E08;
  645.  
  646. si (graph) ;
  647.   trac liii1 elocold modold   TITR 'energie champ avant proj';
  648.   trac liii1 elocproj modepr  TITR 'energie champprojete';
  649.  
  650.   trac elocold modold  TITR 'energie champ avant proj';
  651.   trac elocproj modepr TITR 'energie champprojete';
  652. finsi;
  653.  
  654. *Résolution PASAPAS
  655. TABPAP=0.;
  656. TABPAP= TABL;
  657. TABPAP . 'TEMPS_CALCULES' = PROG 0. pas 0.1 1. ;
  658. TABPAP . 'CARACTERISTIQUES' = (MATepr et matgoup) ;
  659. TABPAP . 'CHARGEMENT' = CHA1 ;
  660. TABPAP . 'BLOCAGES_MECANIQUES' = CL ET KRELA ;
  661. TABPAP . 'MODELE' = (MODepr et modgoup) ;
  662. TABPAP . 'LAGRANGIEN' = mot 'REACTUALISE' ;
  663. TABPAP . 'DEPLACEMENTS' = TABL;
  664. TABPAP . 'DEPLACEMENTS' . 0 = uproj;
  665. TABPAP . 'CONTRAINTES' = TABL;
  666. TABPAP . 'CONTRAINTES' . 0 = sigproj;
  667. TABPAP . 'VARIABLES_INTERNES' = TABL;
  668. TABPAP . 'VARIABLES_INTERNES' . 0 = pproj;
  669. PASAPAS TABPAP ;
  670. TABRAF.2=TABPAP;
  671.  
  672. *  opti donn 5;
  673. J=0;
  674. REPE bcl2 10 ;
  675.     J=J+1;
  676.  
  677.     ouv1 =(2*(EXTR (TABPAP . 'DEPLACEMENTS' . j) 'UY' P7));
  678.  
  679.  
  680.     ouv2 = ouv2 ET ouv1;
  681.     K=0;
  682.     for1=0;
  683.     REPE bc21 np_ep;
  684.       K=K+1;
  685.       for1 = for1 + ((EXTR (TABPAP. 'REACTIONS' . j ) 'FY' (POIN lchar K))*2);
  686.     fin bc21;
  687.     for2 = for2 ET for1;
  688.     sig1 = TABPAP . 'CONTRAINTES' . j;
  689.     eps1 = EPSI (MODEPR et modgoup) TABPAP . 'DEPLACEMENTS'. j  'LINE';
  690.     eloc1 = ENER (MODEPR et modgoup)  eps1 sig1;
  691.     eglo1 = INTG eloc1 (MODEPR et modgoup) ;
  692.     eglo2 = eglo2 et eglo1 ;
  693.  
  694.  
  695. fin bcl2;
  696.  
  697. *----------------------------------------------------------------------*
  698. *          Resolution en partant directement du dernier maillage       *
  699. *----------------------------------------------------------------------*
  700.  
  701. * chargement
  702. f1 = depi cl2 uchar;
  703. LI2 = PROG 0.0 1.0 ;
  704. EV1 = EVOL MANU T LI1 F(T) LI2 ;
  705. CHA1 = CHAR 'DIMP' F1 EV1 ;
  706.  
  707. TABPAP3=0.;
  708. TABPAP3= TABL;
  709. TABPAP3 . 'TEMPS_CALCULES' = PROG 0. pas 0.05 1. ;
  710. TABPAP3 . 'CARACTERISTIQUES' = (MATEPR et matgoup) ;
  711. TABPAP3 . 'CHARGEMENT' = CHA1 ;
  712. TABPAP3 . 'BLOCAGES_MECANIQUES' = CL ET KRELA ;
  713. TABPAP3 . 'MODELE' = (MODEPR et modgoup) ;
  714. TABPAP3 . 'LAGRANGIEN' = mot 'REACTUALISE' ;
  715. PASAPAS TABPAP3 ;
  716. *temps.(I+2)=DATE;
  717.  
  718. ouv3= prog;
  719. for3= prog;
  720. eglo3=prog;
  721. ouv4= prog;
  722. for4= prog;
  723.  
  724. J=0;
  725. REPE bcl3 20 ;
  726.     J=J+1;
  727.  
  728.     ouv1 =(2*(EXTR (TABPAP3 . 'DEPLACEMENTS' . j) 'UY' P7));
  729.     ouv3 = ouv3 ET ouv1;
  730.  
  731.     ouv4 = ouv4 et (2*(EXTR (TABPAP4 . 'DEPLACEMENTS' . j) 'UY' P7));
  732.     K=0;
  733.     for1=0;
  734.     REPE bcl31 np_ep;
  735.        K=K+1;
  736.        for1 = for1 + ((EXTR (TABPAP3. 'REACTIONS' . j )'FY' (POIN lchar K))*2);
  737.     fin bcl31;
  738.     for3 = for3 ET for1;
  739.     K=0;
  740.     for1=0;
  741.     REPE bcl32 np_ep;
  742.        K=K+1;
  743.        for1 = for1 + ((EXTR (TABPAP4. 'REACTIONS' . j )'FY' (POIN lchar K))*2);
  744.     fin bcl32;
  745.     for4 = for4 ET for1;
  746.     sig1 = TABPAP3 . 'CONTRAINTES' . j;
  747.     eps1 = EPSI (MODEPR et modgoup) TABPAP3 . 'DEPLACEMENTS'. j  'LINE';
  748.     eloc1 = ENER (MODEPR et modgoup)  eps1 sig1;
  749.     eglo1 = INTG eloc1 (MODEPR et modgoup) ;
  750.     eglo3 = eglo3 et eglo1 ;
  751.  
  752. fin bcl3;
  753.  
  754. TAB1= TABL;
  755. TAB1 . 'TITRE'= 'TABLE';
  756. TAB1 . 'TITRE' . 1 = 'MOT' 'Raff en cour de calcul';
  757. TAB1 . 'TITRE' . 2 = 'MOT' 'Maillage fin' ;
  758. TAB1 . 'TITRE' . 3 = 'MOT' 'Maillage grossier' ;
  759. TAB1 . 'TITRE' . 4 = 'MOT' 'Courbe experimentale' ;
  760. *TAB1 . 1 = 'MOT' 'MARQ  PLUS ';
  761. TAB1 . 2 = 'MOT' 'TIRR';
  762. TAB1 . 3 = 'MOT' 'TIRR';
  763.  
  764. * Données expérimentales pour comparaison :
  765. * (essais 5FTRA20RY-AT au LISN)
  766.  
  767.  
  768.  
  769. OUVEXP1 = PROG 0 2.41661E-03  5.30094E-03  7.63577E-03  1.00449E-02 1.27110E-02  1.56070E-02  1.86920E-02  2.16473E-02  2.45408E-02 2.77426E-02  3.07212E-02  3.34408E-02  3.67156E-02  4.03118E-02 4.37164E-02  4.62874E-02  5.01488E-02  5.31909E-02  5.61370E-02 5.99129E-02  6.34043E-02  6.65528E-02  6.99978E-02  7.32631E-02 7.70875E-02  8.08755E-02  8.46865E-02  8.85926E-02  9.18141E-02 9.52742E-02  9.88186E-02  0.10224 0.10657 0.10996 0.11396 0.11699 ;
  770. OUVEXP2 =  PROG 0.12151 0.12498 0.12893 0.13283 0.13624 0.14064 0.14422 0.14830 0.15246 0.15596 0.16034 0.16425 0.16871 0.17227  0.17591 0.17957 0.18386 0.18799 0.19211 0.19610 0.20000 0.20378 0.20782 0.21256  0.21643 0.22014 0.22449 0.22856 0.23254 0.23670 0.24096 0.24470 0.24898 0.25300 0.25716 0.26109 0.26519 0.26925 0.27342 0.27816 0.28178 0.28576 0.28991 0.29410 0.29791 0.30235 0.30668 0.31095 0.31533 0.31948 0.32415 0.32819 0.33253;
  771. OUVEXP3 = PROG  0.33713 0.34150 0.34597 0.35026 0.35450 0.35883 0.36311 0.36743 0.37209 0.37653 0.38110 0.38537 0.38967 0.39411 0.39873 0.40309 0.40792 0.41242 0.41704 0.42137 0.42601 0.43042 0.43556 0.44009 0.44495 0.44955 0.45372 0.45806 0.46273 0.46761 0.47230 0.47712 0.48179 0.48671 0.49134 0.49650 0.50160 0.50623 0.51082 0.51634 0.52069 ;
  772. ouvexp = OUVEXP1 et OUVEXP2 ET OUVEXP3 ;
  773. * convertion en m
  774. ouvexp = 0.001*ouvexp;
  775.  
  776.  
  777. forexp1 = PROG 456.08621 852.54  1164.9  1548.8  1858.2  2286.3  2581.0 2930.3  3287.3  3573.5  3998.0  4388.6  4773.6 5174.7  5624.6  5985.0 6383.5  6811.0  7200.5  7646.5  8078.4 8530.0  8972.0  9405.0  9875.8 10339.  10802.  11255.  11715.  12197.  12659. 13113.  13599.  14104. 14587.  15079.  15533.  15990.  16466.  16991. 17503.  17984.  18501.;
  778. forexp2 = PROG 18979.  19474.  19970.  20461.  20989.  21498. 22031.  22501.  23011. 23529.  24052.  24538.  25023.  25511.  26017. 26507.  27024.  27557. 28015.  28540.  29037.  29512.  30038.  30523. 31008.  31491.  32003. 32556. 33043.  33557.  34057.  34541.  35032.  35524.  35980.  36502. 36983.  37509. 38014.  38534.  39051.  39536.  40020.  40547.  41007. 41510.  41980.  42478. 42946.  43439.  43923.;
  779. forexp3 = PROG 44400.  44871.  45352.  45827.  46339.  46847.  47294. 47771.  48213. 48679.  49142.  49596.  50044.  50490.  50935.  51389.  51841.  52291. 52750.  53187.  53645.  54089.  54507.  54902.  55338.  55790.  56257. 56719.  57154.  57562.  57987.  58401.  58821.  59262.  59687.  60060. 60441.;
  780. forexp= forexp1 et forexp2 et forexp3;
  781.  
  782.  
  783. EVFOUV2 = EVOL 'MANU' ouv2 for2  ;
  784. EVFOUV3 = EVOL 'ROUG' 'MANU' ouv3 for3 ;
  785. EVFOUV4 = EVOL 'BLEU' 'MANU' ouv4 for4 ;
  786. EVFOUVE = EVOL 'VERT' 'MANU' ouvexp forexp ;
  787.  
  788. EVEOUV2 = EVOL 'MANU' ouv2 eglo2  ;
  789. EVEOUV3 = EVOL 'ROUG' 'MANU' ouv3 eglo3  ;
  790. EVEOUV4 = EVOL 'BLEU' 'MANU' ouv4 eglo4 ;
  791.  
  792. res2 = TABRAF. 2 .'DEPLACEMENTS'. 10;
  793. ressig2 = TABRAF. 2 .'CONTRAINTES'. 10;
  794. resp2 = TABRAF. 2 .'VARIABLES_INTERNES'. 10;
  795. res3 = TABPAP3.'DEPLACEMENTS'. 20;
  796. ressig3 = TABPAP3 .'CONTRAINTES'. 20;
  797. resp3 = TABPAP3.'VARIABLES_INTERNES'. 20;
  798.  
  799. *    deformees finales
  800.  
  801. def0 = DEFO 0.0 res2 veprou 'GRIS' ;
  802. def2 = DEFO 1 res2 veprou ;
  803. def3 = DEFO 1 res3 veprou 'ROUGE';
  804.  
  805.  
  806. si (graph);
  807.  
  808.  
  809.    DESS (EVFOUV2 et EVFOUV3 et EVFOUV4 et EVFOUVE) 'TITR' 'Courbe Force Ouverture' 'LEGE' TAB1;
  810.  
  811.    DESS (EVEOUV2 et EVEOUV3 et EVEOUV4) 'TITR' 'Courbe Energie totale Ouverture' 'LEGE' TAB1;
  812.      TRAC (def0 et def2 et def3) 'CACH';
  813. finsi ;
  814.  
  815. *    Champ différence
  816. udiffx = (EXCO res2 'UX')  - (EXCO res3 'UX') ;
  817. udiffy = (EXCO res2 'UY')  - (EXCO res3 'UY') ;
  818. udiffz = (EXCO res2 'UZ')  - (EXCO res3 'UZ') ;
  819.  
  820. udiff = ( (udiffx**2)+(udiffy**2)+(udiffz**2))**0.5;
  821. umax = maxi ((((EXCO res3 'UX')**2)+ ((EXCO res2 'UY')**2)+((EXCO res3 'UZ')**2))**0.5);
  822.  
  823. uerr = udiff /umax;
  824.  
  825. si (graph);
  826.   trac  udiff veprou TITR 'Ecart sur le deplacement';
  827.   trac  uerr veprou TITR 'Ecart relatif sur le deplacement';
  828. finsi;
  829.  
  830. perr = (resp2 - resp3) / (maxi resp3);
  831.  
  832.  
  833.  
  834. eps2 = EPSI (MODEPR et modgoup) res2  'LINE';
  835. eloc2 = ENER (MODEPR et modgoup)  eps2 ressig2;
  836. eps3 = EPSI (MODEPR et modgoup) res3  'LINE';
  837. eloc3 = ENER (MODEPR et modgoup)  eps3 ressig3;
  838.  
  839. elocerr = (ABS (eloc2 - eloc3)) / (maxi eloc3);
  840.  
  841. si (graph_ps);
  842.     OPTI 'TRAC' 'PSC' 'EPTR' 7 ;
  843.     OPTI 'POTR' 'HELVETICA_16';
  844.  
  845. *    OPTI FTRA 'proj_images/fouv.ps';
  846.     DESS (EVFOUV2 et EVFOUV3 et EVFOUV4 et EVFOUVE) 'TITR' 'Courbe Force Ouverture' 'LEGE' TAB1;
  847.  
  848. *    OPTI FTRA 'proj_images/ufin.ps';
  849.     trac  (exco res2 'UY') veprou TITR 'Deplacement final';
  850.  
  851. *    OPTI FTRA 'proj_images/ufinz.ps';
  852.     trac  (exco res2 'UY') veprou TITR 'Deplacement final' boit sboit;
  853.  
  854. *    OPTI FTRA 'proj_images/sfin.ps';
  855.     trac  ressig2 modepr TITR 'Contraintes finales';
  856.  
  857. *    OPTI FTRA 'proj_images/sfinz.ps';
  858.     trac  ressig2 modepr TITR 'Contraintes finales' boit sboit;
  859.  
  860. *    OPTI FTRA 'proj_images/pfin.ps';
  861.     trac  resp2 modepr TITR 'Deformation plastique finale';
  862.  
  863. *    OPTI FTRA 'proj_images/pfinz.ps';
  864.     trac  resp2 modepr TITR 'Deformation plastique finale' boit sboit;
  865.  
  866. *    OPTI FTRA 'proj_images/eouv.ps';
  867.     DESS (EVEOUV2 et EVEOUV3 et EVEOUV4) 'TITR' 'Courbe Energie totale Ouverture' 'LEGE' TAB1;
  868.  
  869. *    OPTI 'TRAC' 'PSC' 'EPTR' 1 ;
  870.     OPTI FTRA 'proj_images/udiff.ps';
  871.     trac  udiff veprou TITR 'Ecart sur le deplacement ';
  872.  
  873. *    OPTI FTRA 'proj_images/uerr.ps';
  874.     trac  uerr veprou TITR 'Ecart relatif sur le deplacement';
  875.  
  876. *    OPTI FTRA 'proj_images/perr.ps';
  877.     trac  perr modepr TITR 'Ecart relatif sur la deformation plastique';
  878.  
  879. *    OPTI FTRA 'proj_images/elocerr.ps';
  880.     trac  elocerr modepr TITR 'Ecart relatif sur l energie de deformation locale';
  881.  
  882. *    OPTI FTRA 'proj_images/uold.ps';
  883.     trac  (exco uold 'UY') vold TITR 'deplacement UY avent proj ';
  884.  
  885. *    OPTI FTRA 'proj_images/uproj.ps';
  886.     trac  (exco uproj 'UY') VEPROU TITR 'deplacement UY apres proj';
  887.  
  888. *    OPTI FTRA 'proj_images/sigold.ps';
  889.     trac  sigold modold TITR 'sigma avent proj';
  890.  
  891. *    OPTI FTRA 'proj_images/sigproj.ps';
  892.     trac  sigproj modepr TITR 'sigma apres proj';
  893.  
  894. *    OPTI FTRA 'proj_images/pold.ps';
  895.     trac  pold modold TITR 'variable interne avent proj';
  896.  
  897. *    OPTI FTRA 'proj_images/pproj.ps';
  898.     trac  pproj modepr TITR 'variable interne apres proj';
  899.  
  900.     step1=(0.0 + 3.50E08)/22 ;
  901.     liii1= PROG (0.0) PAS step1 3.50E08;
  902.  
  903. *    OPTI FTRA 'proj_images/eold1.ps';
  904.     trac liii1 elocold (modold  ) TITR 'energie champ avant proj';
  905.  
  906. *    OPTI FTRA 'proj_images/eproj1.ps';
  907.     trac liii1 elocproj (modepr  )TITR 'energie champ projete';
  908.  
  909. *    OPTI FTRA 'proj_images/eold2.ps';
  910.     trac elocold (modold  ) TITR 'energie champ avant proj';
  911.  
  912. *    OPTI FTRA 'proj_images/eproj2.ps';
  913.     trac elocproj (modepr  )TITR 'energie champ projete';
  914.  
  915.     OPTI 'TRAC' 'PSC' 'EPTR' 2 ;
  916.  
  917. *    OPTI FTRA 'proj_images/mail_raff.ps';
  918.     trac (veprou et (vgoup coul bleu) et (ssym1 coul roug) et (sfis10 coul vert)) 'CACH';
  919.  
  920. *    OPTI FTRA 'proj_images/mail_raffz.ps';
  921.     trac (veprou et (vgoup coul bleu) et (ssym1 coul roug) et (sfis10 coul vert)) 'CACH' boit sboit;
  922.  
  924.  
  925. finsi;
  926.  
  927.  
  928. *----------------------------------------------------------------------*
  929. *          Ecart experience simulation sur le maillage raffiné         *
  930. *----------------------------------------------------------------------*
  931. OPTI SAUV 'RAFF02.SAUV';
  933. nrjsim = (intg EVFOUV3 indi 1 3) ;
  934. ouvf   = EXTR ouv3 3;
  935.  
  936. repe bcl4 (dime ouvexp);
  937.   si ((EXTR ouvexp &bcl4) > ouvf) ;
  938.     indf = &bcl4;
  939.     quit bcl4;
  940.   finsi;
  941. fin bcl4;
  942.  
  943.  
  944. nrjexp = (intg EVFOUVE indi 1 indf) ;
  945. errexp = (ABS (nrjsim - nrjexp))/nrjexp;
  946.  
  947. *----------------------------------------------------------------------*
  948. *                  Erreur de projection                                *
  949. *----------------------------------------------------------------------*
  950.  
  951. nrjdir = (intg EVFOUV3 indi 11 20)  ;
  952. nrjproj = (intg EVFOUV2 indi 11 20) ;
  953. errproj = (ABS (nrjdir - nrjproj))/nrjdir;
  954. list errexp;
  955. list errproj;
  956.  
  957. SI  ((errproj < (1.0E-2)) et (errexp < (1.0E-1)));
  958.   'MESS' ' ----------------------' ;
  959.   'MESS' '  SUCCES DU CAS-TEST !' ;
  960.   'MESS' ' ----------------------' ;
  961.   Erre 0;
  962. Sinon;
  963.   'MESS' ' ---------------------' ;
  964.   'MESS' '  ECHEC DU CAS-TEST !' ;
  965.   'MESS' ' ---------------------' ;
  966.   Erre 5;
  967. finsi;
  968.  
  969. FIN ;
  970.  
  971.  
  972.  
  973.  
  974.  
  975.  
  976.  
  977.  
  978.  
  979.  
  980.  
  981.  
  982.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales