Télécharger la plaquette Cast3M


fr en

Télécharger plas10.dgibi

Retour à la liste

Numérotation des lignes : 

  1. * fichier :  plas10.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4. *           Test Plas10.dgibi: Jeux de données        *
  5. *           ---------------------------------         *
  6. *                                                     *
  7. OPTION ECHO 0;
  8. GRAPH='N';
  9. SAUT PAGE ;                                                                     
  10. *                                                                               
  11. *******************************************************      
  12. *  TEST PLAS10
  13. *                                                                               
  14. * Sortie du domaine élastique et phase plastique           
  15. * (comportement élasto-plastique modèle CAM-CLAY).
  16. *                                                                               
  17. * Un parallelépipède est soumis à des déplacements 
  18. * imposés sur trois de ses faces et fixé de manière 
  19. * isosattique. On compare la courbe de réponse en 
  20. * compression hydrostatique à la solution exacte.
  21. *                                                                               
  22. *******************************************************       
  23.  
  24. TITRE 'PARALLELEPIPEDE EN COMPRESSION HYDROSTATIQUE ' ;
  25. OPTION ECHO 0 ;
  26. OPTION DIME 3 ELEM CUB8 MODE TRID      ;                                        
  27. *------------------------------------------------------      
  28. *           DEFINITION DE LA GEOMETRIE                                          
  29. *------------------------------------------------------     
  30. A1= 0. 0. 0.;                                                                  
  31. B1= 1. 0. 0.;
  32. C1= 1. 1. 0.;
  33. D1= 0. 1. 0.;
  34. A2= 0. 0. 1.;                                                                   
  35. B2= 1. 0. 1.;
  36. C2= 1. 1. 1.;
  37. D2= 0. 1. 1.;
  38. *                                                                               
  39. L1 = A1 DROIT 1 B1  ;                                                           
  40. L2 = B1  DROIT 1 C1  ;                                                          
  41. L3 = C1  DROIT 1 D1  ;                                                          
  42. L4 = D1  DROIT 1 A1  ;                                                          
  43. LL = L1 ET L2 ET L3 ET L4 ;                                                     
  44. SU1= SURF LL PLAN ;                                                             
  45. M1 = A2 DROIT 1 B2  ;                                                           
  46. M2 = B2  DROIT 1 C2  ;                                                          
  47. M3 = C2  DROIT 1 D2  ;                                                          
  48. M4 = D2  DROIT 1 A2  ;                                                          
  49. MM = M1 ET M2 ET M3 ET M4 ;                                                     
  50. SU2= SURF MM PLAN ;                                                             
  51. SU = SU1 VOLU  1 SU2 ;                                                          
  52. SI(NEG GRAPH 'N');
  53.   TRAC (888  1000 2000 )  SU ;
  54. FINSI ;
  55. *------------------------------------------------------     
  56. *        DEFINITION DES CONDITIONS AUX LIMITES                               
  57. *             ET DES DEPLACEMENTS IMPOSES                                    
  58. *------------------------------------------------------      
  59. BLX = BLOQ UX ( A1  ET A2 ET D1 ET D2 );
  60. BLY = BLOQ UY ( A1 ET B1 ET B2 ET A2 ) ;
  61. BLZ = BLOQ UZ SU1 ;
  62. BL = BLX ET BLY ET BLZ  ;
  63. *
  64. CLX = BLOQ UX ( B1  ET B2 ET C1 ET C2 );
  65. CLY = BLOQ UY ( D1 ET C1 ET C2 ET D2 ) ;
  66. CLZ = BLOQ UZ SU2 ;
  67. CL = CLX ET CLY ET CLZ  ;
  68. *                                                                               
  69. VAL = -2.664328E-5 ;
  70. DEPX= DEPI CLX  VAL   ;
  71. DEPY= DEPI CLY  VAL   ;
  72. DEPZ= DEPI CLZ  VAL   ;
  73. *                                                                               
  74. *------------------------------------------------------
  75. *        DEFINITION DES PROPRIETES MATERIELLES
  76. *------------------------------------------------------
  77. MO  = MODE SU MECANIQUE ELASTIQUE PLASTIQUE CAM_CLAY ;
  78. *
  79. XL = 0.1 ;
  80. CC = 0.5 ;
  81. XK = 0.01 ;
  82. EE = 2. ;
  83. PI0 = 5.;
  84. *
  85. MAT  = MATE MO  'YOUN' 1000.  'NU' 0.2
  86.  'E0' EE  'COHE' CC  'M' 1.2   'P0' PI0   'LAMD' XL  
  87.  'KAPA' XK 'G1'  416.666667 ;
  88. *
  89. LITX = PROG 0. PAS 1. 300. ;
  90. LIX =  PROG 0. PAS 1. 300. ;
  91. EVX= EVOL MANU 'TEMP' LITX 'FX'   LIX ;
  92. CHA1 = CHAR 'DIMP' (DEPX ET DEPY ET DEPZ) EVX;
  93. *
  94. *------------------------------------------                                     
  95. *            APPEL A PASAPAS
  96. * AU TEMPS T , LE DEPLACEMENT VAUDRA F(T)*D                                     
  97. *------------------------------------------                                     
  98.  TAB1 = TABLE ;
  99.  LIS1 = PROG 0. PAS 10.  200. ;
  100.  TAB1.'MODELE' = MO;
  101.  TAB1.'CARACTERISTIQUES' = MAT;
  102.  TAB1.'CHARGEMENT' = CHA1;
  103.  TAB1.'TEMPS_CALCULES' = LIS1;
  104.  TAB1.'BLOCAGES_MECANIQUES' = CL 'ET' BL;
  105.  TAB1.'HYPOTHESE_DEFORMATIONS'='LINEAIRE' ;
  106.  PASAPAS TAB1 ;
  107. *
  108. *------------------------------------------                                     
  109. *           DEPOUILLEMENT ET
  110. *     CALCUL DE LA SOLUTION ANALYTIQUE
  111. *------------------------------------------                                     
  112. *                                                                               
  113. SI(NEG GRAPH 'N');
  114. NT = (DIME (TAB1.DEPLACEMENTS)) - 1 ;
  115. IT = 0 ;
  116. PRD = PROG 0. ;
  117. PRF = PROG 0. ;
  118. REPETER BOPI NT;
  119. IT = IT + 1 ;
  120. DD= TAB1.DEPLACEMENTS.IT;
  121. RR =  REAC CLY DD;
  122. RRR = RESU RR;
  123. LEP = ( EXTR RRR 'MAIL' 'NOMU'  ) POIN 1  ;
  124. PRD = PRD ET (PROG ( EXTR DD UY D1));
  125. PRF = PRF ET (PROG ( EXTR RRR FY LEP) ) ;
  126. FIN BOPI ;
  127. FV = EVOL ROSE MANU 'D' PRD 'F ' PRF;
  128. DESS FV ;
  129. FINSI;
  130. *
  131. VV = PECHE TAB1 VARIABLES_INTERNES 200. ;
  132. SS = PECHE TAB1 CONTRAINTES 200. ;
  133. PCAL =  EXTR SS SMXX 1 1 1  ;
  134. PTHE =  -1. * ( PI0 + CC) *
  135.         (EXP ( ( -300. * VAL ) * ( 1.+EE ) / XL) );
  136. PTHE = PTHE + CC ;
  137. EVPCAL =  EXTR VV TRAP 1 1 1  ;
  138. EVPTHE = (300. * VAL ) * ( XL - XK ) / XL ;
  139. SAUTER 3 LIGNE ;
  140. MESS ' PRESSION MOYENNE THEORIQUE ' PTHE 
  141. '  CALCULEE'  PCAL;
  142. MESS ' TRACE PLASTIQUE THEORIQUE ' EVPTHE  
  143. ' CALCULEE ' EVPCAL;
  144. *
  145. RESI1 = ABS ( (PCAL-PTHE)/PTHE );
  146. RESI2 = ABS ( (EVPCAL-EVPTHE)/EVPTHE);
  147. SAUTER 3 LIGNE ;
  148. MESS ' ERREURS RELATIVES ' RESI1 RESI2 ;
  149. *
  150. *             CODE FONCTIONNEMENT
  151. *
  152. SI (RESI1 <EG 1.E-6) ;
  153.   SI (RESI2 <EG 1.E-6) ;
  154.     ERRE  0;
  155.   SINO;
  156.     ERRE  5;
  157.   FINSI;
  158. SINON;
  159.     ERRE  5;
  160. FINSI;
  161. FIN;
  162.  
  163.  
  164.  
  165.  
  166.  
  167.  
  168.  
  169.  
  170.  
  171.  
  172.  
  173.  
  174.  
  175.  
  176.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales