Exemples de jeux de données Cast3M

* fichier poutre1.dgibi
* section : mecanique, non lineaire
*----------------------------------------------------------------------*
*                       P O U T R E 1 . D G I B I                      *
*----------------------------------------------------------------------*
* Objet :                                                              
* -------
*
*  Cet exemple simule la flexion simple d'une poutre sous poids propre,
*  a laquelle on ajoute ensuite une condition en deplacement impose a
*  son extremite libre.
*
*  Cela necessite d'introduire la condition aux limites au cours du
*  calcul avec PASAPAS, l'extremite non encastre de la poutre etant
*  d'abord libre de se deplacer.
*
*  Pour cela, on realise un chargement de type BLOM (BLOcage Mecanique)
*  a l'aide de listes d'objets RIGIDITE.
*
*  Par ailleurs, le deplacement est impose de facon incrementale afin
*  qu'il s'ajoute au deplacement sous poids propre (chargement DINC).
*
*  La solution calculee est validee en comparant le deplacement de
*  l'extremite de la poutre a celui attendu.
*
* Description :
* -------------
*
* Type de calcul : Mecanique PASAPAS
* Mode de calcul : 3D
* Type d'element : SEG2, POUT
* Chargement     : poids propre, deplacement impose (DINC), ajout d'une
*                  condition aux limites au cours du calcul (BLOM)
*
*----------------------------------------------------------------------*
OPTION ECHO 1 ;
TITRE 'POUTRE EN FLEXION ' ;
OPTI DIME 3 ELEM SEG2 MODE TRID ;
 
* POUR AFFICHAGES, METTRE IG1 A VRAI :
IG1 = FAUX ;
 
*------------------DONNEES--------------------*
LON1  = 5. ;
DIA1  = 0.1 ;
RHOP  = 7800. ;
NUP   = 0.3 ;
YOP   = 210.0E9 ;
SIGYP = 235.0E6 ;
 
*------CALCUL DES DONNEES GEOMETRIQUES-------*
S1 = PI*(DIA1**2)/4. ;
IY = PI*(DIA1**4)/64. ;
IZ = IY ;
IG = PI*(DIA1**4)/32. ;
 
*-----------------GEOMETRIE------------------*
P1 = 0. 0. 0.;
P2 = LON1 0. 0.;
L1 = DROI 10 P1 P2 ;
 
*----DEFINITION DU MODELE ET DU MATERIAU-----*
MOD1 = MODE L1 'MECANIQUE' 'ELASTIQUE' 'PLASTIQUE' 'CINEMATIQUE' 'POUT' ;
MAT1 = MATE MOD1 'YOUN' YOP 'NU' NUP 'RHO' RHOP 'SIGY' SIGYP 'H' (0.1*YOP) ;
CAR1 = CARA MOD1 'SECT' S1 'INRY' IY 'INRZ' IZ 'TORS' IG 'VECT' (0. 1. 0.) 'DX' 0. 'DY' 0. 'DZ' 0.333 ;
MAT1 = MAT1 ET CAR1 ;
 
*-----------DEPLACEMENT IMPOSE ET CONDITIONS AUX LIMITES------------*
AMPDY = -0.1 ;
CL1   = BLOQ 'DEPL' 'ROTA' P1 ;
CLDY  = BLOQ P2 'UY' ;
DEPLY = DEPI CLDY AMPDY ;
CLTOT = CL1 ET CLDY ;
 
*-----------------------------CHARGEMENTS---------------------------*
* Liste des instants du chargement :
* - poids propre de 0. a 3.
* - depl. de -0.1 de 3 a 6
* - retour au depl. initial de 6. a 9. 
LI1  = PROG 0. 3. 6. 9. ;
 
* Poids propre :
LIP  = PROG 0. 1. 1. 1. ;
MAS1 = MASS MOD1 MAT1 ;
CHP1 = MANU CHPO L1 1 'UY' -9.81 ;
GP   = MAS1 * CHP1 ;
EVP  = EVOL MANU 'Temps' LI1 'F(t)' LIP ;
CHPP = CHAR 'MECA' GP EVP ;
 
* Chargement constant CL1 :
LCL1  = ENUM 4*CL1 ;
CGCL1 = CHAR BLOM LI1 LCL1 ;
 
* Chargement CLDY non nul (vide) pour t > 3. :
LCLD1 = ENUM (VIDE RIGIDITE) CLDY ;
CGCLD = CHAR BLOM (PROG 3. 3.0001) LCLD1 ;
 
* Increment de deplacement impose :
* Increment positif jusqu'a t=6, negatif apres
* Valeur increment depend du nombre de pas de calcul (NDT1)
NDT1 = 10. ;
LIY1 = PROG 6. 6.0001 ;
LDY1 = enum (DEPLY / NDT1) (-1. * DEPLY / NDT1) ;
CHA1 = CHAR 'DINC' LIY1 LDY1 ;
 
*--------------------------CALCUL PAS A PAS-------------------------*
* LISTE TEMPS CALCULES :
LIS_TPS = PROG 0. 'PAS' (3. / NDT1) 9. ;
 
* TABLE PASAPAS :
TAB1                     = TABLE ;
TAB1.MODELE              = MOD1 ;
TAB1.CARACTERISTIQUES    = MAT1 ;
TAB1.CHARGEMENT          = CHA1 ET CHPP ;
TAB1.BLOCAGES_MECANIQUES = CGCL1 ET CGCLD ;
TAB1.TEMPS_CALCULES      = LIS_TPS ;
 
* RESOLUTION :
PASAPAS TAB1 ;
 
*-------------------------POST TRAITEMENT--------------------------*
TAB2 = TAB1.DEPLACEMENTS ;
TABREAC = TAB1.REACTIONS ;
NDIM = DIME TAB2 ;
 
* DEFORMEE FINALE :
FFIN = NDIM - 1 ;
CHDEPF = TAB2.FFIN ;
DEF0 = DEFO L1 CHDEPF 0.  'BLAN' ;
DEF1 = DEFO L1 CHDEPF 10. 'ROUGE' ;
 
* AFFICHAGES :
SI IG1 ;
  IB = 0 ;
  LIS1 = PROG ;
  LIS2 = PROG ;
  REPETER BOUC1 NDIM ;
 
*   LISTE DEPLACEMENTS / EFFORTS
    DDD = EXTR (TAB2.IB) P2 'UY' ;
    LIS2 = INSE LIS2 &BOUC1 (-1.*DDD) ;
    SI (IB EGA 0) ;
      REACY = 0.0 ;
    SINON ;
      REACY = EXTR (TABREAC.IB) P1 'FY' ;
    FINSI ;
    LIS1 = INSE LIS1 &BOUC1 REACY ;
 
*   AFFICHAGES DEFORMEE SUICCESSIVES :
    DEF2 = DEFO L1 (TAB2.IB) 10. VERT ;
    OEIL = 0. 0. 1000. ;
    TPS1 = TAB1 . TEMPS . IB ;
    TITRE (CHAI FORMAT '(F4.1)' 'DEFORMEE DE LA POUTRE AU TEMPS =' TPS1) ;
    TRAC OEIL (DEF0 ET DEF1 ET DEF2) ;
    IB = IB+1 ;
  FIN BOUC1 ;
 
  TITRE 'COURBE DEPLACEMENT AU COURS DU TEMPS' ;
  EV1 = EVOL MANU LIS_TPS 'TEMPS' LIS2 'DEPLACEMENT' ;
  DESS EV1 ;
 
  TITRE 'COURBE FORCE-DEPLACEMENT' ;
  EV1 = EVOL MANU LIS2 'DEPLACEMENT' LIS1 'FORCE' ;
  DESS EV1 ;
 
FINS ;
 
*
*----------------------------- VALIDATION -----------------------------*
*
DEP3 = PECHE TAB1 DEPLACEMENTS 3. ;
DEP6 = PECHE TAB1 DEPLACEMENTS 6. ;
DEP9 = PECHE TAB1 DEPLACEMENTS 9. ;
UYP23 = EXTR DEP3 UY P2 ;
UYP26 = EXTR DEP6 UY P2 ;
UYP29 = EXTR DEP9 UY P2 ;
 
* DEPLACEMENT POIDS PROPRE EGALE FINAL :
SI (UYP23 NEG UYP29) ;
  ERRE 5 ;
FINS ;
* VERIFICATION INCREMENT DEPLACEMENT IMPOSE :
SI ((UYP23 + AMPDY) NEG UYP26) ;
  ERRE 5 ;
FINS ;
 
*----------------- F I N    P O U T R E 1 . D G I B I -----------------*
FIN ;