Télécharger la plaquette Cast3M


fr en

Télécharger plas8.dgibi

Retour à la liste

Numérotation des lignes : 

  1. * fichier :  plas8.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4. *           Test Plas8.dgibi: Jeux de données         *
  5. *           ---------------------------------         *
  6. *                                                     *
  7.  
  8. *******************************************************
  9. *           Test plas8.dgibi: Jeux de données         *
  10. *           ---------------------------------         *
  11. *******************************************************
  12.  
  13. *  POUR CALCUL COMPLET METTRE COMPLET À : VRAI;
  14.  
  15. complet = vrai;
  16.  
  17. * SI GRAPH = N PAS DE GRAPHIQUE AFFICHE
  18. * SINON SI GRAPH DIFFERENT DE N TOUS
  19. * LES GRAPHIQUES SONT AFFICHES
  20.  
  21. GRAPH = 'N' ;
  22.  
  23. SAUT PAGE;
  24. SI (NEG GRAPH 'N') ;
  25.   OPTI ECHO 1   ;
  26.   OPTI TRAC PSC   ;
  27. SINO ;
  28.   OPTI ECHO 0   ;
  29. FINSI ;
  30.  
  31. SAUT PAGE;
  32. *******************************************************
  33. *  TEST PLAS8
  34. *
  35. *   CONSOLE SOUS CHARGE CONCENTREE
  36. *
  37. *   On impose un deplacement vertical (une fleche) sur
  38. *   l'extremite libre d'une console. On etudie
  39. *   l'evolution de la force de reaction fonction de la
  40. *   fleche.La force doit tendre vers une valeur
  41. *   asymptotique donnee par l'expression suivante
  42. *   (si on considere la loi elastoplastique parfaite):
  43. *
  44. *   FU = (SIGY*H**2)/(4*L)
  45. *    ou  SIGY = contrainte limite elastique
  46. *        H    = l'epaisseur de la poutre
  47. *        L    = longueur de poutre
  48. *
  49. *******************************************************
  50. OPTI DIME 3 ELEM TRI3 DENS 0.5 ;
  51.  
  52. *______________________________________________________
  53. *  GEOMETRIE
  54. *______________________________________________________
  55. B   =  1. ;
  56. L   = 10. ;
  57. nel = 20;
  58.  
  59. A1 = 0. 0. 0. ;
  60. A2 = 0. B  0. ;
  61. B1 = L  0. 0. ; 
  62. B2 = L  B 0.  ;
  63.  
  64. A2A1 = DROI 2   A2 A1 ;
  65. A1B1 = DROI nel A1 B1 ;
  66. B1B2 = DROI 2   B1 B2 ;
  67. B2A2 = DROI nel B2 A2 ;
  68. ST   = DALL A2A1 A1B1 B1B2 B2A2 PLAN ;
  69. OEIL = -100 -100 -100 ;
  70.  
  71. SI (NEG GRAPH 'N') ;
  72.   TRAC OEIL 'QUAL' ST  ;
  73. FINSI ;
  74.  
  75. *______________________________________________________
  76. *  INITIALISATION
  77. *______________________________________________________
  78. XABS  = PROG ;
  79. FONC1 = PROG ;
  80. EP    = L/10 ;
  81.  
  82. *______________________________________________________
  83. *   MODELE
  84. *______________________________________________________
  85. MOD1 = MODE ST MECANIQUE ELASTIQUE PLASTIQUE  PARFAIT DKT  'INTEGRE' 7 ;
  86.  
  87. *______________________________________________________
  88. *  MATERIAUX
  89. *______________________________________________________
  90. E    = 2.1E11 ; 
  91. SY   = 100.E6;
  92. MAT1 = MATE MOD1 YOUN E NU 0. SIGY SY  EPAI EP CALF 1. ;
  93.  
  94. *______________________________________________________
  95. *  CONDITIONS AUX LIMITES ET RIGIDITE
  96. *______________________________________________________
  97. RI1   = RIGI MOD1 MAT1 ;
  98. CL1   = BLOQ UX UY UZ RY RZ A2A1 ;
  99. CLDEP = BLOQ UZ B1B2 ;
  100. CL    = CL1  ET CLDEP;
  101. RIT1  = RI1  ET CL;
  102.  
  103. *______________________________________________________
  104. *   DEPLACEMENT IMPOSE
  105. *______________________________________________________
  106.  FDEP = DEPI CLDEP  0.2;
  107.  
  108. *______________________________________________________
  109. *  PREPARATION POUR PASAPAS
  110. *______________________________________________________
  111. LI1 = PROG 0. 1. ;
  112. LI2 = PROG 0. 1. ;
  113. EV = EVOL MANU T LI1 F(T) LI2 ;
  114. CHA1 = CHAR DIMP FDEP  EV ;
  115. *
  116. si complet;
  117.   LIS1 = PROG 0. PAS 0.01 0.5;
  118. sinon;
  119.   LIS1 = PROG PAS 0.03333 0.1 PAS 0.02 0.16 ;
  120. finsi;
  121.  
  122. TAB1 = TABL ;
  123. TAB1.'CARACTERISTIQUES'    = MAT1;
  124. TAB1.'CHARGEMENT'          = CHA1;
  125. TAB1.'MODELE'              = MOD1;
  126. TAB1.'TEMPS_CALCULES'      = LIS1;
  127. TAB1.'BLOCAGES_MECANIQUES' = CL  ;
  128. TAB1.'PROCESSEURS'         = 'MOT' 'COMPORTEMENT';
  129.  
  130. *______________________________________________________
  131. * CALCUL
  132. *______________________________________________________
  133. PASAPAS TAB1;
  134.  
  135. TEMPS ;
  136.  
  137. *______________________________________________________
  138. * POST-TRAITEMENT
  139. *______________________________________________________
  140. NB   = DIME LIS1           ;
  141. XABS = INSER XABS  1 (0.0) ;
  142. FONC1= INSER FONC1 1 (0.0) ;
  143.  
  144. REPE BOUC1 NB ;
  145.   ITER1 = &BOUC1 ;
  146.   TT    = EXTR LIS1 ITER1              ;
  147.   DEP   = PECHE TAB1 'DEPLACEMENTS' TT ;
  148.   FLECH = EXTR DEP UZ B1               ;
  149.   FF    = REAC DEP RIT1                ;
  150.   FFF   = RESU(REDU FF B1B2)           ;
  151.   FORC  = EXTR FFF 'FZ' B1             ;
  152.   XABS  = INSER XABS  ITER1 FLECH      ;
  153.   FONC1 = INSER FONC1 ITER1 FORC       ;
  154.  
  155.   SI (ITER1 EGA (NB-1));
  156.     LIST TAB1.'DEPLACEMENTS' ;
  157.     DEF0 = DEFO 0. DEP ST      ;
  158.     DEF1 = DEFO 5. DEP ST VERT ;
  159.     SI (NEG GRAPH 'N') ;
  160.       TITR 'DEPLACEMENT UZ';
  161.       TRAC 'CACH' (EXCO DEP UZ)  ST ;
  162.       TITR 'DEFORMEE';
  163.       TRAC 'CACH' (DEF0 ET DEF1) ST ;
  164.     FINSI;
  165.   FINSI;
  166. FIN BOUC1 ;
  167.  
  168. *______________________________________________________
  169. * ON TRACE LA COURBE FORCE-FLECHE
  170. *______________________________________________________
  171. TITR 'FORCE PONCTUELLE FONCTION DE LA FLECHE  ';
  172. EV1 = EVOL ROUGE MANU 'FLECHE' XABS 'FORCE' FONC1 ;
  173.  
  174. *______________________________________________________
  175. * CALCUL ANALYTIQUE DE LA VALEUR ASYMPTOTIQUE
  176. *______________________________________________________
  177. si complet;
  178.   FU= (SY * (EP**2))/(4*L) ;
  179.   ERRMAX = 8.5 ;
  180. sinon;
  181.   FU = 1.679E+06;
  182.   ERRMAX = 0.06;
  183. finsi;
  184.  
  185. SI(NEG GRAPH 'N');
  186.  DESS EV1 ;
  187. FINSI ;
  188.  
  189. *______________________________________________________
  190. *            CODE FONCTIONNEMENT
  191. *______________________________________________________
  192. FC  = RESU(REDU FF B1B2) ;
  193. FCC = EXTR FC 'FZ' B1 ;
  194.  
  195. RESI= 100 * (ABS((FCC-FU)/FU)) ;
  196.  
  197. MESS '    Force theorique  :' FU  'N';
  198. MESS '    Force calcule    :' FCC 'N';
  199. MESS '    Soit un ecart de :' RESI '%';
  200.  
  201. SI (RESI <EG ERRMAX) ;
  202.     ERRE  0 ;
  203. SINO;
  204.     ERRE  5 ;
  205. FINSI;
  206.  
  207. TEMPS ;
  208. FIN ;
  209.  
  210.  
  211.  
  212.  
  213.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales