Télécharger la plaquette Cast3M


fr en

Télécharger pecker_t.dgibi

Retour à la liste

Numérotation des lignes : 

  1. * fichier : pecker_t.dgibi
  2. ************************************************************************
  3. ************************************************************************
  4. * etude propagation dans sol
  5. * approche interaction sol structure Pecker 1973 temporel
  6. * grandeurs numériques arbitraires !!!
  7. * attention mo1 reaffecte
  8. opti dime 2 elem qua4 ;
  9. dgraph = faux ;
  10. long1 = 10000.; longma = 100. ; nl1 = long1 / longma ;
  11. epai1 = 1000. ; epai2 = epai1 / longma ; nep1 = 10 ;
  12.  
  13. p_ori = 0. 0. ; e_i = longma 0.; e_j = 0. longma ;
  14. p1 = p_ori moins (0. epai1) ;
  15. p20 = p1 plus (nl1 * e_i) ;
  16. l120 = p1 d p20 dini 100. dfin 1000. ;
  17. v10 = l120 tran nep1 (epai2 * e_j) ;
  18. l40 = v10 cote 4 ;
  19. v1 = elem v10 contenant p1 ;
  20. v2 = v10 diff v1 ;
  21. l1 = elem l120 contenant p1 ;
  22. l2 = l120 diff l1 ;
  23. l4v = diff l40 (elem l40 contenant p1) ;
  24. l3 = v10 cote 2 ;l3p1 = changer l3 poi1 ;
  25. **
  26. p_fonda = long1 / 3  0. ;
  27. p_fonda = point v10 proc p_fonda ;
  28. v_fonda = manu poi1 p_fonda;
  29. v1fonda = elem v10 appuye largement v_fonda ;
  30. v2fonda = elem v10 appuye largement v1fonda ;
  31. v2 = diff v2 v2fonda ;
  32. l_fonda = inte (contour v2) (contour v2fonda) ;
  33.  
  34.  
  35. *
  36.  
  37. tfinca = 2. ;
  38. *
  39. mo1 = mode v1 mecanique elastique ;
  40. mo2 = mode v2 mecanique elastique ;
  41. mo3 = mode l3p1 mecanique elastique impedance voigt ;
  42. mo3 = mode l3p1 mecanique elastique impedance reuss ;
  43.  
  44. m_fonda = mode l_fonda mecanique elastique ;
  45.  
  46. ca1 = mate mo1 youn 1.e10 nu 0.2 rho 500. ;
  47. ca2 = mate mo2 youn 1.e10 nu 0.2 rho 500.  ;
  48. ca3 = mate mo3 raid 1.e3 visc 1.e1  mass 0. ;
  49.  
  50.  
  51. cl2 = bloq l2 uy ;
  52.  
  53. cl_fonda = rela cori depl  l_fonda ;
  54.  
  55. cl3b = bloq l3 ux ;
  56.  
  57. cv1_x = bloque v1 ux ; cv1_y = bloq v1 uy ;
  58. evacc = evol manu t (prog 0 pas 0.01 0.1 pas 0.1 tfinca ) d  (prog 0 pas 0.2 1 pas -0.2 0. 19*0. ) ;
  59. depv1_x = depi cv1_x 10. ;
  60. chav1 = char dimp evacc depv1_x ;
  61. *
  62. rig_t = rigi (mo1 et mo2) (ca1 et ca2) ;
  63. mas_t = mass (mo1 et mo2) (ca1 et ca2) ;
  64.  
  65. rig_3 = rigi mo3 ca3 ;
  66. mas_3 = mass mo3 ca3 ;
  67.  
  68. si faux ;
  69. tmod = vibr (rig_t et cv1_x et cv1_y et cl2 ) mas_t  proc (prog 0.)  ;
  70. def1 = defo tmod. modes . 1 . deformee_modale (v2 et v1)  5. vert ;
  71. def0 = defo (v2 et v1) tmod . modes . 1 . deformee_modale 0.   ;
  72. titre 'frequence' tmod . modes . 1 . frequence ;
  73. trac (def0 et def1) ;
  74. finsi ;
  75.  
  76. * rotation 
  77. l_fond2 = l_fonda tour p_fonda 30. ;
  78. cce2 = l_fond2 moins l_fonda ;
  79. cche2 = changer cham cce2 l_fonda ;
  80. pcce2 = psca cche2 cche2 (mots ux uy) (mots ux uy) ;
  81. rcce2 = intg m_fonda pcce2 scal ;
  82.     t_sei = table ;
  83. t_sei . modele = mo1 et mo2 et mo3  ;
  84. t_sei . caracteristiques = ca1 et ca2 et ca3 ;
  85. t_sei . blocages_mecaniques = cv1_x et cv1_y et cl2 et cl_fonda ;
  86. t_sei . chargement = chav1 ;
  87. t_sei . dynamique = vrai ;
  88. t_sei . temps_calcules = prog 0. pas 0.01 0.1 pas 0.1  tfinca;
  89. t_sei . temps_sauves = prog 0. pas 0.01 0.1 pas 0.1  tfinca ;
  90. t_sei .'HYPOTHESE_DEFORMATIONS'='LINEAIRE' ;
  91.  
  92. pasapas t_sei ;
  93.  
  94.  
  95. chefo0x = manu chml m_fonda ux 1. noeud ;
  96. r0_fondx = intg m_fonda chefo0x ux ;
  97. chefo0y = manu chml m_fonda uy 1. noeud ;
  98. r0_fondy = intg m_fonda chefo0y uy ;
  99. abs_t = prog ; x_fonda = prog ; y_fonda = prog ;w_fonda = prog ;
  100.  
  101. l_coul = prog -2. -1.5 -1. -0.5  0. 0.3 0.7 1. 1.3 1.9 2. 2.3 2.6 3. 3.3 3.6 ;
  102. repeter b_des (dime t_sei . deplacements) ;
  103.  ind1= &b_des - 1 ;
  104.  titre 'deplacement ux impedance a t = ' t_sei . temps . ind1 ;
  105.   ev_l3 = evol chpo  t_sei.deplacements . ind1 ux l3 ;
  106.   si dgraph ;
  107.   dess ev_l3 ;
  108.   finsi ;
  109.  titre 'deplacement ux a t = ' t_sei . temps . ind1 ;
  110.   chdepd2 = exco ux t_sei . deplacements . ind1 ;
  111.   si dgraph ;
  112.   trac (v1 et v2)  chdepd2  (contour (v1 et v2)) l_coul  ;
  113.   finsi ;
  114.  titre 'contraintes a t = '  t_sei . temps . ind1 ;
  115.   si dgraph ;
  116. *  trac (mo1 et mo2 et mo3) t_sei . contraintes . ind1 ;
  117.   trac (mo1 et mo2 ) t_sei . contraintes . ind1 ;
  118.   finsi ;
  119.   chdfo2 = redu t_sei . deplacements . ind1 l_fonda ;
  120.   dfo2 = defo chdfo2 l_fonda 10. vert ;
  121.   dfo0 = defo chdfo2 l_fonda 0. bleu ;
  122.   chefo2 = changer cham m_fonda chdfo2 noeud ;
  123.   rx_fonda = (intg m_fonda chefo2 ux)/r0_fondx ;
  124.   ry_fonda = (intg m_fonda chefo2 uy)/r0_fondy ;
  125.   titre 'deformee fondation t = '  t_sei . temps . ind1   ' resultante : ' rx_fonda ry_fonda ;
  126.   si dgraph ;
  127.   trac (dfo0 et dfo2)   ;
  128.   finsi ;
  129.   abs_t = abs_t et (prog t_sei . temps . ind1) ;
  130.   x_fonda = x_fonda et (prog rx_fonda) ;
  131.   y_fonda = y_fonda et (prog ry_fonda) ;
  132.   pdce2 = psca chefo2 cche2 (mots ux uy) (mots ux uy) ;
  133.   wdce2 = (intg m_fonda pdce2 scal) / rcce2 ;
  134.   w_fonda = w_fonda et (prog wdce2) ;
  135. fin b_des ;
  136.  
  137. *
  138. * chargement structure avec impedance
  139. *
  140. opti dime 3 elem seg2 ;
  141. * 
  142. d_bloq = faux;
  143.  
  144.  
  145. p0 = 0. 0. 0. ; e_z = 0. 0. 1. ;
  146. q2 = 0. 1. 0. ; q1 = 0. 2. 0. ;
  147. lig1 = d 20 q2 q1 ;
  148.  
  149.  
  150. MO1= MODE LIG1 MECANIQUE ELASTIQUE POUT ;
  151.  
  152. MATPL1=MATE MO1  YOUNG 2.E11 NU 0.3 RHO 7800;
  153. CARPL1= 'CARA' MO1 SECT 0.1 INRY 2.08E-7 INRZ 3.33E-8                            TORS 2.41E-7;
  154. MATE1=MATPL1 ET CARPL1;
  155. ***
  156.  
  157.  
  158. ***
  159.  
  160. RIGPL1 =RIGI MATE1 MO1 ;
  161. MASPLA1=MASS MATE1 MO1 ;
  162. BLOQ2=BLOQ DEPL ROTA Q2 ;
  163. bloq1r = (bloq rota q1)  ; blq1uz = bloq q1 uz ;
  164. blq1ux = bloq q1 ux ; blq1uy = bloq q1 uy ;
  165. bloq1rx = bloq q1 rx ;
  166. *    
  167. *---- 
  168. *  
  169. PR=PROG 0.4 ; n_mv = lect 4 ;
  170. *MODPLA01=VIBR PROC PR (RIGPL1 ET BLOQ2 et bloq1r et 
  171. *        blq1uz et blq1ux et blq1uy)  MASPLA1 ;
  172. *modpla0 = vibr proc pr (RIGPL1 ET BLOQ2 et bloq1r et blq1uz) maspla1 ;
  173.  
  174. tblsta = table 'LIAISONS_STATIQUES' ;
  175. tblsta . 1 = table ; tblsta . 1 . point_liaison = q1 ;
  176.         si d_bloq ;   tblsta . 1 . ddl_liaison = ux ;
  177.         sinon ;  tblsta . 1 . ddl_liaison = fx ; finsi ;
  178. tblsta . 2 = table ; tblsta . 2 . point_liaison = q1 ;
  179.          si d_bloq ; tblsta . 2 . ddl_liaison = uy ;
  180.          sinon ; tblsta . 2 . ddl_liaison = fy ; finsi ;
  181.  
  182. si d_bloq ;
  183.  bliaiq1 =  bloque tblsta ; depi tblsta ;
  184. sinon ;
  185.  force tblsta ;
  186. finsi ;
  187.  si d_bloq ;
  188. * modes vibrations
  189. MODPLA1=VIBR PROC PR n_mv (RIGPL1 ET BLOQ2 et bloq1r et blq1uz et bliaiq1)  MASPLA1 ;
  190. * solutions statiques
  191. tbsta = resout (RIGPL1 ET BLOQ2 et bloq1r et bliaiq1) tblsta ;
  192. react bliaiq1 tbsta ;
  193.  sinon ;
  194. * modes vibrations
  195. MODPLA1=VIBR PROC PR n_mv (RIGPL1 ET BLOQ2  et bloq1rx et  blq1uz)  MASPLA1 ;
  196. * solutions statiques
  197. tbsta = resout (RIGPL1 ET BLOQ2) tblsta ;
  198.  finsi ;
  199.  
  200. tbsta maspla1 * ;
  201.  
  202.  repeter bmod ((dime tbsta) - 1) ;
  203.   ind1 = &bmod ;
  204. psta1 = manu poi1  tbsta . ind1 . point_repere ;
  205. mostai1 = mode psta1 mecanique elastique statique ;
  206.  si d_bloq ;
  207. castai1 = mate mostai1  defo tbsta . ind1 . deformee made tbsta . ind1 . masse_deformee  ride tbsta . ind1 . reaction ;
  208.  sinon ;
  209. castai1 = mate mostai1  defo tbsta . ind1 . deformee made tbsta . ind1 . masse_deformee  ride tbsta . ind1 . force ;
  210.  finsi ;
  211.   si (ega 1 ind1) ;
  212.     mosta1 = mostai1 ; casta1 = castai1 ;
  213.   sinon ;
  214.     mosta1 = mosta1 et mostai1 ; casta1 = casta1 et castai1 ;
  215.   finsi ;
  216.   def1 = defo tbsta . ind1 . deformee lig1 1. vert ;
  217.   def0 = defo tbsta . ind1 . deformee lig1 0. bleu ;
  218.   titre ' sol statique ind = ' ind1 ;
  219.   si dgraph ;
  220.   trac (0. 0. 1000.) (def0 et def1) ;
  221.   finsi ;
  222.  fin bmod ;
  223. masta1 = masse mosta1 casta1 ;
  224. rista1 = rigi mosta1 casta1 ;
  225.  
  226. modto1 = mosta1 ; casto1 = casta1  ; tmod = modpla1 . modes ;
  227.  
  228.  repeter bmod ((dime modpla1 . modes) - 2) ;
  229.   ind1 = &bmod ;
  230. psta1 = manu poi1  tmod . ind1 . point_repere ;
  231. momoda1 = mode psta1 mecanique elastique modal ;
  232. camoda1 = mate momoda1 freq tmod . ind1 . frequence mass tmod . ind1 . masse_generalisee defo tmod . ind1 . deformee_modale ;
  233.   si (ega 1 ind1) ;
  234.     momod1 = momoda1 ; camod1 = camoda1 ;
  235.   sinon ;
  236.     momod1 = momod1 et momoda1 ; camod1 = camod1 et camoda1 ;
  237.   finsi ;
  238.   def1 = defo tmod . ind1 . deformee_modale lig1 1. vert ;
  239.   def0 = defo tmod . ind1 . deformee_modale lig1 0. bleu ;
  240.   titre ' mode propre ind = ' ind1 ;
  241.  si dgraph ; trac (0. 0. 1000.) (def0 et def1) ; finsi ;
  242.  fin bmod ;
  243.  
  244.  modto1 = modto1 et momod1 ; casto1 = casto1 et camod1 ;
  245.  
  246. chq2ux = manu chpo lig1 ux 1. ; chq2uy = manu chpo lig1 uy 1. ;
  247. blq2rz = bloq q2 rz ; fblq2rz = depi blq2rz 1. ;
  248. blq2de = bloq q2 depl ;
  249. chq2rz = resou (rigpl1 et blq2rz et blq2de) fblq2rz;
  250. chq2mz = react (rigpl1 et blq2rz et blq2de) chq2rz ;
  251.   def2 = defo chq2rz lig1 1. vert ;
  252.   titre ' mode statique rotation ' ;
  253.  si dgraph ; trac (0. 0. 1000.) (def0 et def2) ; finsi ;
  254.  
  255. pq2ux = manu poi1 (1. 0. 0.) ;
  256. moq2ux = modele pq2ux mecanique elastique statique ;
  257. caq2ux = mate moq2ux defo chq2ux made (maspla1 * chq2ux) ride (rigpl1 * chq2ux) ;
  258. pq2uy = manu poi1 (0. 1. 0.) ;
  259. moq2uy = modele pq2uy mecanique elastique statique ;
  260. caq2uy = mate moq2uy defo chq2uy made (maspla1 * chq2uy) ride (rigpl1 * chq2uy) ;
  261. pq2rz = manu poi1 (0. 0. 100.) ;
  262. moq2rz = modele pq2rz mecanique elastique statique ;
  263. caq2rz = mate moq2rz defo chq2rz made (maspla1 * chq2rz) ride chq2mz ;
  264.  
  265. maq2 = manu poi1 q2;
  266. mimq2rz = mode maq2 mecanique elastique impedance reuss pout ;
  267. cimq2rz = mate mimq2rz raid 1.e4 cple 1.e4 visc 1.e3 mass 0. iner 0.;
  268.  
  269. mimq2 = mode pq2rz mecanique elastique statique  impedance reuss ;
  270. cimq2 = mate mimq2 raid 1.e4 visc 1.e3  mass 0. ;
  271.  
  272. tfinca = 0.1 ;
  273. * evolution - test
  274. evacc = evol manu t (prog 0 pas 0.01 0.1 tfinca) d  (prog 0 pas 0.2 1 pas -0.2 0. 0. ) ;
  275. * chargement en x seul, par exemple, après calcul séisme
  276. evacc =  evol manu t abs_t d x_fonda ;
  277. *abs_t = prog 0. 0.1 0.2 ;
  278. *evacc = evol manu t abs_t d  (prog 0 0.2 0.4) ;
  279. si dgraph ;
  280. dess evacc titre ' chargement ' ;
  281. finsi ;
  282. ***
  283. cq2yz = bloq q2 uy uz ;
  284. cq2ux = bloq q2  ux ;
  285. dq2ux = depi cq2ux 1. ;
  286. chaq2ux = char dimp evacc dq2ux ;
  287.  
  288. t_bul1 = table ;
  289. t_bul1 . modele = mo1 ;
  290. t_bul1 . caracteristiques = mate1 ;
  291. t_bul1 . chargement = chaq2ux ;
  292. t_bul1 . blocages_mecaniques = cq2ux et cq2yz;
  293. t_bul1 . dynamique = vrai ;
  294. t_bul1 . temps_calcules = abs_t ;
  295. t_bul1 . temps_sauves = abs_t;
  296. t_bul1 .'HYPOTHESE_DEFORMATIONS'='LINEAIRE' ;
  297.  
  298. pasapas t_bul1 ;
  299.  
  300. t_bul3 = table ;
  301. t_bul3 . modele = mo1 et mimq2rz ;
  302. t_bul3 . caracteristiques = mate1 et cimq2rz ;
  303. t_bul3 . chargement = chaq2ux ;
  304. t_bul3 . blocages_mecaniques = cq2ux et cq2yz;
  305. t_bul3 . dynamique = vrai ;
  306. t_bul3 . temps_calcules = abs_t ;
  307. t_bul3 . temps_sauves = abs_t ;
  308. t_bul3 .'HYPOTHESE_DEFORMATIONS'='LINEAIRE' ;
  309. pasapas t_bul3 ;
  310.  
  311. si dgraph ;
  312. repeter b_des1 (dime t_bul1 . deplacements) ;
  313.  ind1= &b_des1 - 1 ;
  314.  titre 'deplacement ux a t = ' t_bul1 . temps . ind1 ;
  315.  chbul1 = t_bul1 . deplacements . ind1  ;
  316.  dfbul12 = defo chbul1 lig1 1. bleu ;
  317.  chbul3 = t_bul3 . deplacements . ind1  ;
  318.  dfbul13 = defo chbul3 lig1 1. rouge ;
  319.  dfbul10 = defo chbul1 lig1 0. jaune ;
  320.   trac (0. 0. 1000.) (dfbul10 et dfbul12 et dfbul13)  ;
  321. fin b_des1 ;
  322. finsi ;
  323. ***
  324. c_pq2ux = bloq pq2ux beta ;
  325. deq2ux = depi c_pq2ux 1. ;
  326. chq2ux = char dimp evacc deq2ux ;
  327.  
  328. ***
  329. t_bul2 = table ;
  330. t_bul2 . modele = momod1 et moq2ux et moq2uy et moq2rz et mimq2 ;
  331. t_bul2 . caracteristiques = camod1 et caq2ux et caq2uy et caq2rz  et cimq2 ;
  332. t_bul2 . chargement = chq2ux ;
  333. t_bul2 . blocages_mecaniques = c_pq2ux ;
  334. t_bul2 . dynamique = vrai ;
  335. t_bul2 . temps_calcules = abs_t ;
  336. t_bul2 . temps_sauves = abs_t ;
  337. t_bul2 .'HYPOTHESE_DEFORMATIONS'='LINEAIRE' ;
  338.  
  339. pasapas t_bul2 ;
  340.  
  341. si dgraph ;
  342. repeter b_des (dime t_bul2 . deplacements) ;
  343.  ind1= &b_des - 1 ;
  344.  titre 'deplacement ux a t = ' t_bul2 . temps . ind1 ;
  345.  chbul2 = reco t_bul2 . deplacements . ind1  t_bul2 . modele t_bul2 . caracteristiques ;
  346.  dfbul22 = defo chbul2 lig1 1. rouge ;
  347.  dfbul0 = defo chbul2 lig1 0. bleu ;
  348.   trac (0. 0. 1000.) (dfbul0 et dfbul22)  ;
  349. fin b_des ;
  350. finsi ;
  351. ***
  352. t_bul = table ;
  353. t_bul . modele = momod1 et moq2ux et moq2uy et moq2rz ;
  354. t_bul . caracteristiques = camod1 et caq2ux et caq2uy et caq2rz ;
  355. t_bul . chargement = chq2ux ;
  356. t_bul . blocages_mecaniques = c_pq2ux ;
  357. t_bul . dynamique = vrai ;
  358. t_bul . temps_calcules = abs_t ;
  359. t_bul . temps_sauves = abs_t ;
  360. t_bul .'HYPOTHESE_DEFORMATIONS'='LINEAIRE' ;
  361.  
  362. pasapas t_bul ;
  363. repeter b_des (dime t_bul . deplacements) ;
  364.  ind1= &b_des - 1 ;
  365.  chbul1 = t_bul1 . deplacements . ind1  ;
  366.  dfbul12 = defo chbul1 lig1 1. bleu ;
  367.  chbul3 = t_bul3 . deplacements . ind1  ;
  368.  dfbul13 = defo chbul3 lig1 1. bleu ;
  369.  chbul2 = reco t_bul2 . deplacements . ind1  t_bul2 . modele t_bul2 . caracteristiques ;
  370.  dfbul22 = defo chbul2 lig1 1. rouge ;
  371.  chbul0 = reco t_bul . deplacements . ind1  t_bul . modele t_bul . caracteristiques ;
  372.  dfbul2 = defo chbul0 lig1 1. vert ;
  373.  dfbul0 = defo chbul2 lig1 0. jaune ;
  374.   si dgraph;
  375.  titre 'modal(vert)/EF(bleu) defo t = ' t_bul . temps . ind1 ;
  376.   trac (0. 0. 1000.) (dfbul0 et dfbul12 et dfbul2)  ;
  377.  titre 'impedance modal(rouge)/EF(bleu) - sans(vert)  defo  t = ' t_bul . temps . ind1 ;
  378.   trac (0. 0. 1000.) (dfbul0 et dfbul13 et dfbul2 et dfbul22)  ;
  379.   finsi ;
  380. fin b_des ;
  381. **
  382.  
  383. uxq1_1 = extr chbul1 ux q1 ;
  384. uxq1_2 = extr chbul2 ux q1 ;
  385. uxq1_0 = extr chbul0 ux q1 ;
  386. uxq1_3 = extr chbul3 ux q1 ;
  387.  
  388. err1 = abs (uxq1_1 - uxq1_0); err2 = abs (uxq1_2 - uxq1_3) ;
  389.  
  390.  
  391. si ((err1 > 1.e-2) ou (err2 > 1.e-2)) ;
  392.  erre 5 ;
  393. sinon ;
  394.  erre 0 ;
  395. finsi ;
  396.  
  397. fin ;
  398.  
  399.  
  400.  
  401.  
  402.  
  403.  
  404.  
  405.  
  406.  
  407.  
  408.  
  409.  
  410.  
  411.  
  412.  
  413.  
  414.  
  415.  
  416.  
  417.  
  418.  
  419.  
  420.  
  421.  
  422.  

© Cast3M 2003 - Tous droits réservés.
Mentions légales